home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG041.ARK / TEACH.ASM < prev    next >
Assembly Source File  |  1984-04-29  |  9KB  |  516 lines
  1. ;TEACH MORSE CODE
  2. ;
  3. ; 
  4. ;
  5. ; REVISION HISTORY
  6. ;
  7. ;    10/02/76 INITIAL VERSION ADAPTED FROM 6800
  8. ;    10/07/76 DOUBLE WEIGHT IF AVERABE > 90 PCT. ADDED.
  9. ;    10/07/76 LETTER PROBABILITY NEVER ZERO ADDED.
  10. ;    12/06/76 REVISED RANDOM AND REMOVED PUNCTUATION
  11. ;         TO SAVE SPACE IN 512 BYTE ROM.
  12. ;    03/23/77 CORRECT TYPO IN DOUBLE WEIGHT PROBABILITY.
  13. ;    06/03/77 ADDED SWITCHES FOR CPM, MORORW, IMSAI, AND HAL
  14. ;    09/08/78 ADDED SWITCH FOR SHERWOOD ASSEMBLY
  15. ;
  16. ; ASSEMBLY CONSTANTS
  17. ;
  18. FREQ    EQU    2000    ;MACHINE CYCLES PER MSEC
  19. WPM    EQU    15    ;CHARACTER TRANSMISSION SPEED
  20. IDLE    EQU    3*50    ;IDLE RESPONSE WAIT
  21. MAXNUM    EQU    26+10    ;MAXIMUM NUMBER OF CHARACTERS
  22. PPIM    EQU    0FH    ;8255 MODE SELECT
  23. ;
  24. FALSE    EQU    0
  25. TRUE    EQU    NOT FALSE
  26. ;
  27. IMSAI    EQU    FALSE    ;USES PORT 255
  28. HAL    EQU    FALSE    ;ORRIGINAL VERSION
  29. CPM    EQU    TRUE    ;USE BDOS I/0
  30. MOROWS    EQU    FALSE    ;USE EI/DI INSTEAD OF I/O PORT
  31. SHERWOOD EQU    TRUE    ;USE SONALERT FOR TONE ON PORT 203
  32. ;
  33. LINE    EQU    62    ;TERMINAL LINE LENGTH
  34. ;
  35. ; MONITOR SUBROUTINE ENTRIES
  36. ;
  37.     IF    HAL
  38. CO    EQU    8009H    ;COMMAND OUTPUT
  39. CI    EQU    8003H    ;COMMAND INPUT
  40. CSTS    EQU    8012H    ;COMMAND INPUT STATUS
  41. ;
  42.     ORG    40H    ;RAM
  43.     ENDIF
  44. ;
  45.     IF    CPM
  46.     ORG    100H
  47.     ENDIF
  48. ;
  49.     IF    NOT HAL
  50.     JMP    BEGIN
  51.     ENDIF
  52. ;
  53. ;
  54. ;  GLOBAL DATA
  55. ;
  56. SEED    DW    1234H    ;RANDOM NUMBER (MUST BE NON-ZERO)
  57. NUM    DW    ERROR+4    ;SIZE OF CURRENT ALPHABET
  58. GIVE    DB    IDLE    ;RESPONSE WAIT TIME IS SEC/50
  59. TOLD    DB    0    ;255 IF STUDENT WAS TOLD LETTER, 0 OTHERWISE
  60. COLUMN    DB    LINE    ;PRINT POSITION REMAINING ON LINE
  61. ;
  62. ;  OBJECT TIME STACK
  63. ;
  64.     DS    30
  65. STACK    DS    0
  66. ;
  67. ;  ERROR RATE FUNCTION
  68. ;
  69. ;
  70.     IF    HAL
  71.     ORG    100H    ;MUST ORG AT A MULTIPLE OF 100H
  72.     ENDIF
  73. ;
  74.     IF    NOT HAL    ;ORG TO NEXT MULTIPLE OF 100H
  75.     ORG    ($ OR 255) + 1
  76.     ENDIF
  77. ;
  78. ERROR    DB    255    ;TOTAL ERROR RATE
  79.     DS    MAXNUM
  80. ;
  81. ;  ENTRY POINT (FWA ROM)
  82. ;
  83. ;
  84.     IF    HAL
  85.     ORG    200H
  86.     ENDIF
  87. ;
  88. BEGIN    JMP    TEACH
  89. ;
  90. ;  CHARACTER CODE TABLES
  91. ;
  92. MORSE    EQU    $-1
  93.     DB    11011000B,11000100B,11001000B,11010000B
  94.     DB    11111100B,11110100B,11100100B,11110000B
  95.     DB    01111100B,01111000B,01101000B,01110000B
  96.     DB    01001000B,01010000B,01100000B,11100000B
  97.     DB    10000100B,10001000B,10011000B,10010000B
  98.     DB    10111000B,10101000B,10110000B,10100000B
  99.     DB    00111100B,00011100B,00101000B,00110000B
  100.     DB    00001100B,00000100B,00011000B,00001000B
  101.     DB    00010000B,00100000B,11000000B,01000000B
  102. ;
  103. ASCII    DB    25H    ;OVERALL PERCENTAGE
  104.     DB    'Q7ZG'
  105.     DB    '098O'
  106.     DB    '1JPW'
  107.     DB    'LRAM'
  108.     DB    '6BXD'
  109.     DB    'YCKN'
  110.     DB    '23FU'
  111.     DB    '45VH'
  112.     DB    'SITE'
  113. ;
  114. ; MAIN PROGRAM TEACH
  115. ;
  116. ;    ENTRY VIA JUMP.  STACK POINTER IS REINITIALIZED.
  117. ;    INTERUPTS ARE NOT USED.
  118. ;
  119. TEACH:    LXI    SP,STACK
  120.     CALL    PRESET
  121. TEA1:    CALL    GRAPH
  122. TEA2:    CALL    SELECT
  123.     MVI    A,0
  124.     STA    TOLD    ;CLEAR STUDENT TOLD FLAG
  125. TEA3:    CALL    SEND
  126.     PUSH    D
  127.     CALL    CSTS    ;LOOK FOR ENTRY WHILE SENDING
  128.     ANA    A
  129.     JZ    TEA4
  130.     CALL    CI    ;DISCARD CHARACTER
  131. TEA4:    MVI    B,0    ;CLEAR RESPONSE TIME COUNTER
  132.     MVI    C,0    ;CLEAR CORRECT RESPONSE FLAG
  133. TEA5:    PUSH    B
  134.     CALL    RANDOM    ;MIX UP NUMBERS
  135.     CALL    CSTS
  136.     ANA    A
  137.     JZ    TEA6    ;IF NO RESPONSE YET
  138.     CALL    CI    ;GET CHARACTER
  139.     POP    B
  140.     POP    D
  141.     CPI    0DH    ;CARRIAGE RETURN
  142.     JZ    TEA1    ;GIVE STUDENT A GRAPH
  143.     LXI    H,ASCII-ERROR
  144.     DAD    D
  145.     CMP    M
  146.     PUSH    D
  147.     JNZ    TEA5    ;IF WRONG GUESS
  148.     MOV    C,A    ;SET CORRECT RESPONSE FLAG
  149.     JMP    TEA7
  150. TEA6:    MVI    C,20
  151.     CALL    WAIT    ;KILL SOME TIME
  152.     POP    B
  153.     MOV    A,B
  154.     INR    A    ;GAD***** IS THIS SILLY
  155.     MOV    B,A    ;WHY NOT INR B *********
  156.     LDA    GIVE
  157.     CMP    B
  158.     JNZ    TEA5    ;IF SOME TIME LEFT
  159.     LXI    H,TOLD
  160.     MVI    M,255    ;RECORD TIMEOUT
  161. TEA7:    MOV    A,B    ;COMPUTE NEW SPEED
  162.     POP    D
  163.     STC
  164.     CMC
  165.     RAL        ;RESPONSE TIME * 2
  166.     JNC    TEA8
  167.     MVI    A,255    ;SET TO MAXIMUN ON OVERFLOW
  168. TEA8:    LXI    H,GIVE
  169.     MOV    B,M
  170.     CALL    WEIGHT    ;ADJUST SPEED
  171.     MOV    M,A
  172.     LXI    H,ASCII-ERROR
  173.     DAD    D
  174.     PUSH    B    ;SAVE ANSWER
  175.     MOV    C,M
  176.     CALL    PRINT    ;OUTPUT CORRECT ANSWER
  177.     MVI    C,' '
  178.     CALL    PRINT    ;DOUBLE SPACE
  179.     MVI    C,250
  180.     CALL    WAIT
  181.     POP    B
  182.     MOV    A,C
  183.     ANA    A
  184.     JZ    TEA3    ;IF INCORRECT TYR IT OVER
  185.     CALL    GRADE
  186.     JMP    TEA2
  187. ;
  188. ; SUBROUTINE PRESET
  189. ;
  190. ;    INITIALIZE I/O AND GLOBAL VARIABLES
  191. ;
  192. PRESET:    LXI    H,ERROR+MAXNUM
  193. PRE1:    MVI    M,255    ;SET ERRORS TO MAXIMUM
  194.     DCR    L
  195.     JNZ    PRE1
  196.     MVI    M,256*30/100    ;GUESS AVERAGE OF 70 PERCENT
  197.     LXI    H,ERROR+4
  198.     SHLD    NUM    ;MINIMUM ALPHABET
  199.     MVI    A,IDLE
  200.     STA    GIVE    ;AVERAGE SPEED
  201.     LXI    H,1234H
  202.     SHLD    SEED    ;NON-ZERO RANDOM SEED
  203. ;
  204.     IF    HAL
  205.     MVI    A,0A6H
  206.     OUT    PPIM    ;PROGRAM MODE 1 OUTPUT
  207.     ENDIF
  208. ;
  209.     IF    SHERWOOD
  210.     XRA    A    ;INIT FRONT PANNEL PIA
  211.     OUT    200
  212.     OUT    202
  213.     CMA
  214.     OUT    201
  215.     OUT    203
  216.     MVI    A,4
  217.     OUT    200
  218.     OUT    202
  219.     MVI    A,10H
  220.     OUT    203    ;INITIALLY TURN OFF TONE
  221.     ENDIF
  222. ;
  223.     RET
  224. ;
  225. ;
  226. ; SUBROUTINE RANDOM
  227. ;
  228. ;    TAUSWORTH GENERATOR USING PRIMITAVE TRINOMIAL
  229. ;      X**15 + X + 1 WITH PERIOD 2**15-1.
  230. ;    RETURNS 0 < (D,E) < 2**15.
  231. ;
  232. RANDOM:    LXI    H,SEED
  233.     MOV    A,M
  234.     STC
  235.     CMC
  236.     RAL        ;HE SHOULD HAVE USED ORA A !!!!!!
  237.     MOV    D,A
  238.     INX    H
  239.     MOV    A,M
  240.     RAR
  241.     XRA    M
  242.     MOV    M,A
  243.     MOV    A,D
  244.     DCX    H
  245.     XRA    M
  246.     JNC    RAN1
  247.     XRI    60H
  248. RAN1:    MOV    M,A
  249.     MOV    E,A
  250.     RET
  251. ;
  252. ;
  253. ; SUBROUTINE SELECT
  254. ;
  255. ;    ON EXIT (D,E) CONTAINS A POINTER TO THE SELECTED
  256. ;    CHARACTER IN THE ERROR TABLE.  PRESERVES NO REGISTERS.
  257. ;
  258. SELECT:    CALL    RANDOM
  259.     MOV    A,D
  260.     CMA        ;MAKE RANDOM NUMBER NEGATIVE
  261.     MOV    D,A
  262. SEL1:    LHLD    NUM    ;BEGIN SCAN
  263. SEL2:    MOV    C,M    ;GET ERROR RATE
  264.     MVI    B,0
  265.     INX    B    ;INSURE PROPABILITY IS NEVER ZERO
  266.     XCHG
  267.     DAD    B    ;ADD ERROR TO RANDOM NUMBER
  268.     RC        ;STOP LOOP ON CARRY OUT
  269.     XCHG
  270.     DCR    L
  271.     JNZ    SEL2    ;SCAN REMAINDER OF TABLE
  272.     JMP    SEL1    ;START SCAN OVER
  273. ;
  274. ;
  275. ; SUBROUTINE SEND
  276. ;
  277. ;    THE CHARACTER REFERENCED BY (D,E) IS SENT AS MORSE CODE.
  278. ;    ON EXIT D,E ARE PRESERVED.
  279. ;
  280. SEND:    LXI    H,MORSE-ERROR
  281.     DAD    D
  282.     MOV    B,M    ;GET MORSE LETTER
  283. SEN1:    MOV    A,B
  284.     STC        ;HE SHOULD HAVE USED ORA A !!!!!!***
  285.     CMC
  286.     RAL        ;GET NEXT ELEMENT IN CARRY
  287.     MOV    B,A
  288.     MVI    C,1200/WPM    ;ONE DIT TIME IN MSEC
  289.     JNC    SEN2
  290.     MVI    C,3*1200/WPM    ;ONE DAH TIME
  291. SEN2:    ANA    A
  292.     RZ        ;IF LAST BIT WAS STOP BIT
  293.     CALL    BEEP
  294.     MVI    C,1200/WPM    ;INTER ELEMENT SPACE
  295.     CALL    WAIT
  296.     JMP    SEN1    ;LOOP FOR REMAINING BITS
  297. ;
  298. ;
  299. ; SUBROUTINE WAIT
  300. ;
  301. ;    DELAY C MSEC.  ON EXIT A AND C ARE ZERO.
  302. ;    ALL OTHER REGS ARE PRESERVED.
  303. ;
  304. WAIT:    MVI    A,FREQ/16
  305. WAI1:    DCR    A
  306.     JNZ    WAI1    ;LOOP FOR A MSEC
  307.     DCR    C
  308.     JNZ    WAIT    ;IF MORE MSEC TO GO
  309.     RET
  310. ;
  311. ;
  312. ; SUBROUTINE BEEP
  313. ;
  314. ;    DELAY C MSEC WHILE GENERATING A 1000HZ SIDETONE.
  315. ;    OUTPUT IS ON 8255 PORT PC4.
  316. ;    ENTRY/EXIT SAME AS WAIT (SEE ABOVE).
  317. ;
  318. BEEP:
  319.     IF    SHERWOOD
  320.     MVI    A,20H
  321.     OUT    203    ;TONE ON
  322.     ENDIF
  323. BEE9:    MVI    A,FREQ/16/2
  324. BEE1:    DCR    A
  325.     JNZ    BEE1    ;LOOP FOR 1/2 MSEC
  326. ;
  327.     IF    HAL
  328.     MVI    A,1001B    ;SET PC4
  329.     OUT    PPIM    ;LO TO HIGH ON OUTPUT
  330.     ENDIF
  331. ;
  332.     IF    MOROWS
  333.     EI
  334.     ENDIF
  335. ;
  336.     IF    IMSAI
  337.     MVI    A,1000$0000B
  338.     OUT    0FFH
  339.     ENDIF
  340. ;
  341. BEE2:    MVI    A,FREQ/16/2
  342. BEE3:    DCR    A
  343.     JNZ    BEE3    ;LOOP FOR SECOND 1/2 MSEC
  344. ;
  345.     IF    HAL
  346.     MVI    A,1000B    ;CLEAR PC4
  347.     OUT    PPIM    ;HIGH TO LO ON OUTPUT
  348.     ENDIF
  349. ;
  350.     IF    MOROWS
  351.     DI
  352.     ENDIF
  353. ;
  354.     IF    IMSAI
  355.     MVI    A,0000$0000B
  356.     OUT    0FFH
  357.     ENDIF
  358. ;
  359.     DCR    C
  360.     JNZ    BEE9    ;IF MORE MSECS TO GO
  361. ;
  362.     IF    SHERWOOD
  363.     MVI    A,255
  364.     OUT    203
  365.     ENDIF
  366. ;
  367.     RET
  368. ;
  369. ;
  370. ; SUBROUTINE WEIGHT
  371. ;
  372. ;    COMPUTES A WEIGHTED MOVING AVERAGE
  373. ;    AS FOLLOWS, A = .875 * B + .125 * A
  374. ;    ALL OTHER REGS ARE PRESERVED.
  375. ;
  376. WEIGHT:    ADD    B
  377.     RAR        ;(A+B)/2
  378.     ADD    B
  379.     RAR        ;((A+B)/2+B)/2
  380.     ADD    B
  381.     RAR        ;(((A+B)/2+B)/2+B)/2
  382.     RET
  383. ;
  384. ;
  385. ; SUBROUTINES RETURN, PRINT
  386. ;
  387. ;    OUTPUT CR/LF OR CHARACTER IN C.
  388. ;    ON EXIT D,E AND A ARE PRESERVED.
  389. ;
  390. RETURN:    LXI    H,COLUMN
  391.     MVI    M,LINE+2
  392.     MVI    C,0DH    ;CR
  393.     CALL    PRINT
  394.     MVI    C,0AH    ;LF   FALL THROUGH TO PRINT
  395. PRINT:    PUSH    D
  396.     PUSH    PSW
  397.     CALL    CO
  398.     POP    PSW
  399.     POP    D
  400.     LXI    H,COLUMN
  401.     DCR    M
  402.     JZ    RETURN    ;LOCAL CR/LF
  403.     RET
  404. ;
  405. ;
  406. ; SUBROUTINE GRADE
  407. ;
  408. ;    INDIVIDUAL AND TOTAL ERROR RATES ARE
  409. ;    COMPUTED.  THE SIZE OF THE ALPHABET IS
  410. ;    INCREASED IF PERFORMANCE IS ADAQUATE.
  411. ;    ON ENTRY D,C POINTS TO CHARACTER ERROR TABLE
  412. ;    ENTRY, (TOLD) IS 0 FOR CORRECT OR 255 FOR INCORRECT.
  413. ;
  414. GRADE:    LDA    TOLD
  415.     XCHG
  416.     MOV    B,M
  417.     CALL    WEIGHT    ;ADJUST INDIVIDUAL RATE
  418.     MOV    M,A
  419.     XCHG
  420.     LXI    H,ERROR
  421.     LDA    TOLD
  422.     MOV    B,M
  423.     CALL    WEIGHT    ;ADJUST AVERAGE RATE
  424.     MOV    M,A
  425.     CPI    256*30/100
  426.     JNC    GRA3    ;IF BAD AVERAGE
  427.     CPI    256*10/100
  428.     JNC    GRAD    ;IF GOOD, BUT NOT GREAT
  429.     XCHG
  430.     MOV    B,M
  431.     LDA    TOLD
  432.     CALL    WEIGHT    ;COUNT SCORE TWICE IF HOT
  433.     MOV    M,A
  434. GRAD:    LHLD    NUM
  435.     MVI    A,256*40/100
  436. GRA1:    CMP    M
  437.     JC    GRA3    ;IF BAD INDIVIDUAL RATE
  438.     DCR    L
  439.     JNZ    GRA1
  440. GRA2:    LXI    H,NUM    ;CHECK FOR COMPLETE ALPHABET
  441.     MVI    A,MAXNUM
  442.     CMP    M
  443.     JZ    GRA3
  444.     INR    M    ;ADD LETTER
  445. GRA3:    RET        ;GAD* THIS IS SILL, WHY JUMP TO A RETURN
  446. ;
  447. ;
  448. ; SUBROUTINE GRAPH
  449. ;
  450. ;    THE PREDICTOR FUNCTION IS DISPLAYED.
  451. ;    ALL THE REGISTERS ARE DESTROYED.
  452. ;
  453. GRAPH:    LHLD    NUM
  454.     XCHG
  455. GPH1:    CALL    RETURN
  456.     LXI    H,ASCII-ERROR
  457.     DAD    D
  458.     MOV    C,M    ;GET ASCII FOR CURRENT CHARACTER
  459.     CALL    PRINT
  460.     MVI    C,' '
  461.     MOV    H,D
  462.     MOV    L,E
  463.     MOV    A,M    ;B IS ERROR RATE
  464. GPH2:    CALL    PRINT    ;PRINT BAR GRAPH
  465.     MVI    C,'*'
  466.     SUI    255/LINE+1
  467.     JNC    GPH2    ;IF A IS STILL POSITIVE
  468.     MVI    C,250    ;SLOW DOWN FOR FAST DISPLAYS
  469.     CALL    WAIT
  470.     DCR    E
  471.     JP    GPH1    ;LOOP FOR ALL BARS
  472.     CALL    CI
  473.     CPI    1BH    ;ESC CHAR-WANT NEW RUN AT IT?
  474.     JZ    TEACH    ;YUP-START OVER
  475.     CPI    1    ;JUMP TO MONITOR
  476.     JZ    0FC00H    ;YUP GOTO ODT
  477.     JMP    RETURN
  478. ;
  479. ;
  480. ; ADDED I/O DRIVERS
  481. ;
  482.     IF    CPM
  483. CO:    PUSH    H!    PUSH    D!    PUSH    B
  484.     PUSH    PSW
  485.     MOV    E,C
  486.     MVI    C,2
  487.     CALL    BDOS
  488.     POP    PSW
  489.     POP    B!    POP    D!    POP    H
  490.     RET
  491. ;
  492. BDOS    EQU    5H
  493. ;
  494. CI:    PUSH    H!    PUSH    D!    PUSH    B
  495.     CALL    CICPM
  496.     POP    B!    POP    D!    POP    H
  497.     RET
  498. ;
  499. CICPM:    LHLD    1
  500.     LXI    D,6
  501.     DAD    D
  502.     PCHL
  503. ;
  504. CSTS:    PUSH    H!    PUSH    D!    PUSH    B
  505.     CALL    CSTSCP
  506.     ANI    1
  507.     POP    B!    POP    D!    POP    H
  508.     RET
  509. ;
  510. CSTSCP:    LHLD    1
  511.     INX    H!    INX    H!    INX    H
  512.     PCHL
  513.     ENDIF
  514. ;
  515.     END  TEACH
  516.