home *** CD-ROM | disk | FTP | other *** search
/ The World of Computer Software / World_Of_Computer_Software-02-385-Vol-1of3.iso / c / cmsrc392.zip / ROMAND.MF < prev    next >
Text File  |  1992-03-30  |  15KB  |  319 lines
  1. % Computer Modern Roman digits:
  2. % This file contains the ten digits in so-called roman style.
  3. % Character codes \0060 through \0071 are generated.
  4.  
  5. % All digits have the same height, width, depth, and italic correction.
  6.  
  7. cmchar "The numeral 0";
  8. beginchar("0",9u#,fig_height#,0);
  9. italcorr fig_height#*slant-.5u#;
  10. adjust_fit(0,0);
  11. penpos1(vair,90); penpos3(vair,-90); penpos2(curve,180); penpos4(curve,0);
  12. if not monospace: interim superness:=sqrt(more_super*hein_super); fi
  13. x2r=hround max(.7u,1.45u-.5curve); x4r=w-x2r; x1=x3=.5w;
  14. y1r=h+o; y3r=-o; y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
  15. penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  16.  & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle;  % bowl
  17. penlabels(1,2,3,4); endchar;
  18.  
  19. cmchar "The numeral 1";
  20. beginchar("1",9u#,fig_height#,0);
  21. italcorr fig_height#*slant-.5u#;
  22. adjust_fit(0,0);
  23. numeric light_stem; light_stem=hround .4[stem',cap_stem'];
  24. pickup tiny.nib;
  25. pos1(light_stem,0); pos2(light_stem,0);
  26. lft x1l=lft x2l=hround(.5(w+.5u)-.5cap_stem'); top y1=h+o; bot y2=0;
  27. filldraw stroke z1e--z2e;  % stem
  28. if not serifs: save slab; slab=bar; fi
  29. dish_serif(2,1,a,1/3,min(2.25u,lft x2l-1.5u),
  30.   b,1/3,min(2.25u,w-1.25u-rt x2r)); % serif
  31. pickup crisp.nib; pos3(slab,-90); pos4(bar,-90);
  32. top y3l=h+o; top y4l=if monospace: .8 else: .9 fi\\ h+o;
  33. lft x4=max(1.25u,tiny.lft x1l-2.35u);
  34. tiny.rt x1r=lft x3+.25[tiny,hair];
  35. erase fill z3l{x4l-x3l,3(y4l-y3l)}...z4l{left}
  36.  --(x4l,h+o+1)--(x3l,h+o+1)--cycle; % erase excess at top
  37. filldraw stroke z3e{x4e-x3e,3(y4e-y3e)}..z4e{left};  % point
  38. penlabels(1,2,3,4); endchar;
  39.  
  40. cmchar "The numeral 2";
  41. beginchar("2",9u#,fig_height#,0);
  42. italcorr fig_height#*slant-.5u#;
  43. adjust_fit(0,0);
  44. numeric arm_thickness, hair_vair; hair_vair=.25[vair,hair];
  45. arm_thickness=Vround(if hefty:slab+2stem_corr else:.4[stem,cap_stem] fi);
  46. pickup crisp.nib; pos7(arm_thickness,-90); pos8(hair,0);
  47. bot y7r=0; lft x7=hround .9u; rt x8r=hround(w-.9u); y8=good.y(y7l+beak/2)+eps;
  48. arm(7,8,a,.3beak_darkness,beak_jut);  % arm and beak
  49. pickup fine.nib; pos2(slab,90); pos3(.4[curve,cap_curve],0);
  50. top y2r=h+o; x2=.5(w-.5u); rt x3r=hround(w-.9u); y3+.5vair=.75h;
  51. if serifs: numeric bulb_diam; bulb_diam=hround(flare+2/3(cap_stem-stem));
  52.  pos0(bulb_diam,180); pos1(cap_hair,180);
  53.  lft x1r=hround .9u; y1-.5bulb_diam=2/3h;
  54.  (x,y2l)=whatever[z1l,z2r]; x2l:=x; bulb(2,1,0);  % bulb and arc
  55. else: x2l:=x2l-.25u; pos1(flare,angle(-9u,h));
  56.  lft x1r=hround .75u; bot y1l=vround .7h; y1r:=good.y y1r+eps; x1l:=good.x x1l;
  57.  filldraw stroke term.e(2,1,left,.9,4); fi  % terminal and arc
  58. pos4(.25[hair_vair,cap_stem],0);
  59. pos5(hair_vair,0); pos6(hair_vair,0);
  60. y5=arm_thickness; y4=.3[y5,y3]; top y6=min(y5,slab,top y7l);
  61. lft x6l=crisp.lft x7; z4l=whatever[z6l,(x3l,bot .58h)]; z5l=whatever[z6l,z4l];
  62. erase fill z4l--z6l--lft z6l--(lft x6l,y4l)--cycle;  % erase excess at left
  63. filldraw stroke z2e{right}..tension atleast .9 and atleast 1
  64.  ..z3e{down}.. z4e---z5e--z6e;  % stroke
  65. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  66.  
  67. cmchar "The numeral 3";
  68. beginchar("3",9u#,fig_height#,0);
  69. italcorr fig_height#*slant-.5u#;
  70. adjust_fit(0,0);
  71. numeric top_thickness,mid_thickness,bot_thickness;
  72. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  73. mid_thickness=max(fine.breadth,vround 2/3vair);
  74. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  75. pickup fine.nib; pos2(top_thickness,90); top y2r=h+o;
  76. pos3(max(fine.breadth,.6[curve,cap_curve]-stem_corr),0);
  77. rt x3r=hround(w-1.25u);
  78. pos4(vair,-90); pos5(vair,-90);
  79. pos6(mid_thickness,90); x2=x6=x8=.5[1.5u,x7];
  80. pos7(cap_curve,0); rt x7r=hround(w-.75u); lft x5=min(hround 3u,lft x6)-eps;
  81. pos8(bot_thickness,-90); bot y8r=-o;
  82. y3=.6[top y4l,bot y2l]; y7=.5[bot y6l,top y8l];
  83. top y5l=vround(.54h+.5vair); y5r=y6l;
  84. x4=1/3[x5,x3l]; z4=z5+whatever*(150u,h);
  85. filldraw stroke pulled_super_arc.e(2,3)(.5superpull)
  86.  & z3e{down}...z4e---z5e;  % upper bowl
  87. filldraw z5r--z6l--z6r--z5l---cycle;  % middle tip
  88. filldraw stroke pulled_super_arc.e(6,7)(.5superpull)
  89.  & pulled_super_arc.e(7,8)(.5superpull);  % lower bowl
  90. if serifs: numeric bulb_diam[];
  91.  bulb_diam1=flare+.5(cap_stem-stem); bulb_diam2=flare+cap_stem-stem;
  92.  pos0(bulb_diam1,180); pos1(hair,180);
  93.  lft x0r=hround 1.25u; y0=min(.9h-.5bulb_diam1,.75h+.5bulb_diam1);
  94.  bulb(2,1,0);  % upper bulb
  95.  pos10(bulb_diam2,-180); pos9(cap_hair,-180);
  96.  lft x10r=hround .75u; y10=max(.1h+.5bulb_diam2,.3h-.5bulb_diam2);
  97.  bulb(8,9,10);  % lower bulb
  98. else: pos1(.5[vair,flare],angle(-8u,h));
  99.  lft x1r=hround u; bot y1l=vround .75h+o;
  100.  y1r:=good.y y1r+eps; x1l:=good.x x1l;
  101.  pos9(bot_thickness,angle(-2u,-h));
  102.  lft x9r=hround .75u; top y9l=vround .25h-o;
  103.  y9r:=good.y y9r-eps; x9l:=good.x x9l;
  104.  filldraw stroke term.e(2,1,left,1,4);  % upper terminal
  105.  filldraw stroke term.e(8,9,left,1,4); fi  % lower terminal
  106. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  107.  
  108. cmchar "The numeral 4";
  109. beginchar("4",9u#,fig_height#,0);
  110. italcorr fig_height#*slant-.5u#;
  111. adjust_fit(0,0);
  112. numeric light_stem, light_stem', diag_stem, alpha, cut; cut=.75notch_cut;
  113. light_stem=hround .4[fudged.stem,fudged.cap_stem];
  114. light_stem'=hround max(tiny.breadth,light_stem-2stem_corr);
  115. diag_stem=max(tiny.breadth,.4[vair,fudged.hair]);
  116. pickup crisp.nib; pos5(cap_bar,90); pos6(cap_bar,90);
  117. lft x5=hround .5u; rt x6=hround(w-.5u);
  118. top y5r=vround(if serifs: 5/18[slab,h-light_stem]+1
  119.  else:.35(h-light_stem) fi+.5cap_bar);
  120. z4l=top lft z5r; y2=y2'=y5=y6; x1r=x2r=hround(w-3u+.5light_stem);
  121. penpos1(light_stem',0); penpos2(light_stem',0); y1=y3=h+apex_o+apex_oo;
  122. x3r+apex_corr=x1r; alpha=diag_ratio(1,diag_stem,y3-y4l,x3r-x4l);
  123. penpos3(alpha*diag_stem,0); penpos4(alpha*diag_stem,0);
  124. x0=x1l; z0=whatever[z3r,z4r];
  125. x5'=x5; z5''=z5'+penoffset z4-z3 of currentpen=whatever[z4l,z3l];
  126. fill diag_end(2r,1r,1,.5,3l,4l)---z5''...lft z5'
  127.  ---lft z5l -- (x4r,y5l) -- z4r
  128.  if y0<h-cut:{z3r-z4r}...{up}(x1l-1,h-cut)
  129.   --(x1l,h-cut) else: -- z0 fi
  130.  --z2l--z2r--cycle;  % diagonal and upper stem
  131. filldraw stroke z5e--z6e;  % bar
  132. pickup tiny.nib; pos7(light_stem,0); rt x7r=x1r; bot y7=0;
  133. pos2'(light_stem,0); x2'=x7;
  134. filldraw stroke z2'e--z7e;  % lower stem
  135. if serifs: dish_serif(7,2',a,1/3,1.75u,
  136.   b,1/3,min(1.75u,w-.5u-rt x7r)); fi  % serif
  137. penlabels(0,1,2,3,4,5,6,7); endchar;
  138.  
  139. cmchar "The numeral 5";
  140. beginchar("5",9u#,fig_height#,0);
  141. italcorr fig_height#*slant-.5u#;
  142. adjust_fit(0,0);
  143. numeric bot_thickness,light_hair;
  144. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  145. light_hair=hround(cap_hair if hefty: -\\2stem_corr fi);
  146. pickup tiny.nib; pos5(vair,180); pos6(vair,90);
  147. bot y5=vround(.53h-vair); top y6r=max(vround .61803h+o,top y6r+y5+eps-y6l);
  148. pos3(light_hair,0); pos4(light_hair,0);
  149. lft x3l=max(1.35u,2.1u-.5light_hair); x3=x4=x5; y4=y5;
  150. top y3=h if not hefty: +\\o fi;
  151. filldraw stroke z3e--z4e;  % thin stem
  152. penpos7(cap_stem-fine,0); penpos8(bot_thickness-fine,-90);
  153. fine.rt x7r=hround(w-.9u); x8=.5[u,x7]; x6=.5[x5,x7];
  154. erase fill z5--bot z5--(x6,bot y5)--z6{left}
  155.  ..tension .9 and 1..{x5-x6,3(y5-y6)}cycle; % erase excess in middle
  156. filldraw stroke z6e{left}..tension .9 and 1..{x5-x6,3(y5-y6)}z5e;  % link
  157. pickup fine.nib; pos6'(vair,90); z6'=z6;
  158. y7=.5[y6,y8]; bot y8r=-o;
  159. filldraw stroke pulled_arc.e(6',7) & pulled_arc.e(7,8);  % bowl
  160. if serifs: pos9(hair,-180); y9=.5y5; lft x9r=hround .9u;
  161.  pos10(flare+1/3(cap_stem-stem),-180); bulb(8,9,10);  % bulb
  162. else: pos9(3/7[bot_thickness,flare],angle(-7u,-h));
  163.  lft x9r=hround(tiny.lft x3l-.75u); bot y9r=vround .15h-o;
  164.  x9l:=good.x x9l; y9l:=good.y y9l;
  165.  filldraw stroke term.e(8,9,left,1,4); fi  % terminal
  166. if hefty: pickup crisp.nib; pos1(slab,90); pos2(hair,0);
  167.  top y1r=h; x1=x4; rt x2r=hround(w-1.5u); y2=y1l-eps;
  168.  arm(1,2,a,0,0);  % arm
  169. else: numeric flag_breadth; flag_breadth=7/8[vair,cap_curve];
  170.  pos1(flag_breadth,90); pos2(flag_breadth,60);
  171.  pos0(vair,90); top y1r=tiny.top y3; top y2r=vround .95h+o; y0r=y1r;
  172.  lft x1=tiny.lft x3l; x2r=.5[x1,x0]; rt x0=hround(w-1.6u);
  173.  erase fill top z1r--z1r...{right}z2r
  174.   --(x2r,top y1r)--cycle; % erase excess at top
  175.  filldraw stroke z1e...{right}z2e...z0e; fi  % flag
  176. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  177.  
  178. cmchar "The numeral 6";
  179. beginchar("6",9u#,fig_height#,0);
  180. italcorr fig_height#*slant-.5u#;
  181. adjust_fit(0,0);
  182. numeric top_thickness,bot_thickness,side_thickness,pull;
  183. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  184. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  185. side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
  186. pull=min(.25,1.5superpull);
  187. pickup fine.nib; pos2(top_thickness,-270);
  188. pos3(side_thickness,-180); pos4(bot_thickness,-90);
  189. pos5(side_thickness,0); pos6(vair,90);
  190. lft x3r=w-rt x5r=hround max(.75u,1.5u-.5side_thickness);
  191. x4=x6-.1u=x2-u=.5w;
  192. top y2r=h+o; y3=.5[y2,y4]; bot y4r=-o;
  193. y5=.5[y4,y6]; top y6=vround 5/8h+o;
  194. path p; p=pulled_super_arc.l(3,4)(pull);
  195. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  196. pos7(thin_join,180); z7l=point t of p;
  197. (x,y6r)=whatever[z7l,z6l]; x6r:=min(x,.5[x5r,x6]);
  198. filldraw stroke pulled_super_arc.e(2,3)(pull)
  199.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  200.  & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
  201.  & z6e{left}...{direction t of p}z7e;  % arc and bowl
  202. if serifs: pos1(hair,-360); pos0(flare,-360);
  203.  rt x0r=max(rt x2+eps,hround(w-1.2u));
  204.  y0=vround min(.9h-.5flare,.85h+.5flare)+o;
  205.  {{less_tense; bulb(2,1,0)}};  % arc and bulb
  206. else: pos1(vround .1[top_thickness,flare],90);
  207.  top y1r=vround .97h+o; rt x1=hround(x5-.5);
  208.  filldraw stroke term.e(2,1,right,.9,4); fi  % terminal
  209. penlabels(0,1,2,3,4,5,6,7); endchar;
  210.  
  211. cmchar "The numeral 7";
  212. beginchar("7",9u#,fig_height#,0);
  213. italcorr fig_height#*slant-.5u#;
  214. adjust_fit(0,0);
  215. numeric arm_thickness, bot_width, top_shift, top_hair;
  216. if hefty: arm_thickness=Vround(slab+2stem_corr); top_shift=0;
  217.  bot_width=hround .51[curve,cap_curve]; top_hair=.4[thin_join,bot_width];
  218. else: arm_thickness=Vround .4[stem,cap_stem]; top_shift=.5u;
  219.  bot_width=flare; top_hair=cap_hair; fi
  220. if top_hair<tiny.breadth: top_hair:=tiny.breadth; fi
  221. pickup crisp.nib; pos2(arm_thickness,90); pos1(hair,180);
  222. top y2r=h; rt x2=hround(w-.75u+top_shift);
  223. lft x1r=hround(.75u+.5top_shift); y1=good.y(y2l-beak/2)-eps;
  224. arm(2,1,a,.3beak_darkness,-beak_jut);  % arm and beak
  225. pos3(hair,180); y3=good.y(y2r+beak/6)+eps; z3r=whatever[z1r,z.a0];
  226. penpos2'(eps,-90); z2'=z2r;
  227. arm(2',3,b,beak_darkness,x3r-x.a0);  % upward extension of beak
  228. pickup tiny.nib; pos4(top_hair,0); pos6(bot_width,0);
  229. bot y4=max(h-arm_thickness,h-slab,bot y2l); rt x4r=crisp.rt x2;
  230. lft x6l=hround(3.5u+top_shift-.5bot_width);
  231. if serifs: y6-.5bot_width=-o; filldraw z6l{down}..{up}z6r--cycle;  % bulb
  232. else: bot y6=-oo; fi
  233. if hefty: erase fill rt z4r--z4r...{down}z6r
  234.   --(rt x4r,y6)--cycle;  % erase excess at top
  235.  filldraw stroke z4e...{down}z6e;  % stroke
  236. else: pos5(top_hair,0); y5=2/3h; z5=whatever[z4,(.75u,y6)];
  237.  erase fill rt z4r--z4r--z5r--(rt x4r,y5)--cycle;  % erase excess at top
  238.  filldraw stroke z4e---z5e...{down}z6e; fi  % stroke
  239. penlabels(1,2,3,4,5,6); endchar;
  240.  
  241. cmchar "The numeral 8";
  242. beginchar("8",9u#,fig_height#,0);
  243. italcorr fig_height#*slant-.5u#;
  244. adjust_fit(0,0);
  245. numeric top_thickness,mid_thickness,bot_thickness,upper_side,lower_side,theta;
  246. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  247. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  248. x0=.5w; y0=.54h;
  249. if hefty: mid_thickness=vround 2/3vair; upper_side=hround(stem-3stem_corr);
  250.  lower_side=hround min(.5[curve,cap_curve]-stem_corr,upper_side+.25u);
  251.  penpos1(top_thickness,90); penpos2(upper_side,180);
  252.  penpos3(mid_thickness,270); penpos8(upper_side,360);
  253.  penpos4(mid_thickness,90); penpos7(lower_side,180);
  254.  penpos6(bot_thickness,270); penpos5(lower_side,360);
  255.  penpos0(vair,90); z3l=z0r; z4l=z0l;
  256.  x1=x6=.5w; x2r=w-x8r=hround u; x7r=w-x5r=hround .75u;
  257.  top y1r=h+o; bot y6r=-o; y2=y8=.5[y1l,y3l]; y7=y5=.5[y4l,y6l];
  258.  filldraw stroke pulled_arc.e(1,2)
  259.   & pulled_arc.e(2,3);  % left half of upper bowl
  260.  filldraw stroke pulled_arc.e(4,5)
  261.   & pulled_arc.e(5,6);  % right half of lower bowl
  262.  filldraw stroke pulled_arc.e(6,7)
  263.   & pulled_arc.e(7,4);  % left half of lower bowl
  264.  filldraw stroke pulled_arc.e(3,8)
  265.   & pulled_arc.e(8,1);  % right half of upper bowl
  266. else: pickup fine.nib; theta=90-angle(18u,h); slope:=-h/18u;
  267.  upper_side=max(fine.breadth,hround(.5[hair,stem]-stem_corr));
  268.  lower_side=hround(.5[hair,stem]+stem_corr);
  269.  if lower_side>1.2upper_side: upper_side:=lower_side; fi
  270.  pos1(top_thickness,-90); pos6(bot_thickness,-90);
  271.  x1=x6=.5w; top y1l=h+o; bot y6r=-o; pos0(cap_stem,theta);
  272.  lft x2l=w-rt x8l=hround 1.25u; lft x7r=w-rt x5r=hround .75u;
  273.  x2r-x2l=upper_side-fine; x5r-x5l=lower_side-fine;
  274.  ellipse_set(1l,2l,3l,0l); ellipse_set(1r,2r,3r,0r);
  275.  ellipse_set(6l,5l,4l,0l); ellipse_set(6r,5r,4r,0r);
  276.  numeric tau; tau=max(.8,.20710678/(superness-.5));
  277.  filldraw stroke z1e{left}..tension atleast tau..z2e{down}
  278.   ..z3e---z4e..z5e{down}..tension atleast tau..z6e{left};  % S stroke
  279.  pos7(lower_side,180); pos8(upper_side,180);
  280.  y7=.5[y5l,y5r]; y8=.5[y2l,y2r]; pos9(vair,90); z9=z0;
  281.  filldraw stroke z1e{right}..tension atleast tau..z8e{down}
  282.   ..tension atleast tau and atleast 1..{-18u,-.618h}z9e; % upper right stroke
  283.  filldraw stroke z6e{left}..tension atleast tau..z7e{up}
  284.   ..tension atleast tau and atleast 1..{18u,.5h}z9e; fi % lower left stroke
  285. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  286.  
  287. cmchar "The numeral 9";
  288. beginchar("9",9u#,fig_height#,0);
  289. italcorr fig_height#*slant-.5u#;
  290. adjust_fit(0,0);
  291. numeric top_thickness,bot_thickness,side_thickness,pull;
  292. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  293. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  294. side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
  295. pull=min(.25,1.5superpull);
  296. pickup fine.nib; pos2(bot_thickness,-90);
  297. pos3(side_thickness,0); pos4(top_thickness,90);
  298. pos5(side_thickness,180); pos6(vair,270);
  299. w-rt x3r=lft x5r=hround max(.75u,1.5u-.5side_thickness);
  300. x4-.1u=x6+.1u=x2+.75u=.5w;
  301. bot y2r=-o; y3=.5[y2,y4]; top y4r=h+o;
  302. y5=.5[y4,y6]; bot y6=vround 3/8h-o;
  303. path p; p=pulled_super_arc.l(3,4)(pull);
  304. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  305. pos7(thin_join,360); z7l=point t of p;
  306. (x,y6r)=whatever[z7l,z6l]; x6r:=max(x,.5[x5r,x6]);
  307. filldraw stroke pulled_super_arc.e(2,3)(pull)
  308.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  309.  & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
  310.  & z6e{right}...{direction t of p}z7e;  % arc and bowl
  311. if serifs: pos1(hair,-180); pos0(flare,-180);
  312.  lft x0r=min(lft x2-eps,hround 1.2u);
  313.  y0=vround max(.1h+.5flare,.15h-.5flare)-o;
  314.  {{less_tense; bulb(2,1,0)}};  % arc and bulb
  315. else: pos1(.1[bot_thickness,flare],-120);
  316.  bot y1r=vround .07h-o; lft x1r=hround 1.3u;
  317.  filldraw stroke term.e(2,1,left,.9,4); fi  % terminal
  318. penlabels(0,1,2,3,4,5,6,7); endchar;
  319.