home *** CD-ROM | disk | FTP | other *** search
/ InfoMagic Source Code 1993 July / THE_SOURCE_CODE_CD_ROM.iso / bsd_srcs / lib / libc / hp300 / string / bcmp.s next >
Encoding:
Text File  |  1991-04-12  |  3.5 KB  |  90 lines
  1. /*-
  2.  * Copyright (c) 1990 The Regents of the University of California.
  3.  * All rights reserved.
  4.  *
  5.  * This code is derived from software contributed to Berkeley by
  6.  * the Systems Programming Group of the University of Utah Computer
  7.  * Science Department.
  8.  *
  9.  * Redistribution and use in source and binary forms, with or without
  10.  * modification, are permitted provided that the following conditions
  11.  * are met:
  12.  * 1. Redistributions of source code must retain the above copyright
  13.  *    notice, this list of conditions and the following disclaimer.
  14.  * 2. Redistributions in binary form must reproduce the above copyright
  15.  *    notice, this list of conditions and the following disclaimer in the
  16.  *    documentation and/or other materials provided with the distribution.
  17.  * 3. All advertising materials mentioning features or use of this software
  18.  *    must display the following acknowledgement:
  19.  *    This product includes software developed by the University of
  20.  *    California, Berkeley and its contributors.
  21.  * 4. Neither the name of the University nor the names of its contributors
  22.  *    may be used to endorse or promote products derived from this software
  23.  *    without specific prior written permission.
  24.  *
  25.  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  26.  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  27.  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  28.  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  29.  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  30.  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  31.  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  32.  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  33.  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  34.  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  35.  * SUCH DAMAGE.
  36.  */
  37.  
  38. #if defined(LIBC_SCCS) && !defined(lint)
  39.     .asciz "@(#)bcmp.s    5.1 (Berkeley) 5/12/90"
  40. #endif /* LIBC_SCCS and not lint */
  41.  
  42. /* bcmp(s1, s2, n) */
  43.  
  44. #include "DEFS.h"
  45.  
  46. /*
  47.  * This is probably not the best we can do, but it is still 2-10 times
  48.  * faster than the C version in the portable gen directory.
  49.  *
  50.  * Things that might help:
  51.  *    - longword align when possible (only on the 68020)
  52.  *    - use nested DBcc instructions or use one and limit size to 64K
  53.  */
  54. ENTRY(bcmp)
  55.     movl    sp@(4),a0    /* string 1 */
  56.     movl    sp@(8),a1    /* string 2 */
  57.     movl    sp@(12),d0    /* length */
  58.     jeq    bcdone        /* if zero, nothing to do */
  59.     movl    a0,d1
  60.     btst    #0,d1        /* string 1 address odd? */
  61.     jeq    bceven        /* no, skip alignment */
  62.     cmpmb    a0@+,a1@+    /* yes, compare a byte */
  63.     jne    bcnoteq        /* not equal, return non-zero */
  64.     subql    #1,d0        /* adjust count */
  65.     jeq    bcdone        /* count 0, reutrn zero */
  66. bceven:
  67.     movl    a1,d1
  68.     btst    #0,d1        /* string 2 address odd? */
  69.     jne    bcbloop        /* yes, no hope for alignment, compare bytes */
  70.     movl    d0,d1        /* no, both even */
  71.     lsrl    #2,d1        /* convert count to longword count */
  72.     jeq    bcbloop        /* count 0, skip longword loop */
  73. bclloop:
  74.     cmpml    a0@+,a1@+    /* compare a longword */
  75.     jne    bcnoteq        /* not equal, return non-zero */
  76.     subql    #1,d1        /* adjust count */
  77.     jne    bclloop        /* still more, keep comparing */
  78.     andl    #3,d0        /* what remains */
  79.     jeq    bcdone        /* nothing, all done */
  80. bcbloop:
  81.     cmpmb    a0@+,a1@+    /* compare a byte */
  82.     jne    bcnoteq        /* not equal, return non-zero */
  83.     subql    #1,d0        /* adjust count */
  84.     jne    bcbloop        /* still more, keep going */
  85.     rts
  86. bcnoteq:
  87.     moveq    #1,d0
  88. bcdone:
  89.     rts
  90.