home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG041.ARK / TTYR1.ASM < prev    next >
Assembly Source File  |  1984-04-29  |  5KB  |  201 lines
  1.     ORG    100H
  2. LOOP    IN    04
  3.     ANI    01
  4.     JNZ    LOOP
  5.     CALL    ASCRCV
  6.     CPI    0FFH
  7.     JZ    LOOP
  8.     OUT    1
  9.     PUSH    B
  10.     MOV    C,A
  11.     IN    0FFH
  12.     CPI    80H
  13.     JNZ    LOOP1
  14.     CALL    0E000H
  15. LOOP1    POP    B
  16.     IN    01
  17.     ANI    7FH
  18.     CPI    1BH
  19.     JZ    0
  20.     JMP    LOOP
  21. ; 
  22. ;    ASCRCV(4), VER. 2
  23. ; BY KEITH PETERSEN, W8SDZ.  10/30/78.
  24. ; 
  25. ; THIS IS A PROGRAM TO CHANGE
  26. ; ASCII-CODED-BAUDOT TO ASCII.
  27. ; THE ROUTINE RETURNS WITH A 0FFH
  28. ; IN THE 'A' REGISTER IF CHARACTER
  29. ; IS TO BE IGNORED.  OTHERWISE IT
  30. ; RETURNS WITH THE ASCII CHARACTER
  31. ; IN THE 'A' REGISTER.  IT IS ASSUMED
  32. ; THAT A STATUS TEST HAS BEEN DONE BEFORE
  33. ; CALLING THIS ROUTINE TO DETERMINE THAT
  34. ; A BAUDOT CHARACTER IS AVAILABLE.
  35. ; 
  36. ; EQUATES
  37. ; 
  38. BTTY:    EQU    05H    ;BAUDOT UART DATA PORT
  39. CR:    EQU    0DH    ;ASCII CARRIAGE RETURN
  40. LF:    EQU    0AH    ;ASCII LINE FEED
  41. BELL:    EQU    07H    ;ASCII BELL
  42. LTRS:    EQU    1FH    ;BAUDOT 'LTRS'
  43. SPACE:    EQU    04H    ;BAUDOT 'SPACE'
  44. FIGS:    EQU    1BH    ;BAUDOT 'FIGS'
  45. APOS:    EQU    27H    ;APOSTROPHE
  46. CNTC:    EQU    03H    ;CONTROL C
  47. LARW:    EQU    5FH    ;LEFT ARROW
  48. ASPC:    EQU    20H    ;ASCII SPACE
  49. ATSN:    EQU    40H    ;"AT" SIGN
  50. CNTV:    EQU    16H    ;CONTROL V
  51. CNTO:    EQU    0FH    ;CONTROL O
  52. RUBT:    EQU    7FH    ;RUBOUT
  53. CNTE:    EQU    05H    ;CONTROL E
  54. PCT:    EQU    25H    ;PERCENT SIGN
  55. EQUL:    EQU    3DH    ;EQUALS SIGN
  56. GRTH:    EQU    3EH    ;GREATER-THAN SIGN
  57. CNTH:    EQU    08H    ;CONTROL H
  58. LETH:    EQU    3CH    ;LESS-THAN SIGN
  59. CNTB:    EQU    02H    ;CONTROL B
  60. STAR:    EQU    2AH    ;ASTERISK
  61. CNTI:    EQU    09H    ;CONTROL I
  62. CNTZ:    EQU    1AH    ;CONTROL Z
  63. CNTA:    EQU    01H    ;CONTROL A
  64. CNTX:    EQU    18H    ;CONTROL X
  65. UARW:    EQU    5EH    ;UP-ARROW
  66. PLUS:    EQU    2BH    ;PLUS SIGN
  67. RESL:    EQU    5CH    ;REVERSE SLANT
  68. LBKT:    EQU    5BH    ;LEFT BRACKET
  69. RBKT:    EQU    5DH    ;RIGHT BRACKET
  70. ESCP:    EQU    1BH    ;ESCAPE KEY
  71. ALMD:    EQU    7DH    ;ALTERNATE MODE KEY
  72. BEGIN:    EQU    0200H    ;MY ADDRESS FOR THIS PROGRAM
  73. ; 
  74. ; PROGRAM STARTS HERE
  75. ; 
  76. ; 
  77. ASCRCV:    PUSH    H    ;SAVE HL REGISTERS
  78.     LHLD    CASAVE    ;GET PRESENT CASE
  79. ; 
  80. START:    IN    BTTY    ;GET BAUDOT CHARACTER
  81.     ANI    1FH    ;BAUDOT CHARACTERS ONLY
  82.     CPI    FIGS
  83.     JZ    UCASE
  84.     CPI    LTRS
  85.     JZ    LCASE
  86.     ORA    A    ;BAUDOT 'BLANK' ?
  87.     JZ    TCASE
  88.     CPI    SPACE
  89.     JNZ    START1
  90.     LXI    H,LTABLE ;SPACE GIVES LOWER CASE
  91. ; 
  92. START1:    SHLD    CASAVE    ;SAVE PRESENT CASE
  93.     ADD    L    ;ADD CHAR. TO TABLE ADRS.
  94.     MOV    L,A    ;L POINTS TO ASCII CHAR.
  95.     MOV    A,H    ;GET H FOR CORRECTION
  96.     ACI    0    ;SEE IF CORRECTION NEEDED
  97.     MOV    H,A    ;H IS CORRECT NOW
  98.     XRA    A    ;PUT ZERO IN A REG.
  99.     STA    FLAG    ;CLEAR LTRS-FIGS LAST FLAG
  100.     MOV    A,M    ;GET ASCII EQUIVALENT
  101.     POP    H    ;RESTORE HL REGISTERS
  102.     ORA    A    ;IS IT PRINTABLE?
  103.     RNZ        ;YES, VALID CHAR. RETURN
  104.     CMA        ;MAKE 0FFH 'IGNORE FLAG'
  105.     RET        ;RETURN TO CALLING PROGRAM
  106. ; 
  107. LCASE:    LXI    H,LTABLE ;LOWER CASE TABLE ADDRESS
  108.     JMP    SETFLG    ;SET LTRS LAST FLAG, EXIT
  109. ; 
  110. UCASE:    LXI    H,UTABLE ;UPPER CASE TABLE ADDRESS
  111.     JMP    SETFLG    ;SET FIGS LAST FLAG, EXIT
  112. ; 
  113. TCASE:    LDA    FLAG    ;GET SHIFT REMINDER FLAG
  114.     CPI    FIGS
  115.     JNZ    FCASE
  116.     LXI    H,TTABLE ;THIRD CASE TABLE ADDRESS
  117.     JMP    CLRFLG
  118. ; 
  119. FCASE:    CPI    LTRS    ;CHECK FOR LTRS LAST
  120.     JNZ    CLRFLG
  121.     LXI    H,FTABLE ;FOURTH CASE TABLE ADDRESS
  122. ; 
  123. CLRFLG:    XRA    A    ;READY TO CLEAR FLAG
  124. ; 
  125. SETFLG:    STA    FLAG    ;LTRS-FIGS LAST FLAG
  126.     SHLD    CASAVE    ;SAVE PRESENT CASE
  127.     MVI    A,0FFH    ;'IGNORE FLAG'
  128.     POP    H    ;RESTORE HL REGS.
  129.     RET        ;RETURN TO CALLING PROGRAM
  130. ; 
  131. ; THIS IS THE LOWER-CASE TABLE.
  132. ; 
  133. LTABLE:    DB    0,'E',LF,'A SIU',CR,'DRJNFCK'
  134.     DB    'TZLWHYPQOBG',FIGS,'MXV'
  135. ; 
  136. ; THIS IS THE UPPER-CASE TABLE.
  137. ; 
  138. UTABLE:    DB    0,'3',LF,'- ',BELL,'87',CR,'$4'
  139.     DB    APOS,',!:(5")2#6019?&',FIGS,'./;'
  140. ; 
  141. ; THIS IS THE THIRD-CASE TABLE.
  142. ; IT IS USED FOR SPECIAL CHARACTERS.
  143. ; THE FIRST COLUMN IN THE TABLE
  144. ; THE ASCII CHARACTER EQUIVALENT.
  145. ; THE SECOND COLUMN IS THE SPECIAL
  146. ; CASE BAUDOT CHARACTER FROM WHICH
  147. ; THE CONVERSION IS MADE.
  148. ; 
  149. TTABLE:    DB    0,CNTC,LF    ;BL  3   LF
  150.     DB    LARW,ASPC,ATSN    ;-   SP  BELL
  151.     DB    CNTV,CNTO,CR    ;8   7   CR
  152.     DB    ALMD,CNTE,PCT    ;$   4   '
  153.     DB    RUBT,EQUL,ESCP    ;,   !   :
  154.     DB    LETH,CNTH,LBKT    ;(   5   "
  155.     DB    GRTH,CNTB,STAR    ;)   2   #
  156.     DB    CNTI,CNTZ,CNTA    ;6   0   1
  157.     DB    CNTX,UARW,PLUS    ;9   ?   &
  158.     DB    0,RBKT,RESL    ;FIG .   /
  159.     DB    0            ;;
  160. ; 
  161. ; THIS IS THE FOURTH CASE TABLE
  162. ; FOR LOWER-CASE ALPHA CHARACTERS.
  163. ; 
  164. FTABLE:    DB    0,65H,LF,61H,ASPC,73H
  165.     DB    69H,75H,CR,64H,72H,6AH
  166.     DB    6EH,66H,63H,6BH,74H,7AH
  167.     DB    6CH,77H,68H,79H,70H,71H
  168.     DB    6FH,62H,67H,FIGS,6DH,78H
  169.     DB    76H
  170. ; 
  171. ; TEMPORARY STORAGE AREA
  172. ; 
  173. CASAVE:    DW    LTABLE    ;PRESENT CASE REMINDER
  174. FLAG:    DB    0    ;FIGS/LTRS LAST FLAG
  175. ; 
  176.     END
  177.   
  178. ; THIS IS A SAMPLE OF THE POLLING ROUTINE
  179. ; USED TO ALLOW INPUT FROM EITHER THE ASCII
  180. ; OR BAUDOT KEYBOARD INPUT PORTS.  IT CAN
  181. ; BE LINKED TO ANY PROGRAM WHICH USES A
  182. ; NORMAL INPUT ROUTINE WHICH RETURNS WITH
  183. ; THE ASCII CHARACTER IN THE ACCUMULATOR.
  184. ; 
  185. POLL:    IN    BSTATUS    ;BAUDOT UART STATUS PORT
  186.     ANI    RDA    ;TEST FOR RCVE DATA AVAIL FLAG
  187.     JZ    POLL2    ;NO CHAR. TEST ASCII (MAY NEED JNZ HERE)
  188.     CALL    ASCRCV4    ;CHARACTER THERE, GET AND CONVERT
  189.     CPI    0FFH    ;IGNORE FLAG THERE?
  190.     RNZ        ;NO, RETURN WITH ASCII CHARACTER
  191. ; 
  192. POLL2:    IN    ASTATUS    ;GET ASCII UART STATUS
  193.     ANI    RDA    ;TEST DATA AVAIL. FLAG
  194.     JZ    POLL    ;NO CHAR., RESUME POLLING (MAY NEED JNZ HERE)
  195.     IN    ADATA    ;GET ASCII UART DATA
  196.     ANI    7FH    ;STRIP PARITY BIT
  197.     RET        ;ASCII CHAR. IN ACCUMULATOR
  198. ; 
  199. ; END OF SAMPLE POLLING ROUTINE.
  200.  
  201.