home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / 3d / points.asm < prev    next >
Assembly Source File  |  1998-06-08  |  7KB  |  345 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/3d/rcs/points.asm $
  13. ; $Revision: 1.13 $
  14. ; $Author: matt $
  15. ; $Date: 1995/02/09 22:00:05 $
  16. ;
  17. ; Source for point definition, rotation, etc.
  18. ;
  19. ; $Log: points.asm $
  20. ; Revision 1.13  1995/02/09  22:00:05  matt
  21. ; Removed dependence on divide overflow handler; we now check for overflow
  22. ; before dividing.  This fixed problems on some TI chips.
  23. ; 
  24. ; Revision 1.12  1994/11/11  19:22:06  matt
  25. ; Added new function, g3_calc_point_depth()
  26. ; 
  27. ; Revision 1.11  1994/07/25  00:00:04  matt
  28. ; Made 3d no longer deal with point numbers, but only with pointers.
  29. ; 
  30. ; Revision 1.10  1994/07/21  09:53:32  matt
  31. ; Made g3_point_2_vec() take 2d coords relative to upper left, not center
  32. ; 
  33. ; Revision 1.9  1994/02/10  18:00:41  matt
  34. ; Changed 'if DEBUG_ON' to 'ifndef NDEBUG'
  35. ; 
  36. ; Revision 1.8  1994/02/09  11:48:55  matt
  37. ; Added delta rotation functions
  38. ; 
  39. ; Revision 1.7  1994/01/13  15:39:39  mike
  40. ; Change usage of Frame_count to _Frame_count.
  41. ; 
  42. ; Revision 1.6  1993/12/21  20:35:35  matt
  43. ; Fixed bug that left register pushed if point was already projected in
  44. ; g3_project_list()
  45. ; 
  46. ; Revision 1.5  1993/12/21  11:45:37  matt
  47. ; Fixed negative y bug in g3_point_2_vec()
  48. ; 
  49. ; Revision 1.4  1993/12/20  20:21:51  matt
  50. ; Added g3_point_2_vec()
  51. ; 
  52. ; Revision 1.3  1993/11/21  20:08:41  matt
  53. ; Added function g3_rotate_point()
  54. ; 
  55. ; Revision 1.2  1993/11/04  18:49:17  matt
  56. ; Added system to only rotate points once per frame
  57. ; 
  58. ; Revision 1.1  1993/10/29  22:20:27  matt
  59. ; Initial revision
  60. ; 
  61. ;
  62. ;
  63.  
  64. .386
  65.     option    oldstructs
  66.  
  67.     .nolist
  68.     include    types.inc
  69.     include    psmacros.inc
  70.     include    gr.inc
  71.     include    3d.inc
  72.     .list
  73.  
  74.     assume    cs:_TEXT, ds:_DATA
  75.  
  76. _DATA    segment    dword public USE32 'DATA'
  77.  
  78. rcsid    db    "$Id: points.asm 1.13 1995/02/09 22:00:05 matt Exp $"
  79.     align    4
  80.  
  81. tempv    vms_vector <>
  82.  
  83. tempm    vms_matrix <>
  84.  
  85. _DATA    ends
  86.  
  87.  
  88.  
  89. _TEXT    segment    dword public USE32 'CODE'
  90.  
  91. ;finds clipping codes for a point. takes eax=point. fills in p3_codes,
  92. ;and returns codes in bl.
  93. g3_code_point:
  94. code_point:    push    ecx
  95.  
  96.     xor    bl,bl    ;clear codes
  97.     mov    ecx,[eax].z    ;get z
  98.     cmp    [eax].x,ecx    ;x>z?
  99.     jle    not_right
  100.     or    bl,CC_OFF_RIGHT
  101. not_right:    cmp    [eax].y,ecx    ;y>z?
  102.     jle    not_top
  103.     or    bl,CC_OFF_TOP
  104. not_top:    neg    ecx
  105.     js    not_behind
  106.     or    bl,CC_BEHIND
  107. not_behind:    cmp    [eax].x,ecx    ;x<-z?
  108.     jge    not_left
  109.     or    bl,CC_OFF_LEFT
  110. not_left:    cmp    [eax].y,ecx    ;y<-z
  111.     jge    not_bot
  112.     or    bl,CC_OFF_BOT
  113. not_bot:    pop    ecx
  114.     mov    [eax].p3_codes,bl
  115.     ret
  116.     
  117.  
  118. ;rotate a point. don't look at rotated flags
  119. ;takes esi=dest point, esi=src vector
  120. ;returns bl=codes
  121. g3_rotate_point:    pushm    eax,ecx,esi,edi
  122.  
  123.     push    edi    ;save dest
  124.  
  125.     lea    eax,tempv
  126.     lea    edi,View_position
  127.     call    vm_vec_sub
  128.     mov    esi,eax
  129.  
  130.     pop    eax
  131.     
  132.     lea    edi,View_matrix
  133.     call    vm_vec_rotate
  134.     mov    [eax].p3_flags,0    ;not projected
  135.  
  136.     ;;mov    bx,_Frame_count    ;curren frame
  137.     ;;mov    [eax].p3_frame,bx
  138.  
  139.     call    code_point
  140.  
  141.     popm    eax,ecx,esi,edi
  142.     ret
  143.  
  144.  
  145. ;projects a point. takes esi=point  
  146. g3_project_point:
  147.     ;;ifndef    NDEBUG
  148.     ;; push    eax
  149.     ;; mov    ax,[esi].p3_frame
  150.     ;; cmp    ax,_Frame_count
  151.     ;; break_if    ne,'Trying to project unrotated point!'
  152.     ;; pop    eax
  153.     ;;endif
  154.  
  155.     test    [esi].p3_flags,PF_PROJECTED
  156.     jnz    no_project
  157.     test    [esi].p3_codes,CC_BEHIND
  158.     jnz    no_project
  159.  
  160.     pushm    eax,edx
  161.  
  162.     mov    eax,[esi].x
  163.     imul    Canv_w2
  164. proj_div0:    divcheck    [esi].z,div_overflow_handler
  165.     idiv    [esi].z
  166.     add    eax,Canv_w2
  167.     mov    [esi].p3_sx,eax
  168.  
  169.     mov    eax,[esi].y
  170.     imul    Canv_h2
  171. proj_div1:    divcheck    [esi].z,div_overflow_handler
  172.     idiv    [esi].z
  173.     neg    eax
  174.     add    eax,Canv_h2
  175.     mov    [esi].p3_sy,eax
  176.  
  177.     or    [esi].p3_flags,PF_PROJECTED    ;projected
  178.  
  179.     popm    eax,edx
  180.  
  181. no_project:    ret
  182.  
  183. div_overflow_handler:
  184.     ;int    3
  185.     mov    [esi].p3_flags,PF_OVERFLOW
  186.     popm    eax,edx
  187.     ret
  188.  
  189. ;from a 2d point on the screen, compute the vector in 3-space through that point
  190. ;takes eax,ebx = 2d point, esi=vector
  191. ;the 2d point is relative to the center of the canvas
  192. g3_point_2_vec:    pushm    ecx,edx,esi,edi
  193.  
  194.     push    esi
  195.  
  196.     lea    esi,tempv
  197.  
  198.     ;;mov    edx,eax
  199.     ;;xor    eax,eax
  200.     ;;idiv    Canv_w2
  201.     sal    eax,16
  202.     sub    eax,Canv_w2
  203.     fixdiv    Canv_w2
  204.     imul    Matrix_scale.z
  205.     idiv    Matrix_scale.x
  206.     mov    [esi].x,eax
  207.  
  208.     ;;mov    edx,ebx
  209.     ;;xor    eax,eax
  210.     ;;sub    Canv_h2
  211.     ;;idiv    Canv_h2
  212.     mov    eax,ebx
  213.     sal    eax,16
  214.     sub    eax,Canv_h2
  215.     fixdiv    Canv_h2
  216.     imul    Matrix_scale.z
  217.     idiv    Matrix_scale.y
  218.     neg    eax
  219.     mov    [esi].y,eax
  220.  
  221.     mov    [esi].z,f1_0
  222.  
  223.     call    vm_vec_normalize    ;get normalized rotated vec
  224.  
  225.     lea    edi,tempm
  226.     lea    esi,Unscaled_matrix
  227.     call    vm_copy_transpose_matrix
  228.  
  229.     pop    eax    ;get dest
  230.     lea    esi,tempv    ;edi=matrix
  231.     call    vm_vec_rotate
  232.  
  233.     popm    ecx,edx,esi,edi
  234.  
  235.     ret
  236.  
  237. ;rotate a delta y vector. takes edi=dest vec, ebx=delta y
  238. g3_rotate_delta_y:    pushm    eax,edx
  239.     mov    eax,View_matrix.m4
  240.     fixmul    ebx
  241.     mov    [edi].x,eax
  242.     mov    eax,View_matrix.m5
  243.     fixmul    ebx
  244.     mov    [edi].y,eax
  245.     mov    eax,View_matrix.m6
  246.     fixmul    ebx
  247.     mov    [edi].z,eax
  248.     popm    eax,edx
  249.     ret
  250.  
  251.  
  252. ;rotate a delta x vector. takes edi=dest vec, ebx=delta x
  253. g3_rotate_delta_x:    pushm    eax,edx
  254.     mov    eax,View_matrix.m1
  255.     fixmul    ebx
  256.     mov    [edi].x,eax
  257.     mov    eax,View_matrix.m2
  258.     fixmul    ebx
  259.     mov    [edi].y,eax
  260.     mov    eax,View_matrix.m3
  261.     fixmul    ebx
  262.     mov    [edi].z,eax
  263.     popm    eax,edx
  264.     ret
  265.  
  266.  
  267. ;rotate a delta x vector. takes edi=dest vec, ebx=delta z
  268. g3_rotate_delta_z:    pushm    eax,edx
  269.     mov    eax,View_matrix.m7
  270.     fixmul    ebx
  271.     mov    [edi].x,eax
  272.     mov    eax,View_matrix.m8
  273.     fixmul    ebx
  274.     mov    [edi].y,eax
  275.     mov    eax,View_matrix.m9
  276.     fixmul    ebx
  277.     mov    [edi].z,eax
  278.     popm    eax,edx
  279.     ret
  280.  
  281.  
  282. ;rotate a delta vector. takes edi=dest vec, esi=src vec
  283. g3_rotate_delta_vec:
  284.     pushm    eax,edi
  285.     mov    eax,edi
  286.     lea    edi,View_matrix
  287.     call    vm_vec_rotate
  288.     popm    eax,edi
  289.     ret
  290.  
  291. ;adds a delta vector to a point. takes eax=dest point, esi=src pnt, edi=delta vec
  292. ;returns bl=codes.
  293. g3_add_delta_vec:    ;;ifndef    NDEBUG
  294.     ;; push    eax
  295.     ;; mov    ax,[esi].p3_frame
  296.     ;; cmp    ax,_Frame_count
  297.     ;; break_if    ne,'Trying to add delta to unrotated point!'
  298.     ;; pop    eax
  299.     ;;endif
  300.  
  301.     call    vm_vec_add
  302.  
  303.     ;;mov    bx,_Frame_count
  304.     ;;mov    [eax].p3_frame,bx
  305.     mov    [eax].p3_flags,0    ;not projected
  306.  
  307.     call    g3_code_point
  308.  
  309.     ret
  310.  
  311. ;calculate the depth of a point - returns the z coord of the rotated point
  312. ;takes esi=vec, returns eax=depth
  313. g3_calc_point_depth:
  314.     pushm    edx,ebx,ecx
  315.  
  316.     mov    eax,[esi].x
  317.     sub    eax,View_position.x
  318.     imul    View_matrix.fvec.x
  319.     mov    ebx,eax
  320.     mov    ecx,edx
  321.  
  322.     mov    eax,[esi].y
  323.     sub    eax,View_position.y
  324.     imul    View_matrix.fvec.y
  325.     add    ebx,eax
  326.     adc    ecx,edx
  327.  
  328.     mov    eax,[esi].z
  329.     sub    eax,View_position.z
  330.     imul    View_matrix.fvec.z
  331.     add    eax,ebx
  332.     adc    edx,ecx
  333.  
  334.     shrd    eax,edx,16
  335.  
  336.     popm    edx,ebx,ecx
  337.  
  338.     ret
  339.         
  340.  
  341.  
  342. _TEXT    ends
  343.  
  344.     end
  345.