home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / 3d / rod.asm < prev    next >
Assembly Source File  |  1998-06-08  |  10KB  |  431 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/3d/rcs/rod.asm $
  13. ; $Revision: 1.22 $
  14. ; $Author: matt $
  15. ; $Date: 1995/02/09 22:00:51 $
  16. ; 
  17. ; Code to draw rods (facing bitmaps).
  18. ; 
  19. ; $Log: rod.asm $
  20. ; Revision 1.22  1995/02/09  22:00:51  matt
  21. ; Removed dependence on divide overflow handler; we now check for overflow
  22. ; before dividing.  This fixed problems on some TI chips.
  23. ; 
  24. ; Revision 1.21  1994/11/27  12:55:14  matt
  25. ; Tooks out some unused code
  26. ; 
  27. ; Revision 1.20  1994/09/01  15:34:49  matt
  28. ; Fixed stack mess-up when rod projection overflows
  29. ; 
  30. ; Revision 1.19  1994/09/01  10:41:46  matt
  31. ; Blob routine, renamed g3_draw_bitmap(), now takes seperate 3d width & height.
  32. ; 
  33. ; Revision 1.18  1994/08/01  17:23:27  matt
  34. ; Check for overflow after project in blob code
  35. ; 
  36. ; Revision 1.17  1994/07/25  15:47:13  matt
  37. ; Cleaned up code, and made long-broken flat-shaded rods work.
  38. ; 
  39. ; Revision 1.16  1994/07/25  00:00:05  matt
  40. ; Made 3d no longer deal with point numbers, but only with pointers.
  41. ; 
  42. ; Revision 1.15  1994/07/22  17:58:01  matt
  43. ; Changed the name of the rod functions, and took out some debugging code
  44. ; 
  45. ; Revision 1.14  1994/07/21  12:49:41  mike
  46. ; Create _blob_vertices so powerups can be outlined when selected in editor.
  47. ; 
  48. ; Revision 1.13  1994/06/16  09:07:29  matt
  49. ; Move in UV values for rods to prevent the texture mapper from reading
  50. ; past the edges of the bitmaps.
  51. ; 
  52. ; Revision 1.12  1994/05/31  18:35:29  matt
  53. ; Added light value to g3_draw_facing_bitmap()
  54. ; 
  55. ; Revision 1.11  1994/05/19  23:11:54  matt
  56. ; Support new uvl value ranges
  57. ; 
  58. ; Revision 1.10  1994/05/13  10:18:07  matt
  59. ; Fixed bug introduced last time
  60. ; 
  61. ; Revision 1.9  1994/05/11  10:10:35  matt
  62. ; Changed a little code in attempt to avoid overflows
  63. ; 
  64. ; Revision 1.8  1994/05/07  16:43:26  matt
  65. ; Made rods work right, maybe.
  66. ; 
  67. ; Revision 1.7  1994/03/23  10:25:04  matt
  68. ; Fixed stack messup with blob overflow, and removed debug_brk
  69. ; 
  70. ; Revision 1.6  1994/03/15  21:22:11  matt
  71. ; Put in check for div overflow in blob code
  72. ; 
  73. ; Revision 1.5  1994/02/21  11:04:15  matt
  74. ; Added check for zero-length vector
  75. ; 
  76. ; Revision 1.4  1994/02/15  17:37:23  matt
  77. ; New function, g3_draw_blob()
  78. ; 
  79. ; Revision 1.3  1994/02/11  20:15:04  matt
  80. ; Fixed matrix scale problem, removed unneeded debug_brk
  81. ; 
  82. ; Revision 1.2  1994/02/09  11:49:32  matt
  83. ; Added code for texture-mapped and flat-shaded rods
  84. ; 
  85. ; Revision 1.1  1994/02/02  11:27:21  matt
  86. ; Initial revision
  87. ; 
  88. ; 
  89.  
  90. ALWAYS_USE_SCALER = 0    ;if true, use scaler even when banked
  91.  
  92.  
  93. .386
  94.     option    oldstructs
  95.  
  96.     .nolist
  97.     include    types.inc
  98.     include    psmacros.inc
  99.     include    gr.inc
  100.     include    3d.inc
  101.     .list
  102.  
  103.     assume    cs:_TEXT, ds:_DATA
  104.  
  105.     public    _blob_vertices
  106.  
  107. _DATA    segment    dword public USE32 'DATA'
  108.  
  109. rcsid    db    "$Id: rod.asm 1.22 1995/02/09 22:00:51 matt Exp $"
  110.     align    4
  111.  
  112. bot_width    fix    ?
  113. top_width    fix    ?
  114.  
  115. rod_points    db    4*size g3s_point dup (?)
  116.  
  117. delta_x    fix    ?
  118. delta_y    fix    ?
  119.  
  120. edge_vec_x    fix    ?
  121. edge_vec_y    fix    ?
  122.  
  123. vertbuf    fix    4 dup (?,?)
  124. _blob_vertices    fix    4 dup (?,?)
  125.  
  126. bitmap_ptr    dd    ?
  127.  
  128. delta_vec    vms_vector <>
  129. rod_norm    vms_vector <>
  130. temp_vec    vms_vector <>
  131. top_pnt    dd    ?
  132. bot_pnt    dd    ?
  133.  
  134. rod_point_list    dd    rod_points
  135.     dd    rod_points+(size g3s_point)
  136.     dd    rod_points+(size g3s_point)*2
  137.     dd    rod_points+(size g3s_point)*3
  138.  
  139. ;values here are set to be half a pixel in from the edges so the texture
  140. ;mapper doesn't read past the bitmap  
  141. uvl_list    fix    200h,200h,0
  142.     fix    0fe00h,200h,0
  143.     fix    0fe00h,0fe00h,0
  144.     fix    200h,0fe00h,0
  145.  
  146. ;;uvl_list    fix    0,0,0
  147. ;;    fix    10000h,0,0
  148. ;;    fix    10000h,10000h,0
  149. ;;    fix    0,10000h,0
  150.  
  151. _DATA    ends
  152.  
  153.  
  154.  
  155. _TEXT    segment    dword public USE32 'CODE'
  156.  
  157.     extn    scale_bitmap_
  158.  
  159. ;draws a polygon that's always facing the viewer
  160. ;takes esi,edi=bottom & top points (g3s_point *), eax,edx=3d width at bottom,top
  161. g3_draw_rod_flat:    pushm    eax,ebx,ecx,edx,esi,edi
  162.  
  163.     call    calc_rod_corners
  164.     or    cl,cl    ;check codes
  165.     jnz    no_draw
  166.  
  167.     mov    ecx,4    ;4 corners
  168.     lea    esi,rod_point_list
  169.     call    g3_draw_poly
  170.  
  171.     popm    eax,ebx,ecx,edx,esi,edi
  172.     ret
  173.  
  174. ;draws bitmap that's always facing the viewer
  175. ;takes esi,edi=bottom & top points (g3s_point *), eax,edx=3d width at bottom,top
  176. ;ebx = bitmap
  177. ;points must be rotated
  178. g3_draw_rod_tmap:
  179.     pushm    eax,ebx,ecx,edx,esi,edi
  180.  
  181.     mov    bitmap_ptr,ebx
  182.  
  183.     ;save lighting values
  184.     mov    uvl_list+8,ecx
  185.     mov    uvl_list+20,ecx
  186.     mov    uvl_list+32,ecx
  187.     mov    uvl_list+44,ecx
  188.  
  189.     call    calc_rod_corners
  190.     or    cl,cl    ;check codes
  191.     jnz    no_draw
  192.  
  193.     mov    ecx,4
  194.     lea    esi,rod_point_list
  195.     lea    ebx,uvl_list
  196.     mov    edx,bitmap_ptr
  197.     call    g3_draw_tmap
  198.  
  199.     jmp    no_draw
  200.  
  201.  
  202. ;;@@;can use use scaler?
  203. ;;@@if not ALWAYS_USE_SCALER
  204. ;;@@    mov    eax,vertbuf+4    ;point 0 y
  205. ;;@@    cmp    eax,vertbuf+12    ;point 1 y
  206. ;;@@    jne    must_roll
  207. ;;@@;use the scaler!
  208. ;;@@endif
  209. ;;@@    mov    eax,bitmap_ptr
  210. ;;@@    lea    edx,vertbuf
  211. ;;@@    call    scale_bitmap_
  212. ;;@@    jmp    no_draw
  213. ;;@@
  214. ;;@@;can't call the scaler
  215. ;;@@must_roll:    mov    eax,bitmap_ptr
  216. ;;@@    lea    edx,vertbuf
  217. ;;@@    mov    ebx,15        ;light value
  218. ;;@@    call    rotate_bitmap_
  219.  
  220. no_draw:
  221.     popm    eax,ebx,ecx,edx,esi,edi
  222.     ret
  223.  
  224.  
  225.  
  226.  
  227. ;draws a bitmap with the specified 3d width & height 
  228. ;takes esi=position, ebx=width, ecx=height, eax=bitmap
  229. ;modifies eax,esi,ecx
  230. g3_draw_bitmap:    pushm    edx,edi
  231.  
  232.     mov    bitmap_ptr,eax    ;save bitmap
  233.  
  234.     push    ebx    ;save width
  235.     lea    edi,rod_points    ;get dest point
  236.     call    g3_rotate_point
  237.     or    bl,bl    ;off screen?
  238.     pop    ebx    ;restore width
  239.     js    blob_off_screen
  240.  
  241. ;we should check if off screen based on rad
  242.  
  243.     mov    esi,edi
  244.     call    g3_project_point
  245.     test    [esi].p3_flags,PF_OVERFLOW
  246.     jnz    blob_off_screen
  247.  
  248. ;get 2d width & height
  249.  
  250.     mov    eax,ebx    ;get width
  251.     imul    Canv_w2
  252. blob_div0:    divcheck    [esi].z,blob_overflow_handler
  253.     idiv    [esi].z    ;width3d*canv_w/z
  254.     fixmul    Matrix_scale.x    ;*scale
  255.     mov    edi,eax    ;save width
  256.  
  257.     mov    eax,ecx    ;get height
  258.     imul    Canv_h2
  259. blob_div1:    divcheck    [esi].z,blob_overflow_handler
  260.     idiv    [esi].z    ;height3d*canv_h/z
  261.     fixmul    Matrix_scale.y    ;*scale
  262.     mov    ecx,eax    ;save height
  263.  
  264. ;copy 2d points into buffer
  265.  
  266.     lea    edx,_blob_vertices
  267.  
  268.     mov    eax,[esi].p3_sx
  269.     sub    eax,edi    ;- width
  270.     mov    [edx],eax    ;p0.x
  271.     lea    eax,[eax+edi*2]    ;+ 2*width
  272.     mov    8[edx],eax    ;p1.x
  273.     mov    16[edx],eax    ;p2.x
  274.  
  275.     mov    eax,[esi].p3_sy
  276.     sub    eax,ecx    ;- height
  277.     mov    4[edx],eax    ;p0.y
  278.     mov    12[edx],eax    ;p1.y
  279.     lea    eax,[eax+ecx*2]    ;+ 2*height
  280.     mov    20[edx],eax    ;p2.y
  281.  
  282. ;now draw
  283.     mov    eax,bitmap_ptr    ;get bitmap ptr
  284.     call    scale_bitmap_    ;vertbuf in edx
  285.  
  286. blob_off_screen:    popm    edx,edi
  287.     ret
  288.  
  289. blob_overflow_handler:
  290.     ;debug_brk    "blob overflow - get Matt"
  291.     jmp    blob_off_screen
  292.  
  293.  
  294.  
  295.  
  296. ;compute the corners of a rod.  fills in vertbuf. ret codes in al.
  297. ;points in esi,edi, widths in eax,edx  
  298. ;trashes piles of registers
  299. calc_rod_corners:
  300.  
  301.     mov    bot_width,eax
  302.     mov    top_width,edx
  303.  
  304.     mov    bot_pnt,esi
  305.     mov    top_pnt,edi
  306.  
  307. ;compute vector from one point to other, do cross product with vector
  308. ;from eye to get perpendiclar
  309.  
  310.     lea    eax,delta_vec
  311.     call    vm_vec_sub
  312.  
  313. ;unscale for aspect
  314.     mov    eax,delta_vec.x
  315.     fixdiv    matrix_scale.x
  316.     mov    delta_vec.x,eax
  317.     mov    eax,delta_vec.y
  318.     fixdiv    matrix_scale.y
  319.     mov    delta_vec.y,eax
  320.  
  321.  
  322. ;calc perp vector
  323.  
  324. ;do lots of normalizing to prevent overflowing.  When this code works,
  325. ;it should be optimized
  326.  
  327.     lea    esi,delta_vec
  328.     call    vm_vec_normalize
  329.  
  330.     vm_copy    temp_vec,edi
  331.     mov    edi,esi
  332.     lea    esi,temp_vec
  333.     call    vm_vec_normalize
  334.  
  335.     xchg    esi,edi    
  336.     lea    eax,rod_norm
  337.     call    vm_vec_crossprod
  338.  
  339.     mov    esi,eax
  340.     call    vm_vec_normalize
  341.  
  342. ;scale for aspect
  343.  
  344.     mov    eax,rod_norm.x
  345.     fixmul    matrix_scale.x
  346.     mov    rod_norm.x,eax
  347.     mov    eax,rod_norm.y
  348.     fixmul    matrix_scale.y
  349.     mov    rod_norm.y,eax
  350.  
  351.  
  352. ;now we have the usable edge.  generate four points
  353.  
  354.     mov    cl,0ffh    ;codes and
  355.  
  356.     push    ebp
  357.     lea    ebp,rod_points
  358.  
  359. ;top points
  360.     lea    edi,temp_vec
  361.     lea    ebx,rod_norm
  362.     mov    ecx,top_width
  363.     call    vm_vec_copy_scale
  364.  mov temp_vec.z,0
  365.  
  366.     mov    eax,ebp
  367.     mov    esi,top_pnt    ;temp vec in edi
  368.     call    vm_vec_add
  369.  
  370.     add    eax,size g3s_point
  371.     call    vm_vec_sub
  372.  
  373.     lea    ebp,size g3s_point[eax]
  374.  
  375. ;bot points
  376.     lea    edi,temp_vec
  377.     lea    ebx,rod_norm
  378.     mov    ecx,bot_width
  379.     call    vm_vec_copy_scale
  380.  mov temp_vec.z,0
  381.  
  382.     mov    eax,ebp
  383.     mov    esi,bot_pnt    ;temp vec in edi
  384.     call    vm_vec_sub
  385.  
  386.     add    eax,size g3s_point
  387.     call    vm_vec_add
  388.  
  389.     pop    ebp
  390.  
  391. ;now code the four points
  392.  
  393.     mov    cl,0ffh    ;codes and
  394.  
  395.     lea    eax,rod_points
  396.     call    code_point
  397.     and    cl,bl
  398.     add    eax,size g3s_point
  399.     call    code_point
  400.     and    cl,bl
  401.     add    eax,size g3s_point
  402.     call    code_point
  403.     and    cl,bl
  404.     add    eax,size g3s_point
  405.     call    code_point
  406.     and    cl,bl
  407.     jnz    new_new_off_screen
  408.  
  409.     push    ecx    ;save codes
  410.  
  411. ;clear flags for new points (not projected)
  412.  
  413.     lea    esi,rod_points
  414.     mov    [esi].p3_flags,0
  415.     mov    [esi+size g3s_point].p3_flags,0
  416.     mov    [esi+(size g3s_point)*2].p3_flags,0
  417.     mov    [esi+(size g3s_point)*3].p3_flags,0
  418.  
  419.     pop    ecx    ;restore codes
  420.  
  421.     ret
  422.  
  423. new_new_off_screen:
  424.     ret
  425.  
  426.  
  427. _TEXT    ends
  428.  
  429.     end
  430.  
  431.