home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / texmap / tmap_16r.asm < prev    next >
Assembly Source File  |  1998-06-08  |  9KB  |  275 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/texmap/rcs/tmap_16r.asm $
  13. ; $Revision: 1.4 $
  14. ; $Author: mike $
  15. ; $Date: 1994/11/30 00:56:41 $
  16. ;
  17. ; inner loop of rgb lighted linear texture mapper for 16 bits/pixel
  18. ;
  19. ; $Log: tmap_16r.asm $
  20. ; Revision 1.4  1994/11/30  00:56:41  mike
  21. ; optimization.
  22. ; 
  23. ; Revision 1.3  1994/11/12  16:39:33  mike
  24. ; jae to ja.
  25. ; 
  26. ; Revision 1.2  1993/11/22  10:24:47  mike
  27. ; *** empty log message ***
  28. ; 
  29. ; Revision 1.1  1993/09/08  17:29:45  mike
  30. ; Initial revision
  31. ; 
  32. ;
  33. ;
  34.  
  35.  
  36.     .386
  37.  
  38.     public    asm_tmap_scanline_lin_rgb_16_
  39.  
  40.     include    tmap_inc.asm
  41.  
  42. _DATA    SEGMENT DWORD PUBLIC USE32 'DATA'
  43.  
  44.     extrn    _fx_u:dword
  45.     extrn    _fx_v:dword
  46.     extrn    _fx_du_dx:dword
  47.     extrn    _fx_dv_dx:dword
  48.     extrn    _fx_y:dword
  49.     extrn    _fx_xleft:dword
  50.     extrn    _fx_xright:dword
  51.  
  52.     extrn    _pixptr:dword
  53.  
  54.     extrn    _x:dword
  55.     extrn    _loop_count:dword
  56.  
  57.     extrn    _fx_rgb:dword,_fx_drgb_dx:dword
  58.  
  59.     extrn    _fx_r:dword,_fx_g:dword,_fx_b:dword,_fx_dr_dx:dword,_fx_dg_dx:dword,_fx_db_dx:dword
  60.  
  61.     align    4
  62. preserve_high_5_bits dd    11111000000000000000000000000000b
  63.  
  64. satadd    label    byte
  65.     db    00,01,02,03,04,05,06,07,08,09,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
  66.     db    01,01,02,03,04,05,06,07,08,09,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
  67.     db    02,02,03,04,05,06,07,08,09,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,31
  68.     db    03,03,04,04,05,06,07,08,09,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,31
  69.     db    04,04,05,05,06,07,08,09,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,31,31
  70.     db    05,05,06,06,07,07,08,09,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,31,31
  71.     db    06,06,07,07,08,08,09,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,31,31,31
  72.     db    07,07,08,08,09,09,10,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,31,31,31
  73.     db    08,08,09,09,10,10,11,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,31,31,31,31
  74.     db    09,09,10,10,11,11,12,12,13,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,31,31,31,31
  75.     db    10,10,11,11,12,12,13,13,14,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,31,31,31,31,31
  76.     db    11,11,12,12,13,13,14,14,15,15,16,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,31,31,31,31,31
  77.     db    12,12,13,13,14,14,15,15,16,16,17,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,31,31,31,31,31,31
  78.     db    13,13,14,14,15,15,16,16,17,17,18,18,19,19,20,21,22,23,24,25,26,27,28,29,30,31,31,31,31,31,31,31
  79.     db    14,14,15,15,16,16,17,17,18,18,19,19,20,20,21,22,23,24,25,26,27,28,29,30,31,31,31,31,31,31,31,31
  80.     db    15,15,16,16,17,17,18,18,19,19,20,20,21,21,22,22,23,24,25,26,27,28,29,30,31,31,31,31,31,31,31,31
  81.     db    16,16,17,17,18,18,19,19,20,20,21,21,22,22,23,23,24,25,26,27,28,29,30,31,31,31,31,31,31,31,31,31
  82.     db    17,17,18,18,19,19,20,20,21,21,22,22,23,23,24,24,25,25,26,27,28,29,30,31,31,31,31,31,31,31,31,31
  83.     db    18,18,19,19,20,20,21,21,22,22,23,23,24,24,25,25,26,26,27,28,29,30,31,31,31,31,31,31,31,31,31,31
  84.     db    19,19,20,20,21,21,22,22,23,23,24,24,25,25,26,26,27,27,28,28,29,30,31,31,31,31,31,31,31,31,31,31
  85.     db    20,20,21,21,22,22,23,23,24,24,25,25,26,26,27,27,28,28,29,29,30,31,31,31,31,31,31,31,31,31,31,31
  86.     db    21,21,22,22,23,23,24,24,25,25,26,26,27,27,28,28,29,29,30,30,31,31,31,31,31,31,31,31,31,31,31,31
  87.     db    22,22,23,23,24,24,25,25,26,26,27,27,28,28,29,29,30,30,31,31,31,31,31,31,31,31,31,31,31,31,31,31
  88.     db    23,23,24,24,25,25,26,26,27,27,28,28,29,29,30,30,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31
  89.     db    24,24,25,25,26,26,27,27,28,28,29,29,30,30,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31
  90.     db    25,25,26,26,27,27,28,28,29,29,30,30,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31
  91.     db    26,26,27,27,28,28,29,29,30,30,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31
  92.     db    27,27,28,28,29,29,30,30,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31
  93.     db    28,28,29,29,30,30,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31
  94.     db    29,29,30,30,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31
  95.     db    30,30,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31
  96.     db    31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31,31
  97.  
  98. _DATA    ENDS
  99.  
  100. DGROUP    GROUP    _DATA
  101.  
  102. _TEXT   SEGMENT PARA PUBLIC USE32 'CODE'
  103.  
  104.     ASSUME    DS:_DATA
  105.     ASSUME    CS:_TEXT
  106.  
  107. ; --------------------------------------------------------------------------------------------------
  108. ; Enter:
  109. ;    _xleft    fixed point left x coordinate
  110. ;    _xright    fixed point right x coordinate
  111. ;    _y    fixed point y coordinate
  112. ;    _pixptr    address of source pixel map
  113. ;    _u    fixed point initial u coordinate
  114. ;    _v    fixed point initial v coordinate
  115. ;    _du_dx    fixed point du/dx
  116. ;    _dv_dx    fixed point dv/dx
  117.  
  118. ;   for (x = (int) xleft; x <= (int) xright; x++) {
  119. ;      _setcolor(read_pixel_from_tmap(srcb,((int) (u/z)) & 63,((int) (v/z)) & 63));
  120. ;      _setpixel(x,y);
  121. ;
  122. ;      u += du_dx;
  123. ;      v += dv_dx;
  124. ;      z += dz_dx;
  125. ;   }
  126.  
  127.     align    4
  128. asm_tmap_scanline_lin_rgb_16_:
  129.     pusha
  130.  
  131. ; Setup for loop:    _loop_count  iterations = (int) xright - (int) xleft
  132. ;    esi    source pixel pointer = pixptr
  133. ;    edi    initial row pointer = y*320+x
  134.  
  135. ; set esi = pointer to start of texture map data
  136.     mov    esi,_pixptr
  137.  
  138. ; set edi = address of first pixel to modify
  139.     mov    edi,_fx_y
  140.     cmp    edi,_window_bottom
  141.     ja    _none_to_do
  142.  
  143.     sub    edi,_window_top
  144.     imul    edi,_bytes_per_row
  145.     mov    eax,_fx_xleft
  146.     sar    eax,16
  147.     jns    eax_ok
  148.     sub    eax,eax
  149. eax_ok:
  150.     sub    eax,_window_left
  151.     add    edi,eax
  152.     add    edi,eax
  153.     add    edi,write_buffer
  154.  
  155. ; set _loop_count = # of iterations
  156.     mov    eax,_fx_xright
  157.     sar    eax,16
  158.     cmp    eax,_window_right
  159.     jb    eax_ok1
  160.     mov    eax,_window_right
  161. eax_ok1:    cmp    eax,_window_left
  162.     ja    eax_ok2
  163.     mov    eax,_window_left
  164. eax_ok2:
  165.  
  166.     mov    ebx,_fx_xleft
  167.     sar    ebx,16
  168.     sub    eax,ebx
  169.     js    _none_to_do
  170.     cmp    eax,_window_width
  171.     jbe    _ok_to_do
  172.     mov    eax,_window_width
  173. _ok_to_do:
  174.     mov    _loop_count,eax
  175.  
  176. ;    edi    destination pixel pointer
  177.  
  178.     mov    ebx,_fx_u
  179.     mov    ebp,_fx_v
  180.  
  181.     shl    ebx,10
  182.     shl    ebp,10
  183.  
  184.     shl    _fx_du_dx,10
  185.     shl    _fx_dv_dx,10
  186.  
  187. ; shift up all light values and deltas so that the highest 5 bits are the integer portion
  188.     shl    _fx_r,11
  189.     shl    _fx_g,11
  190.     shl    _fx_b,11
  191.  
  192.     shl    _fx_dr_dx,11
  193.     shl    _fx_dg_dx,11
  194.     shl    _fx_db_dx,11
  195.  
  196. ; ---------------------------------------------------------------------------------------------------------------------
  197.  
  198. ; register usage:
  199. ;  eax    work
  200. ;  ebx    _fx_du_dx
  201. ;  ecx    work
  202. ;  edx    work
  203. ;  ebp    _fx_dv_dx
  204. ;  esi    texture map pixel data start
  205. ;  edi    write address
  206.  
  207. ; do the regular texture mapper linear interpolation to get the pixel from the source bitmap
  208. _loop1:    sub    edx,edx
  209.     shld    edx,ebp,6    ; shift in v coordinate
  210.     add    ebp,_fx_dv_dx    ; update v coordinate
  211.     shld    edx,ebx,6    ; shift in u coordinate while shifting up v coordinate
  212.     add    ebx,_fx_du_dx    ; update u coordinate
  213.     lea    edx,[esi+4*edx]    ; get pixel from source bitmap
  214.  
  215. ; edx = pointer to rgbX dword pixel value
  216.     mov    eax,_fx_r    ; light value in high 5 bits
  217.     and    eax,preserve_high_5_bits
  218.     mov    al,[edx]    ; get red pixel value
  219.     rol    eax,5    ; now 10 low bits = light:pixel
  220.     movzx    ecx,byte ptr satadd[eax]
  221.     shl    ecx,5
  222.  
  223.     mov    eax,_fx_g    ; light value in high 5 bits
  224.     and    eax,preserve_high_5_bits
  225.     mov    al,1[edx]    ; get green pixel value
  226.     rol    eax,5    ; now 10 low bits = light:pixel
  227.     or    cl,byte ptr satadd[eax]
  228.     shl    ecx,5
  229.  
  230.     mov    eax,_fx_b    ; light value in high 5 bits
  231.     and    eax,preserve_high_5_bits
  232.     mov    al,2[edx]    ; get blue pixel value
  233.     rol    eax,5    ; now 10 low bits = light:pixel
  234.     or    cl,byte ptr satadd[eax]
  235.  
  236. ; now %ecx = r|g|b, each 5 bits, bit #15 clear, write the pixel
  237.     mov    [edi],cx
  238.     add    edi,2
  239.  
  240. ; now add the deltas
  241.     mov    eax,_fx_dr_dx
  242.     add    _fx_r,eax
  243.  
  244.     mov    eax,_fx_dg_dx
  245.     add    _fx_g,eax
  246.  
  247.     mov    eax,_fx_db_dx
  248.     add    _fx_b,eax
  249.  
  250.     dec    _loop_count
  251.     jns    _loop1
  252.  
  253. ; ---------------------------------------------------------------------------------------------------------------------
  254.  
  255. _none_to_do:    popa
  256.  
  257.     ret
  258.  
  259. ; -- Code to get rgb 5 bits integer, 5 bits fraction value into 5 bits integer (for each gun)
  260. ; suitable for inverse color lookup
  261. ;**__test:
  262. ;** int 3
  263. ;**;                  rrrrrfffffrrrrrfffffxxbbbbbfffff
  264. ;**    mov    eax,11111001001010101110101101110111b
  265. ;**    and    eax,11111000001111100000001111100000b
  266. ;**    shld    ebx,eax,15
  267. ;**    or    bx,ax
  268.  
  269. _TEXT    ends
  270.  
  271.     end
  272.  
  273.  
  274.  
  275.