home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / texmap / tmap_aa.asm < prev    next >
Assembly Source File  |  1998-06-08  |  14KB  |  690 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/texmap/rcs/tmap_per.asm $
  13. ; $Revision: 1.8 $
  14. ; $Author: mike $
  15. ; $Date: 1993/12/16 18:37:52 $
  16. ;
  17. ; Perspective texture mapper inner loop.
  18. ;
  19. ; $Log: tmap_per.asm $
  20. ; Revision 1.8  1993/12/16  18:37:52  mike
  21. ; Align some stuff on 4 byte boundaries.
  22. ; 
  23. ; Revision 1.7  1993/11/30  08:44:18  john
  24. ; Made selector set check for < 64*64 bitmaps.
  25. ; 
  26. ; Revision 1.6  1993/11/23  17:25:26  john
  27. ; Added safety "and eax, 0fffh" in lighting lookup.
  28. ; 
  29. ; Revision 1.5  1993/11/23  15:08:52  mike
  30. ; Fixed lighting bug. 
  31. ; 
  32. ; Revision 1.4  1993/11/23  14:38:50  john
  33. ; optimized NORMAL code by switching EBX and ESI, so BH can be used in
  34. ; the lighting process.
  35. ; 
  36. ; Revision 1.3  1993/11/23  14:30:53  john
  37. ; Made the perspective tmapper do 1/8 divides; added lighting.
  38. ; 
  39. ; Revision 1.2  1993/11/22  10:24:59  mike
  40. ; *** empty log message ***
  41. ; 
  42. ; Revision 1.1  1993/09/08  17:29:53  mike
  43. ; Initial revision
  44. ; 
  45. ;
  46. ;
  47.  
  48.     .386
  49.  
  50.     public    _fx_u,_fx_v,_fx_z,_fx_du_dx,_fx_dv_dx,_fx_dz_dx,_fx_y,_fx_xleft,_fx_xright
  51.     public    _pixptr
  52.     public    asm_tmap_scanline_per_
  53. ;**    public    copy_canvas_to_a000_,clear_canvas_
  54.  
  55.     include    tmap_inc.asm
  56.  
  57. ;**    public    _v_window_left,_v_window_right,_v_window_top,_v_window_bottom
  58.  
  59.  public _max_ecx,_min_ecx
  60.  
  61.     extern    _fx_l:dword
  62.     extern     _fx_dl_dx:dword
  63.     extern    _dither_intensity_lighting:dword
  64.     extern _Lighting_on:dword
  65.  
  66. _DATA    SEGMENT DWORD PUBLIC USE32 'DATA'
  67.     align    4
  68. ;**_v_window_left    dd    _window_left
  69. ;**_v_window_right    dd    _window_right
  70. ;**_v_window_top    dd    _window_top
  71. ;**_v_window_bottom    dd    _window_bottom
  72.  
  73. ; ---------- These are passed in by the C caller ----------
  74. _fx_u    dd    ?    
  75. _fx_v    dd    ?
  76. _fx_z    dd    ?
  77. _fx_du_dx    dd    ?
  78. _fx_dv_dx    dd    ?
  79. _fx_dz_dx    dd    ?
  80.  
  81. _fx_y    dd    ?
  82. _fx_xleft    dd    ?
  83. _fx_xright    dd    ?
  84.  
  85. _pixptr    dd    ?
  86. ; ----------^^ These are passed in by the C caller ^^----------
  87.  
  88.     public    _x,_loop_count
  89.     align    4
  90. _x    dd    ?
  91. _loop_count    dd    ?
  92. ;**temp    dd    ?
  93.  
  94. _max_ecx    dd    0
  95. _min_ecx    dd    55555555h
  96.  
  97.     public    _per2_flag
  98. _per2_flag    dd    1
  99.  
  100.     public    _tmap_aliasing
  101.  
  102. _tmap_aliasing    dd 0
  103.  
  104. ;---------- local variables
  105.     align    4
  106. req_base    dd ?
  107. req_size    dd ?
  108. U0        dd ?
  109. U1        dd ?
  110. V0        dd ?
  111. V1        dd ?
  112. temp        dd ?
  113. num_left_over    dd ?
  114. DU1        dd ?
  115. DV1        dd ?
  116. DZ1        dd ?
  117. _fx_dl_dx1    dd ?
  118. _fx_dl_dx2    dd ?
  119.  
  120. initialized    db 10 dup (?)
  121. selector    dw 10 dup (?)
  122.  
  123. _DATA    ENDS
  124.  
  125. DGROUP    GROUP    _DATA
  126.  
  127.  
  128. _TEXT   SEGMENT DWORD PUBLIC USE32 'CODE'
  129.     ASSUME    DS:_DATA
  130.     ASSUME    CS:_TEXT
  131.  
  132. ; --------------------------------------------------------------------------------------------------
  133. ; Enter:
  134. ;    _xleft    fixed point left x coordinate
  135. ;    _xright    fixed point right x coordinate
  136. ;    _y    fixed point y coordinate
  137. ;    _pixptr    address of source pixel map
  138. ;    _u    fixed point initial u coordinate
  139. ;    _v    fixed point initial v coordinate
  140. ;    _z    fixed point initial z coordinate
  141. ;    _du_dx    fixed point du/dx
  142. ;    _dv_dx    fixed point dv/dx
  143. ;    _dz_dx    fixed point dz/dx
  144.  
  145. ;   for (x = (int) xleft; x <= (int) xright; x++) {
  146. ;      _setcolor(read_pixel_from_tmap(srcb,((int) (u/z)) & 63,((int) (v/z)) & 63));
  147. ;      _setpixel(x,y);
  148. ;
  149. ;      u += du_dx;
  150. ;      v += dv_dx;
  151. ;      z += dz_dx;
  152. ;   }
  153.  
  154.  
  155. TMAP_NORMAL MACRO
  156.     LOCAL NoLight1
  157.  
  158.     xchg    ebx, esi
  159.  
  160.     ; compute v coordinate
  161.     mov    eax,ebp    ; get v
  162.     cdq
  163.     idiv    ecx    ; eax = (v/z)
  164.  
  165.     and    eax,3fh    ; mask with height-1
  166.     mov    ebx,eax
  167.  
  168.     ; compute u coordinate
  169.     mov    eax,esi    ; get u
  170.     cdq
  171.     idiv    ecx    ; eax = (u/z)
  172.  
  173.     shl     eax,26
  174.     shld     ebx,eax,6        ; esi = v*64+u
  175.  
  176.     ; read 1  pixel
  177.     mov    al,es:[ebx]    ; get pixel from source bitmap
  178.  
  179.     cmp    _Lighting_on, 0
  180.     je    NoLight1
  181.     ;LIGHTING CODE
  182.     mov    ebx, _fx_l    ; get temp copy of lighting value
  183.     mov    ah, bh        ; get lighting level
  184.     add    ebx, _fx_dl_dx1    ; update lighting value
  185.     and    eax, 0fffh    ; make sure no garbage in EAX
  186.     mov    al, fs:[eax]    ; xlat pixel thru lighting tables
  187.     mov    _fx_l, ebx    ; save temp copy of lighting value
  188.                     
  189.     ;DITHERING CODE
  190.     mov     ebx, _fx_dl_dx1
  191.     xchg    ebx, _fx_dl_dx2
  192.     mov    _fx_dl_dx1, ebx
  193. NoLight1:
  194.     
  195.     cmp    _tmap_aliasing, 0
  196.     je    @f
  197.     ;ANTI-ALIASING CODE
  198.     mov    bl, [edi-320]     ; pixel above
  199.     mov    bh, [edi-1]    ; pixel to left
  200.     and    ebx, 0ffffh
  201.     mov    ah, gs:[ebx]    ; average those two
  202.     and    eax, 0ffffh
  203.     mov    al, gs:[eax]    ; average with current
  204. @@:    
  205.     ; write 1 pixel
  206.     mov    [edi],al
  207.     inc    edi
  208.     
  209.     ; update deltas
  210.     add    ebp,_fx_dv_dx
  211.     add    esi,_fx_du_dx
  212.     add    ecx,_fx_dz_dx
  213.  
  214.     xchg    esi, ebx
  215. ENDM
  216.  
  217. asm_tmap_scanline_per_:
  218.     push    es
  219.     push    fs
  220.     push    gs
  221.     pusha
  222.     
  223. ;---------------------------- setup for loop ---------------------------------
  224. ; Setup for loop:    _loop_count  iterations = (int) xright - (int) xleft
  225. ;    esi    source pixel pointer = pixptr
  226. ;    edi    initial row pointer = y*320+x
  227.  
  228. ; set esi = pointer to start of texture map data
  229. ;**    mov    esi,_pixptr
  230.     mov    es,selector[0*2]
  231.     mov    fs,selector[1*2]    ; fs = bmd_fade_table
  232.     mov    gs,selector[2*2]      ; gs = bmd_blend_table
  233.     cmp    _tmap_aliasing, 0
  234.     jne    @f
  235.     mov    gs,selector[1*2]      ; gs = bmd_fade_table
  236.     @@:    
  237.  
  238.  
  239. ; set edi = address of first pixel to modify
  240.     mov    edi,_fx_y
  241.     cmp    edi,_window_bottom
  242.     jae    _none_to_do
  243.  
  244.     imul    edi,_bytes_per_row
  245.     mov    eax,_fx_xleft
  246.     sar    eax,16
  247.     jns    eax_ok
  248.     sub    eax,eax
  249. eax_ok:
  250.     add    edi,eax
  251.     add    edi,write_buffer
  252.  
  253. ; set _loop_count = # of iterations
  254.     mov    eax,_fx_xright
  255.     sar    eax,16
  256.     cmp    eax,_window_right
  257.     jb    eax_ok1
  258.     mov    eax,_window_right
  259. eax_ok1:    cmp    eax,_window_left
  260.     ja    eax_ok2
  261.     mov    eax,_window_left
  262. eax_ok2:
  263.  
  264.     mov    ebx,_fx_xleft
  265.     sar    ebx,16
  266.     sub    eax,ebx
  267.     js    _none_to_do
  268.     cmp    eax,_window_width
  269.     jbe    _ok_to_do
  270.     mov    eax,_window_width
  271. _ok_to_do:
  272.     mov    _loop_count,eax
  273.  
  274. ;-------------------------- setup for dithering -----------------------------
  275. ; lighting values are passed in fixed point, but need to be in 8 bit integer, 8 bit fraction so we can easily
  276. ; get the integer by reading %bh
  277.     sar    _fx_l, 8
  278.     sar    _fx_dl_dx,8
  279.     jns    dl_dx_ok
  280.     inc    _fx_dl_dx    ; round towards 0 for negative deltas
  281. dl_dx_ok:
  282.  
  283. ; do dithering, use lighting values which are .5 less than and .5 more than actual value
  284.     mov    ebx,80h    ; assume dithering on
  285.     test    _dither_intensity_lighting,-1
  286.     jne    do_dither
  287.     sub    ebx,ebx    ; no dithering
  288. do_dither:
  289.     mov    eax,_fx_dl_dx
  290.     add    eax,ebx    ; add 1/2
  291.     mov    _fx_dl_dx1,eax
  292.     sub    eax,ebx
  293.     sub    eax,ebx
  294.     mov    _fx_dl_dx2,eax
  295.     mov    ebx,_fx_xleft
  296.     shr    ebx,16
  297.     xor    ebx,_fx_y
  298.     and    ebx,1
  299.     jne    dith_1
  300.     xchg    eax,_fx_dl_dx1
  301. dith_1:    mov    _fx_dl_dx2,eax
  302.  
  303.  
  304. ; set initial values
  305.     mov    ebx,_fx_u
  306.     mov    ebp,_fx_v
  307.     mov    ecx,_fx_z
  308.  
  309.     test _per2_flag,-1
  310.     je   tmap_loop
  311.  
  312.     jmp    tmap_loop_fast
  313.  
  314. ;================ PERSPECTIVE TEXTURE MAP INNER LOOPS ========================
  315. ;
  316. ; Usage in loop:    eax    division, pixel value
  317. ;    ebx    u
  318. ;    ecx    z
  319. ;    edx    division
  320. ;    ebp    v
  321. ;    esi    source pixel pointer
  322. ;    edi    destination pixel pointer
  323.  
  324. ;-------------------- NORMAL PERSPECTIVE TEXTURE MAP LOOP -----------------
  325.     align    4
  326. tmap_loop:
  327.     TMAP_NORMAL
  328.     dec    _loop_count
  329.     jns    tmap_loop
  330.  
  331. _none_to_do:    
  332.     popa
  333.     pop    gs
  334.     pop    fs
  335.     pop    es
  336.     ret
  337.  
  338. ;-------------------------- PER/4 TMAPPER ----------------
  339. ; 
  340. ;    x = x1
  341. ;    U0 = u/w; V0 = v/w;
  342. ;    while ( 1 )
  343. ;        u += du_dx*4; v+= dv_dx*4
  344. ;        U1 = u/w; V1 = v/w;
  345. ;        DUDX = (U1-U0)/4; DVDX = (V1-V0)/4;
  346. ;
  347. ;        ; Pixel 0
  348. ;        pixels = texmap[V0*64+U0];
  349. ;        U0 += DUDX; V0 += DVDX
  350. ;        ; Pixel 1
  351. ;        pixels = (pixels<<8)+texmap[V0*64+U0];
  352. ;        U0 += DUDX; V0 += DVDX
  353. ;        ; Pixel 2
  354. ;        pixels = (pixels<<8)+texmap[V0*64+U0];
  355. ;        U0 += DUDX; V0 += DVDX
  356. ;        ; Pixel 3
  357. ;        pixels = (pixels<<8)+texmap[V0*64+U0];
  358. ;
  359. ;        screen[x] = pixel
  360. ;        x += 4;
  361. ;        U0 = U1; V0 = V1 
  362.  
  363. NBITS = 3
  364. ZSHIFT = 3
  365.  
  366.  
  367. PDIV MACRO
  368.     ; Returns EAX/ECX in 16.16 format in EAX. Trashes EDX
  369.     ;          sig bits   6.3
  370.     cdq
  371.     shld    edx,eax, ZSHIFT
  372.     shl    eax, ZSHIFT
  373.     idiv    ecx    ; eax = (v/z)
  374.     shl    eax, 16-ZSHIFT
  375. ENDM
  376.  
  377. public tmap_loop_fast
  378. tmap_loop_fast:
  379.  
  380. NotDwordAligned1:
  381.     test    edi, 11b
  382.     jz    DwordAligned1
  383.     TMAP_NORMAL
  384.     dec    _loop_count
  385.     jns    NotDwordAligned1
  386.     jmp    _none_to_do
  387.  
  388. DwordAligned1:
  389.     mov    eax, _loop_count
  390.     inc    eax
  391.     mov    num_left_over, eax
  392.     shr    eax, NBITS
  393.  
  394.     cmp    eax, 0        
  395.     je    tmap_loop
  396.     
  397.     mov     _loop_count, eax    ; _loop_count = pixels / NPIXS
  398.     shl    eax, NBITS
  399.     sub    num_left_over, eax    ; num_left_over = obvious
  400.         
  401.     ; compute initial v coordinate
  402.     mov    eax,ebp    ; get v
  403.     PDIV
  404.     mov    V0, eax
  405.  
  406.     ; compute initial u coordinate
  407.     mov    eax,ebx    ; get u
  408.     PDIV    
  409.     mov    U0, eax
  410.  
  411.     ; Set deltas to NPIXS pixel increments
  412.     mov    eax, _fx_du_dx
  413.     shl    eax, NBITS
  414.     mov    DU1, eax
  415.     mov    eax, _fx_dv_dx
  416.     shl    eax, NBITS
  417.     mov    DV1, eax
  418.     mov    eax, _fx_dz_dx
  419.     shl    eax, NBITS
  420.     mov    DZ1, eax
  421.     
  422. TopOfLoop4:
  423.         add    ebx, DU1
  424.         add    ebp, DV1
  425.         add    ecx, DZ1
  426.  
  427.         ; Done with ebx, ebp, ecx until next iteration
  428.         push    ebx
  429.         push    ecx
  430.         push    ebp
  431.         push    edi
  432.     
  433.         ; Find fixed U1        
  434.         mov    eax, ebx
  435.         PDIV
  436.         mov    ebx, eax    ; ebx = U1 until pop's
  437.  
  438.         ; Find fixed V1        
  439.         mov    eax, ebp
  440.         PDIV
  441.         mov    ebp, eax    ; ebp = V1 until pop's
  442.  
  443.         mov    ecx, U0        ; ecx = U0 until pop's
  444.         mov    edi, V0        ; edi = V0 until pop's
  445.  
  446.         ; Make ESI =  V0:U0 in 6:10,6:10 format
  447.         mov    eax, ecx
  448.         shr    eax, 6
  449.         mov    esi, edi
  450.         shl    esi, 10
  451.         mov    si, ax
  452.         
  453.         ; Make EDX = DV:DU in 6:10,6:10 format
  454.         mov    eax, ebx
  455.         sub    eax, ecx
  456.         ;**sar    eax, NBITS      ; EAX = U1-U0 / 2^NBITS
  457.         ;**shr    eax, 6        ; put 6:10 int:frac into low word
  458.         sar    eax, NBITS+6
  459.         mov    edx, ebp
  460.         sub    edx, edi
  461.         ;**sar    edx, NBITS        ; EDX = V1-V0 / 4
  462.         ;**shl    edx, 10        ; put 6:10 int:frac into low word
  463.         shl    edx, 10-NBITS
  464.         mov    dx, ax        ; put delta u in low word
  465.  
  466.         ; Save the U1 and V1 so we don't have to divide on the
  467.         ; next iteration
  468.         mov    U0, ebx
  469.         mov    V0, ebp
  470.  
  471.         pop    edi        ; Restore EDI before using it
  472.         
  473.         cmp    _Lighting_on, 0
  474.         je    NoLight
  475.                 
  476.         ;LIGHTING CODE
  477.         mov    ebx, _fx_l
  478.         mov    ebp, _fx_dl_dx1
  479.  
  480.         mov    cl, [edi-1]
  481.                         
  482.         REPT (1 SHL (NBITS-2))
  483.             ITERATION = 0
  484.             REPT 2
  485.                 ; Do even pixel
  486.                 mov    eax, esi    ; get u,v
  487.                 shr    eax, 26        ; shift out all but int(v)
  488.                 shld    ax,si,6        ; shift in u, shifting up v
  489.                 add    esi, edx    ; inc u,v
  490.  
  491.                 ;LIGHTING CODE
  492.                 mov     al, es:[eax]    ; get pixel
  493.                 mov    ah, bh        ; get lighting table
  494.                 ;SAFETY CHECK
  495.                 and    eax, 0fffh
  496.                 add    ebx, ebp    ; update lighting value
  497.  
  498.                 ;ANTI-ALIASING CODE
  499.                 cmp    _tmap_aliasing, 0
  500.                 je    @f
  501.                 mov    ch, fs:[eax]
  502.                 mov    al, [edi-(320+ITERATION)]     ; pixel above
  503.                 mov    ah, cl         ; pixel to left
  504.                 ;**and    eax, 0ffffh
  505.                 mov    al, gs:[eax]    ; average those two
  506.                 mov    ah, ch
  507.                 @@:                
  508.                 
  509.                 ror    ecx, 8
  510.                 mov    cl, gs:[eax]    ; average with current
  511.  
  512.                 ITERATION = ITERATION + 1
  513.                 ; Do odd pixel
  514.                 mov    eax, esi    ; get u,v
  515.                 shr    eax, 26        ; shift out all but int(v)
  516.                 shld    ax,si,6        ; shift in u, shifting up v
  517.                 add    esi, edx    ; inc u,v
  518.  
  519.                 ;LIGHTING CODE
  520.                 mov     al, es:[eax]    ; get pixel
  521.                 mov    ah, bh        ; get lighting table
  522.                 ;SAFETY CHECK
  523.                 and    eax, 0fffh
  524.                 add    ebx, _fx_dl_dx2    ; update lighting value
  525.  
  526.                 ;ANTI-ALIASING CODE
  527.                 cmp    _tmap_aliasing, 0
  528.                 je    @f
  529.                 mov    ch, fs:[eax]
  530.                 mov    al, [edi-(320+ITERATION)]     ; pixel above
  531.                 mov    ah, cl         ; pixel to left
  532.                 ;**and    eax, 0ffffh
  533.                 mov    al, gs:[eax]    ; average those two
  534.                 mov    ah, ch
  535.                 @@:                
  536.                 
  537.                 ror    ecx, 8
  538.                 mov    cl, gs:[eax]    ; average with current
  539.  
  540.                 ITERATION = ITERATION + 1
  541.  
  542.  
  543.             ENDM
  544.                     
  545.             ror ecx, 8
  546.             mov [edi],ecx        ; Draw 4 pixels to display
  547.             rol ecx, 8    ; for aliasing
  548.             add edi,4
  549.         ENDM
  550.  
  551.         ;LIGHTING CODE
  552.         mov    _fx_l, ebx
  553.         pop    ebp
  554.         pop    ecx
  555.         pop    ebx
  556.         dec    _loop_count
  557.         jnz    TopOfLoop4
  558.         jmp    EndOfLoop4
  559.  
  560. NoLight:    
  561.         mov    cl, [edi-1]
  562.  
  563.         REPT (1 SHL (NBITS-2))
  564.             ITERATION = 0
  565.             REPT 4    
  566.                 LOCAL NoAA    
  567.                 LOCAL AA
  568.                 ; Do 1 pixel 
  569.                 mov    eax, esi    ; get u,v
  570.                 shr    eax, 26        ; shift out all but int(v)
  571.                 shld    ax,si,6        ; shift in u, shifting up v
  572.                 add    esi, edx    ; inc u,v
  573.  
  574.                 ;ANTI-ALIASING CODE
  575.                 cmp    _tmap_aliasing, 0
  576.                 je    NoAA
  577.                 mov    ch, es:[eax]
  578.                 mov    al, [edi-(320+ITERATION)]     ; pixel above
  579.                 mov    ah, cl         ; pixel to left
  580.                 mov    al, gs:[eax]    ; average those two
  581.                 mov    ah, ch
  582.                 ror    ecx, 8
  583.                 mov    cl, gs:[eax]    ; average with current
  584.                 jmp    AA        
  585.  
  586. NoAA:                ror    ecx, 8
  587.                 mov    cl, es:[eax]    ; average with current
  588.  
  589. AA:                    
  590.                 ITERATION = ITERATION + 1
  591.             ENDM
  592.                     
  593.             ror    ecx, 8
  594.             mov     [edi],ecx        ; Draw 4 pixels to display
  595.             rol    ecx, 8
  596.             add     edi,4
  597.         ENDM
  598.  
  599.         pop    ebp
  600.         pop    ecx
  601.         pop    ebx
  602.         dec    _loop_count
  603.         jnz    TopOfLoop4
  604. EndOfLoop4:
  605.  
  606.     cmp    num_left_over, 0
  607.     je    _none_to_do
  608.  
  609. DoEndPixels:
  610.     TMAP_NORMAL
  611.     dec    num_left_over
  612.     jnz    DoEndPixels
  613.     jmp    _none_to_do
  614.     
  615.  
  616. PUBLIC     tmap_set_selector_
  617.  
  618.     ; EAX = Selector number    
  619.     ; EDX = 32-bit base address #1
  620.     ; EBX = Size in bytes #1
  621.  
  622.     ; Returns:  EAX = 0 if ok, otherwise, EAX = non-zero (1)
  623.  
  624.     ; Uses variables: initialized    db 10 dup (?)
  625.     ;                 selector    dw 10 dup (?) 
  626.     ;          req_base    dd ?
  627.     ;          req_size    dd ?
  628.         
  629. tmap_set_selector_:
  630.  
  631.     pusha
  632.     
  633.     mov    esi, eax
  634.     
  635.     mov    req_base, edx
  636.     mov    req_size, ebx
  637.  
  638.     cmp    req_size, 64*64
  639.     jge    @f
  640.  
  641.     ;Too small of a texture map!!! (Not 64x64)
  642.     int    3
  643.  
  644. @@:    cmp     initialized[esi], 1
  645.     je    already_initialized
  646.     mov    initialized[esi], 1
  647.  
  648.     ; Allocate a selector using DPMI
  649.     mov    eax, 0
  650.     mov    ecx, 1
  651.     int    31h
  652.     jc    failed
  653.     mov    selector[esi*2], ax
  654.  
  655.  
  656. already_initialized:    
  657.  
  658.     ; Set the selector's base address using DPMI
  659.     mov    eax, 7
  660.     mov    bx, selector[esi*2]
  661.     mov    ecx, req_base
  662.     mov    edx, ecx
  663.     shr    ecx, 16
  664.     int    31h
  665.     jc     failed
  666.  
  667.     ; Set the selector's size using DPMI
  668.     mov    ax, 08h
  669.     mov    bx, selector[esi*2]
  670.     mov    ecx, req_size
  671.     mov    edx, ecx
  672.     shr    ecx, 16
  673.     int    31h
  674.     jc    failed
  675.  
  676.     popa
  677.     mov    eax, 0
  678.     ret
  679. failed:
  680.     popa
  681.     mov    eax, 1
  682.     ret
  683.  
  684.  
  685.  
  686. _TEXT    ends
  687.  
  688.     end
  689.  
  690.