home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / texmap / tmap_16p.asm < prev    next >
Assembly Source File  |  1998-06-08  |  4KB  |  205 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/texmap/rcs/tmap_16p.asm $
  13. ; $Revision: 1.4 $
  14. ; $Author: mike $
  15. ; $Date: 1994/11/30 00:56:40 $
  16. ;
  17. ; Perspective 16 bit per pixel texture mapper
  18. ;
  19. ; $Log: tmap_16p.asm $
  20. ; Revision 1.4  1994/11/30  00:56:40  mike
  21. ; optimization.
  22. ; 
  23. ; Revision 1.3  1994/11/12  16:39:32  mike
  24. ; jae to ja.
  25. ; 
  26. ; Revision 1.2  1993/11/22  10:24:43  mike
  27. ; *** empty log message ***
  28. ; 
  29. ; Revision 1.1  1993/09/08  17:29:21  mike
  30. ; Initial revision
  31. ; 
  32. ;
  33. ;
  34.  
  35.     .386
  36.  
  37.     include    tmap_inc.asm
  38.  
  39.     public    asm_tmap_scanline_per_16_
  40.  
  41. _DATA    SEGMENT DWORD PUBLIC USE32 'DATA'
  42.     extrn    _fx_u:dword
  43.     extrn    _fx_v:dword
  44.     extrn    _fx_z:dword
  45.     extrn    _fx_du_dx:dword
  46.     extrn    _fx_dv_dx:dword
  47.     extrn    _fx_dz_dx:dword
  48.     extrn    _fx_y:dword
  49.     extrn    _fx_xleft:dword
  50.     extrn    _fx_xright:dword
  51.  
  52.     extrn    _pixptr:dword
  53.  
  54.     extrn    _x:dword
  55.     extrn    _loop_count:dword
  56.  
  57. temp    dd    ?
  58.  
  59. _DATA    ENDS
  60.  
  61. DGROUP    GROUP    _DATA
  62.  
  63.  
  64. _TEXT   SEGMENT PARA PUBLIC USE32 'CODE'
  65.     ASSUME    DS:_DATA
  66.     ASSUME    CS:_TEXT
  67.  
  68. ; --------------------------------------------------------------------------------------------------
  69. ; Enter:
  70. ;    _xleft    fixed point left x coordinate
  71. ;    _xright    fixed point right x coordinate
  72. ;    _y    fixed point y coordinate
  73. ;    _pixptr    address of source pixel map
  74. ;    _u    fixed point initial u coordinate
  75. ;    _v    fixed point initial v coordinate
  76. ;    _z    fixed point initial z coordinate
  77. ;    _du_dx    fixed point du/dx
  78. ;    _dv_dx    fixed point dv/dx
  79. ;    _dz_dx    fixed point dz/dx
  80.  
  81. ;   for (x = (int) xleft; x <= (int) xright; x++) {
  82. ;      _setcolor(read_pixel_from_tmap(srcb,((int) (u/z)) & 63,((int) (v/z)) & 63));
  83. ;      _setpixel(x,y);
  84. ;
  85. ;      u += du_dx;
  86. ;      v += dv_dx;
  87. ;      z += dz_dx;
  88. ;   }
  89.  
  90. asm_tmap_scanline_per_16_:
  91.     pusha
  92.  
  93. ; Setup for loop:    _loop_count  iterations = (int) xright - (int) xleft
  94. ;    esi    source pixel pointer = pixptr
  95. ;    edi    initial row pointer = y*320+x
  96.  
  97. ; set esi = pointer to start of texture map data
  98.     mov    esi,_pixptr
  99.  
  100. ; set edi = address of first pixel to modify
  101.     mov    edi,_fx_y
  102.  
  103.     cmp    edi,_window_bottom
  104.     ja    _none_to_do
  105.  
  106.     sub    edi,_window_top
  107.     imul    edi,_bytes_per_row
  108.     mov    eax,_fx_xleft
  109.     sar    eax,16
  110.     jns    eax_ok
  111.     sub    eax,eax
  112. eax_ok:
  113.     sub    eax,_window_left
  114.     add    edi,eax
  115.     add    edi,eax
  116.     add    edi,write_buffer
  117.  
  118. ; set _loop_count = # of iterations
  119.     mov    eax,_fx_xright
  120.     sar    eax,16
  121.     cmp    eax,_window_right
  122.     jb    eax_ok1
  123.     mov    eax,_window_right
  124. eax_ok1:    cmp    eax,_window_left
  125.     ja    eax_ok2
  126.     mov    eax,_window_left
  127. eax_ok2:
  128.  
  129.     mov    ebx,_fx_xleft
  130.     sar    ebx,16
  131.     sub    eax,ebx
  132.     js    _none_to_do
  133.     cmp    eax,_window_width
  134.     jbe    _ok_to_do
  135.     mov    eax,_window_width
  136. _ok_to_do:
  137. ;** dec eax ; don't write rightmost pixel
  138. ;** js _none_to_do
  139.     mov    _loop_count,eax
  140.  
  141. ; set initial values
  142.     mov    ebx,_fx_u
  143.     mov    ebp,_fx_v
  144.     mov    ecx,_fx_z
  145.  
  146. ; Usage in loop:    eax    division, pixel value
  147. ;    ebx    u
  148. ;    ecx    z
  149. ;    edx    division
  150. ;    ebp    v
  151. ;    esi    source pixel pointer
  152. ;    edi    destination pixel pointer
  153.  
  154.     align    4
  155. tmap_loop:
  156. ; cmp ecx,_max_ecx
  157. ; jl nonewmax
  158. ; mov _max_ecx,ecx
  159. ;nonewmax:
  160. ; cmp ecx,_min_ecx
  161. ; ja nonewmin
  162. ; mov _min_ecx,ecx
  163. ;nonewmin:
  164.  
  165. ;** cmp ecx,0
  166. ;** jle skip 
  167.  
  168. ; compute u coordinate
  169.     mov    eax,ebx    ; get u
  170.     cdq
  171.     idiv    ecx    ; eax = (u/z)
  172.     and    eax,3fh    ; mask with width-1
  173.     mov    temp,eax
  174.  
  175. ; compute v coordinate
  176.     mov    eax,ebp    ; get v
  177.     cdq
  178.     idiv    ecx    ; eax = (v/z)
  179.     and    eax,3fh    ; mask with height-1
  180.     shl    eax,6    ; multiply by 64 (bitmap width)
  181.     add    eax,temp
  182.  
  183. ; read/write pixel
  184.     mov    ax,[esi+2*eax]    ; get pixel from source bitmap
  185.  
  186. ; update deltas
  187.     mov    [edi],ax
  188.     add    edi,2
  189.  
  190. skip:    add    ebp,_fx_dv_dx
  191.     add    ebx,_fx_du_dx
  192.     add    ecx,_fx_dz_dx
  193.  
  194.     dec    _loop_count
  195.     jns    tmap_loop
  196.  
  197. _none_to_do:    popa
  198.  
  199.     ret
  200.  
  201. _TEXT    ends
  202.  
  203.     end
  204.  
  205.