home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG041.ARK / TTYR.ASM < prev    next >
Assembly Source File  |  1984-04-29  |  5KB  |  182 lines
  1. ; 
  2. ;    ASCRCV(4), VER. 2
  3. ; BY KEITH PETERSEN, W8SDZ.  10/30/78.
  4. ; 
  5. ; THIS IS A PROGRAM TO CHANGE
  6. ; ASCII-CODED-BAUDOT TO ASCII.
  7. ; THE ROUTINE RETURNS WITH A 0FFH
  8. ; IN THE 'A' REGISTER IF CHARACTER
  9. ; IS TO BE IGNORED.  OTHERWISE IT
  10. ; RETURNS WITH THE ASCII CHARACTER
  11. ; IN THE 'A' REGISTER.  IT IS ASSUMED
  12. ; THAT A STATUS TEST HAS BEEN DONE BEFORE
  13. ; CALLING THIS ROUTINE TO DETERMINE THAT
  14. ; A BAUDOT CHARACTER IS AVAILABLE.
  15. ; 
  16. ; EQUATES
  17. ; 
  18. BTTY:    EQU    0BH    ;BAUDOT UART DATA PORT
  19. CR:    EQU    0DH    ;ASCII CARRIAGE RETURN
  20. LF:    EQU    0AH    ;ASCII LINE FEED
  21. BELL:    EQU    07H    ;ASCII BELL
  22. LTRS:    EQU    1FH    ;BAUDOT 'LTRS'
  23. SPACE:    EQU    04H    ;BAUDOT 'SPACE'
  24. FIGS:    EQU    1BH    ;BAUDOT 'FIGS'
  25. APOS:    EQU    27H    ;APOSTROPHE
  26. CNTC:    EQU    03H    ;CONTROL C
  27. LARW:    EQU    5FH    ;LEFT ARROW
  28. ASPC:    EQU    20H    ;ASCII SPACE
  29. ATSN:    EQU    40H    ;"AT" SIGN
  30. CNTV:    EQU    16H    ;CONTROL V
  31. CNTO:    EQU    0FH    ;CONTROL O
  32. RUBT:    EQU    7FH    ;RUBOUT
  33. CNTE:    EQU    05H    ;CONTROL E
  34. PCT:    EQU    25H    ;PERCENT SIGN
  35. EQUL:    EQU    3DH    ;EQUALS SIGN
  36. GRTH:    EQU    3EH    ;GREATER-THAN SIGN
  37. CNTH:    EQU    08H    ;CONTROL H
  38. LETH:    EQU    3CH    ;LESS-THAN SIGN
  39. CNTB:    EQU    02H    ;CONTROL B
  40. STAR:    EQU    2AH    ;ASTERISK
  41. CNTI:    EQU    09H    ;CONTROL I
  42. CNTZ:    EQU    1AH    ;CONTROL Z
  43. CNTA:    EQU    01H    ;CONTROL A
  44. CNTX:    EQU    18H    ;CONTROL X
  45. UARW:    EQU    5EH    ;UP-ARROW
  46. PLUS:    EQU    2BH    ;PLUS SIGN
  47. RESL:    EQU    5CH    ;REVERSE SLANT
  48. LBKT:    EQU    5BH    ;LEFT BRACKET
  49. RBKT:    EQU    5DH    ;RIGHT BRACKET
  50. ESCP:    EQU    1BH    ;ESCAPE KEY
  51. ALMD:    EQU    7DH    ;ALTERNATE MODE KEY
  52. BEGIN:    EQU    0FB00H    ;MY ADDRESS FOR THIS PROGRAM
  53. ; 
  54. ; PROGRAM STARTS HERE
  55. ; 
  56.     ORG    BEGIN    ;PUT DESIRED ADDRESS HERE
  57. ; 
  58. ASCRCV:    PUSH    H    ;SAVE HL REGISTERS
  59.     LHLD    CASAVE    ;GET PRESENT CASE
  60. ; 
  61. START:    IN    BTTY    ;GET BAUDOT CHARACTER
  62.     ANI    1FH    ;BAUDOT CHARACTERS ONLY
  63.     CPI    FIGS
  64.     JZ    UCASE
  65.     CPI    LTRS
  66.     JZ    LCASE
  67.     ORA    A    ;BAUDOT 'BLANK' ?
  68.     JZ    TCASE
  69.     CPI    SPACE
  70.     JNZ    START1
  71.     LXI    H,LTABLE ;SPACE GIVES LOWER CASE
  72. ; 
  73. START1:    SHLD    CASAVE    ;SAVE PRESENT CASE
  74.     ADD    L    ;ADD CHAR. TO TABLE ADRS.
  75.     MOV    L,A    ;L POINTS TO ASCII CHAR.
  76.     MOV    A,H    ;GET H FOR CORRECTION
  77.     ACI    0    ;SEE IF CORRECTION NEEDED
  78.     MOV    H,A    ;H IS CORRECT NOW
  79.     XRA    A    ;PUT ZERO IN A REG.
  80.     STA    FLAG    ;CLEAR LTRS-FIGS LAST FLAG
  81.     MOV    A,M    ;GET ASCII EQUIVALENT
  82.     POP    H    ;RESTORE HL REGISTERS
  83.     ORA    A    ;IS IT PRINTABLE?
  84.     RNZ        ;YES, VALID CHAR. RETURN
  85.     CMA        ;MAKE 0FFH 'IGNORE FLAG'
  86.     RET        ;RETURN TO CALLING PROGRAM
  87. ; 
  88. LCASE:    LXI    H,LTABLE ;LOWER CASE TABLE ADDRESS
  89.     JMP    SETFLG    ;SET LTRS LAST FLAG, EXIT
  90. ; 
  91. UCASE:    LXI    H,UTABLE ;UPPER CASE TABLE ADDRESS
  92.     JMP    SETFLG    ;SET FIGS LAST FLAG, EXIT
  93. ; 
  94. TCASE:    LDA    FLAG    ;GET SHIFT REMINDER FLAG
  95.     CPI    FIGS
  96.     JNZ    FCASE
  97.     LXI    H,TTABLE ;THIRD CASE TABLE ADDRESS
  98.     JMP    CLRFLG
  99. ; 
  100. FCASE:    CPI    LTRS    ;CHECK FOR LTRS LAST
  101.     JNZ    CLRFLG
  102.     LXI    H,FTABLE ;FOURTH CASE TABLE ADDRESS
  103. ; 
  104. CLRFLG:    XRA    A    ;READY TO CLEAR FLAG
  105. ; 
  106. SETFLG:    STA    FLAG    ;LTRS-FIGS LAST FLAG
  107.     SHLD    CASAVE    ;SAVE PRESENT CASE
  108.     MVI    A,0FFH    ;'IGNORE FLAG'
  109.     POP    H    ;RESTORE HL REGS.
  110.     RET        ;RETURN TO CALLING PROGRAM
  111. ; 
  112. ; THIS IS THE LOWER-CASE TABLE.
  113. ; 
  114. LTABLE:    DB    0,'E',LF,'A SIU',CR,'DRJNFCK'
  115.     DB    'TZLWHYPQOBG',FIGS,'MXV'
  116. ; 
  117. ; THIS IS THE UPPER-CASE TABLE.
  118. ; 
  119. UTABLE:    DB    0,'3',LF,'- ',BELL,'87',CR,'$4'
  120.     DB    APOS,',!:(5")2#6019?&',FIGS,'./;'
  121. ; 
  122. ; THIS IS THE THIRD-CASE TABLE.
  123. ; IT IS USED FOR SPECIAL CHARACTERS.
  124. ; THE FIRST COLUMN IN THE TABLE
  125. ; THE ASCII CHARACTER EQUIVALENT.
  126. ; THE SECOND COLUMN IS THE SPECIAL
  127. ; CASE BAUDOT CHARACTER FROM WHICH
  128. ; THE CONVERSION IS MADE.
  129. ; 
  130. TTABLE:    DB    0,CNTC,LF    ;BL  3   LF
  131.     DB    LARW,ASPC,ATSN    ;-   SP  BELL
  132.     DB    CNTV,CNTO,CR    ;8   7   CR
  133.     DB    ALMD,CNTE,PCT    ;$   4   '
  134.     DB    RUBT,EQUL,ESCP    ;,   !   :
  135.     DB    LETH,CNTH,LBKT    ;(   5   "
  136.     DB    GRTH,CNTB,STAR    ;)   2   #
  137.     DB    CNTI,CNTZ,CNTA    ;6   0   1
  138.     DB    CNTX,UARW,PLUS    ;9   ?   &
  139.     DB    0,RBKT,RESL    ;FIG .   /
  140.     DB    0            ;;
  141. ; 
  142. ; THIS IS THE FOURTH CASE TABLE
  143. ; FOR LOWER-CASE ALPHA CHARACTERS.
  144. ; 
  145. FTABLE:    DB    0,65H,LF,61H,ASPC,73H
  146.     DB    69H,75H,CR,64H,72H,6AH
  147.     DB    6EH,66H,63H,6BH,74H,7AH
  148.     DB    6CH,77H,68H,79H,70H,71H
  149.     DB    6FH,62H,67H,FIGS,6DH,78H
  150.     DB    76H
  151. ; 
  152. ; TEMPORARY STORAGE AREA
  153. ; 
  154. CASAVE:    DW    LTABLE    ;PRESENT CASE REMINDER
  155. FLAG:    DB    0    ;FIGS/LTRS LAST FLAG
  156. ; 
  157.     END
  158.   
  159. ; THIS IS A SAMPLE OF THE POLLING ROUTINE
  160. ; USED TO ALLOW INPUT FROM EITHER THE ASCII
  161. ; OR BAUDOT KEYBOARD INPUT PORTS.  IT CAN
  162. ; BE LINKED TO ANY PROGRAM WHICH USES A
  163. ; NORMAL INPUT ROUTINE WHICH RETURNS WITH
  164. ; THE ASCII CHARACTER IN THE ACCUMULATOR.
  165. ; 
  166. POLL:    IN    BSTATUS    ;BAUDOT UART STATUS PORT
  167.     ANI    RDA    ;TEST FOR RCVE DATA AVAIL FLAG
  168.     JZ    POLL2    ;NO CHAR. TEST ASCII (MAY NEED JNZ HERE)
  169.     CALL    ASCRCV4    ;CHARACTER THERE, GET AND CONVERT
  170.     CPI    0FFH    ;IGNORE FLAG THERE?
  171.     RNZ        ;NO, RETURN WITH ASCII CHARACTER
  172. ; 
  173. POLL2:    IN    ASTATUS    ;GET ASCII UART STATUS
  174.     ANI    RDA    ;TEST DATA AVAIL. FLAG
  175.     JZ    POLL    ;NO CHAR., RESUME POLLING (MAY NEED JNZ HERE)
  176.     IN    ADATA    ;GET ASCII UART DATA
  177.     ANI    7FH    ;STRIP PARITY BIT
  178.     RET        ;ASCII CHAR. IN ACCUMULATOR
  179. ; 
  180. ; END OF SAMPLE POLLING ROUTINE.
  181.  
  182.