home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib31a.dsk / JUNE.1987 / INSTALL.TURBO.bas < prev    next >
BASIC Source File  |  2023-02-26  |  3KB  |  70 lines
  1. 10  REM  **********************
  2. 20  REM  *   INSTALL.TURBO    *
  3. 30  REM  *   BY CLAUDE LEYO   *
  4. 40  REM  * COPYRIGHT (C) 1987 *
  5. 50  REM  * BY MICROSPARC, INC *
  6. 60  REM  * CONCORD, MA  01742 *
  7. 70  REM  **********************
  8. 80  TEXT : HOME : VTAB 10: HTAB 9: PRINT "APPLESOFT TURBO EDITOR"
  9. 90  PRINT : HTAB 13: PRINT "BY CLAUDE LEYO": PRINT : PRINT " COPYRIGHT 1987 BY MICROSPARC, INC."
  10. 100  PRINT : HTAB 6: PRINT "INSTALLING TURBO.EDITOR..."
  11. 110  PRINT  CHR$(149): REM  CTRL-U TO DEACTIVATE 80-COLUMN CARD
  12. 120  REM  DETERMINE SYSTEM USED
  13. 130  IF  PEEK(48896) = 76  THEN S$ = "P": GOTO 230: REM  PRODOS
  14. 140 S$ = "D": REM  DOS 3.3
  15. 150  REM   INSTALLING THE EDITOR BETWEEN DOS AND ITS BUFFERS
  16. 160  REM  $9D00 CONTAINS ADDRESS OF FIRST BUFFER (USUALLY $D39C)
  17. 170  POKE 40193,143: REM  40193=$9D01, 143=$8F, AFTER POKE $9D00 CONTAINS $D38F
  18. 180  CALL 42964: REM  42964=$A7D4 INITIALIZE DOS BUFFER CHAIN
  19. 190  PRINT  CHR$(4);"BLOAD TURBO.EDITOR,A$9000"
  20. 200 ED = 36864: REM  EDITOR ADDRESS 36864=$9000
  21. 210  GOTO 380
  22. 220  REM  INSTALLING THE EDITOR BETWEEN DOS AND ITS BUFFERS
  23. 230  CALL 48888: REM  FREE BUFFERS 48888=$BEF8
  24. 240  REM   REQUEST A 13-PAGE BUFFER
  25. 250  REM  STORE BUFFER ADDRESS INTO ADR
  26. 260 ADR = 768: REM  768=$0300
  27. 270  DATA     169,13,32,245,190,141,0,3,96
  28. 280  REM  0301  A9 0C      LDA #$0C
  29. 290  REM  0303  20 F5 BE   JSR $BEF5
  30. 300  REM  0306  8D 00 03   STA $0300
  31. 310  REM  0309  60         RTS
  32. 320  FOR I = 1 TO 9: READ N: POKE ADR +I,N: NEXT I
  33. 330  CALL ADR +1
  34. 340  IF  PEEK(ADR) < >141  THEN  PRINT : PRINT "BUFFER ERROR": END 
  35. 350  PRINT  CHR$(4);"BLOAD TURBO.EDITOR,A36096"
  36. 360 ED = 36096
  37. 370  REM  READ CONTROL CHARACTERS
  38. 380  DIM R$(11)
  39. 390 R$(1) =  CHR$( PEEK(ED +23) -64)
  40. 400 R$(2) =  CHR$( PEEK(ED +21) -64)
  41. 410 R$(3) =  CHR$( PEEK(ED +13) -64)
  42. 420 R$(4) =  CHR$( PEEK(ED +9) -64)
  43. 430 R$(5) =  CHR$( PEEK(ED +29) -64)
  44. 440 R$(6) =  CHR$( PEEK(ED +33) -64)
  45. 450 R$(7) =  CHR$( PEEK(ED +35) -64)
  46. 460 R$(8) =  CHR$( PEEK(ED +31) -64)
  47. 470 R$(9) =  CHR$( PEEK(ED +17) -64)
  48. 480 R$(10) =  CHR$( PEEK(ED +37) -64)
  49. 490 R$(11) =  CHR$( PEEK(ED +39) -64)
  50. 500  REM  DISPLAY CONTROL CHARACTERS
  51. 510  INVERSE 
  52. 520  PRINT "CTRL RESET   ACTIVATE EDITOR           "
  53. 530  PRINT "CTRL ";R$(1);"       FORWARD LISTING           "
  54. 540  PRINT "CTRL ";R$(2);"       BACKWARD LISTING          "
  55. 550  PRINT "CTRL I (TAB) INSERT CHARACTER          "
  56. 560  PRINT "CTRL ";R$(3);"       INSERT CONTROL CHARACTER  "
  57. 570  PRINT "CTRL ";R$(4);" (DEL) DELETE CHARACTER          "
  58. 580  PRINT "CTRL ";R$(5);"       ERASE  END OF INSTRUCTION "
  59. 590  PRINT "CTRL ";R$(6);"       SEARCH STRING OF CHAR.    "
  60. 600  PRINT "CTRL ";R$(7);"       CONTINUE SEARCH           "
  61. 610  PRINT "CTRL ";R$(8);" (UP-ARROW)   CURSOR UP          "
  62. 620  PRINT "CTRL ";R$(9);" (DOWN-ARROW) CURSOR DOWN        "
  63. 630  PRINT "  <==  ==>          CURSOR LEFT, RIGHT "
  64. 640  PRINT "CTRL ";R$(10);"       80 COLUMN MODE            "
  65. 650  PRINT "CTRL ";R$(11);"       DISCONNECT EDITOR         "
  66. 660  PRINT "CALL ";ED;"   RECONNECT EDITOR          ";
  67. 670  NORMAL 
  68. 680  IF S$ = "P"  THEN  PRINT 
  69. 690  REM     ACTIVATE EDITOR
  70. 700  CALL ED: REM  NO RETURN. PROGRAM BRANCHES TO RESET