home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG041.ARK / TTY.ASM < prev    next >
Assembly Source File  |  1984-04-29  |  8KB  |  350 lines
  1. ;SYSTEM EQUATES
  2. UART1    EQU    02400H    ;ASCII PORT
  3. UART2    EQU    02B00H    ;TTY PORT
  4. ; 
  5. ;    BEGINING OF ROUTINE
  6.     ORG    0400H
  7. ;
  8. LOOP:
  9.     LDA    UART1+1
  10.     ANI    02H
  11.     JZ    LOOP1
  12.     LDA    UART1
  13.     ANI    7FH
  14.     CPI    0DH
  15.     CZ    CRLF
  16.     STA    UART1
  17.     CALL    TTYXMIT
  18. LOOP1:
  19.     LDA    UART2+1
  20.     ANI    02H
  21.     JZ    LOOP
  22.     CALL    TTYRCV
  23.     STA    UART1
  24.     JMP    LOOP
  25. CRLF:
  26.     PUSH    PSW
  27.     CALL    TTYXMIT
  28.     MVI    A,0DH
  29.     CALL    TTYXMIT
  30.     MVI    A,0AH
  31.     STA    UART1
  32.     CALL    TTYXMIT
  33.     POP    PSW
  34.     RET
  35. ;    ASCRCV(4), VER. 2
  36. ; BY KEITH PETERSEN, W8SDZ.  10/30/78.
  37. ; 
  38. ; THIS IS A PROGRAM TO CHANGE
  39. ; ASCII-CODED-BAUDOT TO ASCII.
  40. ; THE ROUTINE RETURNS WITH A 0FFH
  41. ; IN THE 'A' REGISTER IF CHARACTER
  42. ; IS TO BE IGNORED.  OTHERWISE IT
  43. ; RETURNS WITH THE ASCII CHARACTER
  44. ; IN THE 'A' REGISTER.  IT IS ASSUMED
  45. ; THAT A STATUS TEST HAS BEEN DONE BEFORE
  46. ; CALLING THIS ROUTINE TO DETERMINE THAT
  47. ; A BAUDOT CHARACTER IS AVAILABLE.
  48. ; 
  49. ; EQUATES
  50. ; 
  51. BTTY:    EQU    02B00H    ;BAUDOT UART DATA PORT
  52. CR:    EQU    0DH    ;ASCII CARRIAGE RETURN
  53. LF:    EQU    0AH    ;ASCII LINE FEED
  54. BELL:    EQU    07H    ;ASCII BELL
  55. LTRS:    EQU    1FH    ;BAUDOT 'LTRS'
  56. SPACE:    EQU    04H    ;BAUDOT 'SPACE'
  57. FIGS:    EQU    1BH    ;BAUDOT 'FIGS'
  58. APOS:    EQU    27H    ;APOSTROPHE
  59. CNTC:    EQU    03H    ;CONTROL C
  60. LARW:    EQU    5FH    ;LEFT ARROW
  61. ASPC:    EQU    20H    ;ASCII SPACE
  62. ATSN:    EQU    40H    ;"AT" SIGN
  63. CNTV:    EQU    16H    ;CONTROL V
  64. CNTO:    EQU    0FH    ;CONTROL O
  65. RUBT:    EQU    7FH    ;RUBOUT
  66. CNTE:    EQU    05H    ;CONTROL E
  67. PCT:    EQU    25H    ;PERCENT SIGN
  68. EQUL:    EQU    3DH    ;EQUALS SIGN
  69. GRTH:    EQU    3EH    ;GREATER-THAN SIGN
  70. CNTH:    EQU    08H    ;CONTROL H
  71. LETH:    EQU    3CH    ;LESS-THAN SIGN
  72. CNTB:    EQU    02H    ;CONTROL B
  73. STAR:    EQU    2AH    ;ASTERISK
  74. CNTI:    EQU    09H    ;CONTROL I
  75. CNTZ:    EQU    1AH    ;CONTROL Z
  76. CNTA:    EQU    01H    ;CONTROL A
  77. CNTX:    EQU    18H    ;CONTROL X
  78. UARW:    EQU    5EH    ;UP-ARROW
  79. PLUS:    EQU    2BH    ;PLUS SIGN
  80. RESL:    EQU    5CH    ;REVERSE SLANT
  81. LBKT:    EQU    5BH    ;LEFT BRACKET
  82. RBKT:    EQU    5DH    ;RIGHT BRACKET
  83. ESCP:    EQU    1BH    ;ESCAPE KEY
  84. ALMD:    EQU    7DH    ;ALTERNATE MODE KEY
  85. BEGIN:    EQU    $    ;MY ADDRESS FOR THIS PROGRAM
  86. ; 
  87. ; PROGRAM STARTS HERE
  88. ; 
  89. TTYRCV:
  90. ; 
  91. ASCRCV:    PUSH    H    ;SAVE HL REGISTERS
  92.     LHLD    CASAVE    ;GET PRESENT CASE
  93. ; 
  94. START:    LDA    BTTY    ;GET BAUDOT CHARACTER
  95.     ANI    1FH    ;BAUDOT CHARACTERS ONLY
  96.     CPI    FIGS
  97.     JZ    UCASE
  98.     CPI    LTRS
  99.     JZ    LCASE
  100.     ORA    A    ;BAUDOT 'BLANK' ?
  101.     JZ    TCASE
  102.     CPI    SPACE
  103.     JNZ    START1
  104.     LXI    H,LTABLE ;SPACE GIVES LOWER CASE
  105. ; 
  106. START1:    SHLD    CASAVE    ;SAVE PRESENT CASE
  107.     ADD    L    ;ADD CHAR. TO TABLE ADRS.
  108.     MOV    L,A    ;L POINTS TO ASCII CHAR.
  109.     MOV    A,H    ;GET H FOR CORRECTION
  110.     ACI    0    ;SEE IF CORRECTION NEEDED
  111.     MOV    H,A    ;H IS CORRECT NOW
  112.     XRA    A    ;PUT ZERO IN A REG.
  113.     STA    FLAG    ;CLEAR LTRS-FIGS LAST FLAG
  114.     MOV    A,M    ;GET ASCII EQUIVALENT
  115.     POP    H    ;RESTORE HL REGISTERS
  116.     ORA    A    ;IS IT PRINTABLE?
  117.     RNZ        ;YES, VALID CHAR. RETURN
  118.     CMA        ;MAKE 0FFH 'IGNORE FLAG'
  119.     RET        ;RETURN TO CALLING PROGRAM
  120. ; 
  121. LCASE:    LXI    H,LTABLE ;LOWER CASE TABLE ADDRESS
  122.     JMP    SETFLG    ;SET LTRS LAST FLAG, EXIT
  123. ; 
  124. UCASE:    LXI    H,UTABLE ;UPPER CASE TABLE ADDRESS
  125.     JMP    SETFLG    ;SET FIGS LAST FLAG, EXIT
  126. ; 
  127. TCASE:    LDA    FLAG    ;GET SHIFT REMINDER FLAG
  128.     CPI    FIGS
  129.     JNZ    FCASE
  130.     LXI    H,TTABLE ;THIRD CASE TABLE ADDRESS
  131.     JMP    CLRFLG
  132. ; 
  133. FCASE:    CPI    LTRS    ;CHECK FOR LTRS LAST
  134.     JNZ    CLRFLG
  135.     LXI    H,FTABLE ;FOURTH CASE TABLE ADDRESS
  136. ; 
  137. CLRFLG:    XRA    A    ;READY TO CLEAR FLAG
  138. ; 
  139. SETFLG:    STA    FLAG    ;LTRS-FIGS LAST FLAG
  140.     SHLD    CASAVE    ;SAVE PRESENT CASE
  141.     MVI    A,0FFH    ;'IGNORE FLAG'
  142.     POP    H    ;RESTORE HL REGS.
  143.     RET        ;RETURN TO CALLING PROGRAM
  144. ; 
  145. ; THIS IS THE LOWER-CASE TABLE.
  146. ; 
  147. LTABLE:    DB    0,'E',LF,'A SIU',CR,'DRJNFCK'
  148.     DB    'TZLWHYPQOBG',FIGS,'MXV'
  149. ; 
  150. ; THIS IS THE UPPER-CASE TABLE.
  151. ; 
  152. UTABLE:    DB    0,'3',LF,'- ',BELL,'87',CR,'$4'
  153.     DB    APOS,',!:(5")2#6019?&',FIGS,'./;'
  154. ; 
  155. ; THIS IS THE THIRD-CASE TABLE.
  156. ; IT IS USED FOR SPECIAL CHARACTERS.
  157. ; THE FIRST COLUMN IN THE TABLE
  158. ; THE ASCII CHARACTER EQUIVALENT.
  159. ; THE SECOND COLUMN IS THE SPECIAL
  160. ; CASE BAUDOT CHARACTER FROM WHICH
  161. ; THE CONVERSION IS MADE.
  162. ; 
  163. TTABLE:    DB    0,CNTC,LF    ;BL  3   LF
  164.     DB    LARW,ASPC,ATSN    ;-   SP  BELL
  165.     DB    CNTV,CNTO,CR    ;8   7   CR
  166.     DB    ALMD,CNTE,PCT    ;$   4   '
  167.     DB    RUBT,EQUL,ESCP    ;,   !   :
  168.     DB    LETH,CNTH,LBKT    ;(   5   "
  169.     DB    GRTH,CNTB,STAR    ;)   2   #
  170.     DB    CNTI,CNTZ,CNTA    ;6   0   1
  171.     DB    CNTX,UARW,PLUS    ;9   ?   &
  172.     DB    0,RBKT,RESL    ;FIG .   /
  173.     DB    0            ;;
  174. ; 
  175. ; THIS IS THE FOURTH CASE TABLE
  176. ; FOR LOWER-CASE ALPHA CHARACTERS.
  177. ; 
  178. FTABLE:    DB    0,65H,LF,61H,ASPC,73H
  179.     DB    69H,75H,CR,64H,72H,6AH
  180.     DB    6EH,66H,63H,6BH,74H,7AH
  181.     DB    6CH,77H,68H,79H,70H,71H
  182.     DB    6FH,62H,67H,FIGS,6DH,78H
  183.     DB    76H
  184. ; 
  185. ; TEMPORARY STORAGE AREA
  186. ; 
  187. ; 
  188. ; 
  189. ;        ASCXMT(4) REV. 2
  190. ;    BY KEITH PETERSEN, W8SDZ.  10/29/78.
  191. ; 
  192. ; THIS PROGRAM IS FOR TRANSMITTING ASCII
  193. ; THROUGH A BAUDOT MEDIUM USE A SPECIAL
  194. ; FORMAT OF FIGURES BLANK (X) - WHERE (X)
  195. ; IS A SPECIAL BAUDOT CHARACTER USED TO
  196. ; CONVEY THE ASCII EQUIVALENT CHARACTER TO THE
  197. ; RECEIVING END WHERE IT IS THEN CONVERTED BACK
  198. ; TO ASCII AGAIN.  LOWER CASE ALPHA CHARACTERS
  199. ; ARE TRANSMITTED VIA A 4TH CASE, LTRSX BLANK (X).
  200. ;
  201. ; EQUATES
  202. ; 
  203. LTRSX:    EQU    1FH
  204. FIGSX:    EQU    1BH
  205. CRX:    EQU    48H
  206. LFX:    EQU    42H
  207. ALTMOD:    EQU    7DH    ;ALTERNATE MODE KEY
  208. ; 
  209. ;          PROGRAM STARTS HERE.
  210. TTYXMIT:
  211. ; CALL WITH ASCII CHARACTER IN ACCUMULATOR.
  212. ; 
  213. ; 
  214. STARTX:    PUSH    PSW    ;SAVE REGISTERS USED
  215.     PUSH    B
  216.     PUSH    H
  217. ; 
  218. BAUDOT:    MVI    C,0    ;SET UP COUNTER
  219.     ANI    7FH    ;STRIP PARITY BIT
  220.     CPI    ALTMOD    ;ALTERNATE MODE KEY?
  221.     JNZ    BAUD2    ;NO, IGNORE NEXT ROUTINE
  222.     MVI    A,09H    ;BAUDOT '$'
  223.     JMP    BAUD3
  224. ; 
  225. BAUD2:    CPI    7BH    ;ABOVE L.C. 'Z' ?
  226.     JNC    TTY0    ;IF SO, IGNORE IT
  227.     LXI    H,BTABLE ;POINT TO TABLE START
  228.     ADD    L    ;ADD CHARACTER VALUE
  229.     MOV    L,A    ;L POINTS TO BAUDOT CHAR.
  230.     MOV    A,H    ;GET H FOR CORRECTION
  231.     ACI    0    ;CORRECT IF NECESSARY
  232.     MOV    H,A    ;H IS NOW CORRECT
  233.     MOV    A,M    ;GET BAUDOT CHARACTER
  234.     ORA    A    ;IS IT A NON-PRINTING CHAR?
  235.     JZ    TTY0    ;IF SO IGNORE IT
  236.     CPI    CRX    ;IS IT A CARRIAGE RETURN?
  237.     JZ    TTYOUT-1 ;YES, HANDLE WITHOUT CASE TEST
  238.     CPI    LFX    ;IS IT A LINE FEED?
  239.     JNZ    BAUD3    ;NO, IGNORE NEXT ROUTINE
  240.     MVI    A,LTRSX    
  241.     PUSH    PSW    ;SAVE IT ON STACK
  242.     MVI    A,LFX
  243.     LXI    H,SCASE    ;POINT TO PRESENT CASE REG.
  244.     MVI    M,40H    ;SET IT TO LOWER CASE
  245.     JMP    TTYOUT-2 ;SEND LF AND LTRSX
  246. ; 
  247. BAUD3:    PUSH    PSW    ;SAVE CHARACTER
  248.     ANI    0C0H    ;STRIP ALL BUT CASE BITS
  249.     LXI    H,SCASE    ;POINT TO PRESENT CASE REG.
  250.     CMP    M    ;SAME CASE AS PREVIOUS CHARACTER?
  251.     JZ    TTYOUT    ;YES NO CHANGE NECESSARY
  252.     MOV    M,A    ;UPDATE CASE REGISTER
  253.     ORA    A
  254.     JZ    TCASEX
  255.     CPI    80H
  256.     JZ    UCASEX
  257.     CPI    0C0H
  258.     JNZ    LCASEX
  259. ; 
  260. FCASEX:    XRA    A    ;GET A BAUDOT 'BLANK'
  261.     PUSH    PSW    ;SAVE IT ON THE STACK
  262.     INR    C    ;INCRXEMENT CHARACTER COUNT
  263. ; 
  264. LCASEX:    MVI    A,LTRSX
  265.     JMP    TTYOUT-2
  266. ; 
  267. TCASEX:    XRA    A    ;GET A BAUDOT 'BLANK'
  268.     PUSH    PSW    ;SAVE IT ON THE STACK
  269.     INR    C    ;INCRXEMENT CHARACTER COUNT
  270. ; 
  271. UCASEX:    MVI    A,FIGSX
  272.     INR    C    ;INCRXEMENT CHARACTER COUNT
  273.     PUSH    PSW    ;SAVE IT ON THE STACK
  274. ; 
  275. TTYOUT:
  276.     LDA    UART2+1
  277.     ANI    1
  278.     JZ    TTYOUT
  279.     POP    PSW    ;GET CHARACTER
  280. ; 
  281. ;
  282. ; 
  283.     ORI    0E0H    ;MAKE UPPER 3 BITS MARKING
  284.     STA    UART2    ;SEND TO BAUDOT PORT
  285.     DCR    C    ;MORE TO SEND?
  286.     JP    TTYOUT    ;YES, CONTINUE SENDING
  287. ; 
  288. TTY0:    POP    H    ;RESTORE REGISTERS
  289.     POP    B
  290.     POP    PSW
  291.     RET        ;RETURN TO CALLING PROGRAM
  292. ; 
  293. BTABLE:    DB    5FH,17H,13H    ;NUL SOH STX
  294.     DB    1,0,0AH        ;ETX EOT ENQ
  295.     DB    0,85H,10H    ;ACK BEL BS
  296.     DB    15H,42H,0C2H    ;HT  LF  VT
  297.     DB    2,48H,0        ;FF  CRX  SO
  298.     DB    7,0,0        ;SI  DLE DC1
  299.     DB    0,0,0        ;DC2 DC3 DC4
  300.     DB    0,6,0        ;NAK SYN ETB
  301.     DB    18H,0,16H    ;CAN EM  SUB
  302.     DB    0EH,0,0        ;ESC FS  GS
  303.     DB    0,0,44H        ;RS  US  SPACE
  304.     DB    8DH,91H,94H    ;!   "   #
  305.     DB    89H,0BH,9AH    ;$   PCT &
  306.     DB    8BH,8FH,92H    ;'   (   )
  307.     DB    14H,1AH,8CH    ;AS  PL  ,
  308.     DB    83H,9CH,9DH    ;-   .   /
  309.     DB    96H,97H,93H    ;0   1   2
  310.     DB    81H,8AH,90H    ;3   4   5
  311.     DB    95H,87H,86H    ;6   7   8
  312.     DB    98H,8EH,9EH    ;9   :   ;
  313.     DB    0FH,0DH,12H    ;LT  EQ  GT
  314.     DB    99H,5,43H    ;?   AT  A
  315.     DB    59H,4EH,49H    ;B   C   D
  316.     DB    41H,4DH,5AH    ;E   F   G
  317.     DB    54H,46H,4BH    ;H   I   J
  318.     DB    4FH,52H,5CH    ;K   L   M
  319.     DB    4CH,58H,56H    ;N   O   P
  320.     DB    57H,4AH,45H    ;Q   R   S
  321.     DB    50H,47H,5EH    ;T   U   V
  322.     DB    53H,5DH,55H    ;W   X   Y
  323.     DB    51H,11H,1DH    ;Z   LB  LS
  324.     DB    1CH,19H,3    ;RB  UA  LA
  325. ; 
  326. ; THESE ARE THE LOWER CASE ALPHA CHARACTERS
  327. ; 
  328.     DB    0,0C3H,0D9H    ;'   A   B
  329.     DB    0CEH,0C9H,0C1H    ;C   D   E
  330.     DB    0CDH,0DAH,0D4H    ;F   G   H
  331.     DB    0C6H,0CBH,0CFH    ;I   J   K
  332.     DB    0D2H,0DCH,0CCH    ;L   M   N
  333.     DB    0D8H,0D6H,0D7H    ;O   P   Q
  334.     DB    0CAH,0C5H,0D0H    ;R   S   T
  335.     DB    0C7H,0DEH,0D3H    ;U   V   W
  336.     DB    0DDH,0D5H,0D1H    ;X   Y   Z
  337. ; 
  338. ; TEMPORARY STORAGE AREA
  339. ; 
  340. RAM    EQU    1400H
  341.     ORG    RAM
  342. SCASE:    DB    40H    ;PRESENT CASE REGISTER
  343. ; 
  344.   
  345. ; TEMPORARY STORAGE AREA
  346. ; 
  347. CASAVE:    DW    LTABLE    ;PRESENT CASE REMINDER
  348. FLAG:    DB    0    ;FIGS/LTRS LAST FLAG
  349. ; 
  350.