home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / 3d / matrix.asm < prev    next >
Assembly Source File  |  1998-06-08  |  3KB  |  155 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/3d/rcs/matrix.asm $
  13. ; $Revision: 1.4 $
  14. ; $Author: matt $
  15. ; $Date: 1994/11/20 15:59:34 $
  16. ;
  17. ; Source for matrix setup & manipulation routines
  18. ;
  19. ; $Log: matrix.asm $
  20. ; Revision 1.4  1994/11/20  15:59:34  matt
  21. ; instance functions were trashing eax
  22. ; 
  23. ; Revision 1.3  1994/01/04  12:06:17  matt
  24. ; Made scale_matrix save and restore ecx, which it was trashing.
  25. ; 
  26. ; Revision 1.2  1993/11/04  18:49:16  matt
  27. ; Added system to only rotate points once per frame
  28. ; 
  29. ; Revision 1.1  1993/10/29  22:20:27  matt
  30. ; Initial revision
  31. ; 
  32. ;
  33. ;
  34.  
  35. .386
  36.     option    oldstructs
  37.  
  38.     .nolist
  39.     include    types.inc
  40.     include    psmacros.inc
  41.     include    gr.inc
  42.     include    3d.inc
  43.     .list
  44.  
  45.     assume    cs:_TEXT, ds:_DATA
  46.  
  47. _DATA    segment    dword public USE32 'DATA'
  48.  
  49. rcsid    db    "$Id: matrix.asm 1.4 1994/11/20 15:59:34 matt Exp $"
  50.     align    4
  51.  
  52.  
  53. _DATA    ends
  54.  
  55.  
  56.  
  57. _TEXT    segment    dword public USE32 'CODE'
  58.  
  59.  
  60. ;set view from x,y,z, p,b,h, & zoom. 
  61. ;takes esi=orient vec, edi=pos vec, eax=zoom. returns nothing
  62. g3_set_view_angles:
  63.     pushm    eax,edi
  64.  
  65.     mov    View_zoom,eax
  66.  
  67.     vm_copy    View_position,edi    ;trashes eax
  68.  
  69.     lea    edi,View_matrix
  70.     call    vm_angles_2_matrix
  71.  
  72.     jmp    scale_matrix        ;leave eax,edi pushed
  73.  
  74.  
  75. ;set view from x,y,z, matrix, & zoom.
  76. ;takes esi=orientation matrix, edi=pos vec, eax=zoom. returns nothing
  77. g3_set_view_matrix:
  78.     pushm    eax,edi
  79.     pushm    ecx,esi
  80.  
  81.     mov    View_zoom,eax
  82.  
  83.     vm_copy    View_position,edi    ;trashes eax
  84.  
  85.     lea    edi,View_matrix
  86.     mov    ecx,9
  87.     rep    movsd    ;slow? easy anyway...
  88.  
  89.     popm    ecx,esi
  90.  
  91.     jmp    scale_matrix    ;leave eax,edi pushed
  92.  
  93.  
  94. ;scale memory location dest by register s
  95. scale    macro    dest,s
  96.     mov    eax,dest
  97.     fixmul    s
  98.     mov    dest,eax
  99.     endm
  100.  
  101.  
  102. ;scale for aspect ratio, zoom, etc. eax,edi already pushed
  103. scale_matrix:    pushm    esi,ebx,ecx,edx
  104.  
  105.     lea    esi,View_matrix
  106.     lea    edi,Unscaled_matrix
  107.     mov    ecx,9
  108.     rep    movsd    ;save before scaling
  109.  
  110.     vm_copy    Matrix_scale,Window_scale
  111.             ;get aspect ratio scale
  112. ;set scale for zoom
  113.     mov    ebx,View_zoom
  114.     cmp    ebx,f1_0    ;> 1?
  115.     jg    zoom_out    ;..yep
  116.  
  117.     scale    Matrix_scale.z,ebx    ;zoom in by scaling z
  118.     jmp    done_zoom
  119.  
  120. zoom_out:    mov    eax,f1_0
  121.     fixdiv    ebx    ;get 1/zoom
  122.     mov    ebx,eax
  123.     scale    Matrix_scale.x,ebx
  124.     scale    Matrix_scale.y,ebx    ;zoom out by scaling x&y
  125. done_zoom:
  126.  
  127. ;now scale matrix elements
  128.  
  129.     mov    ebx,Matrix_scale.x
  130.     scale    View_matrix.m1,ebx
  131.     scale    View_matrix.m4,ebx
  132.     scale    View_matrix.m7,ebx
  133.  
  134.     mov    ebx,Matrix_scale.y
  135.     scale    View_matrix.m2,ebx
  136.     scale    View_matrix.m5,ebx
  137.     scale    View_matrix.m8,ebx
  138.  
  139.     mov    ebx,Matrix_scale.z
  140.     scale    View_matrix.m3,ebx
  141.     scale    View_matrix.m6,ebx
  142.     scale    View_matrix.m9,ebx
  143.  
  144.  
  145.     popm    esi,ebx,ecx,edx
  146.     popm    eax,edi
  147.     ret
  148.  
  149.  
  150.  
  151. _TEXT    ends
  152.  
  153.     end
  154.  
  155.