home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Antennas
/
Antennas_CD-ROM_Walnut_Creek_September_1996.iso
/
w4mb
/
vol1
/
basic
/
flat.asc
< prev
next >
Wrap
Text File
|
1996-06-30
|
5KB
|
111 lines
100 CLS : PRINT " ***********************************"
110 PRINT " * FLAT TOP BEAMS *"
120 PRINT " * REFERENCES-KRAUS, ANTENNAS *"
130 PRINT " * HAM RADIO, MAY 1976, MAY 1980 *"
140 PRINT " * CQ MAGAZINE, DEC 1973 *"
150 PRINT " * PROGRAM COPYRIGHT 1985 *"
160 PRINT " * R.P. HAVILAND, W4MB *"
170 REM PROGRAM 17
180 PRINT " ***********************************"
190 DEF FNP (X) = INT(100 * X + .5) / 100
200 PRINT "A FLAT TOP BEAM EMPLOYS TWO HALF WAVE DIPOLES, CLOSE SPACED, AND"
210 PRINT " BOTH CENTER FED, OUT OF PHASE"
220 PRINT : PRINT "THE ZL-SPECIAL CHANGES ELEMENT LENGTH TO DEVELOP UNI-DIRECTIONAL GAIN."
230 PRINT : PRINT "THE FOLDED SPECIAL IS FOR SMALL SPACE."
240 PRINT : PRINT "ALL HAVE A TWIST IN THE PHASING LINE."
250 PRINT : INPUT "ENTER DESIGN FREQUENCY, MHZ"; FO
260 LA = 984 / FO
270 PRINT : PRINT "ENTER 1=FLAT-TOP BEAM"
280 PRINT " 2=ZL SPECIAL"
290 PRINT " 3=FOLDED TWIN-LEAD SPECIAL"
300 PRINT " 4=FOLDED TUBING SPECIAL"
310 PRINT " 5=NEW FREQUENCY"
320 PRINT " 6=QUIT"
330 INPUT PC
340 IF PC < 1 OR PC > 6 THEN 320
350 ON PC GOSUB 400, 800, 1200, 1600, 250, 370
360 GOTO 270
370 STOP
400 PRINT " WIRE (THIN) CONDUCTOR IS ASSUMED"
410 LR = .492 * LA
420 SP = LA / 8
430 LS = .4 * LA
440 PRINT "LENGTH RADIATORS="; FNP(LR); "FEET"
450 PRINT "RADIATOR SPACING="; FNP(SP); "FEET"
460 PRINT "OPEN LINE PHASING LENGTH="; FNP(.95 * LA / 2); "FEET"
470 PRINT "TWIN-LEAD PHASING LENGTH="; FNP(LS); "FEET"
480 PRINT : PRINT "GAIN=3.9 DB"
490 PRINT "FRONT/BACK RATIO=0 DB"
500 PRINT "DRIVE IMPEDANCE=9 OHMS"
510 PRINT : PRINT "PRESS A KEY FOR MORE"
520 Q$ = INKEY$: IF Q$ = "" GOTO 520
530 RETURN
800 PRINT : PRINT "FOR ELEMENTS OF 300 OHM TWINLEAD"
810 LF = .4546 * LA
820 LB = .4834 * LA
830 SP = .12 * LA
840 PRINT "FORWARD RADIATOR LENGTH="; FNP(LF); "FEET"
850 PRINT "REAR RADIATOR LENGTH="; FNP(LB); "FEET"
860 PRINT "ELEMENT SPACING="; FNP(SP); "FEET"
870 PRINT "PHASING SECTION LENGTH="; FNP(SP); "FEET"
880 PRINT "FEED POINT IS THE FORWARD RADIATOR"
890 PRINT "GAIN=6 DB"
900 PRINT "FRONT/BACK RATIO=15 DB"
910 PRINT "DRIVE IMPEDANCE=70 OHMS"
920 PRINT : PRINT "PRESS A KEY FOR MORE"
930 Q$ = INKEY$: IF Q$ = "" GOTO 930
940 RETURN
1200 PRINT : PRINT "FOR ELEMENTS OF 300 OHM TWIN-LEAD"
1210 PRINT "WITH ENDS FOLDED WITH 2 INCH SPACING TO GIVE SPAN OF";
1220 PRINT FNP(.292 * LA); "FEET"
1230 PRINT "FRONT ELEMENT LENGTH="; FNP(.4512 * LA); "FEET"
1240 PRINT "REAR ELEMENT LENGTH="; FNP(.4797 * LA); "FEET"
1250 PRINT "SPACING="; FNP(.121 * LA); "FEET"
1260 PRINT "PHASING SECTION LENGTH="; FNP(.121 * LA); "FEET"
1270 PRINT "FEED POINT IS AT THE FORWARD RADIATOR"
1280 PRINT "GAIN=6 DB APPROX."
1290 PRINT "FRONT/BACK RATIO=12 DB APPROX"
1300 PRINT "FEED IMPEDANCE=70 OHMS APPROX."
1310 PRINT "PRESS A KEY FOR MORE"
1320 Q$ = INKEY$: IF Q$ = "" GOTO 1320
1330 RETURN
1600 PRINT : PRINT "FOR THE FOLDED ZL-SPECAL,"
1610 PRINT " ELEMENTS ARE SHAPED AS FOUR U SECTIONS": PRINT
1620 PRINT " AAAAAA AAAAAA ^"
1630 PRINT " B B RADIATION"
1640 PRINT " B B"
1650 PRINT " CCCCC CCCCC": PRINT
1660 PRINT " EEEEEE EEEEEE"
1670 PRINT " F F"
1680 PRINT " F F"
1690 PRINT " GGGGG GGGGG": PRINT
1700 PRINT " AA AND EE ARE CONNECTED BY A PHASING "
1710 PRINT "SECTION WITH A 180 DEG TWIST"
1720 PRINT : PRINT "PRESS A KEY TO CONTINUE"
1730 Q$ = INKEY$: IF Q$ = "" THEN 1730
1740 PRINT : PRINT "DIMENSIONS IN FEET ARE"
1750 PRINT : PRINT " LENGTH OF AAAAAA="; FNP(.0805 * LA)
1760 PRINT " LENGTH OF BB="; FNP(.0722 * LA)
1770 PRINT " LENGTH OF CCCCC="; FNP(.0794 * LA)
1780 PRINT " SEPARATION, C-E="; FNP(8.999999E-03 * LA)
1790 PRINT " LENGTH OF EEEEEE="; FNP(.0794 * LA)
1800 PRINT " LENGTH OF FF="; FNP(.0745 * LA)
1810 PRINT " LENGTH OF GGGGG="; FNP(.072 * LA)
1820 PRINT " LENGTH OF PHASING SECTION="; FNP(.1034 * LA)
1830 PRINT : PRINT "PRESS A KEY TO CONTINUE"
1840 Q$ = INKEY$: IF Q$ = "" GOTO 1840
1850 DS = .25 * INT(28 / FO + .5)
1860 IF DS = 0 THEN DS = .25
1870 DS = .25 * INT(28 / FO + .5)
1880 IF DS = 0 THEN DS = .25
1900 PRINT "DIAMETER OF SECTIONS AAAAAA AND EEEEEE ARE"; DS; "INCHES"
1910 PRINT "OTHER SECTIONS HALF THIS"
1920 PRINT "DRIVE IMPEDANCE=48 OHMS"
1930 PRINT "GAIN=4 DB APPROX."
1940 PRINT "F-B RATIO=10 DB APPROX."
1950 PRINT "TURNING RADIUS="; FNP(.102 * LA + .15); "FEET"
1960 PRINT : PRINT "PRESS A KEY TO CONTINUE"
1970 Q$ = INKEY$: IF Q$ = "" THEN 1970
1980 RETURN