home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / 3d / objects.asm < prev    next >
Assembly Source File  |  1998-06-08  |  6KB  |  309 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/3d/rcs/objects.asm $
  13. ; $Revision: 1.5 $
  14. ; $Author: matt $
  15. ; $Date: 1993/12/07 23:04:47 $
  16. ; 
  17. ; Code to draw objects
  18. ; 
  19. ; $Log: objects.asm $
  20. ; Revision 1.5  1993/12/07  23:04:47  matt
  21. ; Misc changes.
  22. ; NOTE: This file will not be used anymore.  See object.c in main.
  23. ; 
  24. ; Revision 1.4  1993/12/02  16:09:50  matt
  25. ; Removed debugging print to mono screen
  26. ; 
  27. ; Revision 1.3  1993/11/24  16:58:49  matt
  28. ; Changed bitmap number of cube object
  29. ; 
  30. ; Revision 1.2  1993/11/23  14:29:53  matt
  31. ; Fixed bitmap objects, hopefully.
  32. ; 
  33. ; Revision 1.1  1993/11/21  20:09:02  matt
  34. ; Initial revision
  35. ; 
  36. ; 
  37.  
  38. .386
  39.     option    oldstructs
  40.  
  41.     .nolist
  42.     include    types.inc
  43.     include    psmacros.inc
  44.     include    vecmat.inc
  45.     include    3d.inc
  46.     include    fix.inc
  47.     .list
  48.  
  49.     assume    cs:_TEXT, ds:_DATA
  50.  
  51. _DATA    segment    dword public USE32 'DATA'
  52.  
  53. rcsid    db    "$Id: objects.asm 1.5 1993/12/07 23:04:47 matt Exp $"
  54.     align    4
  55.  
  56. obj_pos    dd    ?    ;ptr to pos vector
  57. obj_type    dd    ?
  58. obj_matrix    dd    ?
  59.  
  60. new_obj_matrix    vms_matrix <>
  61.  
  62. obj_vec_g    vms_vector <>    ;object->eye, global frame
  63. obj_vec_obj    vms_vector <>    ;in objects frame of ref.
  64.  
  65. vec_matrix_g    vms_matrix <>
  66.  
  67. ;3d points for corners of bitmap
  68. up_left_v    vms_vector <>
  69. up_right_v    vms_vector <>
  70. down_right_v    vms_vector <>
  71.  
  72. up_left_p    g3s_point <>
  73. up_right_p    g3s_point <>
  74. down_right_p    g3s_point <>
  75.  
  76. bitmap_points    dd    up_left_p,up_right_p,down_right_p
  77.  
  78. bitmap_number    dd    ?
  79.  
  80. up_vec    vms_vector <>
  81. right_vec    vms_vector <>
  82.  
  83.     public    draw_bitmap_lines
  84. draw_bitmap_lines    dd    0
  85.  
  86.     extb    _Vector_to_viewnum,_up_vecs
  87.     extb    _Vector_to_viewnum2,_up_vecs2
  88.  
  89.  
  90. _DATA    ends
  91.  
  92.  
  93.  
  94. _TEXT    segment    dword public USE32 'CODE'
  95.  
  96.     extn    render_object_
  97.  
  98. ;draws a bitmap object.  takes esi=pos, edi=matrix, eax=size, ebx=obj type
  99. g3_draw_object:    pushm    eax,ebx,ecx,edx,esi,edi
  100.  
  101.     mov    obj_type,ebx    ;save objnum
  102.     mov    obj_pos,esi    ;save pos
  103.     mov    obj_matrix,edi    ;save matrix
  104.  
  105.     push    eax    ;save size
  106.  
  107. ;get vector from object to eye
  108.     lea    eax,obj_vec_g    ;dest
  109.     mov    edi,esi    ;obj position
  110.     lea    esi,View_position    ;eye positon
  111.     call    vm_vec_sub
  112.  
  113. ;normalize vector
  114.     lea    esi,obj_vec_g
  115.     call    vm_vec_normalize
  116.  
  117. ;rotate into object's frame of reference
  118.     lea    eax,obj_vec_obj
  119.     lea    esi,obj_vec_g
  120.     mov    edi,obj_matrix
  121.     call    vm_vec_rotate
  122.  
  123. ;select the right bitmap by looking in a table.
  124. ;get five bits for each of x,y,z, make a 15-bit index, and look in table
  125.  
  126.     mov    eax,obj_vec_obj.x
  127.     add    eax,f1_0    ;make in range 0..2
  128.     break_if    s,'bad value in vector'
  129.     cmp    eax,f2_0
  130.     jl    not_max_x
  131.     dec    eax    ;make less than 1
  132. not_max_x:    sar    eax,2
  133.     and    eax,111110000000000b
  134.     mov    ebx,eax
  135.  
  136.     mov    eax,obj_vec_obj.y
  137.     add    eax,f1_0    ;make in range 0..2
  138.     break_if    s,'bad value in vector'
  139.     cmp    eax,f2_0
  140.     jl    not_max_y
  141.     dec    eax    ;make less than 1
  142. not_max_y:    sar    eax,2+5
  143.     and    eax,1111100000b
  144.     or    ebx,eax
  145.  
  146.     mov    eax,obj_vec_obj.z
  147.     add    eax,f1_0    ;make in range 0..2
  148.     break_if    s,'bad value in vector'
  149.     cmp    eax,f2_0
  150.     jl    not_max_z
  151.     dec    eax    ;make less than 1
  152. not_max_z:    sar    eax,2+10
  153.     and    eax,11111b
  154.     or    ebx,eax
  155.  
  156.     movzx    eax,_Vector_to_viewnum[ebx]
  157.     cmp    obj_type,1    ;other object?
  158.     jne    got_viewnum
  159.     movzx    eax,_Vector_to_viewnum2[ebx]
  160. got_viewnum:
  161.     mov    bitmap_number,eax
  162.  
  163. ;;    debug    "bm=%d\n",eax
  164.  
  165. ;build matrix with vec from obj to eye & bitmap's up vector
  166.  
  167.     mov    eax,bitmap_number
  168.     sal    eax,1    ;*2
  169.     add    eax,bitmap_number    ;*3
  170.     sal    eax,2    ;*12
  171.     lea    eax,_up_vecs[eax]
  172.  
  173.     cmp    obj_type,1    ;other object/
  174.     jne    got_up_vec
  175.     add    eax,offset _up_vecs2
  176.     sub    eax,offset _up_vecs
  177. got_up_vec:
  178.  
  179.     lea    edi,vec_matrix_g
  180.     lea    esi,obj_vec_obj    ;obj_vec_g
  181.     call    vm_vector_2_matrix
  182.  
  183. ;rotate object's matrix through new matrix
  184.  
  185.     lea    eax,new_obj_matrix
  186.     mov    esi,obj_matrix
  187.     lea    edi,vec_matrix_g
  188.     call    vm_matrix_x_matrix
  189.  
  190. ;now, up and right describe edges
  191.  
  192.     vm_copy    up_vec,new_obj_matrix.uvec
  193.     vm_copy    right_vec,new_obj_matrix.rvec
  194.  
  195. ;calculate corner points of bitmap
  196.  
  197.     pop    ecx    ;get size
  198.     sar    ecx,1
  199.  
  200.     lea    ebx,up_vec
  201.     call    vm_vec_scale
  202.  
  203.     lea    ebx,right_vec
  204.     call    vm_vec_scale
  205.  
  206. ;upper left
  207.     lea    eax,up_left_v
  208.     mov    esi,obj_pos
  209.     lea    edi,right_vec
  210.     call    vm_vec_add
  211.  
  212.     mov    edi,eax
  213.     lea    esi,up_vec
  214.     call    vm_vec_add2
  215.  
  216. ;upper right
  217.     lea    eax,up_right_v
  218.     lea    esi,up_left_v
  219.     lea    edi,right_vec
  220.     call    vm_vec_sub
  221.  
  222.     mov    esi,edi    ;rvec
  223.     mov    edi,eax    ;dest=up_right
  224.     call    vm_vec_sub2
  225.  
  226. ;lower right
  227.     lea    eax,down_right_v
  228.     lea    esi,up_right_v
  229.     lea    edi,up_vec
  230.     call    vm_vec_sub
  231.  
  232.     mov    esi,edi    ;uvec
  233.     mov    edi,eax    ;dest=down_right
  234.     call    vm_vec_sub2
  235.  
  236. ;now take three points, rotate & project
  237.  
  238.     lea    esi,up_left_v
  239.     lea    edi,up_left_p
  240.     call    g3_rotate_point
  241.     or    bl,bl
  242.     js    obj_off_screen
  243.  
  244.     lea    esi,up_right_v
  245.     lea    edi,up_right_p
  246.     call    g3_rotate_point
  247.     or    bl,bl
  248.     js    obj_off_screen
  249.  
  250.     lea    esi,down_right_v
  251.     lea    edi,down_right_p
  252.     call    g3_rotate_point
  253.     or    bl,bl
  254.     js    obj_off_screen
  255.  
  256. ;set all z values same before project
  257.     mov    eax,up_left_p.z
  258.     mov    up_right_p.z,eax
  259.     mov    down_right_p.z,eax
  260.  
  261.     lea    esi,up_left_p
  262.     call    g3_project_point
  263.     lea    esi,up_right_p
  264.     call    g3_project_point
  265.     lea    esi,down_right_p
  266.     call    g3_project_point
  267.  
  268.  
  269.     mov    eax,obj_type
  270.     mov    edx,bitmap_number
  271.     lea    ebx,bitmap_points
  272.     call    render_object_
  273.  
  274.     test    draw_bitmap_lines,-1
  275.     jz    skip_lines
  276.  
  277.  extn gr_setcolor_,gr_line_
  278.  
  279.     mov    eax,15
  280.     call    gr_setcolor_
  281.  
  282.     mov    eax,up_left_p.p3_sx
  283.     mov    edx,up_left_p.p3_sy
  284.  
  285.     mov    ebx,up_right_p.p3_sx
  286.     mov    ecx,up_right_p.p3_sy
  287.  
  288.     call    gr_line_
  289.  
  290.     mov    ebx,up_right_p.p3_sx
  291.     mov    ecx,up_right_p.p3_sy
  292.  
  293.     mov    eax,down_right_p.p3_sx
  294.     mov    edx,down_right_p.p3_sy
  295.  
  296.     call    gr_line_
  297. skip_lines:
  298.  
  299. obj_off_screen:
  300.     popm    eax,ebx,ecx,edx,esi,edi
  301.     ret
  302.  
  303.  
  304.  
  305. _TEXT    ends
  306.  
  307.     end
  308.  
  309.