home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / texmap / tmap_16g.asm < prev    next >
Assembly Source File  |  1998-06-08  |  5KB  |  215 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/texmap/rcs/tmap_16g.asm $
  13. ; $Revision: 1.4 $
  14. ; $Author: mike $
  15. ; $Date: 1994/11/30 00:56:37 $
  16. ;
  17. ; inner loop of rgb lighted linear texture mapper for 16 bits/pixel
  18. ;
  19. ; $Log: tmap_16g.asm $
  20. ; Revision 1.4  1994/11/30  00:56:37  mike
  21. ; optimization.
  22. ; 
  23. ; Revision 1.3  1994/11/12  16:39:23  mike
  24. ; jae to ja.
  25. ; 
  26. ; Revision 1.2  1993/11/22  10:24:28  mike
  27. ; *** empty log message ***
  28. ; 
  29. ; Revision 1.1  1993/09/08  17:29:17  mike
  30. ; Initial revision
  31. ; 
  32. ;
  33. ;
  34.  
  35.  
  36.     .386
  37.  
  38.     option    oldstructs
  39.  
  40.     .nolist
  41.     include    psmacros.inc
  42.     .list
  43.  
  44.     public    asm_tmap_scanline_lin_rgb_16g_
  45.  
  46.     include    tmap_inc.asm
  47.  
  48. _DATA    SEGMENT DWORD PUBLIC USE32 'DATA'
  49.  
  50.     extd    _fx_u
  51.     extd    _fx_v
  52.     extd    _fx_du_dx
  53.     extd    _fx_dv_dx
  54.     extd    _fx_y
  55.     extd    _fx_xleft
  56.     extd    _fx_xright
  57.  
  58.     extd    _pixptr
  59.  
  60.     extd    _x
  61.     extd    _loop_count
  62.  
  63.     extd    _fx_rgb,_fx_drgb_dx
  64.  
  65.     extd    _fx_r,_fx_g,_fx_b,_fx_dr_dx,_fx_dg_dx,_fx_db_dx
  66.  
  67.     align    4
  68.  
  69. _DATA    ENDS
  70.  
  71. DGROUP    GROUP    _DATA
  72.  
  73. _TEXT   SEGMENT PARA PUBLIC USE32 'CODE'
  74.  
  75.     ASSUME    DS:_DATA
  76.     ASSUME    CS:_TEXT
  77.  
  78. ; --------------------------------------------------------------------------------------------------
  79. ; Enter:
  80. ;    _xleft    fixed point left x coordinate
  81. ;    _xright    fixed point right x coordinate
  82. ;    _y    fixed point y coordinate
  83. ;    _pixptr    address of source pixel map
  84. ;    _u    fixed point initial u coordinate
  85. ;    _v    fixed point initial v coordinate
  86. ;    _du_dx    fixed point du/dx
  87. ;    _dv_dx    fixed point dv/dx
  88.  
  89. ;   for (x = (int) xleft; x <= (int) xright; x++) {
  90. ;      _setcolor(read_pixel_from_tmap(srcb,((int) (u/z)) & 63,((int) (v/z)) & 63));
  91. ;      _setpixel(x,y);
  92. ;
  93. ;      u += du_dx;
  94. ;      v += dv_dx;
  95. ;      z += dz_dx;
  96. ;   }
  97.  
  98.     align    4
  99. asm_tmap_scanline_lin_rgb_16g_:
  100.     pusha
  101.  
  102. ; Setup for loop:    _loop_count  iterations = (int) xright - (int) xleft
  103. ;    esi    source pixel pointer = pixptr
  104. ;    edi    initial row pointer = y*320+x
  105.  
  106. ; set esi = pointer to start of texture map data
  107.     mov    esi,_pixptr
  108.  
  109. ; set edi = address of first pixel to modify
  110.     mov    edi,_fx_y
  111.     cmp    edi,_window_bottom
  112.     ja    _none_to_do
  113.  
  114.     sub    edi,_window_top
  115.     imul    edi,_bytes_per_row
  116.     mov    eax,_fx_xleft
  117.     sar    eax,16
  118.     jns    eax_ok
  119.     sub    eax,eax
  120. eax_ok:
  121.     sub    eax,_window_left
  122.     add    edi,eax
  123.     add    edi,eax
  124.     add    edi,write_buffer
  125.  
  126. ; set _loop_count = # of iterations
  127.     mov    eax,_fx_xright
  128.     sar    eax,16
  129.     cmp    eax,_window_right
  130.     jb    eax_ok1
  131.     mov    eax,_window_right
  132. eax_ok1:    cmp    eax,_window_left
  133.     ja    eax_ok2
  134.     mov    eax,_window_left
  135. eax_ok2:
  136.  
  137.     mov    ebx,_fx_xleft
  138.     sar    ebx,16
  139.     sub    eax,ebx
  140.     js    _none_to_do
  141.     cmp    eax,_window_width
  142.     jbe    _ok_to_do
  143.     mov    eax,_window_width
  144. _ok_to_do:
  145.     mov    _loop_count,eax
  146.  
  147. ;    edi    destination pixel pointer
  148.  
  149. ; shift up all light values and deltas so that the highest 5 bits are the integer portion
  150.     shl    _fx_r,11
  151.     shl    _fx_g,11
  152.     shl    _fx_b,11
  153.  
  154.     shl    _fx_dr_dx,11
  155.     shl    _fx_dg_dx,11
  156.     shl    _fx_db_dx,11
  157.  
  158. ; ---------------------------------------------------------------------------------------------------------------------
  159.     mov    eax,_fx_g
  160.     mov    edx,_fx_b
  161.     mov    ebx,_fx_r
  162.     mov    ebp,_fx_dr_dx
  163.     mov    esi,_fx_dg_dx
  164.  
  165. ; register usage:
  166. ;  eax    _fx_g
  167. ;  ebx    _fx_r
  168. ;  ecx    work
  169. ;  edx    _fx_b
  170. ;  ebp    _fx_dr_dx
  171. ;  esi    _fx_dg_dx
  172. ;  edi    write address
  173.  
  174. ; do the regular texture mapper linear interpolation to get the pixel from the source bitmap
  175. _loop1:
  176.     mov    ecx,ebx    ; light value in high 5 bits
  177.     shr    ecx,27    ; shift out all but light value
  178.     shld    ecx,eax,5
  179.     shld    ecx,edx,5
  180.  
  181. ; now %ecx = r|g|b, each 5 bits, bit #15 clear, write the pixel
  182.     mov    [edi],cx
  183.     add    edi,2
  184.  
  185. ; now add the deltas
  186.     add    ebx,ebp
  187.     add    eax,esi
  188.     add    edx,_fx_db_dx
  189.  
  190.     dec    _loop_count
  191.     jns    _loop1
  192.  
  193. ; ---------------------------------------------------------------------------------------------------------------------
  194.  
  195. _none_to_do:    popa
  196.  
  197.     ret
  198.  
  199. ; -- Code to get rgb 5 bits integer, 5 bits fraction value into 5 bits integer (for each gun)
  200. ; suitable for inverse color lookup
  201. ;**__test:
  202. ;** int 3
  203. ;**;                  rrrrrfffffrrrrrfffffxxbbbbbfffff
  204. ;**    mov    eax,11111001001010101110101101110111b
  205. ;**    and    eax,11111000001111100000001111100000b
  206. ;**    shld    ebx,eax,15
  207. ;**    or    bx,ax
  208.  
  209. _TEXT    ends
  210.  
  211.     end
  212.  
  213.  
  214.  
  215.