home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol1 / basic / dipoles.asc < prev    next >
Text File  |  1996-06-30  |  2KB  |  45 lines
  1. 100 CLS : PRINT "   ***********************************"
  2. 110 PRINT "   *      DIPOLES NEAR RESONANCE     *"
  3. 120 PRINT "   *   REFERENCE-LAWSON, HAM RADIO   *"
  4. 130 PRINT "   *      JANUARY, DECEMBER 1980     *"
  5. 140 PRINT "   *     JASIK,  ANTENNA HANDBOOK    *"
  6. 150 PRINT "   *      PROGRAM COPYRIGHT, 1985    *"
  7. 160 PRINT "   *       R.P. HAVILAND, W4MB       *"
  8. 180 PRINT "   ***********************************"
  9. 185 REM PROGRAM 1
  10. 190 PRINT
  11. 200 DEF FNP (X) = INT(100 * X + .5) / 100: PI = 3.14159
  12. 210 INPUT "ENTER DESIGN FREQUENCY, MHZ"; FO
  13. 220 INPUT "ENTER CONDUCTOR DIAMETER, INCHES"; DC
  14. 230 PRINT : PRINT "ENTER TYPE OF CONSTRUCTION"
  15. 240 PRINT "        1=END SUPPORTED"
  16. 250 PRINT "        2=CENTER (BOOM) SUPPORTED"
  17. 260 INPUT AQ: IF AQ < 1 OR AQ > 2 THEN 230
  18. 270 IF AQ = 2 THEN PRINT "ENTER SUPPORT WIDTH,INCHES": INPUT DB
  19. 400 LA = 984 / FO
  20. 410 LD = LA / 2
  21. 420 KR = 12 * LD / DC
  22. 430 LR = 1 - 1 / (4.6719 * LOG(KR) - 8)
  23. 440 TV = LA * LR / 2
  24. 450 IF ABS(LD - TV) > .00001 THEN LD = TV: GOTO 420
  25. 500 PRINT : PRINT "THE FREE-SPACE WAVELENGTH="; FNP(LA); "FEET"
  26. 510 PRINT "THE LENGTH-DIAMETER RATIO IS"; FNP(KR)
  27. 520 PRINT : PRINT "UNSUPPORTED ANTENNA LENGTH="; FNP(LD); "FEET"
  28. 530 IF AQ = 1 THEN PRINT "THE END SUPPORTED LENGTH="; FNP(.95 * LD); "FEET": GOTO 550
  29. 540 PRINT "THE CENTER SUPPORTED LENGTH="; FNP(LD + .7 * DB / 12); "FEET"
  30. 550 PRINT : PRINT "PRESS A KEY FOR MORE"
  31. 560 T$ = INKEY$: IF T$ = "" THEN 560
  32. 600 PRINT : PRINT "FEED VALUES AND 50 OHM LINE SWR ARE"
  33. 610 PRINT : PRINT "FREQUENCY", "RESISTANCE", "REACTANCE", "SWR"
  34. 620 FOR N = .9 TO 1.1 STEP .02
  35. 630 RR = 17.32 + 30 * LOG(2 * PI * LR * N)
  36. 640 XR = (18.6777 * LOG(KR) + 32) * (N - 1) / .1
  37. 650 ZR = SQR(RR * RR + XR * XR)
  38. 660 RC = SQR(((RR - 50) * (RR - 50) + XR * XR) / ((RR + 50) * (RR + 50) + XR * XR))
  39. 670 SW = (1 + RC) / (1 - RC)
  40. 680 PRINT FNP(N * FO), FNP(RR), FNP(XR), FNP(SW)
  41. 690 NEXT N
  42. 800 PRINT "PRESS R TO RERUN, ANY OTHER KEY TO QUIT."
  43. 810 R$ = INKEY$: IF R$ = "" THEN 810
  44. 820 IF R$ = "R" OR R$ = "r" THEN RUN
  45.