home *** CD-ROM | disk | FTP | other *** search
/ The World of Computer Software / World_Of_Computer_Software-02-385-Vol-1of3.iso / c / cmsrc392.zip / ROMANL.MF < prev    next >
Text File  |  1992-03-30  |  40KB  |  821 lines
  1. % Computer Modern Roman lower case:
  2. % These letters were originally coded by D. E. Knuth in November, 1979,
  3. % inspired by the Monotype faces used in {\sl The Art of Computer Programming}.
  4. % Sans serif designs by Richard Southall were added in April, 1982.
  5. % The programs were revised for the new \MF\ conventions in 1985.
  6.  
  7. % Character codes \0141 through \0172 are generated.
  8.  
  9. cmchar "The letter a";
  10. beginchar("a",9u#,x_height#,0);
  11. bh#:=min(bar_height#,1.14x_height#-bar_height#); define_pixels(bh);
  12. italcorr 1/3[bh#,x_height#]*slant+.5stem#-serif_fit#-2u#;
  13. adjust_fit(0,serif_fit# if serifs: if hair#+.5stem#>1.5u#:-.25u# fi\\fi);
  14. pickup fine.nib; top y3r=h+vround 1.5oo;
  15. if serifs: pos1(flare,180); pos2(hair,180);
  16.  pos3(vair,90);  lft x1r=hround max(u,2.1u-.5flare); x3=.5w-.5u;
  17.  y1=min(bh+.5flare+2vair+2,.9[bh,h]-.5flare);
  18.  bulb(3,2,1);  % bulb
  19. else: pos1(5/7[vair,flare],95); x1l=good.x 1.5u; x1r:=good.x x1r;
  20.  pos3(1/8[vair,thin_join],90);
  21.  x3=.5w-.2u; top y1r=vround .82[bh,top y3r];
  22.  filldraw stroke term.e(3,1,left,.9,4); fi  % terminal
  23. pos4(stem,0); rt x4r=hround(w-2.5u+.5stem); y4=1/3[bh,h];
  24. pos5(stem,0); x5=x4; y5=max(.55bh,2vair);
  25. filldraw stroke super_arc.e(3,4)&z4e..z5e;  % arc and stem
  26. pos6(.3[thin_join,vair],90); x6=x4; bot y6=bh;
  27. pos7(hround(curve-2stem_corr),180);
  28. lft x7r=hround max(.5u,1.5u-.5curve); y7=1/3[top y8l,top y6r];
  29. pos8(vair,270); x8l=.5w-.75u; bot y8r=-oo;
  30. pos9(thin_join,360); z9l=z5l;
  31. (x,y8r)=whatever[z8l,z9l]; x8r:=max(x,x8-u);
  32. {{interim superness:=more_super;
  33.  filldraw stroke z9e{down}...z8e{left}...{up}z7e&super_arc.e(7,6)}}; % bowl
  34. if serifs: numeric shaved_stem; shaved_stem=hround(stem-3stem_corr);
  35.  if hair#+.5stem#>1.5u#: pickup tiny.nib;
  36.   pos5'(shaved_stem,0); rt x5'r=fine.rt x5r; y5'=y5;
  37.   pos10(shaved_stem,0); x10=x5'; y10=.2[.5tiny,bh];
  38.   pos11(shaved_stem,0); rt x11r=hround(w-.25u); bot y11=0;
  39.   pos12(shaved_stem,0); x11=x12; top y12=slab+eps;
  40.   filldraw z5'l---z10l...z11l{right}--z11r
  41.    --z12r{left}...z10r+.75(z12-z11)---z5'r--cycle;  % foot
  42.  else: pickup crisp.nib; pos5'(shaved_stem,0); rt x5'r=fine.rt x5r; y5'=y5;
  43.   pos10(shaved_stem,0); x10=x5'; y10=1/3bh;
  44.   pos11(.2[vair,stem],90); x11r=.5[x10r,x12r]; bot y11l=-vround .5oo;
  45.   pos12(hair,180); rt x12l=hround(w-.1u); y12=max(y10,y11+vair);
  46.   pos13(hair,180); x13=x12; top y13=max(vround .6bh,top y12);
  47.   (x',y11l)=whatever[z11r,z12r]; x11l:=max(x',x10);
  48.   filldraw stroke z5'e---z10e...z11e{right}...z12e---z13e; fi  % hook
  49. else: numeric shaved_stem; shaved_stem=hround(stem-stem_corr);
  50.  pickup tiny.nib; pos5'(shaved_stem,0); rt x5'r=fine.rt x5r; y5'=y5;
  51.  pos10(shaved_stem,0); x10=x5'; bot y10=0;
  52.  filldraw stroke z5'e--z10e; fi  % base of stem
  53. penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13); endchar;
  54.  
  55. cmchar "The letter b";
  56. beginchar("b",10u#+serif_fit#,asc_height#,0);
  57. italcorr .5x_height#*slant+min(.5curve#-u#,-.25u#);
  58. adjust_fit(serif_fit#,0);
  59. pickup tiny.nib; pos1(stem',0); pos2(stem,0);
  60. pos0'(stem',0); pos0(stem,0); z0l=z0'l; x0'=x1; x0=x2;
  61. lft x1l=hround(2.5u-.5stem'); top y1=h;
  62. numeric edge; edge=rt x2r;
  63. pickup fine.nib; pos3(if hefty:thin_join else: hair fi,180);
  64. pos4(vair,90); pos5(curve,0); pos6(vair,-90); penpos7(x3l-x3r,-180);
  65. rt x3l=max(rt x3l-(lft x3r-tiny.lft x2l),1/3[rt x2,edge]);
  66. y3=1/8[bar_height,x_height];
  67. x4l=w-.5(w-serif_fit)+.5u; top y4r=x_height+oo;
  68. rt x5r=hround min(w-1.35u+.5curve,w-.6u); y5=.5x_height;
  69. x6l=x4l-.2u; bot y6r=-oo;
  70. x7=x3; y7=min(y3,y6+y4-y3+.6vair);
  71. (x,y4r)=whatever[z3l,z4l]; x4r:=min(x,.5[x4,x5r]);
  72. (x',y6r)=whatever[z7l,z6l]; x6r:=min(x',.5[x6,x5r]);
  73. filldraw stroke z3e{up}...pulled_arc.e(4,5)&pulled_arc.e(5,6)...{up}z7e; % bowl
  74. y0=ypart(((edge,h)--(edge,0))intersectionpoint(z3l{up}...{right}z4l));
  75. y2=ypart(((edge,h)--(edge,0))intersectionpoint(z6l{left}...{up}z7l));
  76. pickup tiny.nib; filldraw stroke z1e--z0'e--z0e--z2e;  % stem
  77. pickup crisp.nib; pos8(hair,0); pos7'(stem,0);
  78. z7'=z2; x8l=x7'l; bot y8=0;
  79. filldraw stroke z7'e--z8e;  % point
  80. if serifs: sloped_serif.l(1,0',a,1/3,jut,serif_drop); fi  % upper serif
  81. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  82.  
  83. cmchar "The letter c";
  84. beginchar("c",8u#,x_height#,0);
  85. italcorr x_height#*slant-.2u#;
  86. adjust_fit(if monospace: .5u#,.5u# else: 0,0 fi);
  87. pickup fine.nib; pos2(vair',90); pos4(vair',270);
  88. x2=x4=.5(w+u); top y2r=vround(h+1.5oo); bot y4r=-oo;
  89. pos3(curve,180); lft x3r=hround max(.6u,1.35u-.5curve); y3=.5h;
  90. if serifs: pos1(hair,0); pos0(flare,0);
  91.  y1=min(bar_height+.5flare+2vair'+2,.9[bar_height,h]-.5flare);
  92.  rt x1r=hround(w-.7u); bulb(2,1,0);  % bulb
  93.  pos5(hair,0); rt x5r=hround(w-.5u);
  94.  y5=max(good.y(.5bar_height-.9),y4l+vair');
  95.  (x,y4l)=whatever[z4r,z5l]; x4l:=min(x,x4l+.5u);
  96.  filldraw stroke pulled_super_arc.e(2,3)(.7superpull)
  97.   & pulled_super_arc.e(3,4)(.5superpull)
  98.   ..tension .9 and 1..{x5-x4,5(y5-y4)}z5e;  % arc and lower terminal
  99. else: pos1(4/7[vair',flare],80);
  100.  rt x1r=hround(w-.6u); top y1r=vround .82[bar_height,top y2r];
  101.  filldraw stroke term.e(2,1,right,.8,4);  % upper terminal
  102.  pos5(.6[vair',flare],275); rt x5r=hround(w-.5u);
  103.  y5r=good.y(y5r+1/3bar_height-y5); y5l:=good.y y5l; x5l:=good.x x5l;
  104.  forsuffixes e=l,r: path p.e; p.e=z4e{right}..tension .9 and 1..z5e;
  105.   if angle direction 1 of p.e>75:
  106.    p.e:=z4e{right}..tension atleast.9 and 1..{dir 75}z5e; fi endfor
  107.  filldraw stroke pulled_super_arc.e(2,3)(.7superpull)
  108.   & pulled_super_arc.e(3,4)(.5superpull) & p.e; fi  % arc and lower terminal
  109. penlabels(0,1,2,3,4,5); endchar;
  110.  
  111. cmchar "The letter d";
  112. beginchar("d",10u#+serif_fit#,asc_height#,0);
  113. italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
  114. adjust_fit(0,serif_fit#);
  115. pickup tiny.nib; pos1(stem',0); pos2(stem,0);
  116. pos0'(stem',0); pos0(stem,0); z0r=z0'r; x0'=x1; x0=x2;
  117. rt x1r=hround(w-2.5u+.5stem'); top y1=h;
  118. numeric edge; edge=lft x2l;
  119. pickup fine.nib; pos3(if hefty:thin_join else: hair fi,0);
  120. pos4(vair,90); pos5(curve,180); pos6(vair,270); penpos7(x3r-x3l,360);
  121. lft x3l=min(lft x3l-(rt x3r-tiny.rt x2r),1/3[lft x2,edge]);
  122. y3=1/8[bar_height,x_height];
  123. x4l=.5(w-serif_fit)-.3u; top y4r=x_height+oo;
  124. lft x5r=hround max(1.35u-.5curve,.6u); y5=.5x_height;
  125. x6l=x4l-.2u; bot y6r=-oo;
  126. x7=x3; y7=min(y3,y6+y4-y3+.6vair);
  127. (x,y4r)=whatever[z3l,z4l]; x4r:=max(x,.5[x5r,x4]);
  128. (x',y6r)=whatever[z7l,z6l]; x6r:=max(x',.5[x5r,x6]);
  129. filldraw stroke z3e{up}...pulled_arc.e(4,5)
  130.  & pulled_arc.e(5,6)...{up}z7e; % bowl
  131. y0=ypart(((edge,h)--(edge,0))intersectionpoint(z3l{up}...{left}z4l));
  132. pickup tiny.nib; bot y2=if serifs:-min(oo,serif_drop) else: 0 fi;
  133. filldraw stroke z1e--z0'e--z0e--z2e;  % stem
  134. if serifs: sloped_serif.l(1,0',a,1/3,jut,serif_drop);  % upper serif
  135.  sloped_serif.r(2,0,b,1/3,jut,min(oo,serif_drop)); fi  % lower serif
  136. penlabels(0,1,2,3,4,5,6,7); endchar;
  137.  
  138. cmchar "The letter e";
  139. beginchar("e",7.25u#+max(.75u#,.5curve#),x_height#,0);
  140. italcorr .5[bar_height#,x_height#]*slant+.5min(curve#-1.5u#,0);
  141. adjust_fit(if monospace: .25u#,.5u# else: 0,0 fi);
  142. numeric left_curve,right_curve;
  143. left_curve=right_curve+6stem_corr=curve if not serifs: -3stem_corr fi;
  144. if right_curve<tiny.breadth: right_curve:=tiny.breadth; fi
  145. if left_curve<tiny.breadth: left_curve:=tiny.breadth; fi
  146. pickup tiny.nib; pos1(right_curve,0);
  147. pos2(vair,90); pos3(left_curve,180);
  148. y1=good.y bar_height; top y2r=h+vround 1.5oo; y0l=bot y1;
  149. rt x1r=hround min(w-.5u,w-u+.5right_curve);
  150. lft x3r=hround max(.5u,1.25u-.5left_curve); x2=.5w+.25u;
  151. {{interim superness:=more_super;
  152.  filldraw stroke super_arc.e(1,2)}};  % right bowl
  153. y3=.5[y2,y4]; bot y4r=-oo; x4=x2+.25u;
  154. if serifs: pos4(vair',270); pos5(hair,360);
  155.  y5=max(good.y(.5bar_height-.9),y4l+vair); x5r=x1r;
  156.  (x,y4l)=whatever[z4r,z5]; x4l:=min(x,x4l+.5u);
  157.  filldraw stroke pulled_arc.e(2,3) & pulled_arc.e(3,4)
  158.   ...{x5-x4,5(y5-y4)}z5e; % left bowl, arc, and terminal
  159. else: pos4(vair,270);
  160.  filldraw stroke super_arc.e(2,3) & super_arc.e(3,4);  % left bowl and arc
  161.  pickup fine.nib; pos4'(vair,270); z4=z4';
  162.  pos5(.5[vair,flare],275); rt x5r=hround(w-.6u);
  163.  y5r=good.y(y5r+1/3bar_height-y5); y5l:=good.y y5l; x5l:=good.x x5l;
  164.  filldraw stroke term.e(4',5,right,1,4); fi  % terminal
  165. path testpath; testpath=super_arc.r(2,3) & super_arc.r(3,4);
  166. y1'r=y0r=y0l+.6[thin_join,vair]; y1'l=y0l; x1'l=x1'r=x1;
  167. forsuffixes $=l,r:
  168.  x0$=xpart(((0,y0$)--(x1,y0$)) intersectionpoint testpath); endfor
  169. fill stroke z0e--z1'e;  % crossbar
  170. penlabels(0,1,2,3,4,5); endchar;
  171.  
  172. cmchar "The letter f";
  173. beginchar("f",5.5u#,asc_height#,0);
  174. italcorr asc_height#*slant+if serifs:flare#-.25u# else: 1.25u# fi;
  175. adjust_fit(stem_shift#,if monospace: .5u# else:-stem_shift# fi);
  176. pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
  177. pickup fine.nib; numeric bulb_diam;
  178. if serifs: bulb_diam=hround .8[stem,flare];
  179.  pos2(bulb_diam,0); y2+.5bulb_diam=.9[x_height,h+oo];
  180.  if monospace: rt x2r=hround(w-.5u)+1 else: lft x2l=hround(w-.75u+.5) fi;
  181. else: pos2(5/7[vair,flare],90); top y2r=h;
  182.  rt x2=hround(if monospace:w-.5u else:w+.75u fi); fi
  183. f_stroke(1,2,a,b,c,jut,if not monospace:1.25fi\\ jut); % stem, terminal, serif
  184. pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
  185. pos3(bar,90); pos4(bar,90);
  186. rt x4=hround(w-if monospace:.75u+1 else:1/3u fi);
  187. filldraw stroke z3e--z4e;  % bar
  188. penlabels(1,2,3,4); endchar;
  189.  
  190. iff not variant_g: cmchar "The letter g";
  191. beginchar("g",9u#,x_height#,desc_depth#);
  192. italcorr x_height#*slant+.25u#;
  193. adjust_fit(0,0);
  194. numeric light_vair,light_curve,loop_top,loop_side;
  195. light_vair=Vround(.5[thin_join,vair]+vair_corr);
  196. light_curve=max(fine.breadth,hround(curve-3stem_corr));
  197. loop_top=Vround .77[vair,fudged.stem];
  198. loop_side=hround .64[vair,fudged.stem];
  199. pickup fine.nib; pos1(light_vair,90);
  200. pos2(light_curve,180); pos3(light_vair,270);
  201. pos4(light_curve,360); pos11(loop_top,90);
  202. y11r=good.y(y11r+.15bar_height-y11); x1=x3=.5[x2,x4]; y2=y4=.5[y1,y3];
  203. lft x2r=hround(1.75u-.5light_curve); rt x4r=hround(w-2.75u+.5light_curve);
  204. top y1r=h+oo; y3r=good.y(y3r+.27[top y11r,bot y1l]-y3);
  205. filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3);  % left half of bowl
  206. filldraw stroke pulled_arc.e(3,4) & pulled_arc.e(4,1);  % right half of bowl
  207. x0=superness[x1r,x4r]; y0=superness[y4r,y1r];  % NE point on the super bowl
  208. x8'=superness[x3r,x2r]; y8'=superness[y2r,y3r];  % SW point on the super bowl
  209. x8''=superness[x3,x2]; y8''=superness[y2,y3];
  210. pos0(thin_join,angle(z0-z8')+90);
  211. pos8(thin_join,angle(z0-z8')-90); z8=.618[z8',z8''];
  212. if serifs: pos5(vair,90);
  213.  pos6(hair,0); pos7(.5[hair,flare],0); x5=.75[x0,x6]; top y5r=h+o;
  214.  rt x6r=hround(w-.25u); y6+(.5[hair,flare])/2=.95[bar_height,h]+oo;
  215.  filldraw stroke z0e..{right}z5e; bulb(5,6,7);  % ear
  216. else: pos5(vair',100); top y5r=h+oo;
  217.  rt x5l=hround(w-.25u); y5l:=good.y y5l;
  218.  filldraw z0l{z5-z0}..z5l--z5r{left}..{curl 1}z0r--cycle; fi  % ear
  219. pos10(loop_top,90); x10=x8+.75u; y10=y11;
  220. pos12(loop_side,0); pos13(light_vair,-90);
  221. pos14(loop_side,-180); pos10'(.5[thin_join,vair],-270);
  222. rt x12r=hround max(w-1.25u+.5loop_side,w-.5u); y12=y14=.5[y11,y13];
  223. x11=x13=max(.5w,x10+eps); bot y13r=-d-oo-1; x14=w-x12; z10'l=z10l;
  224. filldraw stroke z8e{z8-z0}..z10e---z11e;  % link
  225. filldraw stroke {{interim superness:=hein_super; super_arc.e(11,12)}}
  226.  & super_arc.e(12,13) & super_arc.e(13,14) & super_arc.e(14,10');  % loop
  227. penlabels(0,1,2,3,4,5,6,7,8,10,11,12,13,14); labels(8',8''); endchar;
  228.  
  229. iff variant_g: cmchar "Variant letter g";
  230. beginchar("g",10u#+serif_fit#,x_height#,desc_depth#);
  231. italcorr x_height#*slant-serif_fit#+.5stem#-2u# if serifs:+.5u# fi;
  232. adjust_fit(0,serif_fit# if serifs: -.5u# fi);
  233. pickup tiny.nib; pos1(stem',0); pos2(stem,0);
  234. pos0'(stem',0); pos0(stem,0); z0r=z0'r; x0'=x1; x0=x2;
  235. rt x1r=hround(w-2.5u+.5stem');
  236. numeric edge; edge=lft x2l;
  237. path edge_path; edge_path=(edge,h)--(edge,0);
  238. pickup fine.nib; pos3(if hefty:thin_join else: hair fi,0);
  239. pos4(vair,90); pos5(curve,180); pos6(vair,270); penpos7(x3r-x3l,360);
  240. lft x3l=min(lft x3l-(rt x3r-tiny.rt x2r),2/3[lft x2,edge]); y3=bar_height;
  241. x4l=.5(w-serif_fit)-.3u; top y4r=x_height+oo;
  242. lft x5r=hround max(1.35u-.5curve,.6u); y5=.5x_height;
  243. x6l=x4l-.2u; bot y6r=vround 1/3vair;
  244. lft x7l=edge; y7=min(y3,y6+y4-y3+.6vair);
  245. (x,y4r)=whatever[z3l,z4l]; x4r:=max(x,.5[x5r,x4]);
  246. (x',y6r)=whatever[z7l,z6l]; x6r:=max(x',.5[x5r,x6]);
  247. filldraw stroke z3e{up}...{left}z4e&super_arc.e(4,5)
  248.  &super_arc.e(5,6)&z6e{right}...{up}z7e;  % bowl
  249. y1=ypart(edge_path intersectionpoint(z3l{up}...{left}z4l));
  250. y0=ypart(edge_path intersectionpoint(z7l{down}...{left}z6l));
  251. pickup tiny.nib; bot y2=if serifs: -.25d else: 0 fi;
  252. filldraw stroke z1e--z0'e--z0e--z2e;  % stem
  253. pickup crisp.nib;
  254. pos8(hround(hair-stem_corr),0); pos7'(stem',0);
  255. z7'=z1; x8r=x7'r; top y8=h+oo;
  256. filldraw stroke z7'e--z8e;  % point
  257. if serifs: pickup tiny.nib;
  258.  pos9(vair,-90); x9=.5[x2,x10]; bot y9r=-d-o-1;
  259.  pos10(hair,-180); lft x10r=hround u; y10=-.75d+.5flare;
  260.  pos11(flare,-180); z11r=z10r;
  261.  bulb(9,10,11); filldraw stroke super_arc.e(2,9);  % tail
  262. else: pickup fine.nib; pos2'(stem,0); z2'=z2;
  263.  z2''r=z2'r; z2''=z2'; z2''l=(x2'l,0);
  264.  pos9(vair,-90); x9=4.5u; bot y9r=-d-o-1;
  265.  pos10(.5[vair,flare],-90); lft x10=hround 1.25u;
  266.  y10r=good.y -5/6d; y10l:=good.y y10l;
  267.  filldraw stroke z2'e..z2''e&super_arc.e(2'',9)
  268.   & term.e(9,10,left,.9,4); fi  % tail
  269. penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
  270.  
  271. cmchar "The letter h";
  272. beginchar("h",10u#,asc_height#,0);
  273. italcorr .5[bar_height#,x_height#]*slant-serif_fit#+.5stem#-2u#;
  274. adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
  275. pickup tiny.nib; pos1(stem,0); pos2(stem,0);
  276. pos1'(stem',0); pos2'(stem',0); pos3(stem,0);
  277. lft x1l=hround(2.5u-.5stem); x1l=x1'l=x2l=x2'l; x3=w-x1;
  278. top y1=h; bot y2=0; y1=y1'; y2=y2';
  279. filldraw stroke z1'e--z2'e;  % left stem
  280. h_stroke(2,a,3,4);  % arch and right stem
  281. if serifs: sloped_serif.l(1',2',b,1/3,jut,serif_drop); % upper left serif
  282.  numeric inner_jut; pickup tiny.nib;
  283.  if rt x2r+jut+.5u+1<=lft x4l-jut: inner_jut=jut;
  284.  else: rt x2r+jut+.5u+1=lft x4l-inner_jut; fi
  285.  dish_serif(2,1,c,1/3,jut,d,1/3,jut); % lower left serif
  286.  dish_serif(4,3,e,1/3,inner_jut,f,1/3,jut); fi % lower right serif
  287. penlabels(1,2,3,4); endchar;
  288.  
  289. cmchar "The letter i";
  290. numeric dot_diam#; dot_diam#=max(dot_size#,cap_curve#);
  291. beginchar("i",5u#,min(asc_height#,10/7x_height#+.5dot_diam#),0);
  292. define_whole_blacker_pixels(dot_diam);
  293. italcorr h#*slant-serif_fit# + .5dot_diam# -2u#;
  294. adjust_fit(serif_fit#+stem_shift# if monospace:+.25u#fi,serif_fit#-stem_shift#);
  295. pickup tiny.nib; pos1(stem',0); pos2(stem',0);
  296. if odd(w-stem'): change_width; fi
  297. lft x1l=hround(.5w-.5stem'); x1=x2;
  298. top y1=x_height if serifs: +min(oo,serif_drop) fi; bot y2=0;
  299. filldraw stroke z1e--z2e;  % stem
  300. pos3(dot_diam,0); pos4(dot_diam,90);
  301. if serifs: x3r=max(x1r,hround(x1+.5dot_diam-.2jut)-.5tiny)
  302. else: x3=x1-.5 fi;
  303. top y4r=h+1;
  304. if bot y4l-top y1<slab: y4l:=min(y4r-eps,y1+tiny+slab); fi
  305. x3=x4; y3=.5[y4l,y4r]; dot(3,4);  % dot
  306. if serifs: sloped_serif.l(1,2,a,1/3,.95jut,serif_drop);  % upper serif
  307.  dish_serif(2,1,b,1/3,jut,c,1/3,.9jut); fi  % lower serif
  308. penlabels(1,2,3,4); endchar;
  309.  
  310. cmchar "The letter j";
  311. numeric dot_diam#; dot_diam#=max(dot_size#,cap_curve#);
  312. beginchar("j",5.5u#,min(asc_height#,10/7x_height#+.5dot_diam#),desc_depth#);
  313. define_whole_blacker_pixels(dot_diam);
  314. italcorr h#*slant-serif_fit#+.5stem#-2u#;
  315. adjust_fit(serif_fit#+2stem_shift# if monospace:+\\.5u# fi,
  316.  serif_fit#-2stem_shift# if monospace:-.5u# fi);
  317. pickup tiny.nib; pos1(stem',0); pos2(stem',0);
  318. rt x1r=hround(.5w+.25u+.5stem'); x1=x2;
  319. top y1=x_height if serifs: +min(oo,serif_drop) fi; bot y2=-1/3d;
  320. filldraw stroke z1e--z2e;  % stem
  321. pos3(dot_diam,0); pos4(dot_diam,90);
  322. x3r=x1r; top y4r=h+1;
  323. if bot y4l-top y1<slab: y4l:=min(y4r-eps,y1+tiny+slab); fi
  324. x3=x4; y3=.5[y4l,y4r]; dot(3,4);  % dot
  325. if serifs: sloped_serif.l(1,2,a,1/3,1.1jut,serif_drop);  % upper serif
  326.  pickup tiny.nib; pos5(vair,-90); pos6(hair,-180); pos7(flare,-180);
  327.  x5=.5[x2,x6r]; bot y5r=-d-oo; y6-.5flare=-.88d;
  328.  if monospace: lft x6r=0 else: z6r=z7r; rt x7l=floor .75u fi;
  329.  (x,y5r)=whatever[z5l,z2l]; x5r:=max(x,.5[x6r,x5]);
  330.  filldraw stroke z2e{down}...z5e{left};  bulb(5,6,7); % arc and bulb
  331. else: pickup fine.nib; pos2'(stem',0); z2'=z2;
  332.  pos6(.2[vair,stem'],-90); pos7(vair,-90);
  333.  lft x7r=hround -.75u; bot y7r=vround 5/6(-d-oo);
  334.  (x,y7l)=whatever[z7r,z3]; x7l:=x;
  335.  z5r=z2'r; (x2'l,y5l)=whatever[z7l,z5r]; x5l=x2'l; y5=y5r;
  336.  x6r=.5[x7r,x5r]; x6l:=.5[x7l,x5l]; bot y6r=-d-oo;
  337.  filldraw stroke z2'e..{down}z5e & super_arc.e(5,6)
  338.   & z6e{left}..z7e; fi  % arc and terminal
  339. penlabels(1,2,3,4,5,6,7); endchar;
  340.  
  341. cmchar "The letter k";
  342. beginchar("k",9.5u#,asc_height#,0);
  343. italcorr x_height#*slant-.2u#;
  344. adjust_fit(serif_fit#,serif_fit#); pickup tiny.nib;
  345. numeric right_jut,stem[],alpha[];
  346. stem1=max(tiny.breadth,hround(fudged.stem-stem_corr));
  347. stem2=max(tiny.breadth,hround(fudged.stem-2stem_corr));
  348. stem3=max(tiny.breadth,hround(fudged.hair if hefty:-\\4stem_corr fi));
  349. stem4=max(tiny.breadth,hround(fudged.stem-3stem_corr));
  350. if serifs: right_jut=.6jut; else: right_jut=.4tiny; fi
  351. pos1(stem1,0); pos2(stem2,0); top y1=h; bot y2=0;
  352. lft x1l=lft x2l=hround(2.5u-.5stem1);
  353. top y3=x_height; rt x3r=hround(r-letter_fit-.7u-right_jut)+eps;
  354. bot y6=0; rt x6r=hround(r-letter_fit-.3u-right_jut)+eps;
  355. x4=x11=x1; y4=.7bar_height; y11=y3;
  356. alpha1=diag_ratio(1,.5(stem3-tiny),y3-y4,x3r-x4);
  357. alpha2=diag_ratio(1,.5(stem4-tiny),y11-y6,x6r-x1);
  358. penpos3(alpha1*(stem3-tiny),0); penpos4(whatever,-90);
  359. z5=.5[z5l,z5r]; penpos6(alpha2*(stem4-tiny),0);
  360. forsuffixes $=l,r: y3'$=x_height; y6'$=0; z4$=z3'$+whatever*(z3-z4);
  361.  z5$=z6'$+whatever*(z11-z6)=whatever[z3,z4]; endfor
  362. z3'r=z3r+penoffset z3-z4 of currentpen+whatever*(z3-z4);
  363. % we have also |z3'l=z3l+penoffset z4-z3 of currentpen+whatever*(z3-z4)|;\]
  364. z6'r=z6r+penoffset z11-z6 of currentpen+whatever*(z11-z6);
  365. z6'l=z6l+penoffset z6-z11 of currentpen+whatever*(z11-z6);
  366. fill z4r--diag_end(4r,3'r,1,.5,3'l,4l)--z4l--cycle;  % upper diagonal
  367. fill z5l--diag_end(5l,6'l,.5,1,6'r,5r)--z5r--cycle;  % lower diagonal
  368. pos0(stem1,0); pos0'(stem2,0); y0=y0'; x0=x1; x0'=x2;
  369. rt z0r=whatever[z3,z4]; filldraw stroke z1e..z0e--z0'e..z2e; % stem
  370. if serifs: numeric inner_jut;
  371.  if rt x2r+jut+.5u+1<=lft x6l-jut: inner_jut=jut;
  372.  else: rt x2r+inner_jut+.5u+1=lft x6l-inner_jut; fi
  373.  sloped_serif.l(1,0,a,1/3,jut,serif_drop); % upper stem serif
  374.  dish_serif(2,0',b,1/3,jut,c,1/3,inner_jut);  % lower stem serif
  375.  dish_serif(3,4,d,2/3,1.4jut,e,1/2,right_jut)(dark); % upper diagonal serif
  376.  dish_serif(6,5,f,1/2,inner_jut,g,1/3,right_jut)(dark);fi % lower diagonal serif
  377. penlabels(0,1,2,3,4,5,6,11); endchar;
  378.  
  379. cmchar "The letter l";
  380. beginchar("l",5u#,asc_height#,0); l_width#:=5u#+2serif_fit#;
  381. italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
  382. adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
  383. pickup tiny.nib; pos1(stem',0); pos2(stem',0);
  384. if odd(w-stem'): change_width; fi
  385. lft x1l=hround(.5w-.5stem'); x1=x2; top y1=h; bot y2=0;
  386. filldraw stroke z1e--z2e;  % stem
  387. if serifs: sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % upper serif
  388.  dish_serif(2,1,b,1/3,jut,c,1/3,jut); fi  % lower serif
  389. penlabels(1,2); endchar;
  390.  
  391. cmchar "The letter m";
  392. beginchar("m",15u#,x_height#,0);
  393. italcorr .5[bar_height#,x_height#]*slant-serif_fit#+.5stem#-2u#;
  394. adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
  395. numeric shaved_stem; shaved_stem=hround(mfudged.stem-2stem_corr);
  396. pickup tiny.nib; pos1(mfudged.stem,0); pos2(mfudged.stem,0);
  397. pos1'(shaved_stem,0); pos2'(shaved_stem,0);
  398. pos3(mfudged.stem,0); pos5(mfudged.stem,0);
  399. lft x1l=hround(2.5u-.5stem); x1l=x1'l=x2l=x2'l; % stem, sic
  400. lft x3l=hround(.5w-.5mfudged.stem); x5-x3=x3-x1;
  401. if not monospace: r:=hround(x5+x1)+r-w; fi  % change width for better fit
  402. top y1=h+min(oo,serif_drop); bot y2=0; y1=y1'; y2=y2';
  403. filldraw stroke z1'e--z2'e;  % left stem
  404. h_stroke(2,a,3,4);  % left arch and middle stem
  405. h_stroke(4,b,5,6);  % right arch and right stem
  406. if serifs: sloped_serif.l(1',2',c,1/3,jut,serif_drop); % upper left serif
  407.  numeric inner_jut; pickup tiny.nib;
  408.  if rt x2r+jut+.5u+1<=lft x4l-jut: inner_jut=jut;
  409.  else: rt x2r+jut+.5u+1=lft x4l-inner_jut; fi
  410.  dish_serif(2,1,d,1/3,jut,e,1/3,jut); % lower left serif
  411.  dish_serif(4,3,f,1/3,inner_jut,g,1/3,jut); % lower middle serif
  412.  dish_serif(6,5,h,1/3,inner_jut,i,1/3,jut); fi % lower right serif
  413. penlabels(1,2,3,4,5,6); endchar;
  414.  
  415. cmchar "The letter n";
  416. beginchar("n",10u#,x_height#,0);
  417. italcorr .5[bar_height#,x_height#]*slant-serif_fit#+.5stem#-2u#;
  418. adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
  419. pickup tiny.nib; pos1(stem,0); pos2(stem,0);
  420. numeric shaved_stem; shaved_stem=hround(stem-2stem_corr);
  421. pos1'(shaved_stem,0); pos2'(shaved_stem,0); pos3(stem,0);
  422. lft x1l=hround(2.5u-.5stem); x1l=x1'l=x2l=x2'l; x3=w-x1;
  423. top y1=h+min(oo,serif_drop); bot y2=0; y1=y1'; y2=y2';
  424. filldraw stroke z1'e--z2'e;  % left stem
  425. h_stroke(2,a,3,4);  % arch and right stem
  426. if serifs: sloped_serif.l(1',2',b,1/3,jut,serif_drop); % upper left serif
  427.  numeric inner_jut; pickup tiny.nib;
  428.  if rt x2r+jut+.5u+1<=lft x4l-jut: inner_jut=jut;
  429.  else: rt x2r+jut+.5u+1=lft x4l-inner_jut; fi
  430.  dish_serif(2,1,c,1/3,jut,d,1/3,jut); % lower left serif
  431.  dish_serif(4,3,e,1/3,inner_jut,f,1/3,jut); fi % lower right serif
  432. penlabels(1,2,3,4); endchar;
  433.  
  434. cmchar "The letter o";
  435. beginchar("o",9u#,x_height#,0);
  436. italcorr .7x_height#*slant;
  437. adjust_fit(if monospace: .5u#,.5u# else: 0,0 fi);
  438. penpos1(vair,90); penpos3(vair',-90);
  439. penpos2(curve,180); penpos4(curve,0);
  440. x2r=hround max(.5u,1.25u-.5curve);
  441. x4r=w-x2r; x1=x3=.5w; y1r=h+vround 1.5oo; y3r=-oo;
  442. y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
  443. penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  444.  & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle;  % bowl
  445. penlabels(1,2,3,4); endchar;
  446.  
  447. cmchar "The letter p";
  448. beginchar("p",10u#+serif_fit#,x_height#,desc_depth#);
  449. italcorr .5x_height#*slant+min(.5curve#-.85u#,-.1u#);
  450. adjust_fit(serif_fit#,0);
  451. pickup tiny.nib; pos1(stem',0); pos2(stem,0);
  452. pos0'(stem',0); pos0(stem,0); z0l=z0'l; x0'=x1; x0=x2;
  453. lft x1l=hround(2.5u-.5stem'); top y1=h if serifs: +min(oo,serif_drop) fi;
  454. numeric edge; edge=rt x2r;
  455. pickup fine.nib; pos3(if hefty:thin_join else: hair fi,180);
  456. pos4(vair',90); pos5(curve,0); pos6(vair,-90); penpos7(x3l-x3r,-180);
  457. rt x3l=max(rt x3l-(lft x3r-tiny.lft x2l), 1/3[rt x2,edge]);
  458. y3=1/8[bar_height,x_height];
  459. x4l=w-.5(w-serif_fit)+.5u; top y4r=x_height+oo;
  460. rt x5r=hround min(w-1.35u+.5curve,w-.6u); y5=.5x_height;
  461. x6l=x4l-.2u; bot y6r=-oo;
  462. x7=x3; y7=min(y3,y6+y4-y3+.6vair);
  463. (x,y4r)=whatever[z3l,z4l]; x4r:=min(x,.5[x5r,x4]);
  464. (x',y6r)=whatever[z7l,z6l]; x6r:=min(x',.5[x5r,x6]);
  465. filldraw stroke z3e{up}...{right}z4e&super_arc.e(4,5)
  466.  &super_arc.e(5,6)&z6e{left}...{up}z7e;  % bowl
  467. y0=ypart(((edge,h)--(edge,0))intersectionpoint(z3l{up}...{right}z4l));
  468. pickup tiny.nib; bot y2=-d;
  469. filldraw stroke z1e--z0'e--z0e--z2e;  % stem
  470. pickup crisp.nib; pos8(hair,0); pos7'(stem,0);
  471. z7'=z2; x8l=x7'l; bot y8=0;
  472. filldraw stroke z7'e--z8e;  % point
  473. if serifs: sloped_serif.l(1,0',a,1/3,jut,serif_drop);  % upper serif
  474.  dish_serif(2,0,b,1/3,jut,c,1/3,jut); fi  % lower serif
  475. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  476.  
  477. cmchar "The letter q";
  478. beginchar("q",10u#+serif_fit#,x_height#,desc_depth#);
  479. italcorr x_height#*slant-serif_fit#+.5stem#-2u# if serifs:+.5u# fi;
  480. adjust_fit(0,serif_fit# if serifs: -.5u# fi);
  481. pickup tiny.nib; pos1(stem',0); pos2(stem,0);
  482. pos0'(stem',0); pos0(stem,0); z0r=z0'r; x0'=x1; x0=x2;
  483. rt x1r=hround(w-2.5u+.5stem');
  484. numeric edge; edge=lft x2l;
  485. pickup fine.nib; pos3(if hefty:thin_join else: hair fi,0);
  486. pos4(vair',90); pos5(curve,180); pos6(vair,270); penpos7(x3r-x3l,360);
  487. lft x3l=min(lft x3l-(rt x3r-tiny.rt x2r),2/3[lft x2,edge]); y3=bar_height;
  488. x4l=.5(w-serif_fit)-.3u; top y4r=x_height+oo;
  489. lft x5r=hround max(1.35u-.5curve,.6u); y5=.5x_height;
  490. x6l=x4l-.2u; bot y6r=-oo; y7=min(y3,y6+y4-y3+.6vair);
  491. lft x7l=min(lft x7l-(rt x7r-tiny.rt x2r),1/3[lft x2,edge]);
  492. (x,y4r)=whatever[z3l,z4l]; x4r:=max(x,.5[x5r,x4]);
  493. (x',y6r)=whatever[z7l,z6l]; x6r:=max(x',.5[x5r,x6]);
  494. filldraw stroke z3e{up}...{left}z4e&super_arc.e(4,5)
  495.  &super_arc.e(5,6)&z6e{right}...{up}z7e;  % bowl
  496. y1=ypart(((edge,h)--(edge,0))intersectionpoint(z3l{up}...{left}z4l));
  497. y0=ypart(((edge,h)--(edge,0))intersectionpoint(z6l{right}...{up}z7l));
  498. pickup tiny.nib; bot y2=-d;
  499. filldraw stroke z1e--z0'e--z0e--z2e;  % stem
  500. pickup crisp.nib;
  501. pos8(hround(hair-stem_corr),0); pos7'(stem',0);
  502. z7'=z1; x8r=x7'r; top y8=h+oo;
  503. filldraw stroke z7'e--z8e;  % point
  504. if serifs: dish_serif(2,0,b,1/3,jut,c,1/3,jut); fi  % lower serif
  505. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  506.  
  507. cmchar "The letter r";
  508. numeric r_flare#; r_flare#=.75[if serifs: stem# else: vair# fi,flare#];
  509. define_whole_blacker_pixels(r_flare);
  510. beginchar("r",if serifs:max(7u#,5.5u#+r_flare#) else:6.5u# fi,x_height#,0);
  511. italcorr x_height#*slant if not serifs: +.25u# fi;
  512. adjust_fit(serif_fit#,0);
  513. pickup fine.nib; top y4r=h+oo;
  514. if serifs: pos4(vair,90); pos5(hair,0);
  515.  x4=w-max(1.75u,.25u+r_flare);
  516.  rt x5r=hround(w-.5u+.5); y5+.5r_flare=.9[bar_height,h]+oo;
  517.  pos6(r_flare,0); bulb(4,5,6);  % bulb
  518. else: pos4(r_flare,90); rt x4=hround(w-.25u); fi
  519. pos3(thin_join,180); rt x3l=hround(2.5u-.5stem')+stem'; top y3=bar_height;
  520. filldraw stroke z3e{up}...{right}z4e;  % arc
  521. pickup tiny.nib; pos0(stem',0); pos2(stem',0);
  522. pos1(hround(stem-3stem_corr),0); top y1=h+min(oo,serif_drop);
  523. pos0'(hround(stem-3stem_corr),0); y0=y0'=y3; x1l=x0l=x0'l=x2l;
  524. lft x1l=hround(2.5u-.5stem'); bot y2=0;
  525. filldraw stroke z1e--z0'e--z0e--z2e;  % stem
  526. if serifs: sloped_serif.l(1,0',a,1/3,jut,serif_drop);  % upper serif
  527.  dish_serif(2,0,b,1/3,jut,c,1/3,1.25jut); fi  % lower serif
  528. penlabels(1,2,3,4,5,6); endchar;
  529.  
  530. cmchar "The letter s";
  531. beginchar("s",7.1u#,x_height#,0);
  532. italcorr x_height#*slant-if serifs:.55u# else:.3u# fi;
  533. adjust_fit(if monospace: .5u#,.4u# else: 0,if serifs:0 else:-.2u# fi fi);
  534. numeric theta; theta=90-angle(40u,h); slope:=-h/40u;  % angle at middle
  535. numeric s_slab; s_slab=if serifs:vair else:Vround .1[vair,stem] fi;
  536. numeric ess'; ess'=max(fine.breadth,ess);
  537. pickup fine.nib; pos2(max(fine.breadth,s_slab-vround vair_corr),-100);
  538. pos0(ess',theta); pos7(s_slab,-90); x2l=x0=x7=.5w;
  539. top y2l=h+vround 1.5oo; bot y7r=-oo;
  540. y0-.5ess'=y7l+if serifs:.54 else: .52 fi\\(y2r-y7l-ess');
  541. lft x3l=hround .6u; rt x6r=hround(w-.6u);
  542. x3r-x3l=x6r-x6l=hround .5[s_slab,ess']-fine;
  543. ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
  544. ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
  545. interim superness:=more_super;
  546. filldraw stroke super_arc.e(2,3) & z3e{down}
  547.  ..z4e---z5e..z6e{down} & super_arc.e(6,7);  % main stroke
  548. if serifs: pos1(hair,180); pos8(hair,180);
  549.  rt x1l=hround(w-1.05u); lft x8r=hround .6u;
  550.  bot y1=min(bot y2r,vround 1/5[top y5r,h]);
  551.  top y8=max(top y7l,vround 5/6 bot y4l);
  552.  filldraw stroke z1e{up}....{left}z2e;  % upper arc
  553.  filldraw stroke z7e{left}....{x8-x7,5(y8-y7)}z8e;  % lower arc
  554.  path upper_arc, lower_arc;
  555.  upper_arc=z1{up}....{left}z2; lower_arc=z7{left}....{x8-x7,5(y8-y7)}z8;
  556.  pos10(.3[fine.breadth,cap_hair],0); pos9(.3[fine.breadth,cap_hair],0);
  557.  x10r=x1l; top y10=top y2l; x9l=x8r; bot y9=bot y7r;
  558.  x1l-x1'=x8'-x8r=1.6cap_curve-fine; y1'=y1; y8'=y8;
  559.  numeric t; t=xpart(upper_arc intersectiontimes(z10l--z1'));
  560.  filldraw z1l--z10r--z10l--subpath(t,0) of upper_arc--cycle;  % upper barb
  561.  t:=xpart(lower_arc intersectiontimes(z9r--z8'));
  562.  filldraw z8r--z9l--z9r--subpath(t,1) of lower_arc--cycle;  % lower barb
  563. else: pos1(4/7[s_slab,flare],-100); pos8(flare,-100);
  564.  x1l=good.x(x1l+w-u-rt x1); lft x8r=hround .5u;
  565.  top y1l=vround(.93h+1.5oo); bot y8r=vround .1h-oo;
  566.  filldraw stroke term.e(2,1,right,.9,4);  % upper arc and terminal
  567.  filldraw stroke term.e(7,8,left,1,4); fi  % lower arc and terminal
  568. penlabels(0,1,1',2,3,4,5,6,7,8,8',9,10); endchar;
  569.  
  570. cmchar "The letter t";
  571. beginchar("t",6u#+max(u#,.5stem#),
  572.  min(asc_height#,if hefty:9/7 else:10/7 fi\\ x_height#),0);
  573. italcorr x_height#*slant if serifs: -.9u# else: -.4u# fi;
  574. adjust_fit(0,if serifs: 0 else: -.5u# fi);
  575. numeric shaved_stem; shaved_stem=hround(stem if hefty:-\\2stem_corr fi);
  576. pickup fine.nib; pos2(shaved_stem,180);pos3(shaved_stem,180);
  577. lft x2r=lft x3r=hround(2.5u-.5shaved_stem);
  578. y2=y8; y3=max(.5bar_height,2vair);
  579. pickup crisp.nib; pos8(bar,90);
  580. rt x8=hround(w-1.3u); top y8r=x_height; lft x7=hround 1/3u; y7l=y8l;
  581. if hefty: pos7(bar,90);
  582.  filldraw stroke z7e--z8e;  % crossbar
  583.  pickup tiny.nib; pos1(hround(shaved_stem-stem_corr),0);
  584.  rt x1r=fine.rt x2l; top y1=h;
  585.  penpos2'(x1r-x1l,0); x2'=x1; y2'=y2;
  586.  filldraw stroke z1e--z2'e;  % upper terminal
  587. else: pos7(vair,90); pos1(hair,0);
  588.  rt x1r=fine.rt x2l; top y1=h;
  589.  filldraw z1l{down}...{left}z7r--z7l--z8l
  590.   --z8r--(x1r,y8r)--z1r--cycle; fi  % upper terminal and crossbar
  591. pickup fine.nib; interim superness:=more_super;
  592. pos4(vair',-90); bot y4r=-oo; rt x5r=hround(w-u);
  593. if serifs: pos5(hair,0); y5=y3; x4l=.5[x3l,x5l];
  594.  (x,y4r)=whatever[z4l,z5l]; x4r:=max(x,.5[x3r,x4]);
  595.  filldraw stroke z2e..super_arc.e(3,4)...{up}z5e;  % stem and hook
  596.  pickup crisp.nib; pos6(hair,0); pos5'(hair,0);
  597.  x6=x5=x5'; top y6=max(vround .75bar_height,top y5); y5=y5';
  598.  filldraw stroke z5'e--z6e;  % terminal
  599. else: pos5(vair,-75); top y5l=vround .2[top y4l,bar_height];
  600.  x5l:=good.x x5l; x4l=1/3[x3l,x5l]; x4r:=1/3[x3r,x5r]; y3l:=y3l+.2vair;
  601.  filldraw stroke z2e..super_arc.e(3,4);  % stem and hook
  602.  path p; p=stroke z4e{right}..tension .9 and atleast 1..z5e;  % terminal
  603.  if (xpart(z5l-precontrol 1 of p)<0) or (xpart(z5r-postcontrol 2 of p)<0):
  604.   filldraw stroke z4e{right}...{up}z5e;
  605.  else: filldraw p; fi fi;
  606. penlabels(1,2,3,4,5,6,7,8); endchar;
  607.  
  608. cmchar "The letter u";
  609. beginchar("u",10u#,x_height#,0);
  610. italcorr x_height#*slant-serif_fit#+.5stem#-2u#;
  611. adjust_fit(serif_fit#+stem_shift#,serif_fit#-stem_shift#);
  612. numeric light_vair; light_vair=vair if hefty: -vround 2vair_corr fi;
  613. if light_vair<fine.breadth: light_vair:=fine.breadth; fi
  614. pickup tiny.nib; pos1(stem,0); pos2(stem,0);
  615. pos3(stem,0); pos4(stem',0);
  616. lft x1l=hround(2.5u-.5stem); x1=x2; x3=w-x1; x3r=x4r;
  617. if serifs: top y1=h+min(oo,serif_drop); bot y4=-min(oo,serif_drop);
  618. else: top y1=h; bot y4=0; fi
  619. pos0(stem,0); pos0'(stem',0); x0=x3; x0'=x4; y0=y0';
  620. penpos2'(stem-fine,-180); z2'=z2; y3=y1; y2=.5bar_height;
  621. penpos5(max(eps,light_vair-fine),-90); penpos6(thin_join-fine,0);
  622. y6=y0=2/3bar_height;
  623. filldraw stroke z1e--z2e;  % left stem
  624. filldraw stroke z3e..z0e--z0'e..z4e;  % right stem
  625. pickup fine.nib; bot y5r=-oo; x5l=.5w-.25u; lft x6l=tiny.lft x0l;
  626. (x,y5r)=whatever[z5l,z6l]; x5r:=max(x,.5[x5,x2'r]);
  627. filldraw stroke {{interim superness:=hein_super;
  628.   pulled_arc.e(2',5)}} & z5e{right}...{up}z6e;  % arc
  629. if serifs: sloped_serif.l(1,2,a,1/3,jut,serif_drop); % upper left serif
  630.  sloped_serif.l(3,0,b,1/3,jut,serif_drop); % upper right serif
  631.  sloped_serif.r(4,0',c,1/3,jut,min(oo,serif_drop)); fi % lower right serif
  632. penlabels(1,2,3,4,5); labels(6); endchar;
  633.  
  634. cmchar "The letter v";
  635. beginchar("v",if serifs: 9.5u# else:9u# fi,x_height#,0);
  636. italcorr x_height#*slant+.25u#;
  637. adjust_fit(serif_fit# if monospace:+\\.5u#,.5u#+ else:,fi\\ serif_fit#);
  638. numeric left_stem,right_stem,outer_jut,alpha;
  639. left_stem=fudged.stem-stem_corr;
  640. right_stem=min(fudged.hair if hefty:-2stem_corr fi,left_stem);
  641. outer_jut=.75jut; x1l=w-x4r=l+letter_fit+outer_jut+.25u; y1=y4=h;
  642. x2-x1=x4-x3; x2l+apex_corr=x3l; y2=y3=-apex_oo;
  643. alpha=diag_ratio(2,right_stem,y1-y2,x4r-x1l-apex_corr);
  644. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  645. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  646. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  647. if y0>notch_cut: y0:=notch_cut;
  648.   fill z0+.5right{up}...{z4-z3}diag_end(3l,4l,1,1,4r,3r)
  649.     --diag_end(4r,3r,1,1,2l,1l)--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  650.     ...{down}z0+.5left--cycle; % left and right diagonals
  651. else: fill z0--diag_end(0,4l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)
  652.     --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
  653. if serifs: numeric inner_jut; pickup tiny.nib;
  654.  prime_points_inside(1,2); prime_points_inside(4,3);
  655.  if rt x1'r+jut+.5u+1<=lft x4'l-jut: inner_jut=jut;
  656.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  657.  dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut);  % left serif
  658.  dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark); fi  % right serif
  659. penlabels(0,1,2,3,4); endchar;
  660.  
  661. cmchar "The letter w";
  662. beginchar("w",13u#,x_height#,0);
  663. italcorr x_height#*slant+.25u#;
  664. adjust_fit(serif_fit#,serif_fit#);
  665. numeric stem[],outer_jut,upper_notch,alpha,mid_corr;
  666. outer_jut=.7jut; x1l=w-x8r=l+letter_fit+outer_jut+.25u;
  667. stem1=fudged.stem-stem_corr;
  668. stem4=min(fudged.hair if hefty:-2stem_corr fi,stem1);
  669. stem2=if hefty:.1[vair,stem4] else: stem4 fi;
  670. stem3=max(stem2,stem1-3stem_corr);
  671. x2-x1=x4-x3=x6-x5=x8-x7; x2l+apex_corr=x3l; x6l+apex_corr=x7l;
  672. y1=y8=h; y2=y3=y6=y7=-apex_oo;
  673. y4=y5=if monospace: vround .6 fi\\ h; upper_notch=y4-notch_cut;
  674. mid_corr=if monospace or hefty:-.3apex_corr else: .5jut fi;
  675. alpha=diag_ratio(4,stem2-stem3+stem4,y1-y2,x8r-x1l+mid_corr-2apex_corr);
  676. penpos1(alpha*stem1,0); penpos2(alpha*stem1,0);
  677. penpos3(alpha*stem2,0); penpos4(alpha*stem2,0);
  678. penpos5(alpha*stem3,0); penpos6(alpha*stem3,0);
  679. penpos7(alpha*stem4,0); penpos8(alpha*stem4,0);
  680. x4l-x1l=floor(x4l-x1l+.5(x5r+mid_corr-x4r)); % |x5r| $\approx$ |x4r+mid_corr|
  681. z23=whatever[z1r,z2r]=whatever[z3l,z4l];
  682. z45=whatever[z3r,z4r]=whatever[z5l,z6l];
  683. z67=whatever[z5r,z6r]=whatever[z7l,z8l];
  684. fill diag_end(1l,2l,1,1,3r,4r){z4-z3}
  685.  ...if y45<upper_notch:(x45,upper_notch)+.5left{up}
  686.    --(x45,upper_notch)+.5right{down} else: z45&z45 fi
  687.  ...{z6-z5}diag_end(5l,6l,1,1,7r,8r)--diag_end(7r,8r,1,1,8l,7l){z7-z8}
  688.  ...if y67>notch_cut:(x67,notch_cut)+.5right{down}
  689.    --(x67,notch_cut)+.5left{up} else: z67&z67 fi
  690.  ...{z5-z6}special_diag_end(6,5,4,3){z3-z4}
  691.  ...if y23>notch_cut:(x23,notch_cut)+.5right{down}
  692.    --(x23,notch_cut)+.5left{up} else: z23&z23 fi
  693.  ...{z1-z2}diag_end(2r,1r,1,1,1l,2l)--cycle;  % diagonals
  694. if serifs: numeric inner_jut[]; pickup tiny.nib;
  695.  prime_points_inside(1,2); prime_points_inside(5,6); prime_points_inside(8,7);
  696.  if monospace: inner_jut1=inner_jut4=1.5jut;
  697.  elseif hefty: inner_jut1=inner_jut4=jut;
  698.  else: fill diag_end(6r,5r,1,1,5l,6l)--.9[z5l,z6l]
  699.    ..{z5-z6}.1[z5r,z6r]--cycle; % middle stem
  700.   inner_jut2=.7inner_jut1; inner_jut4=1.1inner_jut3;
  701.   if rt x1'r+jut+.5u+1<=lft x5'l-.7jut: inner_jut1=jut;
  702.   else: rt x1'r+inner_jut1+.5u+1=lft x5'l-inner_jut2; fi
  703.   if rt x5'r+jut+.5u+1<=lft x8'l-1.1jut: inner_jut3=jut;
  704.   else: rt x5'r+inner_jut3+.5u+1=lft x8'l-inner_jut4; fi
  705.   dish_serif(5',6,e,1/3,inner_jut2,f,1/2,inner_jut3); fi  % middle serif
  706.  dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut1);  % left serif
  707.  dish_serif(8',7,c,.6,inner_jut4,d,1/2,outer_jut)(dark); fi  % right serif
  708. penlabels(0,1,2,3,4,5,6,7,8,23,45,67); endchar;
  709.  
  710. cmchar "The letter x";
  711. beginchar("x",if serifs:9.5u# else:9u# fi,x_height#,0);
  712. italcorr x_height#*slant-.05u#;
  713. adjust_fit(serif_fit# if monospace:+\\.5u#,.5u#+ else:,fi\\ serif_fit#);
  714. numeric stem[],outer_jut,xjut,alpha[];
  715. stem1=fudged.stem-4stem_corr; stem2=min(fudged.hair,stem1);
  716. outer_jut=.75jut; xjut= if serifs: (stem1-stem2)/4 else: 0 fi;
  717. x1l=l+letter_fit+.1u+outer_jut; x2r=r-letter_fit-.3u-outer_jut-xjut;
  718. x3l=l+letter_fit+outer_jut+xjut; x4r=r-letter_fit-outer_jut;
  719. y1=y2=h; y3=y4=0;
  720. alpha1=diag_ratio(1,stem1,h,x4r-x1l);
  721. alpha2=diag_ratio(1,stem2,h,x2r-x3l);
  722. penpos1(alpha1*stem1,0); penpos2(alpha2*stem2,0);
  723. penpos3(alpha2*stem2,0); penpos4(alpha1*stem1,0);
  724. if hefty: z0=whatever[z1,z4]=whatever[z2,z3];
  725.  x12=x34=x0; y13=y24=y0;
  726.  z12=whatever[z2l,z3l]; z13=whatever[z2l,z3l];
  727.  z24=whatever[z2r,z3r]; z34=whatever[z2r,z3r];
  728.  forsuffixes $=13,24,34: z$'=.2[z$,z0]; endfor
  729.  fill diag_end(12,1r,.5,1,1l,13')--z13'--diag_end(13',3l,1,.5,3r,34')--z34'
  730.   --diag_end(34',4l,.5,1,4r,24')--z24'
  731.   --diag_end(24',2r,1,.5,2l,12)--z12--cycle; % diagonals
  732. else: fill diag_end(4r,1r,.5,1,1l,4l)
  733.   --diag_end(1l,4l,.5,1,4r,1r)--cycle; % left diagonal
  734.  fill diag_end(2l,3l,.5,1,3r,2r)
  735.   --diag_end(3r,2r,.5,1,2l,3l)--cycle; fi  % right diagonal
  736. if serifs: numeric inner_jut[]; pickup tiny.nib;
  737.  prime_points_inside(1,4); prime_points_inside(2,3);
  738.  prime_points_inside(3,2); prime_points_inside(4,1);
  739.  if rt x1'r+jut+.5u+1<=lft x2'l-jut-xjut: inner_jut1=jut;
  740.  else: rt x1'r+inner_jut1+.5u+1=lft x2'l-inner_jut1-xjut; fi
  741.  if rt x3'r+jut+.5u+1<=lft x4'l-jut-xjut: inner_jut2=jut;
  742.  else: rt x3'r+inner_jut2+.5u+1=lft x4'l-inner_jut2-xjut; fi
  743.  dish_serif(1',4,a,1/3,outer_jut,b,2/3,inner_jut1);  % upper left serif
  744.  dish_serif(4',1,c,2/3,inner_jut2,d,1/3,outer_jut);  % lower right serif
  745.  dish_serif(2',3,e,2/3,inner_jut1+xjut,
  746.   f,1/2,outer_jut+xjut)(dark);  % upper right serif
  747.  dish_serif(3',2,g,1/2,outer_jut+xjut,
  748.   h,2/3,inner_jut2+xjut)(dark); fi  % lower left serif
  749. penlabels(0,1,2,3,4,12,13,24,34); endchar;
  750.  
  751. cmchar "The letter y";
  752. beginchar("y",if serifs:9.5u# else:9u# fi,x_height#,desc_depth#);
  753. italcorr x_height#*slant+.25u#;
  754. adjust_fit(serif_fit# if monospace:+\\.5u#,.5u#+ else:,fi\\ serif_fit#);
  755. numeric left_stem,right_stem,bot_stem,bot_vair,outer_jut;
  756. left_stem=fudged.stem-stem_corr;
  757. right_stem=fudged.hair if hefty:-2stem_corr fi;
  758. bot_stem=fudged.hair if hefty:-8stem_corr fi;
  759. bot_vair=Vround(if serifs: vair else:.5[vair,bot_stem] fi);
  760. outer_jut=.75jut;
  761. x1l=w-x4r=l+letter_fit+outer_jut+.25u; y1=y4r=h; y2=y3=0; x2l=x3l;
  762. numeric alpha,alpha[]; x9=3u; y9=bot_vair-d-oo;
  763. alpha1=diag_ratio(2,bot_stem,y1-y3,x4r-x1l-apex_corr);
  764. alpha2=diag_ratio(1,bot_stem,y1-y9,x4r-x9);
  765. if alpha1<alpha2: x2l-x1l=x4r-x3r+apex_corr; alpha=alpha1;
  766. else: alpha=alpha2; z3l=whatever[z9,z4r-(alpha*bot_stem,0)]; fi
  767. penpos3(alpha*bot_stem,0); penpos4(alpha*right_stem,0);
  768. alpha3=(y1++(x2l-x1l))/y1;
  769. penpos1(alpha3*left_stem,0); penpos2(alpha3*left_stem,0);
  770. z0=whatever[z1r,z2r]=z4l+whatever*(z3r-z4r);
  771. if y0>notch_cut: y0:=notch_cut;
  772.   fill z0+.5right{up}...{z4r-z3r}diag_end(0,4l,1,1,4r,3r)
  773.     --z3r--z2l--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  774.     ...{down}z0+.5left--cycle; % left and right diagonals
  775. else: fill z0--diag_end(0,4l,1,1,4r,3r)--z3r--z2l
  776.     --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
  777. penpos5(alpha*bot_stem,0); z5r=whatever[z3r,z4r]; y5-.5vair=-.5d;
  778. if serifs: numeric light_bulb; light_bulb=hround 7/8[hair,flare]; clearpen;
  779.  penpos6(vair,-90); penpos7(hair,-180); penpos8(light_bulb,-180);
  780.  x6=2u; y6r=-d-oo; y8-.5light_bulb=-.85d; x8r=hround .35u;
  781.  fill stroke z3e---z5e...{left}z6e; bulb(6,7,8);  % arc and bulb
  782.  numeric inner_jut; pickup tiny.nib;
  783.  prime_points_inside(1,2); prime_points_inside(4,3);
  784.  if rt x1'r+jut+.5u+1<=lft x4'l-jut: inner_jut=jut;
  785.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  786.  dish_serif(1',2,a,1/3,outer_jut,b,1/2,inner_jut);  % left serif
  787.  dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark);  % right serif
  788. else: penpos6(bot_vair,-90); x6=2.5u; y6r=-d-oo;
  789.  fill stroke z3e---z5e...{left}z6e;  % arc
  790.  pickup fine.nib; pos6'(bot_vair,-90); z6'=z6;
  791.  pos7(2/3[bot_vair,flare],-85);
  792.  lft x7l=hround u; bot y7r=vround-.96d-oo; y7l:=good.y y7l;
  793.  filldraw stroke term.e(6',7,left,1,4); fi % arc and terminal
  794. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  795.  
  796. cmchar "The letter z";
  797. beginchar("z",8u#,x_height#,0);
  798. italcorr x_height#*slant-.5serif_fit#-.3u#;
  799. adjust_fit(0,.5serif_fit#);
  800. numeric arm_thickness[],z_stem;
  801. if hefty: arm_thickness1=Vround(vair-vair_corr); arm_thickness2=vair;
  802.  z_stem=.6[vair,stem];
  803. else: arm_thickness1=vair; arm_thickness2=vair'; z_stem=.9[vair,stem]; fi
  804. pickup tiny.nib; rt x1r=rt x2r=hround(w-.8u); lft x3l=lft x4l=hround .5u;
  805. top y1=h; y2=min(y1,h-2/3arm_thickness1);
  806. bot y4=0; y3=max(y4,2/3arm_thickness2);
  807. numeric alpha; alpha=diag_ratio(1,z_stem-tiny,y2-y3,x2r-x3l-slant*(y2-y3));
  808. penpos1(alpha*(z_stem-tiny),0); penpos2(alpha*(z_stem-tiny),0);
  809. penpos3(alpha*(z_stem-tiny),0); penpos4(alpha*(z_stem-tiny),0);
  810. pair delta; delta=penoffset z3-z2 of currentpen;
  811. fill top lft z1l--z2l+delta---z3l+delta..lft z3l---lft z4l..bot z4l
  812.  ---bot rt z4r--z3r-delta---z2r-delta..rt z2r---rt z1r..top z1r
  813.  ---cycle;  % diagonal
  814. pickup crisp.nib; pos5(arm_thickness1,90); pos6(hair,180);
  815. top y5r=h; x5=x1; lft x6r=hround .75u; y6=good.y(y5l-beak/1.4)-eps;
  816. arm(5,6,a,beak_darkness,-.4beak_jut);  % upper arm and beak
  817. pos7(arm_thickness2,-90); pos8(hair,0);
  818. bot y7r=0; x7=x4; rt x8r=hround(w-.75u); y8=good.y(y7l+beak/1.2)+eps;
  819. arm(7,8,b,beak_darkness,.6beak_jut);  % lower arm and beak
  820. penlabels(1,2,3,4,5,6,7,8); endchar;
  821.