home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / gam / raider.ba < prev    next >
Text File  |  2006-10-19  |  2KB  |  80 lines
  1. 1 'Club 100 Library - 415/939-1246 BBS     937-5039 NEWSLETTER, 932-8856 VOICE
  2. 10 '
  3. 20 ' TOXIC RAIDERS
  4. 30 ' 
  5. 40 ' Initialize Game
  6. 50 '
  7. 60 DEFINT A-Z
  8. 70 CLS:PRINT "ENTER H HOR HARD, E FOR EASY: ";
  9. 80 C$=INKEY$: IF C$="" THEN 80
  10. 90 IF C$="h" OR C$="H" THEN EA=0
  11. 100 IF C$="e" OR C$="E" THEN EA=-1
  12. 110 DIM D$(319)
  13. 120 V=VAL(RIGHT$(TIME$,2))
  14. 130 FOR I=0 TO V:R=RND(1):NEXT I
  15. 140 H$=CHR$(148):M$=CHR$(171):S=0:MM=4
  16. 150 A$=" ":B$=" ":TT=0
  17. 160 '
  18. 170 ' Print Starting Layout
  19. 180 '
  20. 190 CLS:FOR I=34 TO 314 STEP 40:PRINT@I,CHR$(239);:NEXT I
  21. 200 PRINT@35,S;:PRINT@155,MM;
  22. 210 Y=4:X=33:H=193
  23. 220 PRINT@H,H$;:X1=1:Y1=Y
  24. 230 J=3:I=0:M=120
  25. 240 PRINT@120,M$;:J1=J:I1=I
  26. 250 '
  27. 260 ' Print Targets
  28. 270 '
  29. 280 FOR K=0 TO 319:D$(K)=" ":NEXT K
  30. 290 FOR K=1 TO 10
  31. 300 U=INT(RND(1)*32+1):V=INT(RND(1)*8)
  32. 310 PD=U+40*V
  33. 320 IF D$(PD)<>" " THEN 300
  34. 330 D$(PD)=CHR$(134):PRINT@PD,D$(PD);
  35. 340 NEXT K
  36. 350 B$=INKEY$:B$=INKEY$:B$=INKEY$:B$=INKEY$
  37. 360 '
  38. 370 ' Move Hero
  39. 380 '
  40. 390 B$=INKEY$:IF B$="" THEN B$=A$
  41. 400 IF B$="j" OR B$="J" THEN X=X+1:IF X>33 THEN X=0
  42. 410 IF B$="g" OR B$="G" THEN X=X-1:IF X<0 THEN X=33
  43. 420 IF B$="h" OR B$="H" THEN Y=Y+1:IF Y>7 THEN Y=0
  44. 430 IF B$="y" OR B$="Y" THEN Y=Y-1:IF Y<0 THEN Y=7
  45. 440 H=X+40*Y:H1=X1+40*Y1
  46. 450 PRINT @H1," ";:PRINT @H,H$;
  47. 460 X1=X:Y1=Y:A$=B$
  48. 470 IF D$(H)=" " THEN 510
  49. 480 SOUND 16000,2:S=S+10:D$(H)=" ":PRINT@35,S;:TT=TT+1
  50. 490 IF TT=10 THEN 150 ELSE 580
  51. 500 '
  52. 510 ' Move Chaser
  53. 520 '
  54. 530 ' If "Hard" Then Move Chaser, Else Move Every Other Time
  55. 540 '
  56. 550 IF NOT(EA) THEN 580
  57. 560 F=NOT(F):IF F=-1 THEN 390
  58. 570 '
  59. 580 IF X=I THEN 600
  60. 590 IF X>I THEN I=I+1 ELSE I=I-1
  61. 600 IF Y=J THEN 620
  62. 610 IF Y>J THEN J=J+1 ELSE J=J-1
  63. 620 M=I+40*J:M1=I1+40*J1
  64. 630 PRINT @M,M$;:PRINT@M1,D$(M1);
  65. 640 J1=J:I1=I
  66. 650 IF M<>H THEN 390
  67. 660 SOUND 8000,4:MM=MM-1
  68. 670 IF MM=0 THEN 730
  69. 680 PRINT@35,S;:PRINT@155,MM;
  70. 690 GOTO 150
  71. 700 '
  72. 710 ' End of Game
  73. 720 '
  74. 730 PRINT@95,"GAME OVER";
  75. 740 PRINT@155,MM
  76. 750 PRINT@175,"SCORE:  ";S;
  77. 760 R$=INKEY$:R$=INKEY$
  78. 770 R$=INKEY$:IF R$="" THEN 770
  79. 780 GOTO 120
  80.