home *** CD-ROM | disk | FTP | other *** search
/ InfoMagic Source Code 1993 July / THE_SOURCE_CODE_CD_ROM.iso / bsd_srcs / lib / libc / hp300 / string / bzero.s < prev    next >
Encoding:
Text File  |  1991-04-12  |  3.1 KB  |  79 lines
  1. /*-
  2.  * Copyright (c) 1990 The Regents of the University of California.
  3.  * All rights reserved.
  4.  *
  5.  * This code is derived from software contributed to Berkeley by
  6.  * the Systems Programming Group of the University of Utah Computer
  7.  * Science Department.
  8.  *
  9.  * Redistribution and use in source and binary forms, with or without
  10.  * modification, are permitted provided that the following conditions
  11.  * are met:
  12.  * 1. Redistributions of source code must retain the above copyright
  13.  *    notice, this list of conditions and the following disclaimer.
  14.  * 2. Redistributions in binary form must reproduce the above copyright
  15.  *    notice, this list of conditions and the following disclaimer in the
  16.  *    documentation and/or other materials provided with the distribution.
  17.  * 3. All advertising materials mentioning features or use of this software
  18.  *    must display the following acknowledgement:
  19.  *    This product includes software developed by the University of
  20.  *    California, Berkeley and its contributors.
  21.  * 4. Neither the name of the University nor the names of its contributors
  22.  *    may be used to endorse or promote products derived from this software
  23.  *    without specific prior written permission.
  24.  *
  25.  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  26.  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  27.  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  28.  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  29.  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  30.  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  31.  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  32.  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  33.  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  34.  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  35.  * SUCH DAMAGE.
  36.  */
  37.  
  38. #if defined(LIBC_SCCS) && !defined(lint)
  39.     .asciz "@(#)bzero.s    5.1 (Berkeley) 5/12/90"
  40. #endif /* LIBC_SCCS and not lint */
  41.  
  42. #include "DEFS.h"
  43.  
  44. /*
  45.  * This is probably not the best we can do, but it is still much
  46.  * faster than the C version in the portable gen directory.
  47.  *
  48.  * Things that might help:
  49.  *    - unroll the longword loop (might not be good for a 68020)
  50.  *    - longword, as opposed to word, align when possible (only on the 68020)
  51.  *    - use nested DBcc instructions or use one and limit size to 64K
  52.  */
  53. ENTRY(bzero)
  54.     movl    sp@(4),a0    /* destination */
  55.     movl    sp@(8),d0    /* count */
  56.     jeq    bzdone        /* nothing to do */
  57.     movl    a0,d1
  58.     btst    #0,d1        /* address odd? */
  59.     jeq    bzeven        /* no, skip alignment */
  60.     clrb    a0@+        /* yes, clear a byte */
  61.     subql    #1,d0        /* adjust count */
  62.     jeq    bzdone        /* if zero, all done */
  63. bzeven:
  64.     movl    d0,d1
  65.     lsrl    #2,d1        /* convert to longword count */
  66.     jeq    bzbloop        /* no longwords, skip loop */
  67. bzlloop:
  68.     clrl    a0@+        /* clear a longword */
  69.     subql    #1,d1        /* adjust count */
  70.     jne    bzlloop        /* still more, keep going */
  71.     andl    #3,d0        /* what remains */
  72.     jeq    bzdone        /* nothing, all done */
  73. bzbloop:
  74.     clrb    a0@+        /* clear a byte */
  75.     subql    #1,d0        /* adjust count */
  76.     jne    bzbloop        /* still more, keep going */
  77. bzdone:
  78.     rts
  79.