home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / pascal / library / dos / teseract / source / tsint8.asm < prev    next >
Encoding:
Assembly Source File  |  1988-10-02  |  10.8 KB  |  409 lines
  1. IFNDEF TP4
  2.         PAGE 60,132
  3. ;----------------------------------------------------------------------------
  4. SUBTTL  TesSeRact Revision Level 1
  5. ;-----------------------------------------------------------------------------
  6. ;   TesSeRact(tm) -- A Library of Routines for Creating Ram-Resident (TSR)
  7. ;                    programs for the IBM PC and compatible Personal
  8. ;                    Computers.
  9. ;
  10. ;The software, documentation and source code are: 
  11. ; 
  12. ;       Copyright (C) 1986, 1987, 1988 Tesseract Development Team
  13. ;       All Rights Reserved 
  14. ; 
  15. ;       c/o Chip Rabinowitz
  16. ;       Innovative Data Concepts
  17. ;       2084 Woodlawn Avenue
  18. ;       Glenside, PA 19038
  19. ;       1-215-884-3373
  20. ;
  21. ;-----------------------------------------------------------------------------
  22. ;   This product supports the TesSeRact Standard for Ram-Resident Program 
  23. ;   Communication.  For information about TesSeRact, contact the TesSeRact 
  24. ;   Development Team at:
  25. ;       Compuserve:    70731,20
  26. ;       MCIMAIL:       315-5415
  27. ;   This MCIMAIL Account has been provided to the TesSeRact Development
  28. ;   Team by Borland International, Inc.  The TesSeRact Development Team
  29. ;   is in no way associated with Borland International, Inc.
  30. ;-----------------------------------------------------------------------------
  31.  
  32.  
  33. INCLUDE TESS.INC
  34. IFDEF   ALLPUBLIC
  35. INCLUDE tsint8.pub
  36. ENDIF
  37.  
  38. .MODEL small
  39.  
  40. .CODE
  41.  
  42. EXTRN _TESSDOPOPUP:near
  43. EXTRN TESSBEEP:FAR
  44. EXTRN _TESSSTUFFKEYS:near
  45.  
  46. EXTRN TESS_GLOBALS:byte
  47. EXTRN TESS_USERPARMS:byte
  48.  
  49. PUBLIC newint8, _TESSSTOREKEYS, _TESSCLEARKEYS
  50.  
  51. ENDIF
  52.  
  53. KbdCount        dw      0
  54. StuffSpeed      db      0
  55. StuffCount      dw      0
  56.  
  57. KBDBEGIN        equ     $
  58.  
  59. KbdBuffer       dw      80 dup(?)
  60.  
  61. KBDEND          equ     $-2
  62.  
  63. MAXKBDSIZE      equ     (KBDEND - KBDBEGIN) / 2
  64.  
  65. KbdHead         dw      KBDBEGIN
  66. KbdTail         dw      KBDBEGIN
  67.  
  68. wait8   db      8
  69. KbdCleared      db      0
  70.  
  71. _TESSCLEARKEYS proc near
  72.  
  73.         ASSUMEDS
  74.  
  75.         push    ax
  76.  
  77.         xor     ax,ax
  78.         mov     KbdCount,ax             ;say no more keys are waiting
  79.         mov     ax,offset KBDBEGIN      ;reset buffer pointers
  80.         mov     KbdHead,ax
  81.         mov     KbdTail,ax
  82.  
  83.         mov     KbdCleared,18           ;flag value
  84.  
  85.         pop     ax
  86.  
  87.         ret
  88. _TESSCLEARKEYS endp
  89.  
  90. _TESSSTOREKEYS proc near
  91. ;
  92. ;       on entry, es:di points to buffer, SI contains number of 
  93. ;           chars to stuff, dl has speed, dh = 0 to stuff words, 1
  94. ;           to stuff just chars
  95. ;
  96. ;
  97.         ASSUMENODS
  98.  
  99.         push    ds
  100.  
  101.         push    cs
  102.         pop     ds
  103.  
  104.         ASSUMEDS
  105.  
  106.  
  107.         mov     al,KbdCleared           ;did we get a ^C?
  108.         or      al,al
  109.         jnz     clear_buffer            ;yep ... signal on return
  110.  
  111.         or      si,si                   ;if no chars, just exit
  112.         jz      not_enough_room
  113.  
  114.         cli
  115.  
  116.         mov     ax,MAXKBDSIZE
  117.         sub     ax,[KbdCount]           ;how many are already there?
  118.  
  119.         cmp     ax,si                   ;is there room?
  120.         jbe     not_enough_room
  121.  
  122.         mov     cx,si
  123.  
  124.         mov     StuffSpeed,dl
  125. store_them:
  126.         mov     bx,[KbdTail]            ;load pointer
  127.  
  128.         or      dh,dh
  129.         jz      store_both
  130.  
  131.         mov     al,es:[di]              ;store the ascii code
  132.         xor     ah,ah
  133.         cmp     al,0dh                  ;is it a CR
  134.         jne     done_fetch
  135.  
  136.         mov     ah,1ch                  ;yep, add scan code
  137.         jmp     short done_fetch
  138.  
  139. store_both:
  140.         mov     ax,es:[di]              ;load the word
  141.         inc     di
  142. done_fetch:
  143.         inc     di
  144.         mov     [bx],ax                 ;store it in buffer
  145.  
  146.         inc     bx                      ;advance buffer, and wrap if needed
  147.         inc     bx
  148.         cmp     bx,offset KBDEND
  149.         jne     dont_wrap1
  150.  
  151.         mov     bx,offset KBDBEGIN
  152.  
  153. dont_wrap1:
  154.         mov     [KbdTail],bx            ;save end of buffer away
  155.         inc     [KbdCount]
  156.  
  157.         loop    store_them
  158.  
  159.         xor     ax,ax
  160.         jmp     short store_out
  161.  
  162. clear_buffer:
  163.         mov     ax,0f0f0h               ;signal ^C
  164.         mov     KbdCleared,0
  165.         jmp     short store_out
  166. not_enough_room:
  167.         xor     ax,ax
  168.         dec     ax
  169. store_out:
  170.         sti
  171.         pop     ds
  172.         ret
  173.  
  174. _TESSSTOREKEYS endp
  175.  
  176. ;---------------------------------------------------------------------;
  177. ;     Interrupt 8 pops an application over a running program          ;
  178. ;---------------------------------------------------------------------;
  179. newint8 proc far
  180.  
  181.         ASSUMENODS
  182.  
  183. ; IF TIMER CODE IS STILL BUSY, GO DIRECTLY TO BIOS TIMER CODE
  184.  
  185.         push    ds
  186.  
  187.         pushf
  188.  
  189.         push    cs
  190.         pop     ds                      ;recover our Datasegment address
  191.  
  192.         ASSUMEDS
  193.  
  194.         mov     BPTR [WASINT8],1
  195.  
  196. ;---------------------------------------------------------------------;
  197. ;       NOTE:  We don't want to be releasing a TSR from inside an INT8
  198. ;       popup routine!
  199. ;---------------------------------------------------------------------;
  200. ;       test    WPTR [STATUS],TSRRELEASED
  201. ;       jnz     dorel8
  202.  
  203.         test    WPTR [STATUS],TSRENABLED
  204.         jz      do_old8
  205.  
  206. dorel8:
  207.         test    BPTR [SOFTINTFLAGS],ININT08     ;See if recursion has taken place
  208.         jz      start_new_int8          ;If not continue with new int 8
  209. do_old8:
  210.         POPFF
  211.         pop     ds
  212.  
  213.         ASSUMENODS
  214.  
  215.         jmp     DPTR [OLDINT8]  ;Jump to original int 8
  216.  
  217. start_new_int8:
  218.  
  219.         ASSUMEDS
  220.  
  221.         POPFF
  222.         or      BPTR [SOFTINTFLAGS],ININT08     ;Set the int 8 active flag
  223.  
  224.         push    dx
  225.         push    cx                      ;save regs
  226.         push    bx
  227.         push    ax
  228.         push    di
  229.  
  230. ;  call the original Timer interrupt to avoid timer tick misses
  231.  
  232.         pushf                           ;simulate interrupt ...
  233.         call DPTR [OLDINT8]             ;do the original
  234.  
  235.         sti                             ;make sure INTs are ON!!
  236. Start_8:
  237.  
  238.         mov     al,KbdCleared
  239.         or      al,al
  240.         jz      checkword
  241.  
  242.         dec     [KbdCleared]
  243.  
  244. checkword:
  245.         mov     al,BPTR [WORD4DELAY]
  246.         or      al,al
  247.         jz      noword
  248.  
  249.         dec     BPTR [WORD4DELAY]
  250.         jnz     noword
  251.  
  252.         or      WPTR [STATUS],HOTKEYON
  253. noword:
  254.         mov     ax,WPTR [STATUS]
  255.         test    ax,POPUPSET
  256.         jz      again_8_2
  257.         test    ax,HOTKEYON
  258.         jz      again_8_2
  259.         test    ax,TSRACTIVE+INT28ACTIVE        ;are we already running?
  260.         jnz     again_8_2
  261.  
  262. wait_8:
  263.         call    Checkstatus_8
  264.  
  265.         jnz     end_8
  266.  
  267.         call    _TESSDOPOPUP
  268.  
  269. reset_8:
  270.         mov     wait8,8
  271.         jmp     short again_8_2
  272. end_8:
  273.         dec     wait8
  274.         jnz     again_8_2
  275.  
  276.         test    WPTR [STATUS],TSRRELEASED
  277.         jnz     reset_8
  278.         and     WPTR [STATUS],NOT HOTKEYON
  279.  
  280. IFDEF TP4
  281. IFNDEF ASMCOM
  282.         call    FAR PTR TESSBEEP
  283. ELSE
  284.         call    TESSBEEP
  285. ENDIF
  286. ELSE
  287.         call    TESSBEEP
  288. ENDIF
  289.  
  290.         jmp     short reset_8
  291.  
  292. again_8_2:
  293.         mov     ax,[KbdCount]
  294.         or      ax,ax
  295.         jz      no_keys
  296.  
  297.         mov     al,StuffSpeed
  298.         xor     ah,ah                   ;store speed
  299.         mov     di,ax                   ; in DI register
  300.  
  301.         mov     bx,[KbdHead]
  302.         mov     ax,[bx]
  303.  
  304.         call    _TESSSTUFFKEYS
  305.         cmp     ax,-1
  306.         je      no_keys                 ;no room in BIOS buffer -- try again!
  307.  
  308.         inc     bx
  309.         inc     bx
  310.         cmp     bx,offset KBDEND
  311.         jne     dont_wrap
  312.  
  313.         mov     bx,offset KBDBEGIN
  314.  
  315. dont_wrap:
  316.         mov     [KbdHead],bx
  317.         dec     [KbdCount]
  318.         inc     [StuffCount]
  319.  
  320.         mov     ax,di                   ;recover speed
  321.         or      al,al                   ;slow speed
  322.         jz      no_keys
  323.  
  324.         dec     al
  325.         jnz     again_8_2
  326.  
  327.         cmp     StuffCount,4
  328.         jne     again_8_2
  329.  
  330. no_keys:
  331.         xor     ax,ax
  332.         mov     StuffCount,ax
  333.  
  334.         and     BPTR [SOFTINTFLAGS], NOT ININT08 ;Clear the INT08 active flag
  335.  
  336.         ASSUMENODS
  337.  
  338.         pop     di
  339.         pop     ax                           ;get back registers
  340.         pop     bx
  341.         pop     cx
  342.         pop     dx
  343.  
  344. exit_8:
  345.         pop     ds
  346.         iret
  347.  
  348. newint8 endp
  349.  
  350. ; --------------------------------------------------------------------;
  351. ;   Check for occurance of non INT 8 interrupts in progress           ;
  352. ; --------------------------------------------------------------------;
  353. ;  Returns al containing In Service Register except Int 8 flag
  354. Checkstatus_8 proc    near      ;See if any interrupts are being serviced
  355.  
  356.         ASSUMEDS
  357.  
  358.         push    ds                      ;check if dos critical error in effect
  359.         push    si
  360.         push    DX
  361.         mov     DX,OCW3_8259            ;Address of 8259 OCW3
  362. ;;
  363. ;;      NOTE:  Leaving in the next two lines to read Port 20 and OR it with
  364. ;;              the appropriate mask for hte 8259 causes a nasty and subtle
  365. ;;              bug conflicting with the MS-MOUSE version 6.0 driver.  
  366. ;;              changing to a MOV AL,0bh fixes the problem, and still gets
  367. ;;              the 8259 programmed to the appropriate state.
  368. ;;
  369. ;       in      al,dx
  370. ;       or      AL,000001011b           ;Set the In-Service Reg. read
  371. ;;
  372. ;;      this is correct
  373. ;;
  374.         mov     AL,000001011b           ;Set the In-Service Reg. read
  375.                                         ;bits IRR=1 and ISR=1
  376.         out     DX,AL                   ;Tell 8259 to OUT ISR on next read
  377.         nop                             ;let the 8259 settle down
  378.         nop
  379.         nop
  380. status_8259_2:
  381.         in      AL,DX                   ;Get the ISR (clear int 8)
  382.         and     al,0FEh                 ;Set zero flag if no active interrupts
  383.         pop     DX
  384.  
  385.         lds     si,DPTR [DOSCRITERR]    ;zero says dos is interruptable
  386.  
  387.     ASSUMENODS
  388.  
  389.         or      al,[si]                 ;NOT zero says dos is in a critical state
  390.         lds     si,DPTR [INDOSFLAG]     ;add in second status byte
  391.         or      al,[si]
  392.         or      al,BPTR [INTFLAGS]              ;any flags says we're busy
  393.  
  394.         ; -- check to see if a print screen is in progress              ;v0.51
  395. BiosExtraSegment equ 50h                ;Bios extra data area           ;v0.51
  396. PrintScreenFlag  equ 00h                ;offset of PrintScreen flag     ;v0.51
  397.                                                                         ;v0.51
  398.         ASSUMENODS
  399.         mov     si,BiosExtraSegment     ;Checkout the PrintScrn flag    ;v0.51
  400.         mov     ds,si                   ;1=inprogress, -1=print error   ;v0.51
  401.         or      al,ds:PrintScreenFlag                                   ;v0.51
  402.  
  403.         pop     si
  404.         pop     ds
  405.         ret
  406. Checkstatus_8 endp
  407.  
  408. ENDIT
  409.