home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / pascal / library / dos / teseract / source / tsint9.asm < prev    next >
Encoding:
Assembly Source File  |  1988-10-02  |  5.3 KB  |  191 lines
  1. IFNDEF TP4
  2.         PAGE 60,132
  3. ;----------------------------------------------------------------------------
  4. SUBTTL  TesSeRact Revision Level 1
  5. ;-----------------------------------------------------------------------------
  6. ;   TesSeRact(tm) -- A Library of Routines for Creating Ram-Resident (TSR)
  7. ;                    programs for the IBM PC and compatible Personal
  8. ;                    Computers.
  9. ;
  10. ;The software, documentation and source code are: 
  11. ; 
  12. ;       Copyright (C) 1986, 1987, 1988 Tesseract Development Team
  13. ;       All Rights Reserved 
  14. ; 
  15. ;       c/o Chip Rabinowitz
  16. ;       Innovative Data Concepts
  17. ;       2084 Woodlawn Avenue
  18. ;       Glenside, PA 19038
  19. ;       1-215-884-3373
  20. ;
  21. ;-----------------------------------------------------------------------------
  22. ;   This product supports the TesSeRact Standard for Ram-Resident Program 
  23. ;   Communication.  For information about TesSeRact, contact the TesSeRact 
  24. ;   Development Team at:
  25. ;       Compuserve:    70731,20
  26. ;       MCIMAIL:       315-5415
  27. ;   This MCIMAIL Account has been provided to the TesSeRact Development
  28. ;   Team by Borland International, Inc.  The TesSeRact Development Team
  29. ;   is in no way associated with Borland International, Inc.
  30. ;-----------------------------------------------------------------------------
  31.  
  32. INCLUDE TESS.INC
  33. IFDEF   ALLPUBLIC
  34. INCLUDE tsint9.pub      ;public definitions (uses Periscope PUBLIC.COM /E)
  35. ENDIF
  36.  
  37. .MODEL small
  38. .CODE
  39.  
  40. EXTRN TESS_USERPARMS:byte
  41. EXTRN TESS_GLOBALS:byte
  42. EXTRN _TESSCLEARKEYS:near
  43.  
  44. PUBLIC newint9, _TESS_INTERRUPTRETURN
  45.  
  46. ENDIF
  47.  
  48. newint9 proc far
  49.  
  50.         ASSUMENODS
  51.  
  52.         push    ax
  53.  
  54.         in      al,KB_DATA              ;get scan code
  55.  
  56.         mov     ah,al                   ;get scan code to AH
  57.  
  58.         push    ds
  59.         push    si
  60.  
  61.         push    ax
  62.         mov     ax,BIOS_DATA
  63.         mov     ds,ax                   ;set data segment
  64.         mov     si,KB_FLG1              ;set source to keyboard flags
  65.  
  66.         cld
  67.         pop     ax
  68.         lodsb                           ;get the low bytes of kbflags to AL
  69.         pop     si
  70.         pop     ds
  71.  
  72.         and     al,0fh                  ;only want four low bits
  73.  
  74.         push    ds
  75.  
  76.         push    cs
  77.         pop     ds
  78.  
  79.         ASSUMEDS
  80.  
  81.  
  82. check_break:
  83.         test    WPTR [STATUS],TSRENABLED
  84.         jz      no_9_1
  85.  
  86.         cmp     ah,46h                  ;is it scroll lock (or break)?
  87.         je      check_ctl
  88.         cmp     ah,2eh                  ;is it a 'c'??
  89.         jne     check_keys
  90.  
  91. check_ctl:
  92.         cmp     al,04h                  ;is control key down? 
  93.         jne     check_keys              ;no, process further
  94.  
  95. check_stat:                             ;^C, so .....
  96.         call    _TESSCLEARKEYS          ;clear the kbd buffer
  97.  
  98.         test    WPTR [STATUS],TSRACTIVE+INT28ACTIVE     ;are we already running?
  99.         jnz     end_9_2
  100.  
  101.  
  102. check_keys:
  103.         test    WPTR [STATUS],TSRACTIVE+INT28ACTIVE     ;are we already running?
  104.         jnz     no_9_1
  105.  
  106.         cmp     al,BPTR [SHIFTST]       ;check shift state
  107.         jne     check_extra             ;don't match!
  108.  
  109.         cmp     BPTR [HOTKEY],0
  110.         je      hotkeyon                ;Hotkey = 0, shift-state check only
  111.  
  112.         cmp     ah,BPTR [HOTKEY]        ;do they match
  113.         jne     check_extra             ;nope!  
  114.  
  115. hotkeyon:
  116.         xor     al,al                   ;so let's do it!
  117. setflags:
  118.         or      WPTR [STATUS],HOTKEYON
  119.         mov     BPTR [HOTFLAG],al
  120.         jmp     short end_9_2
  121.  
  122. check_extra:
  123.         test    WPTR [STATUS],EXTRAHOTSET
  124.         jz      no_9_1                  ;extra hot keys?
  125.  
  126.         push    cx                      ;save registers
  127.         push    es
  128.         push    bx
  129.  
  130.         xor     ch,ch
  131.         mov     cl,BPTR [HOTCOUNT]      ;load count of extra keys
  132.         les     bx,DPTR [EXTRAHOTK]     ;load structure
  133. extra_loop:
  134.         cmp     BPTR es:[bx+1],al       ;does the shift state match?
  135.         jne     next_check
  136.  
  137.         cmp     BPTR es:[bx],0
  138.         je      nokey                   ;Hotkey = 0, shift-state check only
  139.  
  140.         cmp     BPTR es:[bx],ah         ;does the scan code match?
  141.         jne     next_check
  142.  
  143. nokey:
  144.         mov     al, BPTR es:[bx+2]
  145.         pop     bx
  146.         pop     es
  147.         pop     cx
  148.         jmp     setflags
  149.         
  150. next_check:
  151.         add     bx,3
  152.         loop    extra_loop
  153.  
  154.         pop     bx
  155.         pop     es
  156.         pop     cx
  157.  
  158. no_9_1:
  159.         pop     ds
  160.         pop     ax
  161.  
  162.         ASSUMENODS
  163.  
  164.         jmp     DPTR [OLDINT9]
  165.  
  166. end_9_2:
  167.         in      al,KB_CTL               ;get keyboard status
  168.         mov     ah,al                   ;save it
  169.         or      al,80h                  ;acknowledge it
  170.         out     KB_CTL,al               ;Thanks ...
  171.         xchg    ah,al                   ;get status back
  172.         out     KB_CTL,al               ;reset the keyboard
  173.  
  174.         mov     al,20h
  175.         out     20h,al                  ;EOI
  176.  
  177.         pop     ds
  178.         pop     ax
  179. ;
  180. ; ***************************************************************************
  181. ;       This is the interrupt return address used for dummy routines
  182. ;               for INT1b and INT23 during popup
  183. ;
  184. ;
  185. _TESS_INTERRUPTRETURN:
  186.         iret
  187.  
  188. newint9 endp
  189.  
  190. ENDIT
  191.