home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib31a.dsk / JUNE.1987 / MOUSEPOINTER.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  59 lines
  1. 1  REM  ************************
  2. 2  REM  * MOUSEPOINTER         *
  3. 3  REM  * BY KEVIN GARBELMAN   *
  4. 4  REM  * COPYRIGHT (C) 1987   *
  5. 5  REM  * BY MICROSPARC, INC.  *
  6. 6  REM  * CONCORD, MA  01742   *
  7. 7  REM  ************************
  8. 10  GOSUB 500: REM  SET UP MOUSE
  9. 20  GOSUB 250: REM  PRINT A SCREEN
  10. 30  GOSUB 70: REM  GET A READING
  11. 40  GOSUB 400: REM  ACT ON READING
  12. 50  GOTO 20
  13. 60  REM  MOUSE ROUTINE
  14. 70 OL = 160:OD = 2039
  15. 80  PRINT  CHR$(4);"IN#4"
  16. 90  VTAB 1: HTAB 40: INPUT "";MX,MY,MB
  17. 100  PRINT  CHR$(4);"IN#0"
  18. 110 MY =  INT(MY/6) +1
  19. 120 MX =  INT(MX/4) +1
  20. 130  IF MY >24  THEN MY = 24
  21. 140  IF MX >40  THEN MX = 40
  22. 150  IF MB = 2  OR MB =  -2  THEN  FOR I = 1 TO 5:DU =  PEEK(49200): NEXT : GOTO 220
  23. 160  POKE OD,OL
  24. 170 PK = 128 *MY +MX -(984 * INT((MY -1)/8)) +895
  25. 180 OL =  PEEK(PK)
  26. 190 OD = PK
  27. 200  POKE PK,170
  28. 210  GOTO 80
  29. 220  RETURN 
  30. 230  REM  END OF GET MOUSE
  31. 240  REM  PRINT A SCREEN
  32. 250  HOME 
  33. 260  VTAB 1: PRINT "MOUSEPOINTER"
  34. 270  VTAB 2: PRINT "BY KEVIN GARBELMAN": PRINT "COPYRIGHT 1987 MY MICROSPARC, INC."
  35. 280  VTAB 6: HTAB 5: PRINT " OPTION # 1 "
  36. 290  VTAB 8: HTAB 5: PRINT " OPTION # 2 "
  37. 300  VTAB 10: HTAB 5: PRINT " OPTION # 3          OPTION # 4"
  38. 310  REM  <10SPACES>
  39. 320  VTAB 18: HTAB 4: PRINT "INSTRUCTIONS:"
  40. 330  VTAB 19: HTAB 4: PRINT "MOVE THE MOUSE TO POSITION THE"
  41. 340  VTAB 20: HTAB 4: PRINT "CURSOR OVER AN OPTION AND PRESS"
  42. 350  VTAB 21: HTAB 4: PRINT "THE MOUSE BUTTON. THE 'FINISHED'"
  43. 360  VTAB 22: HTAB 4: PRINT "OPTION BELOW WILL END THE PROGRAM."
  44. 370  VTAB 24: HTAB 5: PRINT "FINISHED";
  45. 380  RETURN 
  46. 390  REM  DEAL WITH READING
  47. 400  HOME : VTAB 12: HTAB 1: PRINT " NO OPTION CHOSEN"
  48. 410  IF MY = 6  THEN  VTAB 12: PRINT " YOU CHOSE OPTION # 1"
  49. 420  IF MY = 8  THEN  VTAB 12: PRINT " YOU CHOSE OPTION # 2"
  50. 430  IF MY = 10  AND MX <20  THEN  VTAB 12: PRINT " YOU CHOSE OPTION # 3"
  51. 440  IF MY = 10  AND MX >19  THEN  VTAB 12: PRINT " YOU CHOSE OPTION # 4"
  52. 450  IF MY = 24  THEN  HOME : VTAB 12: PRINT "GOODBYE": END 
  53. 460  VTAB 18: HTAB 5: PRINT "PUSH THE BUTTON TO RETURN"
  54. 470  GOSUB 70
  55. 480  RETURN 
  56. 490  REM  *********  MOUSE SET UP  *********
  57. 500  PRINT  CHR$(4);"PR#4": PRINT  CHR$(1)
  58. 510  PRINT  CHR$(4);"PR#0"
  59. 520  RETURN