home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / pascal / library / dos / teseract / source / tspopup.asm < prev    next >
Encoding:
Assembly Source File  |  1988-10-02  |  22.6 KB  |  662 lines
  1. IFNDEF TP4
  2.         PAGE 60,132
  3. ;----------------------------------------------------------------------------
  4. SUBTTL  TesSeRact Revision Level 1
  5. ;-----------------------------------------------------------------------------
  6. ;   TesSeRact(tm) -- A Library of Routines for Creating Ram-Resident (TSR)
  7. ;                    programs for the IBM PC and compatible Personal
  8. ;                    Computers.
  9. ;
  10. ;The software, documentation and source code are: 
  11. ; 
  12. ;       Copyright (C) 1986, 1987, 1988 Tesseract Development Team
  13. ;       All Rights Reserved 
  14. ; 
  15. ;       c/o Chip Rabinowitz
  16. ;       Innovative Data Concepts
  17. ;       2084 Woodlawn Avenue
  18. ;       Glenside, PA 19038
  19. ;       1-215-884-3373
  20. ;
  21. ;-----------------------------------------------------------------------------
  22. ;   This product supports the TesSeRact Standard for Ram-Resident Program 
  23. ;   Communication.  For information about TesSeRact, contact the TesSeRact 
  24. ;   Development Team at:
  25. ;       Compuserve:    70731,20
  26. ;       MCIMAIL:       315-5415
  27. ;   This MCIMAIL Account has been provided to the TesSeRact Development
  28. ;   Team by Borland International, Inc.  The TesSeRact Development Team
  29. ;   is in no way associated with Borland International, Inc.
  30. ;-----------------------------------------------------------------------------
  31.  
  32. INCLUDE tess.inc
  33. IFDEF   ALLPUBLIC
  34. INCLUDE tspopup.pub
  35. ENDIF
  36.  
  37. .MODEL small
  38.  
  39. EXTRN TSRMAIN:FAR
  40. EXTRN TSRBACKPROC:FAR
  41.  
  42. .CODE
  43.  
  44. EXTRN _TESSGETPSP:near
  45. EXTRN _TESSSETPSP:near
  46. EXTRN _TESSSETUPINTS:near
  47. EXTRN _TESSRESTOREINTS:near
  48.  
  49. EXTRN newint9:dword
  50. EXTRN _TESSRELEASETSR:near
  51. EXTRN TESSBEEP:FAR
  52.  
  53. EXTRN TESS_GLOBALS:byte
  54. EXTRN TESS_USERPARMS:byte
  55.  
  56. PUBLIC _TESSDOPOPUP, _TESSDOBACK, _TESS_VIDMODE, _TESS_VIDPAGE
  57.  
  58. ENDIF
  59.  
  60. ;
  61. ;
  62. ; ***************************************************************************
  63. ;       This is the main popup routine.  It is converted from STAYSAVE.INC
  64. ;               and STAYRSTR.INC, from STAY42.ARC, Copyright 1985, 1986,
  65. ;               Lane Ferris, The Hunter's Helper.  This was adapted from
  66. ;               Version 4.15.
  67.  
  68.  
  69. AltF9           db      0,70h
  70.  
  71. _TESS_VIDMODE       db      0
  72. _TESS_VIDPAGE       db      0
  73.  
  74. _TESSDOPOPUP proc near
  75.  
  76.         ASSUMEDS
  77.  
  78.         cli                             ;no interrupts now!!!
  79.  
  80.         or      WPTR [STATUS],TSRACTIVE ;set active bit
  81.  
  82.         mov     WPTR [USERSS],ss        ;save user's stack segment
  83.         mov     WPTR [USERSP],sp        ;... and stack pointer
  84.                                         ;DS was saved in INT8 or INT28
  85.  
  86.         mov     ss,WPTR [OURSSSP+2]     ;load TSR stack segment ...
  87.         mov     sp,WPTR [OURSSSP]       ;... and stack pointer
  88.  
  89.         sti
  90.  
  91.         push    bp                      ;save all registers except for
  92.         push    di                      ;...AX,BX,CX,DX,DS are restored on exit
  93.         push    si                      ;...from this procedure
  94.         push    es
  95.  
  96. stack_pop:
  97.  
  98.         test    WPTR [STATUS],TSRRELEASED
  99.         jz      get_mode
  100.         jmp     save_regs
  101.  
  102. get_mode:
  103.         mov     ah,0fh                  ;get current video mode
  104.         int     10h
  105.  
  106.         and     al,7fh                  ;mask off nonsequitor high bit
  107.  
  108.         mov     _TESS_VIDMODE,al
  109.         mov     _TESS_VIDPAGE,bh        ;save them
  110.  
  111.         cmp     al,7
  112.         jne     not_mono
  113.  
  114.         call    HerculesMode            ;if carry flag set, we're in text mode
  115.  
  116.         jc      not_mono
  117.  
  118.         xor     al,al
  119.         dec     al
  120.  
  121.         mov     _TESS_VIDMODE,al
  122.         mov     _TESS_VIDPAGE,al
  123.  
  124. not_mono:
  125.         test    WPTR [STATUS],NOPOPGRAPH
  126.         jz      check_cmdline           ;if not flagged, don't worry about it
  127.  
  128.         mov     al,_TESS_VIDMODE
  129.  
  130.         cmp     al,3
  131.         jbe     check_cmdline           ; 0-3 are valid
  132.  
  133.         cmp     al,7
  134.         je      check_cmdline           ; we're in mono text!
  135.  
  136. no_graphics:
  137.         mov     al,BPTR [INWORD4]
  138.         or      al,al
  139.         jz      notmsword
  140.  
  141.         mov     al,BPTR [WASWORD4]      ;did we already do this?
  142.         or      al,al
  143.         jz      flip_word               ;nope -- send the char
  144.  
  145.         mov     BPTR [WASWORD4],0
  146.         jmp     short notmsword
  147.  
  148. flip_word:
  149.         mov     ax,5453h
  150.         mov     bx,21h
  151.         mov     cx,WPTR [IDNUM]
  152.         mov     si,1
  153.         mov     di,offset AltF9
  154.         mov     dx,0
  155.         push    cs
  156.         pop     es
  157.         int     2fh
  158.  
  159.         mov     BPTR [WORD4DELAY],32
  160.         mov     BPTR [WASWORD4],1
  161.         jmp     back_popup
  162.  
  163. notmsword:
  164. IFDEF TP4
  165. IFNDEF ASMCOM
  166.         call    FAR PTR TESSBEEP
  167. ELSE
  168.         call    TESSBEEP
  169. ENDIF
  170. ELSE
  171.         call    TESSBEEP
  172. ENDIF
  173.         jmp     back_popup              ;anything else is graphics -- go away
  174.  
  175. check_cmdline:
  176.         test    WPTR [STATUS],NOPOPCOMMAND
  177.         jz      save_regs               ;if not flagged, don't worry about it
  178.  
  179.         mov     al,BPTR [SAVEDINDOSFLG]
  180.         or      al,al
  181.         jz      save_regs               ;if zero, not at command line
  182.  
  183. IFDEF TP4
  184. IFNDEF ASMCOM
  185.         call    FAR PTR TESSBEEP
  186. ELSE
  187.         call    TESSBEEP
  188. ENDIF
  189. ELSE
  190.         call    TESSBEEP
  191. ENDIF
  192.         jmp     back_popup
  193.  
  194. save_regs:
  195.  
  196.         getdta  <[USERDTA]>             ;save current DTA
  197.  
  198.         call    _TESSGETPSP             ;get current PSP segment
  199.         mov     WPTR [USERPSP],bx       ;...returned in BX
  200.  
  201.         mov     bx,WPTR [OURPSP]        ;set TSR's PSP in BX
  202.         call    _TESSSETPSP             ;...and do it
  203.  
  204.         setdta  <[OURDTA]>
  205.  
  206.         call    SaveExtendedErr         ;save DOS extended err info     ;v0.51 
  207.         call    SaveBreak               ;save Ctrl Break status         ;v0.51 
  208.         call    SaveVerify              ;save current verify state      ;v0.51 
  209.  
  210.         test    WPTR [STATUS],TSRRELEASED
  211.         jz      no_rel_pop
  212.  
  213.         call    _TESSRELEASETSR
  214.  
  215.         jmp     short not_released_pop
  216.  
  217. no_rel_pop:
  218.  
  219.         xor     ax,ax                   ;popup-interrupts (1B, 23 and 24)
  220.         call    _TESSSETUPINTS          ;replace with our handler
  221.  
  222.         push    ds                      ;save DS for after popup
  223.         push    es
  224.  
  225.         mov     ax,WPTR [OURDSEG]       ;load user's data segment
  226.         push    ax
  227.         push    ax
  228.         pop     ds
  229.         pop     es
  230.  
  231.         ASSUMENODS
  232.  
  233. call_popup:
  234.  
  235. IFDEF   TP4
  236. IFNDEF ASMCOM
  237.         call    DPTR PMAIN              ;call the user routine!! (TP ver)
  238. ELSE
  239.         call    TSRMAIN                 ;call the user routine!!
  240. ENDIF
  241. ELSE
  242.         call    TSRMAIN                 ;call the user routine!!
  243. ENDIF
  244.  
  245. done_pop:
  246.         pop     es
  247.         pop     ds
  248.  
  249.         ASSUMEDS
  250.  
  251.         xor     ax,ax                   ;restore interrupts (1B, 23 and 24)
  252.         call    _TESSRESTOREINTS
  253.  
  254. not_released_pop:
  255.         mov     al,BPTR [WASWORD4]
  256.         or      al,al
  257.         jz      wasnotword
  258.  
  259.         mov     ax,5453h
  260.         mov     bx,21h
  261.         mov     cx,WPTR [IDNUM]
  262.         mov     si,1
  263.         mov     di,offset AltF9
  264.         mov     dx,0
  265.         push    cs
  266.         pop     es
  267.         int     2fh
  268.  
  269.         mov     BPTR [WASWORD4],0
  270.  
  271. wasnotword:
  272.         call    RestoreVerify           ;restore Verify setting         ;v0.51
  273.         call    RestoreBreak            ;restore CtrlBreak status       ;v0.51
  274.         call    RestoreExtendedErr      ;restore Extended error info    ;v0.51
  275.  
  276.         setdta  <[USERDTA]>             ;restore interrupted DTA
  277.  
  278.  
  279.         mov     bx,WPTR [USERPSP]       ;replace interrupted PSP
  280.         call    _TESSSETPSP
  281.  
  282.         ASSUMEDS
  283.  
  284. ;
  285. ; ***************************************************************************
  286. ;
  287. ;       CAUTION!!!! THE USER ROUTINE MUST RETURN SS:SP WITH THE SAME
  288. ;               VALUES AS ON ENTRY.  OTHER REGISTERS WILL BE RESTORED
  289. ;               BY THIS ROUTINE.
  290. ;
  291. ; ***************************************************************************
  292. ;
  293. back_popup:
  294.  
  295.         ASSUMEDS
  296.  
  297.         pop     es
  298.         pop     si
  299.         pop     di
  300.         pop     bp
  301.  
  302.         cli
  303.  
  304.         mov     ss,WPTR [USERSS]        ;restore user's stack segment
  305.         mov     sp,WPTR [USERSP]        ;... and stack pointer
  306.                                         ;DS will be restored in INT8 or INT28
  307.         and     WPTR [STATUS],NOT HOTKEYON+TSRACTIVE+SHIFTSON
  308.  
  309.         test    WPTR [STATUS],TSRRELEASED
  310.         jz      b1
  311.  
  312.         or      WPTR [STATUS],HOTKEYON+POPUPSET
  313.         and     WPTR [STATUS],NOT TSRENABLED
  314.  
  315. b1:                                     ;clear hot-key and inuse bits
  316.         sti                             ;enable interrupts again
  317. dopopup_end:
  318.         ret
  319.  
  320. _TESSDOPOPUP endp
  321.  
  322. took_ints db 0
  323.  
  324. _TESSDOBACK proc near
  325.  
  326.         ASSUMEDS
  327.  
  328.         cli                             ;no interrupts now!!!
  329.  
  330.         mov     WPTR [USER28SS],ss      ;save user's stack segment
  331.         mov     WPTR [USER28SP],sp      ;... and stack pointer
  332.                                         ;DS was saved in INT8 or INT28
  333.  
  334.         mov     ss,WPTR [OUR28SP+2]     ;load TSR stack segment ...
  335.         mov     sp,WPTR [OUR28SP]       ;... and stack pointer
  336.  
  337. stack_28:
  338.         sti
  339.  
  340.         push    bp                      ;save all registers except for
  341.         push    di                      ;...AX,BX,CX,DX,DS are restored on exit
  342.         push    si                      ;...from this procedure
  343.         push    es
  344.  
  345.         mov     took_ints,0
  346.  
  347.         test    WPTR [STATUS],TSRACTIVE ;did we already take them?
  348.         jnz     no_ints_1
  349.  
  350.         mov     took_ints,1
  351.  
  352.         xor     ax,ax                   ;popup-interrupts (1B, 23 and 24)
  353.         call    _TESSSETUPINTS          ;replace with our handler
  354.  
  355. no_ints_1:
  356.         getdta  <[USER28DTA]>           ;save current DTA
  357.  
  358.         call    _TESSGETPSP             ;get current PSP segment
  359.         mov     WPTR [USER28PSP],bx     ;...returned in BX
  360.  
  361.         mov     bx,WPTR [OURPSP]        ;set TSR's PSP in BX
  362.         call    _TESSSETPSP             ;...and do it
  363.  
  364.         setdta  <[OURDTA]>
  365.  
  366.         push    ds                      ;save DS for after popup
  367.         push    es
  368.  
  369.         mov     ds,WPTR [OURDSEG]       ;load user's data segment
  370.         mov     es,WPTR [OURDSEG]       ;load user's extra segment
  371.  
  372.         ASSUMENODS
  373.  
  374. call_28:
  375.  
  376. IFDEF   TP4
  377. IFNDEF ASMCOM
  378.         call    DPTR PBACKPROC          ;call the user routine!! (TP4 ver)
  379. ELSE
  380.         call    TSRBACKPROC             ;call the user routine!!
  381. ENDIF
  382. ELSE
  383.         call    TSRBACKPROC             ;call the user routine!!
  384. ENDIF
  385.  
  386. done_28:
  387.         pop     es
  388.         pop     ds
  389.  
  390.         ASSUMEDS
  391.  
  392.         setdta  <[USER28DTA]>           ;restore interrupted DTA
  393.  
  394.         mov     bx, WPTR [USER28PSP]    ;replace interrupted PSP
  395.         call    _TESSSETPSP
  396.  
  397.         cmp     took_ints,0
  398.         je      no_ints_2
  399.  
  400.         xor     ax,ax                   ;restore interrupts (1B, 23 and 24)
  401.         call    _TESSRESTOREINTS        ;restore interrupts 
  402.  
  403. no_ints_2:
  404.  
  405.         ASSUMEDS
  406.  
  407.         pop     es
  408.         pop     si
  409.         pop     di
  410.         pop     bp
  411.  
  412. back_28:
  413.         ASSUMEDS
  414.         cli
  415.         mov     ss,WPTR [USER28SS]      ;restore user's stack segment
  416.         mov     sp,WPTR [USER28SP]      ;... and stack pointer
  417.                                         ;DS will be restored in INT8 or INT28
  418.         sti                             ;enable interrupts again
  419.  
  420. do28_end:
  421.         ret
  422.  
  423. _TESSDOBACK endp
  424.  
  425.  
  426. LpSet   equ     03B9h                   ;Set light pen address
  427. LpReset equ     03BBh                   ;Reset light pen address
  428. Lpff    equ     2                       ;Flip-flop suitable for s/w query
  429. Our6845 equ     03B4h                   ;6845 index register
  430. OurStat equ     03BAh                   ;Display Status Port
  431. NotVSync equ    80h                     ;This bit 0 during vertical
  432.                                         ; retrace
  433. UseHerc db      0ffh
  434.  
  435. HerculesMode    PROC    NEAR
  436.         ASSUMEDS
  437.  
  438. ;******************            Mode Detection              ******************
  439.  
  440.         cmp     UseHerc,0ffh
  441.         jne     AlreadyTested
  442.  
  443.         inc     UseHerc                 ;assume no herc
  444.  
  445.         call    HerculesPresent
  446.         jc      AlreadyTested           ;if carry, no herc found
  447.  
  448.         inc     UseHerc                 ;say we have a herc
  449.         
  450. AlreadyTested:
  451.         cmp     UseHerc,0
  452.         je      textmode
  453.  
  454.         xor     al,al
  455.         mov     dx,OurStat
  456. wait1:                                  ;test for v-sync transition
  457.         in      al,dx
  458.         test    al,NotVSync
  459.         jz      wait1
  460. wait2:
  461.         in      al,dx                   
  462.         test    al,NotVSync
  463.         jnz     wait2
  464.  
  465.         xor     al,al                   ;Reset and Set Light Pen.
  466.         mov     dx,LpReset
  467.         out     dx,al
  468.         mov     dx,LpSet
  469.         out     dx,al
  470.  
  471.         mov     al,16                   ;Look in the 6845 for the offset into
  472.         mov     dx,Our6845              ; buffer when the light pen is
  473.         out     dx,al                   ; tripped - high byte.
  474.         inc     dx
  475.         in      al,dx
  476.  
  477.         cmp     al,0dh                  ;threshold value is 0dh
  478.         jb      test_modeval
  479.  
  480.  
  481. ; Otherwise, must be graphics mode
  482. GraphicsMode:
  483.         clc
  484.         jmp     short R0
  485.  
  486. test_modeval:
  487.         xor     ax,ax                   ;secondary test for some
  488.         mov     es,ax                   ;clone herc cards
  489.         mov     al,es:[465h]
  490.         test    al,2
  491.         jnz     GraphicsMode
  492.  
  493. textmode:
  494. ; Not in hercules graphics mode, set carry flag.
  495.         stc
  496.  
  497.  
  498.  
  499. R0:
  500.  
  501.         ret
  502. HerculesMode    ENDP
  503.  
  504. ; ==========================================================================
  505.  
  506. ; Determines if a Hercules Graphics Card is present.
  507.  
  508. status_port     equ     03BAh           ; To detect the presence of a Hercules
  509.                                         ; Graphics Card, look for bit 7 of the
  510.                                         ; Display Mode Status Port to change.
  511.                                         ; On the HGC this bit goes low on
  512.                                         ; vertical retrace. The IBM boards do
  513.                                         ; not utilize this bit.
  514.  
  515. ID_mask         equ     01110000b       ; To detect the presence of a Hercules
  516. Plus_ID         equ     00010000b       ; Graphics Card Plus or InColor Card,
  517. InColor_ID      equ     01010000b       ; look at bits 4, 5, and 6 in the
  518.                                         ; status port. These bits are held in a
  519.                                         ; particular state on the Graphics Card
  520.                                         ; Plus and InColor Card and are
  521.                                         ; undefined (floating) on the earlier
  522.                                         ; Hercules card.
  523.  
  524.  
  525. HerculesPresent proc near
  526.  
  527. ; * * * Test for the presence of a Hercules Graphics Card
  528.                                         ; or not currently active - quit
  529. HGC_test:
  530.         mov     dx, status_port         ; Display Status Port
  531.  
  532.         xor     bl, bl                  ; clear counter
  533.         in      al, dx                  ; take a reading
  534.         and     al, 80h                 ; save bit seven
  535.         mov     ah, al                  ; and keep it handy
  536.  
  537.         mov     cx, 8000h               ; a nice big loop
  538. examine:
  539.         in      al, dx                  ; get another reading
  540.         and     al, 80h                 ; isolate bit seven
  541.         cmp     al, ah                  ; is it the same ?
  542.         je      no_change               ; no - keep trying
  543.         inc     bl                      ; yes, bit toggled - increment counter
  544.  
  545.         cmp     bl, 10                  ; if we see a change 10 times
  546.         jae     Hercules                ; then we assume that a Hercules
  547.                                         ; Graphics Card is present. The check
  548.                                         ; for 10 positive tests is done
  549.                                         ; just to be on the safe side.
  550. no_change:
  551.         loop    examine                 ; continue until CX = 0
  552.                                         ; if the loop expires without
  553.                                         ; 10 successes we assume that
  554.                                         ; something besides a HGC is present
  555.         jmp     short No_Hercules
  556.  
  557. ; * * * * End of test for Hercules Graphics Card * * * * * * * * *
  558.  
  559. Hercules:
  560.  
  561. ;******* Makes sure light pen is present and working before loading *********
  562. ;  If the light pen is not present or not working, then even if it is a
  563. ;    a hercules we can't test for graphics mode, so return a false.
  564.  
  565.         mov     dx,LpSet
  566.         out     dx,al
  567.         mov     dx,OurStat
  568.         in      al,dx
  569.         test    al,Lpff
  570.         jz      No_Hercules             ;If light pen stuck low, can't do
  571.                                         ;mode test - abort.
  572.         mov     dx,LpReset
  573.         out     dx,al
  574.         mov     dx,OurStat
  575.         in      al,dx
  576.         test    al,Lpff
  577.         jnz     No_Hercules             ;If light pen stuck high, can't do
  578.                                         ;mode test - abort.
  579. ; We made it! Hercules present.
  580.          clc
  581.          jmp    short R1
  582.  
  583.  
  584. No_Hercules:
  585.          stc
  586.  
  587. R1:
  588.         ret
  589. HerculesPresent endp
  590.  
  591. ;-----------------------------------------------------------------;     ;v0.51
  592. ;      SAVE/RESTORE CURRENT BREAK STATE, RELAX BREAK CHECKING     ;     ;v0.51
  593. ;-----------------------------------------------------------------;     ;v0.51
  594. ; Routines Courtesy of Thomas Brandenborg                               ;v0.51
  595. SaveBreak proc near                                                     ;v0.51
  596.         ASSUMEDS
  597.         mov     ax,3302h                ;to swap DL with BREAK value    ;v0.51
  598.         xor     dl,dl                   ;DL=0=relax checking            ;v0.51
  599.         int     21h                     ;current level in DL            ;v0.51
  600.         mov     BPTR [OLDBREAK],dl      ;save current level             ;v0.51
  601.         ret                                                             ;v0.51
  602. ; ------------  RESTORE SAVED BREAK CHECKING LEVEL                      ;v0.51
  603. RestoreBreak:                                                           ;v0.51
  604.         mov     ax,3301h                ;to set break check level       ;v0.51
  605.         mov     dl,BPTR [OLDBREAK]      ;get saved break state          ;v0.51
  606.         int     21h                                                     ;v0.51
  607.         ret                                                             ;v0.51
  608. SaveBreak endp                                                          ;v0.51
  609. ;----------------------------------------------------------------;      ;v0.51
  610. ;      SAVE/RESTORE DOS EXTENDED ERROR INFO (Int21.59)           ;      ;v0.51
  611. ;----------------------------------------------------------------;      ;v0.51
  612. ; Routines Courtesy of Thomas Brandenborg                               ;v0.51
  613. SaveExtendedErr proc near                                               ;v0.51
  614.         ASSUMEDS
  615.         push    di                                                      ;v0.53 - CR
  616.         cmp     BPTR [DOSVERSION],3     ;Verify version is DOS 3+       ;v0.51
  617.         jb      DosExtSaved             ;NO - skip if if not 3.x        ;v0.51
  618.         mov     ah,59h                  ;to get err info from DOS       ;v0.51
  619.         xor     bx,bx                   ;BX must be zero                ;v0.51
  620.         push    ds                      ;save DS (clobbered by DOS)     ;v0.51
  621.         int     21h                     ;ext err info in AX,BX,CX       ;v0.51
  622.         pop     ds                      ;restore DS                     ;v0.51
  623.         mov     WPTR [OLDEXTERR],ax     ;save extended error info       ;v0.51
  624.         mov     WPTR [OLDEXTERR+2],bx                                   ;v0.51
  625.         mov     WPTR [OLDEXTERR+4],cx                                   ;v0.51
  626. DosExtSaved:                                                            ;v0.51
  627.         pop     di                                                      ;v0.53 - CR
  628.         ret                                                             ;v0.51
  629. ; -- Restore the Dos 3+ extended error information                      ;v0.51
  630. RestoreExtendedErr:                                                     ;v0.51
  631.         push    di                                                      ;v0.53 - CR
  632.         cmp     BPTR [DOSVERSION],3     ;verify  DOS 3.+                ;v0.51
  633.         jb      DosExtRestored          ;NO - skip this                 ;v0.51
  634.         mov     dx,offset OLDEXTERR     ;DS:DX=3 words of ext err       ;v0.51
  635.         mov     ax,5d0ah                ;to set ext err info            ;v0.51
  636.         int     21h                                                     ;v0.51
  637. DosExtRestored:                                                         ;v0.51
  638.         pop     di                                                      ;v0.53 - CR
  639.         ret                                                             ;v0.51
  640. SaveExtendedErr endp                                                    ;v0.51
  641. ;-----------------------------------------------------------------;     ;v0.51
  642. ;      SAVE/RESTORE CURRENT VERIFY SETTING    (int 21.54)         ;     ;v0.51
  643. ;-----------------------------------------------------------------;     ;v0.51
  644. ; Routines Courtesy of Thomas Brandenborg                               ;v0.51
  645. SaveVerify proc near                                                    ;v0.51
  646.         ASSUMEDS
  647.         mov     ax,5400h                ;Ask for Verify setting         ;v0.51
  648.         int     21h                     ;00=off, 01=on                  ;v0.51
  649.         mov     BPTR [OLDVERIFY],al     ;save current setting           ;v0.51
  650.         ret                                                             ;v0.51
  651. ;--------  RESTORE Write Verify SETTING                                 ;v0.51
  652. RestoreVerify:                                                          ;v0.51
  653.         mov     ah,2Eh                  ;function to set verify         ;v0.51
  654.         mov     al,BPTR [OLDVERIFY]     ;get saved verify state         ;v0.51
  655.         xor     dx,dx                   ;dx = zero to set flag          ;v0.51
  656.         int     21h                                                     ;v0.51
  657.         ret                                                             ;v0.51
  658. SaveVerify endp                                                         ;v0.51
  659. ;-----------------------------------------------------------------;     ;v0.51
  660.                                                                         ;v0.51
  661. ENDIT
  662.