home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / texmap / tmap_16.asm < prev    next >
Assembly Source File  |  1998-06-08  |  7KB  |  250 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/texmap/rcs/tmap_16.asm $
  13. ; $Revision: 1.4 $
  14. ; $Author: mike $
  15. ; $Date: 1994/11/30 00:56:32 $
  16. ;
  17. ; 16 bits per pixel texture mapper
  18. ;
  19. ; $Log: tmap_16.asm $
  20. ; Revision 1.4  1994/11/30  00:56:32  mike
  21. ; optimization.
  22. ; 
  23. ; Revision 1.3  1994/11/12  16:39:16  mike
  24. ; jae to ja.
  25. ; 
  26. ; Revision 1.2  1993/11/22  10:23:49  mike
  27. ; *** empty log message ***
  28. ; 
  29. ; Revision 1.1  1993/09/08  17:29:17  mike
  30. ; Initial revision
  31. ; 
  32. ;
  33. ;
  34.  
  35.     .386
  36.  
  37.     public    asm_tmap_scanline_lin_16_
  38.  
  39.     include    tmap_inc.asm
  40.  
  41. _DATA    SEGMENT DWORD PUBLIC USE32 'DATA'
  42.  
  43.     extrn    _fx_u:dword
  44.     extrn    _fx_v:dword
  45.     extrn    _fx_du_dx:dword
  46.     extrn    _fx_dv_dx:dword
  47.     extrn    _fx_y:dword
  48.     extrn    _fx_xleft:dword
  49.     extrn    _fx_xright:dword
  50.  
  51.     extrn    _pixptr:dword
  52.  
  53.     extrn    _x:dword
  54.     extrn    _loop_count:dword
  55.  
  56.  
  57. _DATA    ENDS
  58.  
  59. DGROUP    GROUP    _DATA
  60.  
  61. _TEXT   SEGMENT PARA PUBLIC USE32 'CODE'
  62.  
  63.     ASSUME    DS:_DATA
  64.     ASSUME    CS:_TEXT
  65.  
  66. ; --------------------------------------------------------------------------------------------------
  67. ; Enter:
  68. ;    _xleft    fixed point left x coordinate
  69. ;    _xright    fixed point right x coordinate
  70. ;    _y    fixed point y coordinate
  71. ;    _pixptr    address of source pixel map
  72. ;    _u    fixed point initial u coordinate
  73. ;    _v    fixed point initial v coordinate
  74. ;    _du_dx    fixed point du/dx
  75. ;    _dv_dx    fixed point dv/dx
  76.  
  77. ;   for (x = (int) xleft; x <= (int) xright; x++) {
  78. ;      _setcolor(read_pixel_from_tmap(srcb,((int) (u/z)) & 63,((int) (v/z)) & 63));
  79. ;      _setpixel(x,y);
  80. ;
  81. ;      u += du_dx;
  82. ;      v += dv_dx;
  83. ;      z += dz_dx;
  84. ;   }
  85.  
  86.     align    4
  87. asm_tmap_scanline_lin_16_:
  88.     pusha
  89.  
  90. ; Setup for loop:    _loop_count  iterations = (int) xright - (int) xleft
  91. ;    esi    source pixel pointer = pixptr
  92. ;    edi    initial row pointer = y*320+x
  93.  
  94. ; set esi = pointer to start of texture map data
  95.     mov    esi,_pixptr
  96.  
  97. ; set edi = address of first pixel to modify
  98.     mov    edi,_fx_y
  99.     cmp    edi,_window_bottom
  100.     ja    _none_to_do
  101.  
  102.     sub    edi,_window_top
  103.     imul    edi,_bytes_per_row
  104.  
  105.     mov    eax,_fx_xleft
  106.     sar    eax,16
  107.     jns    eax_ok
  108.     sub    eax,eax
  109. eax_ok:
  110.     sub    eax,_window_left
  111.  
  112.     add    edi,eax
  113.     add    edi,eax    ; add again because it's 2 bytes/pixel
  114.     add    edi,write_buffer
  115.  
  116. ; set _loop_count = # of iterations
  117.     mov    eax,_fx_xright
  118.     sar    eax,16
  119.     cmp    eax,_window_right
  120.     jb    eax_ok1
  121.     mov    eax,_window_right
  122. eax_ok1:    cmp    eax,_window_left
  123.     ja    eax_ok2
  124.     mov    eax,_window_left
  125. eax_ok2:
  126.  
  127.     mov    ebx,_fx_xleft
  128.     sar    ebx,16
  129.     sub    eax,ebx
  130.     js    _none_to_do
  131.     cmp    eax,_window_width
  132.     jbe    _ok_to_do
  133.     mov    eax,_window_width
  134. _ok_to_do:
  135.     mov    _loop_count,eax
  136.  
  137. ;    edi    destination pixel pointer
  138.  
  139.  
  140.     mov    ebx,_fx_u
  141.     mov    ecx,_fx_du_dx
  142.     mov    edx,_fx_dv_dx
  143.     mov    ebp,_fx_v
  144.  
  145.     shl    ebx,10
  146.     shl    ebp,10
  147.     shl    edx,10
  148.     shl    ecx,10
  149.  
  150. ; eax    work
  151. ; ebx    u
  152. ; ecx    du_dx
  153. ; edx    dv_dx
  154. ; ebp    v
  155. ; esi    read address
  156. ; edi    write address
  157.  
  158. _size = (_end1 - _start1)/num_iters
  159.     mov    eax,num_iters-1
  160.     sub    eax,_loop_count
  161.     imul    eax,eax,dword ptr _size
  162.     add    eax,offset _start1
  163.     jmp    eax
  164.  
  165.     align    4
  166. _start1:
  167.  
  168. ; "OPTIMIZATIONS" maybe not worth making
  169. ;    Getting rid of the esi from the mov al,[esi+eax] instruction.
  170. ;       This would require moving into eax at the top of the loop, rather than doing the sub eax,eax.
  171. ;       You would have to align your bitmaps so that the two shlds would create the proper base address.
  172. ;       In other words, your bitmap data would have to begin at 4096x (for 64x64 bitmaps).
  173. ;       I did timings without converting the sub to a mov eax,esi and setting esi to the proper value.
  174. ;       There was a speedup of about 1% to 1.5% without converting the sub to a mov.
  175. ;    Getting rid of the edi by doing a mov nnnn[edi],al instead of mov [edi],al.
  176. ;       The problem with this is you would have a dword offset for nnnn.  My timings indicate it is slower.  (I think.)
  177. ;    Combining u,v and du,dv into single longwords.
  178. ;       The problem with this is you then must do a 16 bit operation to extract them, and you don't have enough
  179. ;       instructions to separate a destination operand from being used by the next instruction.  It shaves out one
  180. ;       register instruction (an add reg,reg), but adds a 16 bit operation, and the setup is more complicated.
  181. ; usage:
  182. ;    eax    work
  183. ;    ebx    u coordinate
  184. ;    ecx    delta u
  185. ;    edx    delta v
  186. ;    ebp    v coordinate
  187. ;    esi    pointer to source bitmap
  188. ;    edi    write address
  189.  rept num_iters
  190.     mov    eax,ebp    ; clear for 
  191.     add    ebp,edx    ; update v coordinate
  192.     shr    eax,26    ; shift in v coordinate
  193.     shld    eax,ebx,6    ; shift in u coordinate while shifting up v coordinate
  194.     add    ebx,ecx    ; update u coordinate
  195.     mov    ax,[esi+2*eax]    ; get pixel from source bitmap
  196.     mov    [edi],ax
  197.     add    edi,2
  198.  
  199. ; inner loop if bitmaps are 256x256
  200. ; your register usage is bogus, and you must clear ecx
  201. ; fix your setup
  202. ; this is only about 10% faster in the inner loop
  203. ; this method would adapt to writing two pixels at a time better than
  204. ; the 64x64 method because you wouldn't run out of registers
  205. ; Note that this method assumes that both dv_dx and du_dx are in edx.
  206. ; edx = vi|vf|ui|uf
  207. ; where each field is 8 bits, vi = integer v coordinate, vf = fractional v coordinate, etc.
  208. ;** add ebx,edx
  209. ;** mov cl,bh
  210. ;** shld cx,bx,8
  211. ;** mov al,[esi+ecx]
  212. ;** mov [edi],al
  213. ;** inc edi
  214.  endm
  215.  
  216. _end1:
  217.  
  218. _none_to_do:    popa
  219.  
  220.     ret
  221.  
  222. _TEXT    ends
  223.  
  224.     end
  225.  
  226.  
  227.  
  228. ; This is the inner loop to write two pixels at a time
  229. ; This is about 2.5% faster overall (on Mike's 66 MHz 80486 DX2, VLB)
  230. ; You must write code to even align edi and do half as many iterations, and write
  231. ; the beginning and ending extra pixels, if necessary.
  232. ;    sub    eax,eax    ; clear for 
  233. ;    shld    eax,ebp,6    ; shift in v coordinate
  234. ;    add    ebp,_fx_dv_dx    ; update v coordinate
  235. ;    shld    eax,ebx,6    ; shift in u coordinate while shifting up v coordinate
  236. ;    add    ebx,ecx    ; update u coordinate
  237. ;    mov    dl,[esi+eax]    ; get pixel from source bitmap
  238. ;
  239. ;    sub    eax,eax    ; clear for 
  240. ;    shld    eax,ebp,6    ; shift in v coordinate
  241. ;    add    ebp,_fx_dv_dx    ; update v coordinate
  242. ;    shld    eax,ebx,6    ; shift in u coordinate while shifting up v coordinate
  243. ;    add    ebx,ecx    ; update u coordinate
  244. ;    mov    dh,[esi+eax]    ; get pixel from source bitmap
  245. ;
  246. ;    mov    [edi],dx
  247. ;    add    edi,2
  248.  
  249.  
  250.