home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / texmap / tmap_skv.asm < prev    next >
Assembly Source File  |  1998-06-08  |  9KB  |  334 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/texmap/rcs/tmap_skv.asm $
  13. ; $Revision: 1.5 $
  14. ; $Author: mike $
  15. ; $Date: 1994/11/30 00:57:03 $
  16. ; 
  17. ; Vertical scanner for sky bitmap rendering.
  18. ; 
  19. ; $Log: tmap_skv.asm $
  20. ; Revision 1.5  1994/11/30  00:57:03  mike
  21. ; optimization.
  22. ; 
  23. ; Revision 1.4  1994/11/12  16:41:13  mike
  24. ; jae -> ja.
  25. ; 
  26. ; Revision 1.3  1994/05/24  11:03:12  mike
  27. ; Make work for any sized (power of 2) bitmap.
  28. ; 
  29. ; Revision 1.2  1994/01/31  15:42:14  mike
  30. ; Vertical scanning sky texture mapper (in inner loop).
  31. ; 
  32. ; Revision 1.1  1994/01/30  14:10:55  mike
  33. ; Initial revision
  34. ; 
  35. ; 
  36.  
  37.  
  38.  
  39. DEBUG_ON    =    1
  40.  
  41.     .386
  42.  
  43.     option    oldstructs
  44.  
  45.     .nolist
  46.     include    psmacros.inc
  47.     .list
  48.  
  49.  
  50.     public    asm_tmap_scanline_lin_sky_v_, asm_tmap_scanline_lin_v_
  51.  
  52.     include    tmap_inc.asm
  53.  
  54. sky_width_log_2    equ    10
  55. sky_height_log_2    equ    7
  56.  
  57. width_log_2    equ    6
  58. height_log_2    equ    6
  59.  
  60. _DATA    SEGMENT DWORD PUBLIC USE32 'DATA'
  61.  
  62.     extd    _fx_u
  63.     extd    _fx_v
  64.     extd    _fx_du_dx
  65.     extd    _fx_dv_dx
  66.     extd    _fx_y
  67.     extd    _fx_xleft
  68.     extd    _fx_xright
  69.  
  70.     extd    _pixptr
  71.  
  72.     extd    _x
  73.     extd    _loop_count
  74.  
  75. _DATA    ENDS
  76.  
  77. DGROUP    GROUP    _DATA
  78.  
  79. _TEXT   SEGMENT PARA PUBLIC USE32 'CODE'
  80.  
  81.     ASSUME    DS:_DATA
  82.     ASSUME    CS:_TEXT
  83.  
  84. ; --------------------------------------------------------------------------------------------------
  85. ; Enter:
  86. ;    _xleft    fixed point left x coordinate
  87. ;    _xright    fixed point right x coordinate
  88. ;    _y    fixed point y coordinate
  89. ;    _pixptr    address of source pixel map
  90. ;    _u    fixed point initial u coordinate
  91. ;    _v    fixed point initial v coordinate
  92. ;    _du_dx    fixed point du/dx
  93. ;    _dv_dx    fixed point dv/dx
  94.  
  95. ;   for (x = (int) xleft; x <= (int) xright; x++) {
  96. ;      _setcolor(read_pixel_from_tmap(srcb,((int) (u/z)) & 63,((int) (v/z)) & 63));
  97. ;      _setpixel(x,y);
  98. ;
  99. ;      u += du_dx;
  100. ;      v += dv_dx;
  101. ;      z += dz_dx;
  102. ;   }
  103.  
  104.     align    4
  105. asm_tmap_scanline_lin_sky_v_:
  106.     pusha
  107.  
  108. ; Setup for loop:    _loop_count  iterations = (int) xright - (int) xleft
  109. ;    esi    source pixel pointer = pixptr
  110. ;    edi    initial row pointer = y*320+x
  111.  
  112. ; set esi = pointer to start of texture map data
  113.     mov    esi,_pixptr
  114.  
  115. ; set edi = address of first pixel to modify
  116.     mov    edi,_fx_xleft
  117.     sar    edi,16
  118.     jns    edi_ok
  119.     sub    edi,edi
  120. edi_ok:
  121.     cmp    edi,_window_bottom
  122.     ja    _none_to_do
  123.     imul    edi,_bytes_per_row
  124.  
  125.     add    edi,_fx_y
  126.     add    edi,write_buffer
  127.  
  128. ; set _loop_count = # of iterations
  129.     mov    eax,_fx_xright
  130.     sar    eax,16
  131.     mov    ebx,_fx_xleft
  132.     sar    ebx,16
  133.     sub    eax,ebx
  134.     js    _none_to_do
  135.     cmp    eax,_window_height
  136.     jbe    _ok_to_do
  137.     mov    eax,_window_height
  138. _ok_to_do:
  139.     mov    _loop_count,eax
  140.  
  141. ;    edi    destination pixel pointer
  142.  
  143.  
  144.     mov    ebx,_fx_u
  145.     mov    ecx,_fx_du_dx
  146.     mov    edx,_fx_dv_dx
  147.     mov    ebp,_fx_v
  148.  
  149.     shl    ebx,16-sky_width_log_2
  150.     shl    ebp,16-sky_height_log_2
  151.     shl    edx,16-sky_height_log_2
  152.     shl    ecx,16-sky_width_log_2
  153.  
  154. ; eax    work
  155. ; ebx    u
  156. ; ecx    du_dx
  157. ; edx    dv_dx
  158. ; ebp    v
  159. ; esi    read address
  160. ; edi    write address
  161.  
  162. _size = (_end1 - _start1)/num_iters
  163.     mov    eax,num_iters-1
  164.     sub    eax,_loop_count
  165.     jns    j_eax_ok1
  166.     inc    eax    ; sort of a hack, but we can get -1 here and want to be graceful
  167.     jns    j_eax_ok1    ; if we jump, we had -1, which is kind of ok, if not, we int 3
  168.     int    3    ; oops, going to jump behind _start1, very bad...
  169.     sub    eax,eax    ; ok to continue
  170. j_eax_ok1:    imul    eax,eax,dword ptr _size
  171.     add    eax,offset _start1
  172.     jmp    eax
  173.  
  174.     align    4
  175. _start1:
  176.  
  177. ; "OPTIMIZATIONS" maybe not worth making
  178. ;    Getting rid of the esi from the mov al,[esi+eax] instruction.
  179. ;       This would require moving into eax at the top of the loop, rather than doing the sub eax,eax.
  180. ;       You would have to align your bitmaps so that the two shlds would create the proper base address.
  181. ;       In other words, your bitmap data would have to begin at 4096x (for 64x64 bitmaps).
  182. ;       I did timings without converting the sub to a mov eax,esi and setting esi to the proper value.
  183. ;       There was a speedup of about 1% to 1.5% without converting the sub to a mov.
  184. ;    Getting rid of the edi by doing a mov nnnn[edi],al instead of mov [edi],al.
  185. ;       The problem with this is you would have a dword offset for nnnn.  My timings indicate it is slower.  (I think.)
  186. ;    Combining u,v and du,dv into single longwords.
  187. ;       The problem with this is you then must do a 16 bit operation to extract them, and you don't have enough
  188. ;       instructions to separate a destination operand from being used by the next instruction.  It shaves out one
  189. ;       register instruction (an add reg,reg), but adds a 16 bit operation, and the setup is more complicated.
  190. ; usage:
  191. ;    eax    work
  192. ;    ebx    u coordinate
  193. ;    ecx    delta u
  194. ;    edx    delta v
  195. ;    ebp    v coordinate
  196. ;    esi    pointer to source bitmap
  197. ;    edi    write address
  198.  rept num_iters
  199.     mov    eax,ebp    ; clear for 
  200.     add    ebp,edx    ; update v coordinate
  201.     shr    eax,32-sky_height_log_2    ; shift in v coordinate
  202.     shld    eax,ebx,sky_width_log_2    ; shift in u coordinate while shifting up v coordinate
  203.     add    ebx,ecx    ; update u coordinate
  204.     mov    al,[esi+eax]    ; get pixel from source bitmap
  205.     mov    [edi],al
  206.     add    edi,_bytes_per_row
  207.  
  208.  endm
  209.  
  210. _end1:
  211.  
  212. _none_to_do:    popa
  213.  
  214.     ret
  215.  
  216. ; --------------------------------------------------------------------------------------------------------------------------------
  217.     align    4
  218. asm_tmap_scanline_lin_v_:
  219.     pusha
  220.  
  221. ; Setup for loop:    _loop_count  iterations = (int) xright - (int) xleft
  222. ;    esi    source pixel pointer = pixptr
  223. ;    edi    initial row pointer = y*320+x
  224.  
  225. ; set esi = pointer to start of texture map data
  226.     mov    esi,_pixptr
  227.  
  228. ; set edi = address of first pixel to modify
  229.     mov    edi,_fx_xleft
  230.     sar    edi,16
  231.     jns    edi_ok_a
  232.     sub    edi,edi
  233. edi_ok_a:
  234.     cmp    edi,_window_bottom
  235.     ja    _none_to_do_a
  236.     imul    edi,_bytes_per_row
  237.  
  238.     add    edi,_fx_y
  239.     add    edi,write_buffer
  240.  
  241. ; set _loop_count = # of iterations
  242.     mov    eax,_fx_xright
  243.     sar    eax,16
  244.     mov    ebx,_fx_xleft
  245.     sar    ebx,16
  246.     sub    eax,ebx
  247.     js    _none_to_do_a
  248.     cmp    eax,_window_height
  249.     jbe    _ok_to_do_a
  250.     mov    eax,_window_height
  251. _ok_to_do_a:
  252.     mov    _loop_count,eax
  253.  
  254. ;    edi    destination pixel pointer
  255.  
  256.  
  257.     mov    ebx,_fx_u
  258.     mov    ecx,_fx_du_dx
  259.     mov    edx,_fx_dv_dx
  260.     mov    ebp,_fx_v
  261.  
  262.     shl    ebx,16-width_log_2
  263.     shl    ebp,16-height_log_2
  264.     shl    edx,16-height_log_2
  265.     shl    ecx,16-width_log_2
  266.  
  267. ; eax    work
  268. ; ebx    u
  269. ; ecx    du_dx
  270. ; edx    dv_dx
  271. ; ebp    v
  272. ; esi    read address
  273. ; edi    write address
  274.  
  275. _size_a = (_end1_a - _start1_a)/num_iters
  276.     mov    eax,num_iters-1
  277.     sub    eax,_loop_count
  278.     jns    j_eax_ok1_a
  279.     inc    eax    ; sort of a hack, but we can get -1 here and want to be graceful
  280.     jns    j_eax_ok1_a    ; if we jump, we had -1, which is kind of ok, if not, we int 3
  281.     int    3    ; oops, going to jump behind _start1, very bad...
  282.     sub    eax,eax    ; ok to continue
  283. j_eax_ok1_a:    imul    eax,eax,dword ptr _size_a
  284.     add    eax,offset _start1_a
  285.     jmp    eax
  286.  
  287.     align    4
  288. _start1_a:
  289.  
  290. ; "OPTIMIZATIONS" maybe not worth making
  291. ;    Getting rid of the esi from the mov al,[esi+eax] instruction.
  292. ;       This would require moving into eax at the top of the loop, rather than doing the sub eax,eax.
  293. ;       You would have to align your bitmaps so that the two shlds would create the proper base address.
  294. ;       In other words, your bitmap data would have to begin at 4096x (for 64x64 bitmaps).
  295. ;       I did timings without converting the sub to a mov eax,esi and setting esi to the proper value.
  296. ;       There was a speedup of about 1% to 1.5% without converting the sub to a mov.
  297. ;    Getting rid of the edi by doing a mov nnnn[edi],al instead of mov [edi],al.
  298. ;       The problem with this is you would have a dword offset for nnnn.  My timings indicate it is slower.  (I think.)
  299. ;    Combining u,v and du,dv into single longwords.
  300. ;       The problem with this is you then must do a 16 bit operation to extract them, and you don't have enough
  301. ;       instructions to separate a destination operand from being used by the next instruction.  It shaves out one
  302. ;       register instruction (an add reg,reg), but adds a 16 bit operation, and the setup is more complicated.
  303. ; usage:
  304. ;    eax    work
  305. ;    ebx    u coordinate
  306. ;    ecx    delta u
  307. ;    edx    delta v
  308. ;    ebp    v coordinate
  309. ;    esi    pointer to source bitmap
  310. ;    edi    write address
  311.  rept num_iters
  312.     mov    eax,ebp    ; clear for 
  313.     add    ebp,edx    ; update v coordinate
  314.     shr    eax,32-height_log_2    ; shift in v coordinate
  315.     shld    eax,ebx,width_log_2    ; shift in u coordinate while shifting up v coordinate
  316.     add    ebx,ecx    ; update u coordinate
  317.     mov    al,[esi+eax]    ; get pixel from source bitmap
  318.     mov    [edi],al
  319.     add    edi,_bytes_per_row
  320.  
  321.  endm
  322.  
  323. _end1_a:
  324.  
  325. _none_to_do_a:    popa
  326.  
  327.     ret
  328.  
  329.  
  330.  
  331. _TEXT    ends
  332.  
  333.     end
  334.