home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Antennas
/
Antennas_CD-ROM_Walnut_Creek_September_1996.iso
/
w4mb
/
vol1
/
basic
/
cylind.asc
< prev
next >
Wrap
Text File
|
1996-06-30
|
2KB
|
45 lines
100 CLS : PRINT "***************************************"
110 PRINT "* GENERAL CYLINDRICAL ANTENNAS *"
120 PRINT "* REFERENCE-SCHELKUNOFF, *"
130 PRINT "* ELECTROMAGNETIC WAVES,PAGE 452FF *"
140 PRINT "* COPYRIGHT 1985 *"
150 PRINT "* R.P. HAVILAND, W4MB *"
160 PRINT "***************************************"
170 REM PROGRAM 2
180 PRINT
190 PI = 3.14159
200 INPUT "ENTER DIAMETER OF ANTENNA, INCHES"; DA
210 INPUT "ENTER HALF-LENGTH OF ANTENNA, FEET"; LE
220 INPUT "ENTER OPERATING FREQUENCY, MHZ"; FO
300 LA = 984 / FO
310 LP = 2 * PI * LE / LA
320 KA = 120 * (LOG(48 * LE / DA) - 1)
330 LQ = LP * 2
340 LR = LP * 4
350 IF LQ > 5 THEN C2 = SIN(LQ) / LQ: S2 = PI / 2 - COS(LQ) / LQ: GOTO 380
360 C2 = .577 + LOG(LQ) - LQ ^ 2 / 4 + LQ ^ 4 / 96 - LQ ^ 6 / 4320 + LQ ^ 8 / 322560! - LQ ^ 10 / 36288000#
370 S2 = LQ - LQ ^ 3 / 18 + LQ ^ 5 / 600 - LQ ^ 7 / 35280! + LQ ^ 9 / 3265920!
380 IF LR > 5 THEN C4 = SIN(LR) / LR: S4 = PI / 2 - COS(LR) / LR: GOTO 410
390 C4 = .577 + LOG(LR) - LR ^ 2 / 4 + LR ^ 4 / 96 - LR ^ 6 / 4320 + LR ^ 8 / 322560! - LR ^ 10 / 36288000#
400 S4 = LR - LR ^ 3 / 18 + LR ^ 5 / 600 - LR ^ 7 / 35280! + LR ^ 9 / 3265920!
410 ML = 60 * (LOG(LQ) - C2 + .577 - 1 + COS(LQ))
420 NL = 60 * (S2 - SIN(LQ))
430 RA = 60 * (.577 + LOG(LQ) - C2) + 30 * (.577 + LOG(LP) - 2 * C2 + C4) * COS(LQ)
440 RA = RA + 30 * (S4 - 2 * S2) * SIN(LQ)
450 XA = 60 * S2 + 30 * (C4 - LOG(LP) - .577) * SIN(LQ) - 30 * S4 * COS(LQ)
460 DE = RA * RA * (COS(LP)) ^ 2 + ((KA + ML) * SIN(LP) + (XA + NL) * COS(LP)) ^ 2
470 RI = KA * RA * (KA + NL * SIN(LQ) - ML * COS(LQ))
480 RI = RI / DE
490 XI = (RA * RA + XA * XA + ML * ML - NL * NL - KA * KA) * SIN(LQ) / 2
500 XI = XI + (ML * NL - KA * XA) * COS(LQ) + ML * XA - KA * NL
510 XI = XI * KA / DE
600 PRINT : PRINT : PRINT "THE KA OF THE ANTENNA IS"; INT(KA)
610 PRINT "THE HALF-LENGTH IS"; INT(1000 * LP / 2 / PI) / 1000; "WAVELENGTHS"
620 PRINT "THE CENTER RESISTANCE IS "; INT(10 * RI) / 10; "OHMS"
630 PRINT "THE CENTER REACTANCE IS "; INT(10 * XI) / 10; "OHMS"
1000 PRINT : PRINT "PRESS R TO RERUN ANY OTHER KEY TO QUIT"
1010 Q$ = INKEY$: IF Q$ = "" THEN 1010
1020 IF Q$ = "R" OR Q$ = "r" THEN RUN
1100 END