home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib31a.dsk / JUNE.1987 / JOYPOINTER.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  54 lines
  1. 1  REM  ************************
  2. 2  REM  * JOYPOINTER           *
  3. 3  REM  * BY KEVIN GARBELMAN   *
  4. 4  REM  * COPYRIGHT (C) 1987   *
  5. 5  REM  * BY MICROSPARC, INC.  *
  6. 6  REM  * CONCORD, MA  01742   *
  7. 7  REM  ************************
  8. 10  GOSUB 250: REM  PRINT A SCREEN
  9. 20  GOSUB 50: REM  GET A READING
  10. 30  GOSUB 380: REM  ACT ON READING
  11. 40  GOTO 10
  12. 50  REM  MOUSE ROUTINE
  13. 60 OL = 160:OD = 2039
  14. 70 MX =  PDL(0)
  15. 80 MY =  PDL(1)
  16. 90 MB =  PEEK(49249)
  17. 100 MX =  INT(MX/6)
  18. 110 MY =  INT(MY/10)
  19. 120  IF MY >24  THEN MY = 24
  20. 130  IF MX >40  THEN MX = 40
  21. 140  IF MX <1  THEN MX = 1
  22. 150  IF MY <1  THEN MY = 1
  23. 160  IF MB >127  THEN  FOR I = 1 TO 10:DU =  PEEK(49200): NEXT : GOTO 230
  24. 170  POKE OD,OL
  25. 180 PK = 128 *MY +MX -(984 * INT((MY -1)/8)) +895
  26. 190 OL =  PEEK(PK)
  27. 200 OD = PK
  28. 210  POKE PK,170
  29. 220  GOTO 70
  30. 230  RETURN 
  31. 240  REM  PRINT A SCREEN
  32. 250  HOME 
  33. 260  VTAB 1: PRINT "JOYPOINTER"
  34. 270  VTAB 2: PRINT "BY KEVIN GARBELMAN": PRINT "COPYRIGHT 1987 MY MICROSPARC, INC."
  35. 280  VTAB 6: HTAB 5: PRINT " OPTION # 1 "
  36. 290  VTAB 8: HTAB 5: PRINT " OPTION # 2 "
  37. 300  VTAB 10: HTAB 5: PRINT " OPTION # 3          OPTION # 4"
  38. 310  VTAB 18: HTAB 4: PRINT "INSTRUCTIONS:"
  39. 320  VTAB 19: HTAB 4: PRINT "MOVE THE JOYSTICK TO POSITION THE"
  40. 330  VTAB 20: HTAB 4: PRINT "CURSOR OVER AN OPTION AND PRESS"
  41. 340  VTAB 21: HTAB 4: PRINT "THE BUTTON.      THE 'FINISHED'"
  42. 350  VTAB 22: HTAB 4: PRINT "OPTION BELOW WILL END THE PROGRAM."
  43. 360  VTAB 24: HTAB 5: PRINT "FINISHED";
  44. 370  RETURN 
  45. 380  REM  DEAL WITH READING
  46. 390  HOME : VTAB 12: HTAB 1: PRINT " NO OPTION CHOSEN"
  47. 400  IF MY = 6  THEN  VTAB 12: PRINT " YOU CHOSE OPTION # 1"
  48. 410  IF MY = 8  THEN  VTAB 12: PRINT " YOU CHOSE OPTION # 2"
  49. 420  IF MY = 10  AND MX <20  THEN  VTAB 12: PRINT " YOU CHOSE OPTION # 3"
  50. 430  IF MY = 10  AND MX >21  THEN  VTAB 12: PRINT " YOU CHOSE OPTION # 4"
  51. 440  VTAB 14: HTAB 5: PRINT "HIT THE BUTTON TO RETURN."
  52. 450  IF MY = 24  THEN  HOME : VTAB 12: PRINT "GOODBYE": END 
  53. 460  GOSUB 60
  54. 470  RETURN