home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / texmap / tmap_sky.asm < prev    next >
Assembly Source File  |  1998-06-08  |  6KB  |  227 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/texmap/rcs/tmap_sky.asm $
  13. ; $Revision: 1.5 $
  14. ; $Author: mike $
  15. ; $Date: 1994/11/30 00:57:04 $
  16. ; 
  17. ; Sky texture mapper.
  18. ; 
  19. ; $Log: tmap_sky.asm $
  20. ; Revision 1.5  1994/11/30  00:57:04  mike
  21. ; optimization.
  22. ; 
  23. ; Revision 1.4  1994/11/12  16:41:14  mike
  24. ; jae -> ja.
  25. ; 
  26. ; Revision 1.3  1994/03/25  17:08:48  matt
  27. ; Attempt to make this code work on wide windows, but I don't think
  28. ; it did.
  29. ; 
  30. ; Revision 1.2  1994/01/18  10:49:54  mike
  31. ; Modified linear texture mapper for sky plotting.
  32. ; 
  33. ; Revision 1.1  1994/01/14  15:07:03  mike
  34. ; Initial revision
  35. ; 
  36. ; 
  37.  
  38. DEBUG_ON    =    1
  39.  
  40.     .386
  41.  
  42.     option    oldstructs
  43.  
  44.     .nolist
  45.     include    psmacros.inc
  46.     .list
  47.  
  48.  
  49.     public    asm_tmap_scanline_lin_sky_
  50.  
  51.     include    tmap_inc.asm
  52.  
  53. width_log_2    equ    10
  54. height_log_2    equ    7
  55.  
  56. big_num_iters equ num_iters*2
  57.  
  58.  
  59. _DATA    SEGMENT DWORD PUBLIC USE32 'DATA'
  60.  
  61.     extd    _fx_u
  62.     extd    _fx_v
  63.     extd    _fx_du_dx
  64.     extd    _fx_dv_dx
  65.     extd    _fx_y
  66.     extd    _fx_xleft
  67.     extd    _fx_xright
  68.  
  69.     extd    _pixptr
  70.  
  71.     extd    _x
  72.     extd    _loop_count
  73.  
  74. _DATA    ENDS
  75.  
  76. DGROUP    GROUP    _DATA
  77.  
  78. _TEXT   SEGMENT PARA PUBLIC USE32 'CODE'
  79.  
  80.     ASSUME    DS:_DATA
  81.     ASSUME    CS:_TEXT
  82.  
  83. ; --------------------------------------------------------------------------------------------------
  84. ; Enter:
  85. ;    _xleft    fixed point left x coordinate
  86. ;    _xright    fixed point right x coordinate
  87. ;    _y    fixed point y coordinate
  88. ;    _pixptr    address of source pixel map
  89. ;    _u    fixed point initial u coordinate
  90. ;    _v    fixed point initial v coordinate
  91. ;    _du_dx    fixed point du/dx
  92. ;    _dv_dx    fixed point dv/dx
  93.  
  94. ;   for (x = (int) xleft; x <= (int) xright; x++) {
  95. ;      _setcolor(read_pixel_from_tmap(srcb,((int) (u/z)) & 63,((int) (v/z)) & 63));
  96. ;      _setpixel(x,y);
  97. ;
  98. ;      u += du_dx;
  99. ;      v += dv_dx;
  100. ;      z += dz_dx;
  101. ;   }
  102.  
  103.     align    4
  104. asm_tmap_scanline_lin_sky_:
  105.     pusha
  106.  
  107. ; Setup for loop:    _loop_count  iterations = (int) xright - (int) xleft
  108. ;    esi    source pixel pointer = pixptr
  109. ;    edi    initial row pointer = y*320+x
  110.  
  111. ; set esi = pointer to start of texture map data
  112.     mov    esi,_pixptr
  113.  
  114. ; set edi = address of first pixel to modify
  115.     mov    edi,_fx_y
  116.     cmp    edi,_window_bottom
  117.     ja    _none_to_do
  118.  
  119.     imul    edi,_bytes_per_row
  120.     mov    eax,_fx_xleft
  121.     sar    eax,16
  122.     jns    eax_ok
  123.     sub    eax,eax
  124. eax_ok:
  125.     add    edi,eax
  126.     add    edi,write_buffer
  127.  
  128. ; set _loop_count = # of iterations
  129.     mov    eax,_fx_xright
  130.     sar    eax,16
  131.     cmp    eax,_window_right
  132.     jb    eax_ok1
  133.     mov    eax,_window_right
  134. eax_ok1:    cmp    eax,_window_left
  135.     ja    eax_ok2
  136.     mov    eax,_window_left
  137. eax_ok2:
  138.  
  139.     mov    ebx,_fx_xleft
  140.     sar    ebx,16
  141.     sub    eax,ebx
  142.     js    _none_to_do
  143.     cmp    eax,_window_width
  144.     jbe    _ok_to_do
  145.     mov    eax,_window_width
  146. _ok_to_do:
  147.     mov    _loop_count,eax
  148.  
  149. ;    edi    destination pixel pointer
  150.  
  151.  
  152.     mov    ebx,_fx_u
  153.     mov    ecx,_fx_du_dx
  154.     mov    edx,_fx_dv_dx
  155.     mov    ebp,_fx_v
  156.  
  157.     shl    ebx,16-width_log_2
  158.     shl    ebp,16-height_log_2
  159.     shl    edx,16-height_log_2
  160.     shl    ecx,16-width_log_2
  161.  
  162. ; eax    work
  163. ; ebx    u
  164. ; ecx    du_dx
  165. ; edx    dv_dx
  166. ; ebp    v
  167. ; esi    read address
  168. ; edi    write address
  169.  
  170. _size = (_end1 - _start1)/big_num_iters
  171.     mov    eax,big_num_iters-1
  172.     sub    eax,_loop_count
  173.     jns    j_eax_ok1
  174.     inc    eax    ; sort of a hack, but we can get -1 here and want to be graceful
  175.     jns    j_eax_ok1    ; if we jump, we had -1, which is kind of ok, if not, we int 3
  176.     int    3    ; oops, going to jump behind _start1, very bad...
  177.     sub    eax,eax    ; ok to continue
  178. j_eax_ok1:    imul    eax,eax,dword ptr _size
  179.     add    eax,offset _start1
  180.     jmp    eax
  181.  
  182.     align    4
  183. _start1:
  184.  
  185. ; "OPTIMIZATIONS" maybe not worth making
  186. ;    Getting rid of the esi from the mov al,[esi+eax] instruction.
  187. ;       This would require moving into eax at the top of the loop, rather than doing the sub eax,eax.
  188. ;       You would have to align your bitmaps so that the two shlds would create the proper base address.
  189. ;       In other words, your bitmap data would have to begin at 4096x (for 64x64 bitmaps).
  190. ;       I did timings without converting the sub to a mov eax,esi and setting esi to the proper value.
  191. ;       There was a speedup of about 1% to 1.5% without converting the sub to a mov.
  192. ;    Getting rid of the edi by doing a mov nnnn[edi],al instead of mov [edi],al.
  193. ;       The problem with this is you would have a dword offset for nnnn.  My timings indicate it is slower.  (I think.)
  194. ;    Combining u,v and du,dv into single longwords.
  195. ;       The problem with this is you then must do a 16 bit operation to extract them, and you don't have enough
  196. ;       instructions to separate a destination operand from being used by the next instruction.  It shaves out one
  197. ;       register instruction (an add reg,reg), but adds a 16 bit operation, and the setup is more complicated.
  198. ; usage:
  199. ;    eax    work
  200. ;    ebx    u coordinate
  201. ;    ecx    delta u
  202. ;    edx    delta v
  203. ;    ebp    v coordinate
  204. ;    esi    pointer to source bitmap
  205. ;    edi    write address
  206.  rept big_num_iters
  207.     mov    eax,ebp    ; clear for 
  208.     add    ebp,edx    ; update v coordinate
  209.     shr    eax,32-height_log_2    ; shift in v coordinate
  210.     shld    eax,ebx,width_log_2    ; shift in u coordinate while shifting up v coordinate
  211.     add    ebx,ecx    ; update u coordinate
  212.     mov    al,[esi+eax]    ; get pixel from source bitmap
  213.     mov    [edi],al
  214.     inc    edi
  215.  
  216.  endm
  217.  
  218. _end1:
  219.  
  220. _none_to_do:    popa
  221.  
  222.     ret
  223.  
  224. _TEXT    ends
  225.  
  226.     end
  227.