home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
club100
/
gam
/
raider.ba
< prev
next >
Wrap
Text File
|
2006-10-19
|
2KB
|
80 lines
1 'Club 100 Library - 415/939-1246 BBS 937-5039 NEWSLETTER, 932-8856 VOICE
10 '
20 ' TOXIC RAIDERS
30 '
40 ' Initialize Game
50 '
60 DEFINT A-Z
70 CLS:PRINT "ENTER H HOR HARD, E FOR EASY: ";
80 C$=INKEY$: IF C$="" THEN 80
90 IF C$="h" OR C$="H" THEN EA=0
100 IF C$="e" OR C$="E" THEN EA=-1
110 DIM D$(319)
120 V=VAL(RIGHT$(TIME$,2))
130 FOR I=0 TO V:R=RND(1):NEXT I
140 H$=CHR$(148):M$=CHR$(171):S=0:MM=4
150 A$=" ":B$=" ":TT=0
160 '
170 ' Print Starting Layout
180 '
190 CLS:FOR I=34 TO 314 STEP 40:PRINT@I,CHR$(239);:NEXT I
200 PRINT@35,S;:PRINT@155,MM;
210 Y=4:X=33:H=193
220 PRINT@H,H$;:X1=1:Y1=Y
230 J=3:I=0:M=120
240 PRINT@120,M$;:J1=J:I1=I
250 '
260 ' Print Targets
270 '
280 FOR K=0 TO 319:D$(K)=" ":NEXT K
290 FOR K=1 TO 10
300 U=INT(RND(1)*32+1):V=INT(RND(1)*8)
310 PD=U+40*V
320 IF D$(PD)<>" " THEN 300
330 D$(PD)=CHR$(134):PRINT@PD,D$(PD);
340 NEXT K
350 B$=INKEY$:B$=INKEY$:B$=INKEY$:B$=INKEY$
360 '
370 ' Move Hero
380 '
390 B$=INKEY$:IF B$="" THEN B$=A$
400 IF B$="j" OR B$="J" THEN X=X+1:IF X>33 THEN X=0
410 IF B$="g" OR B$="G" THEN X=X-1:IF X<0 THEN X=33
420 IF B$="h" OR B$="H" THEN Y=Y+1:IF Y>7 THEN Y=0
430 IF B$="y" OR B$="Y" THEN Y=Y-1:IF Y<0 THEN Y=7
440 H=X+40*Y:H1=X1+40*Y1
450 PRINT @H1," ";:PRINT @H,H$;
460 X1=X:Y1=Y:A$=B$
470 IF D$(H)=" " THEN 510
480 SOUND 16000,2:S=S+10:D$(H)=" ":PRINT@35,S;:TT=TT+1
490 IF TT=10 THEN 150 ELSE 580
500 '
510 ' Move Chaser
520 '
530 ' If "Hard" Then Move Chaser, Else Move Every Other Time
540 '
550 IF NOT(EA) THEN 580
560 F=NOT(F):IF F=-1 THEN 390
570 '
580 IF X=I THEN 600
590 IF X>I THEN I=I+1 ELSE I=I-1
600 IF Y=J THEN 620
610 IF Y>J THEN J=J+1 ELSE J=J-1
620 M=I+40*J:M1=I1+40*J1
630 PRINT @M,M$;:PRINT@M1,D$(M1);
640 J1=J:I1=I
650 IF M<>H THEN 390
660 SOUND 8000,4:MM=MM-1
670 IF MM=0 THEN 730
680 PRINT@35,S;:PRINT@155,MM;
690 GOTO 150
700 '
710 ' End of Game
720 '
730 PRINT@95,"GAME OVER";
740 PRINT@155,MM
750 PRINT@175,"SCORE: ";S;
760 R$=INKEY$:R$=INKEY$
770 R$=INKEY$:IF R$="" THEN 770
780 GOTO 120