home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / texmap / tmap_z.asm < prev    next >
Assembly Source File  |  1998-06-08  |  4KB  |  167 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/texmap/rcs/tmap_z.asm $
  13. ; $Revision: 1.4 $
  14. ; $Author: mike $
  15. ; $Date: 1994/11/30 00:57:06 $
  16. ; 
  17. ; Assembly routines to do a flat-shaded z-buffer tmap.
  18. ; 
  19. ; $Log: tmap_z.asm $
  20. ; Revision 1.4  1994/11/30  00:57:06  mike
  21. ; optimization.
  22. ; 
  23. ; Revision 1.3  1994/11/12  16:41:14  mike
  24. ; jae -> ja.
  25. ; 
  26. ; Revision 1.2  1994/07/08  17:43:14  john
  27. ; Added flat-shaded-zbuffered polygon.
  28. ; 
  29. ; Revision 1.1  1994/07/08  10:58:18  john
  30. ; Initial revision
  31. ; 
  32. ; 
  33.  
  34.     .386
  35.  
  36.     public    asm_tmap_scanline_flat_z_
  37.     public    _tmap_flat_color_z
  38.     public    _tmap_z_buffer
  39.  
  40.     include    tmap_inc.asm
  41.  
  42. _DATA    SEGMENT DWORD PUBLIC USE32 'DATA'
  43.  
  44.     extrn    _fx_y:dword
  45.     extrn    _fx_xleft:dword
  46.     extrn    _fx_xright:dword
  47.     extrn    _fx_z:dword
  48.     extrn    _fx_dz_dx:dword
  49.         
  50. ;**    extrn    _pixptr:dword
  51.  
  52. _tmap_flat_color_z    db    ?
  53. _tmap_z_buffer        dd    0
  54. _loop_count        dd    0
  55.  
  56. _DATA    ENDS
  57.  
  58. DGROUP    GROUP    _DATA
  59.  
  60. _TEXT   SEGMENT PARA PUBLIC USE32 'CODE'
  61.  
  62.     ASSUME    DS:_DATA
  63.     ASSUME    CS:_TEXT
  64.  
  65. ; --------------------------------------------------------------------------------------------------
  66. ; Enter:
  67. ;    _xleft    fixed point left x coordinate
  68. ;    _xright    fixed point right x coordinate
  69. ;    _y    fixed point y coordinate
  70. ;**;    _pixptr    address of source pixel map
  71.  
  72. ;   for (x = (int) xleft; x <= (int) xright; x++) {
  73. ;      _setcolor(read_pixel_from_tmap(srcb,((int) (u/z)) & 63,((int) (v/z)) & 63));
  74. ;      _setpixel(x,y);
  75. ;
  76. ;      z += dz_dx;
  77. ;   }
  78.  
  79. asm_tmap_scanline_flat_z_:
  80.     pusha
  81.  
  82. ; Setup for loop:    _loop_count  iterations = (int) xright - (int) xleft
  83. ;**;    esi    source pixel pointer = pixptr
  84. ;    edi    initial row pointer = y*320+x
  85.  
  86. ; set esi = pointer to start of texture map data
  87. ;**    mov    esi,_pixptr
  88.  
  89. ; set edi = address of first pixel to modify
  90.     mov    edi,_fx_y
  91.     shr    edi,16
  92.     cmp    edi,_window_bottom
  93.     ja    _none_to_do
  94.  
  95.     imul    edi,_bytes_per_row
  96.     mov    eax,_fx_xleft
  97.     sar    eax,16
  98.     jns    eax_ok
  99.     sub    eax,eax
  100. eax_ok:
  101.     add    edi,eax
  102.     mov    esi,edi
  103.     shl    esi, 2
  104.     add    esi, _tmap_z_buffer
  105.     add    edi,write_buffer
  106.  
  107. ; set _loop_count = # of iterations
  108.     mov    eax,_fx_xright
  109.     sar    eax,16
  110.  
  111.     cmp    eax,_window_right
  112.     jb    eax_ok1
  113.     mov    eax,_window_right
  114. eax_ok1:    cmp    eax,_window_left
  115.     ja    eax_ok2
  116.     mov    eax,_window_left
  117. eax_ok2:
  118.     mov    ebx,_fx_xleft
  119.     sar    ebx,16
  120.     sub    eax,ebx
  121.     js    _none_to_do
  122.     cmp    eax,_window_width
  123.     jbe    _ok_to_do
  124.     mov    eax,_window_width
  125. _ok_to_do:
  126.     mov    _loop_count, eax
  127.  
  128.     mov    cl,_tmap_flat_color_z
  129.     mov    edx, _fx_z
  130.     mov    ebp, _fx_dz_dx
  131.     mov    ebx, 4
  132.     
  133. _size = (_end1 - _start1)/num_iters
  134.     mov    eax,num_iters-1
  135.     sub    eax,_loop_count
  136.     jns    j_eax_ok1
  137.     inc    eax    ; sort of a hack, but we can get -1 here and want to be graceful
  138.     jns    j_eax_ok1    ; if we jump, we had -1, which is kind of ok, if not, we int 3
  139.     int    3    ; oops, going to jump behind _start1, very bad...
  140.     sub    eax,eax    ; ok to continue
  141. j_eax_ok1:    imul    eax,eax,dword ptr _size
  142.     add    eax,offset _start1
  143.     jmp    eax
  144.  
  145.     align    4
  146. _start1:
  147.  
  148. rept num_iters
  149. local l1
  150.     cmp    edx, [esi]
  151.     jge    l1
  152.     mov    [esi], edx
  153.     mov    [edi], cl
  154. l1:    add    esi, ebx
  155.     add    edx, ebp
  156.     inc    edi
  157. endm
  158. _end1:
  159.  
  160. _none_to_do:    popa
  161.     ret
  162.  
  163.  
  164. _TEXT    ends
  165.  
  166.     end
  167.