home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / gam / rater.ba < prev    next >
Text File  |  2006-10-19  |  4KB  |  69 lines
  1. 0 'RATER.BA Gene Nestro 
  2. 1 'CLUB 100 Library - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
  3. 2 'Mods by Bill Templeton
  4. 3 ' 3-Jul-86
  5. 4 'You need and must understand a RACING
  6. 5 'FORM.  Use inputs of "head = .06 /
  7. 6 'Distance Code = race your rating
  8. 7 '(last performance). Does not rate
  9. 8 'Maiden Races or horses that did
  10. 9 'not run in last 2 weeks.
  11. 10 DIMX(12):E$=CHR$(27):R$=E$+"p":N$=E$+"q
  12. 11 X(1)=0:X(2)=6:X(3)=12.2:X(4)=18.4:X(5)=24.6:X(6)=37.4:X(7)=39.6:X(8)=41.8:X(9)=44:X(10)=51.2:X(11)=58.4:X(12)=65.6:CLS
  13. 12 SCREEN0,0:CLS:LINE(11,8)-(227,55),1,B:PRINT@95,R$" RATER.100 "N$:PRINT@179,"by":PRINT@215,"Gene Nestro
  14. 13 PRINT@123,CHR$(126)CHR$(145)CHR$(145)CHR$(225):PRINT@153,CHR$(226)CHR$(145)CHR$(145)CHR$(126)
  15. 14 IFINKEY$=""THEN14
  16. 15 CLS:PRINT@81,R$" Do you want Bugle Call (Y/N ?):"N$" ";:A$=INPUT$(1):IFINSTR("yY",A$)THENGOSUB64
  17. 16 PRINT@162,"Enter `99' if you keyed-in wrong        answer to a prior question. Enter       final results in your Racing Form.
  18. 17 IFINKEY$=""THEN17
  19. 18 CLS:DC=0:PRINT"  1 = 5 Furlongs        7 = 1 Mi 40 Yd":PRINT"  2 = 5 1/2 Furlongs    8 = 1 Mi 70 yd
  20. 19 PRINT"  3 = 6 Furlongs        9 = 1 1/16 Mile":PRINT"  4 = 6 1/2 Furlongs   10 = 1 1/8  Mile
  21. 20 PRINT"  5 = 7 Furlongs       11 = 1 3/16 Mile":PRINT"  6 = 1 Mile           12 = 1 1/4  Mile":CALL16959
  22. 21 PRINT@280,R$" Key in selected distance code #:"N$;:INPUTDC:IFDC=99THEN15
  23. 22 IFDC<1ORDC>12THEN21
  24. 23 GOSUB61
  25. 24 FR=0:GOSUB63:PRINT@280,R$" Fractional time (40-150): "N$;:INPUTFR:IFFR=99THEN18
  26. 25 IFFR<40ORFR>150THEN24
  27. 26 FT=0:GOSUB63:PRINT@280,R$" Final time (50-240): "N$;:INPUTFT:IFFT=99THEN24
  28. 27 IFFT<50ORFT>240THEN26
  29. 28 LT=0:GOSUB63:PRINT@280,R$" Lengths behind 3rd call (0-5): "N$;:INPUTLT:IFLT=99THEN26
  30. 29 IFLT<0ORLT>5THEN28
  31. 30 LF=0:GOSUB63:PRINT@280,R$" Lengths behind winner (0-5): "N$;:INPUTLF:IFLF=99THEN28
  32. 31 IFLF<0ORLF>50THEN30
  33. 32 WT=0:GOSUB63:PRINT@280,R$" Weight carried today (90-150): "N$;:INPUTWT:IFWT=99THEN30
  34. 33 IFWT<90ORWT>150THEN32
  35. 34 WR=0:GOSUB63:PRINT@280,R$" Weight rating (90-150): "N$;:INPUTWR:IFWR=99THEN32
  36. 35 IFWR<90ORWR>150THEN34
  37. 36 SR=0:GOSUB63:PRINT@280,R$" Speed rating (0-120): "N$;:INPUTSR:IFSR=99THENGOTO34
  38. 37 IFSR<0ORSR>120THEN36
  39. 38 VA=0:GOSUB63:PRINTR$" Variant (0-100): "N$;:INPUTVA:IFVA=99THEN36
  40. 39 IFVA<0ORVA>100THEN38
  41. 40 IFDC<6THENWA=((WR-WT)/4)ELSEWA=((WR-WT)/3)
  42. 41 GOSUB44:GOSUB55:R=WA+A+B+SR+(VA*.5):R=INT(R):CLS:PRINT@82,R$" Total rating is:"N$;R
  43. 42 PRINT@165,"Write this rating in Racing Form":PRINT@242,R$" Another horse (Y/N ?):"N$;:Q$=INPUT$(1)
  44. 43 PRINT:IFINSTR("yY",Q$)THENCLS:GOTO18ELSEMENU
  45. 44 IFFT>=200THENM=2
  46. 45 IFFT>=200GOTO49
  47. 46 IFFT>=100THENM=1
  48. 47 IFFT>=100GOTO49
  49. 48 M=0
  50. 49 IFFT>=200THENS=FT-200
  51. 50 IFFT>=200GOTO54
  52. 51 IFFT>=100THENS=FT-100
  53. 52 IFFT>=100GOTO54
  54. 53 S=FT
  55. 54 T=S-INT(S):T=T*2:S=INT(S):FT=(M*60)+S+T:FT=FT+(LF*.2):FORX=1TO12:K=X(DC)+56:NEXTX:B=FT-K:B=B*10:B=200-B
  56. 55 IFFR>=100THENM=1ELSEM=0
  57. 56 IFFR>=100THENS=FR-100ELSES=FR
  58. 57 T=S-INT(S):S=INT(S):T=T*2:FR=(M*60)+S+T:FR=FR+(LT*.2):IFDC<6THENA=FR-48
  59. 58 IFDC>5ANDDC<12THENA=FR-72.4
  60. 59 IFDC=12THENA=FR-97
  61. 60 A=A*5:A=100-A:RETURN
  62. 61 CLS:PRINT@40,R$" Fractional & Final time entry examples:"N$:PRINT@136,"1:12 = 112":PRINT@174,"58 2/5 = 58.2
  63. 62 PRINT@212,"1:22 3/5 = 122.3":PRINT:RETURN
  64. 63 PRINT@280,SPACE$(39):RETURN
  65. 64 SOUND6269,7:SOUND4697,7:SOUND3728,7:SOUND3134,25:SOUND3134,7:SOUND3134,7:SOUND3134,7:SOUND3728,25:SOUND3728,7:SOUND3728,7
  66. 65 SOUND3728,7:SOUND4697,25:SOUND3728,12:SOUND4697,12:SOUND6269,50:SOUND6269,7:SOUND4697,7:SOUND3728,7:SOUND3134,25:SOUND3134,7
  67. 66 SOUND3134,7:SOUND3134,7:SOUND3728,25:SOUND3728,7:SOUND3728,7:SOUND3728,7:SOUND4697,25:SOUND6269,18:SOUND6269,18:SOUND4697,75
  68. 67 RETURN
  69.