home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Antennas
/
Antennas_CD-ROM_Walnut_Creek_September_1996.iso
/
w4mb
/
vol1
/
basic
/
depth.asc
< prev
next >
Wrap
Text File
|
1996-06-30
|
2KB
|
64 lines
100 CLS : PRINT " ************************************"
110 PRINT " * POLE AND ANCHOR DEPTHS *"
120 PRINT " *REFERENCE-BUSACK, HP PROGRAM 3636D*"
130 PRINT " * HART,HAM RADIO, MAY 1980 *"
140 PRINT " * PROGRAM COPYRIGHT 1985 *"
150 PRINT " * R.P. HAVILAND, W4MB *"
160 PRINT " ************************************"
170 REM PROGRAM 30
200 PRINT "CAUTION- MOST LOCALES HAVE REGULATIONS FOR FOUNDATION DESIGN"
210 PRINT " USE THIS PROGRAM FOR PRELIMINARY DESIGN AND CHECKING ONLY"
300 PRINT : PRINT " ENTER 1=POLE DEPTH"
310 PRINT " 2=ANCHOR DEPTH"
320 PRINT " 3=QUIT"
330 INPUT MS
340 IF MS = 1 THEN GOTO 1000
350 IF MS = 2 THEN GOTO 2000
360 IF MS = 3 THEN GOTO 3000
370 GOTO 300
1000 PRINT "ENTER DISTANCE, GROUND TO POINT OF LATERAL FORCE"
1010 PRINT " APPLICATION POINT, FEET"
1020 INPUT FH
1030 INPUT "ENTER LATERAL FORCE, POUNDS"; LF
1040 SP = 725
1050 PRINT "ENTER ALLOWABLE SOIL PRESSURE, OR RETURN ONLY=725 PSI"
1060 INPUT SP
1065 IF SP = 0 THEN SP = 725
1070 PRINT "ENTER POLE DIAMETER, INCHES, OR ZERO= SQUARE POLE"
1080 INPUT DA
1090 IF DA < 0 THEN 1070
1100 IF DA <> 0 THEN 1130
1110 INPUT " ENTER FACE WIDTH, INCHES"; WF
1120 DA = 1.414 * WF
1130 DA = DA / 12
1140 D1 = 12
1150 PRINT "ENTER INITIAL ESTIMATE OF POLE DEPTH, FEET; RETURN ONLY =12"
1160 INPUT D1
1165 IF D1 = 0 THEN D1 = 12
1200 GOSUB 1900
1210 IF ABS(D2 - D1) > .01 THEN D1 = (D1 + D2) / 2: GOTO 1200
1220 IF D2 > 12 THEN D1 = 12: GOSUB 1900
1400 PRINT " THE POLE SHOULD BE BURIED"; INT(10 * D2 + .5) / 10; "FEET, MINIMUN DEPTH"
1410 PRINT
1420 PRINT " ON RERUN, REENTER ALL VALUES"
1430 GOTO 300
1900 A = 7.02 * LF / SP / DA / D1
1910 D2 = A / 2 * (1 + SQR(1 + 4.36 * FH / A))
1920 RETURN
2000 PRINT : PRINT "ENTER 1=GOOD DRY SOIL"
2010 PRINT " 2= ANCHOR UNDER WATER"
2020 INPUT WS
2030 IF WS = 1 THEN WE = 100: GOTO 2100
2040 IF WS = 2 THEN WE = 37.7: GOTO 2100
2050 GOTO 2020
2100 INPUT " ENTER LIFTING FORCE ON ANCHOR, LBS"; LF
2110 VO = LF / WE
2120 DB = (2.868 * VO) ^ (1 / 3)
2200 PRINT " THE ANCHOR SHOULD BE BURIED"; INT(10 * DB + .5) / 10; "FEET"
2210 IF WS = 2 THEN PRINT " BELOW WATER BOTTOM"
2220 PRINT
2230 PRINT " ON RERUN,REENTER ALL VALUES"
2240 GOTO 300
3000 END