home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / texmap / tmap_16l.asm < prev    next >
Assembly Source File  |  1998-06-08  |  8KB  |  305 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/texmap/rcs/tmap_16l.asm $
  13. ; $Revision: 1.4 $
  14. ; $Author: mike $
  15. ; $Date: 1994/11/30 00:56:39 $
  16. ;
  17. ; inner loop of 16 bit per pixel lighted texture mapper
  18. ;
  19. ; $Log: tmap_16l.asm $
  20. ; Revision 1.4  1994/11/30  00:56:39  mike
  21. ; optimization.
  22. ; 
  23. ; Revision 1.3  1994/11/12  16:39:31  mike
  24. ; jae to ja.
  25. ; 
  26. ; Revision 1.2  1993/11/22  10:24:32  mike
  27. ; *** empty log message ***
  28. ; 
  29. ; Revision 1.1  1993/09/08  17:29:20  mike
  30. ; Initial revision
  31. ; 
  32. ;
  33. ;
  34.  
  35.  
  36.     .386
  37.  
  38.     public    asm_tmap_scanline_lin_16l_
  39.  
  40.     include    tmap_inc.asm
  41.  
  42. _DATA    SEGMENT DWORD PUBLIC USE32 'DATA'
  43.  
  44.     extrn    _fx_u:dword
  45.     extrn    _fx_v:dword
  46.     extrn    _fx_du_dx:dword
  47.     extrn    _fx_dv_dx:dword
  48.     extrn    _fx_y:dword
  49.     extrn    _fx_xleft:dword
  50.     extrn    _fx_xright:dword
  51.  
  52.     extrn    _pixptr:dword
  53.  
  54.     extrn    _x:dword
  55.     extrn    _loop_count:dword
  56.  
  57.     extrn    _fx_rgb:dword
  58.     extrn    _fx_drgb_dx:dword
  59.  
  60.     extrn    _fx_r:dword
  61.     extrn    _fx_g:dword
  62.     extrn    _fx_b:dword
  63.  
  64.     extrn    _fx_dr_dx:dword
  65.     extrn    _fx_dg_dx:dword
  66.     extrn    _fx_db_dx:dword
  67.  
  68. _DATA    ENDS
  69.  
  70. DGROUP    GROUP    _DATA
  71.  
  72. _TEXT   SEGMENT PARA PUBLIC USE32 'CODE'
  73.  
  74.     ASSUME    DS:_DATA
  75.     ASSUME    CS:_TEXT
  76.  
  77. ; --------------------------------------------------------------------------------------------------
  78. ; Enter:
  79. ;    _xleft    fixed point left x coordinate
  80. ;    _xright    fixed point right x coordinate
  81. ;    _y    fixed point y coordinate
  82. ;    _pixptr    address of source pixel map
  83. ;    _u    fixed point initial u coordinate
  84. ;    _v    fixed point initial v coordinate
  85. ;    _du_dx    fixed point du/dx
  86. ;    _dv_dx    fixed point dv/dx
  87.  
  88. ;   for (x = (int) xleft; x <= (int) xright; x++) {
  89. ;      _setcolor(read_pixel_from_tmap(srcb,((int) (u/z)) & 63,((int) (v/z)) & 63));
  90. ;      _setpixel(x,y);
  91. ;
  92. ;      u += du_dx;
  93. ;      v += dv_dx;
  94. ;      z += dz_dx;
  95. ;   }
  96.  
  97.     align    4
  98. asm_tmap_scanline_lin_rgb_:
  99.     pusha
  100.  
  101. ; Setup for loop:    _loop_count  iterations = (int) xright - (int) xleft
  102. ;    esi    source pixel pointer = pixptr
  103. ;    edi    initial row pointer = y*320+x
  104.  
  105. ; set esi = pointer to start of texture map data
  106.     mov    esi,_pixptr
  107.  
  108. ; set edi = address of first pixel to modify
  109.     mov    edi,_fx_y
  110.  
  111.     cmp    edi,_window_bottom
  112.     ja    _none_to_do
  113.     sub    edi,_window_top
  114.  
  115.     imul    edi,_bytes_per_row
  116.     mov    eax,_fx_xleft
  117.     sar    eax,16
  118.     jns    eax_ok
  119.     sub    eax,eax
  120. eax_ok:
  121.     sub    eax,_window_left
  122.     add    edi,eax
  123.     add    edi,eax
  124.     add    edi,write_buffer
  125.  
  126. ; set _loop_count = # of iterations
  127.     mov    eax,_fx_xright
  128.     sar    eax,16
  129.     cmp    eax,_window_right
  130.     jb    eax_ok1
  131.     mov    eax,_window_right
  132. eax_ok1:    cmp    eax,_window_left
  133.     ja    eax_ok2
  134.     mov    eax,_window_left
  135. eax_ok2:
  136.  
  137.     mov    ebx,_fx_xleft
  138.     sar    ebx,16
  139.     sub    eax,ebx
  140.     js    _none_to_do
  141.     cmp    eax,_window_width
  142.     jbe    _ok_to_do
  143.     mov    eax,_window_width
  144. _ok_to_do:
  145.     mov    _loop_count,eax
  146.  
  147. ;    edi    destination pixel pointer
  148.  
  149.     mov    ebx,_fx_u
  150.     mov    ebp,_fx_v
  151.  
  152.     shl    ebx,10
  153.     shl    ebp,10
  154.  
  155.     shl    _fx_du_dx,10
  156.     shl    _fx_dv_dx,10
  157.  
  158. ; rgb values are passed in the following peculiar, confidential, trade secreted, copyrighted, patented format:
  159. ; [ 5 bits ] [ 5 bits ] [ 5 bits ] [ 5 bits ] [ 2 bits ] [ 5 bits ] [ 5 bits ]
  160. ;   red int   red frac   blue int  blue frac    unused   green int  green frac
  161. ; The reason they are stored in the order red, blue, green is to optimize the process of packing together the three 5 bit
  162. ; values for red, green, blue in the conventional manner, suitable for an inverse table lookup
  163.  
  164. ; convert fixed point values in _fx_dr_dx, _fx_dg_dx, _fx_db_dx to _fx_drgb_dx
  165. ;** int 3
  166.     mov    eax,_fx_dg_dx    ; get green value
  167.     sar    eax,11    ; after shift, low order 10 bits are what we want
  168.     jns    dgok1
  169.     inc    eax
  170. dgok1:    shrd    ecx,eax,10    ; shift green 5i.5f into destination
  171.  
  172.     shr    ecx,2    ; shift in two don't care bits
  173.  
  174.     mov    eax,_fx_db_dx
  175.     sar    eax,11
  176.     jns    dbok1
  177.     inc    eax
  178. dbok1:    shrd    ecx,eax,10
  179.  
  180.     mov    eax,_fx_dr_dx
  181.     sar    eax,11
  182.     jns    drok1
  183.     inc    eax
  184. drok1:    shrd    ecx,eax,10    ; now %ecx is correct!
  185.     mov    _fx_drgb_dx,ecx
  186.  
  187. ; convert fixed point values in _fx_r, _fx_g, _fx_b to _fx_rgb (which is the above peculiar format)
  188.     mov    eax,_fx_g    ; get green value
  189.     sar    eax,11    ; after shift, low order 10 bits are what we want
  190.     jns    rok1
  191.     sub    eax,eax
  192. rok1:    shrd    ecx,eax,10    ; shift green 5i.5f into destination
  193.  
  194.     shr    ecx,2    ; shift in two don't care bits
  195.  
  196.     mov    eax,_fx_b
  197.     sar    eax,11
  198.     jns    bok1
  199.     sub    eax,eax
  200. bok1:    shrd    ecx,eax,10
  201.  
  202.     mov    eax,_fx_r
  203.     sar    eax,11
  204.     jns    gok1
  205.     sub    eax,eax
  206. gok1:    shrd    ecx,eax,10    ; now %ecx is correct!
  207.  
  208. ;**    mov    ecx,_fx_rgb
  209.  
  210.  
  211. _size = (_end1 - _start1)/(num_iters-1)
  212.     mov    eax,num_iters-1
  213.     sub    eax,_loop_count
  214.  jns itsok
  215.  int 3
  216. itsok:
  217.     imul    eax,eax,dword ptr _size
  218.     add    eax,offset _start1
  219. ;**    dec    edi    ; inc edi moved before write to separate instructions
  220.     jmp    eax
  221.  
  222.     align    4
  223. _start1:
  224.  
  225. ; usage:
  226. ;    eax    work
  227. ;    ebx    u coordinate
  228. ;    ecx    rgb (actually rbg, each i5.f5 with 2 bits between blue and green)
  229. ;    edx    work
  230. ;    ebp    v coordinate
  231. ;    esi    pointer to source bitmap
  232. ;    edi    write address
  233.  
  234. ; do all but the last pixel in the unwound loop, last pixel done separately because less work is needed
  235.   rept num_iters-1
  236. ; interpolate the rgb values
  237.     sub    eax,eax
  238.     mov    edx,ecx    ; note, these are in order red, blue, green
  239.     add    ecx,_fx_drgb_dx
  240.     and    edx,11111000001111100000001111100000b    ; preserve ri, bi, gi, strip out fractional portions and 2 extra bits
  241.     shld    eax,edx,15    ; shift in ri, bi
  242.     or    ax,dx    ; mask in gi
  243.  
  244. ; do the regular texture mapper linear interpolation to get the pixel from the source bitmap
  245.     sub    edx,edx
  246.     shld    edx,ebp,6    ; shift in v coordinate
  247.     add    ebp,_fx_dv_dx    ; update v coordinate
  248.     shld    edx,ebx,6    ; shift in u coordinate while shifting up v coordinate
  249.     add    ebx,_fx_du_dx    ; update u coordinate
  250.     mov    ax,[esi+2*edx]    ; get pixel from source bitmap
  251.  
  252. ; get color value based on looked up value from texture map (%al) and light value (%ah)
  253.     mov    al,_pixel_average[eax]    ; get color value based on palette light and color
  254.  
  255. ; write the pixel
  256.     mov    [edi],ax
  257.     add    edi,2
  258.  
  259.   endm
  260.  
  261. _end1:
  262.  
  263. ; now do the leftover pixel
  264.  
  265. ; interpolate the rgb values
  266.     sub    eax,eax
  267.     mov    edx,ecx    ; note, these are in order red, blue, green
  268.     and    edx,11111000001111100000001111100000b    ; preserve ri, bi, gi, strip out fractional portions and 2 extra bits
  269.     shld    eax,edx,15    ; shift in ri, bi
  270.     or    ax,dx    ; mask in gi
  271.  
  272.     mov    ah,_rgb_to_palette[eax]    ; get color value for 15 bit rgb value
  273.  
  274. ; do the regular texture mapper linear interpolation to get the pixel from the source bitmap
  275.     sub    edx,edx
  276.     shld    edx,ebp,6    ; shift in v coordinate
  277.     shld    edx,ebx,6    ; shift in u coordinate while shifting up v coordinate
  278.     mov    al,[esi+edx]    ; get pixel from source bitmap
  279.  
  280. ; get color value based on looked up value from texture map (%al) and light value (%ah)
  281.     mov    al,_pixel_average[eax]    ; get color value based on palette light and color
  282.  
  283. ; write the pixel
  284.     mov    [edi],al
  285.  
  286. _none_to_do:    popa
  287.  
  288.     ret
  289.  
  290. ; -- Code to get rgb 5 bits integer, 5 bits fraction value into 5 bits integer (for each gun)
  291. ; suitable for inverse color lookup
  292. ;**__test:
  293. ;** int 3
  294. ;**;                  rrrrrfffffrrrrrfffffxxbbbbbfffff
  295. ;**    mov    eax,11111001001010101110101101110111b
  296. ;**    and    eax,11111000001111100000001111100000b
  297. ;**    shld    ebx,eax,15
  298. ;**    or    bx,ax
  299.  
  300. _TEXT    ends
  301.  
  302.     end
  303.  
  304.  
  305.