home *** CD-ROM | disk | FTP | other *** search
/ InfoMagic Source Code 1993 July / THE_SOURCE_CODE_CD_ROM.iso / bsd_srcs / lib / libc / hp300 / string / bcopy.s < prev    next >
Encoding:
Text File  |  1991-04-12  |  4.2 KB  |  113 lines
  1. /*-
  2.  * Copyright (c) 1990 The Regents of the University of California.
  3.  * All rights reserved.
  4.  *
  5.  * This code is derived from software contributed to Berkeley by
  6.  * the Systems Programming Group of the University of Utah Computer
  7.  * Science Department.
  8.  *
  9.  * Redistribution and use in source and binary forms, with or without
  10.  * modification, are permitted provided that the following conditions
  11.  * are met:
  12.  * 1. Redistributions of source code must retain the above copyright
  13.  *    notice, this list of conditions and the following disclaimer.
  14.  * 2. Redistributions in binary form must reproduce the above copyright
  15.  *    notice, this list of conditions and the following disclaimer in the
  16.  *    documentation and/or other materials provided with the distribution.
  17.  * 3. All advertising materials mentioning features or use of this software
  18.  *    must display the following acknowledgement:
  19.  *    This product includes software developed by the University of
  20.  *    California, Berkeley and its contributors.
  21.  * 4. Neither the name of the University nor the names of its contributors
  22.  *    may be used to endorse or promote products derived from this software
  23.  *    without specific prior written permission.
  24.  *
  25.  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  26.  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  27.  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  28.  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  29.  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  30.  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  31.  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  32.  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  33.  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  34.  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  35.  * SUCH DAMAGE.
  36.  */
  37.  
  38. #if defined(LIBC_SCCS) && !defined(lint)
  39.     .asciz "@(#)bcopy.s    5.1 (Berkeley) 5/12/90"
  40. #endif /* LIBC_SCCS and not lint */
  41.  
  42. #include "DEFS.h"
  43.  
  44. /*
  45.  * This is probably not the best we can do, but it is still 2-10 times
  46.  * faster than the C version in the portable gen directory.
  47.  *
  48.  * Things that might help:
  49.  *    - unroll the longword copy loop (might not be good for a 68020)
  50.  *    - longword align when possible (only on the 68020)
  51.  *    - use nested DBcc instructions or use one and limit size to 64K
  52.  */
  53. ENTRY(bcopy)
  54.     movl    sp@(12),d1    /* check count */
  55.     jle    bcdone        /* <= 0, don't do anything */
  56.     movl    sp@(4),a0    /* src address */
  57.     movl    sp@(8),a1    /* dest address */
  58.     cmpl    a1,a0        /* src after dest? */
  59.     jlt    bcback        /* yes, must copy backwards */
  60.     movl    a0,d0
  61.     btst    #0,d0        /* src address odd? */
  62.     jeq    bcfeven        /* no, skip alignment */
  63.     movb    a0@+,a1@+    /* yes, copy a byte */
  64.     subql    #1,d1        /* adjust count */
  65.     jeq    bcdone        /* count 0, all done  */
  66. bcfeven:
  67.     movl    a1,d0
  68.     btst    #0,d0        /* dest address odd? */
  69.     jne    bcfbloop    /* yes, no hope for alignment, copy bytes */
  70.     movl    d1,d0        /* no, both even */
  71.     lsrl    #2,d0        /* convert count to longword count */
  72.     jeq    bcfbloop    /* count 0, skip longword loop */
  73. bcflloop:
  74.     movl    a0@+,a1@+    /* copy a longword */
  75.     subql    #1,d0        /* adjust count */
  76.     jne    bcflloop    /* still more, keep copying */
  77.     andl    #3,d1        /* what remains */
  78.     jeq    bcdone        /* nothing, all done */
  79. bcfbloop:
  80.     movb    a0@+,a1@+    /* copy a byte */
  81.     subql    #1,d1        /* adjust count */
  82.     jne    bcfbloop    /* still more, keep going */
  83. bcdone:
  84.     rts
  85. bcback:
  86.     addl    d1,a0        /* src pointer to end */
  87.     addl    d1,a1        /* dest pointer to end */
  88.     movl    a0,d0
  89.     btst    #0,d0        /* src address odd? */
  90.     jeq    bcbeven        /* no, skip alignment */
  91.     movb    a0@-,a1@-    /* yes, copy a byte */
  92.     subql    #1,d1        /* adjust count */
  93.     jeq    bcdone        /* count 0, all done  */
  94. bcbeven:
  95.     movl    a1,d0
  96.     btst    #0,d0        /* dest address odd? */
  97.     jne    bcbbloop    /* yes, no hope for alignment, copy bytes */
  98.     movl    d1,d0        /* no, both even */
  99.     lsrl    #2,d0        /* convert count to longword count */
  100.     jeq    bcbbloop    /* count 0, skip longword loop */
  101. bcblloop:
  102.     movl    a0@-,a1@-    /* copy a longword */
  103.     subql    #1,d0        /* adjust count */
  104.     jne    bcblloop    /* still more, keep copying */
  105.     andl    #3,d1        /* what remains */
  106.     jeq    bcdone        /* nothing, all done */
  107. bcbbloop:
  108.     movb    a0@-,a1@-    /* copy a byte */
  109.     subql    #1,d1        /* adjust count */
  110.     jne    bcbbloop    /* still more, keep going */
  111.     rts
  112.  
  113.