home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol1 / basic / discone.asc < prev    next >
Text File  |  1996-06-30  |  2KB  |  39 lines
  1. 100 CLS : PRINT "  ************************************"
  2. 110 PRINT "  *    DISKCONE WIDEBAND ANTENNAS    *"
  3. 120 PRINT "  *SEE REFERENCE DATA/RADIO ENGINEERS*"
  4. 130 PRINT "  *           PAGE 25-11             *"
  5. 140 PRINT "  *     PROGRAM COPYRIGHT 1985       *"
  6. 150 PRINT "  *       R.P. HAVILAND, W4MB        *"
  7. 160 PRINT "  ************************************"
  8. 170 REM PROGRAM 11
  9. 180 DEF FNP (X) = INT(10 * X) / 10
  10. 190 PI = 3.14159
  11. 200 INPUT "ENTER LOWEST FREQUENCY, MHZ"; FL
  12. 210 PRINT "ENTER 1 FOR NORMAL CONE, 2 FOR MINIMUM  CONE BASE DIAMETER": INPUT CT
  13. 220 CM = 1.15: IF CT = 2 THEN CM = 1.25
  14. 230 SC = CM * 2834 / FL
  15. 240 CA = 60: IF CT = 2 THEN CA = 35
  16. 300 PRINT : PRINT "ENTER DIAMETER OF CONE TIP, INCHES,"
  17. 310 PRINT "GREATER THAN COAX CONNECTOR DIAMETER "
  18. 320 PRINT "BUT LESS THAN "; FNP(SC / 22); "INCHES ";
  19. 325 PRINT "FOR MAX/F-MIN 9:1 OR MORE"
  20. 328 INPUT CS
  21. 330 SP = .3 * CS
  22. 340 LV = SC * COS(CA / 2 * PI / 180)
  23. 350 CB = CS + 2 * SC * SIN(CA / 2 * PI / 180)
  24. 360 DD = .7 * CB
  25. 400 PRINT : PRINT "THE CONE HALF-ANGLE IS "; CA; " DEGREES"
  26. 410 PRINT "THE CONE HEIGHT IS "; FNP(LV); " INCHES"
  27. 420 PRINT "THE CONE SLANT LENGTH IS "; FNP(SC); " INCHES"
  28. 430 PRINT "THE CONE BASE DIAMETER IS "; FNP(CB); " INCHES"
  29. 440 PRINT "THE CONE TIP DIAMETER IS "; FNP(CS); " INCHES"
  30. 450 PRINT "THE CONE-DISK SPACING IS "; FNP(SP); " INCHES"
  31. 460 PRINT "THE DISK DIAMETER IS "; FNP(DD); " INCHES"
  32. 470 PRINT "THE MAXIMUM FREQUENCY FOR LOW SWR EXCEEDS "; FNP(9 * FL); " MHZ"
  33. 480 PRINT "THE LOWER CUTOFF FREQUENCY IS "; FNP(FL / CM); " MHZ"
  34. 500 PRINT : PRINT "PRESS R RERUN, ANY OTHER KEY FOR MENU"
  35. 510 Q$ = INKEY$: IF Q$ = "" THEN 510
  36. 520 IF Q$ = "R" OR Q$ = "r" THEN RUN
  37. 600 END
  38.  
  39.