home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / gam / quest.200 < prev    next >
Text File  |  2006-10-19  |  14KB  |  275 lines
  1. 1 'QUEST!.BA V2.1 C FRED BROWN 1988       Club 100 Library 415-939-1246 bbs
  2. 2 CLS:CLEAR1000:DEFINTA-Z:SCREEN0,0:CALL20318
  3. 3 VP$=CHR$(27)+"p":VQ$=CHR$(27)+"q":CS$=CHR$(27)+"J":CL$=CHR$(27)+"K":PRINTVP$;" QUEST!";SPACE$(33);VQ$
  4. 4 DIMA(606),R(101),C(30),CR$(7),W$(9),A$(9),S$(20),R$(10):POKE63277,PEEK(61983)
  5. 5 FORI=1TO7:READCR$(I):NEXT:FORI=1TO9:READW$(I):NEXT:FORI=1TO9:READA$(I):NEXT:K$="ZIEGFRIED"
  6. 6 FORI=1TO9:READM$(I):NEXT:FORI=1TO9:READO$(I):NEXT:FORI=1TO20:READS$(I):NEXT:FORI=1TO10:READR$(I):NEXT
  7. 7 DATA COMBAT,WISDOM,AGILITY,LUCK,HEALTH,GOLD,SPELLS
  8. 8 DATA Cleaver,Dagger,Axe,Club,Staff,Sword,Blade,Saber,Colt 45
  9. 9 DATA Wrappings,Buckler,Leather,Helm,Shield,Chainmail,Ringmail,Platemail,Magic Cloak
  10. 10 DATA RAT,SKELETON,GOBLIN,GUARD,HOBGOBLIN,ORC,SLIMER,TROLL,HYDRA
  11. 11 DATA a boot,old rations,a mirror,blood,a used torch,a footprint,a sack,a skull,a bag
  12. 12 DATA XNQ[JW%NX%KNWXY,LTQI%NX%XJHTSI,NWTS%NX%YMNWI,YMJ%YWZJ%HWT\S%NX%XNQ[JW
  13. 13 DATA YMJ%KFQXJ%HWT\S%NX%LTQI,INFRTSI%NX%IJFIQ^,ITSY%KJJI%YMJ%IWFLTS
  14. 14 DATA MNX%SFRJ%NX%_NJLKWNJI,YMJ%IWFLTS%MFX%F%PJ^,YMJ%PSNLMY%MFX%F%PJ^
  15. 15 DATA YMJ%LTGQNS%PNSL%MFX%F%PJ^,IWNSP%IJJU%YMJ%\FYJW,IWNSP%STY%YMJ%\NSJ
  16. 16 DATA YMJ%RFLJ%UTNSYX%YT%IJFYM,YMJ%WJI%QJ[JW%GWNSLX%UFNS,YMJ%LWJJS%QJ[JW%GWNSLX%MJQU
  17. 17 DATA YMJ%WJI%GZYYTS%GWNSLX%MJQU,YMJ%LWJJS%GZYYTS%GWNSLX%UFNS,YMWJJ%PJ^X%\NQQ%ZSQTHP%YMJ%HWT\S,FWJ%\J%MF[NSL%KZS%^JYD
  18. 18 DATA the Crystal Cave,the Sysop's Corner,the Den of Inequity,the Radio Shack
  19. 19 DATA the Ogre's Hole,the Oval Office,the Silver Shaft,the Blue Lagoon,the Mage's Room,the Outhouse
  20. 20 X=FRE(A$):PRINT@40,CS$:PRINT"[F1]: LOAD CHARACTER"
  21. 21 PRINT"[F2]: NEW CHARACTER":PRINT"[F4]: BEGIN":PRINT"[F5]: SAVE CHARACTER"
  22. 22 PRINT"[F8]: MENU":PRINT@565,VP$;" PRESS [CAPS LOCK]! ";VQ$
  23. 23 KEYON:ONKEYGOSUB25,27,,32,30,,,24:GOTO23
  24. 24 MENU
  25. 25 PRINT@560,CS$;"Loading..."
  26. 26 OPEN"CHARSV"FORINPUTAS1:INPUT#1,N$:FORI=1TO30:INPUT#1,C(I):NEXT:CLOSE:GOTO32
  27. 27 PRINT@560,CS$;"NAME:";:INPUTN$
  28. 28 FORI=1TO5:C(I)=RND(1)*9+1:NEXT
  29. 29 C(5)=C(5)+9:C(6)=C(5):C(7)=100+RND(1)*200:C(11)=1:C(12)=1:GOTO32
  30. 30 PRINT@560,CS$;"Saving..."
  31. 31 OPEN"CHARSV"FOROUTPUTAS1:PRINT#1,N$:FORI=1TO30:PRINT#1,C(I);",";:NEXT:CLOSE:GOTO20
  32. 32 PRINT@40,CS$:GOSUB207:LINE(0,80)-(239,80):LINE(100,0)-(100,80):LINE(150,20)-(200,70),1,B
  33. 33 PRINT@229,CHR$(148):PRINT@65,"TAVERN":IFC(16)THEN257
  34. 34 PRINT@440," [Q]UIT [G]AMBLE [B]UY"," [R]EST [D]EPART [T]RAIN [P]ACK";CS$
  35. 35 I$=INPUT$(1):PRINT@440,CS$;:ONINSTR("QTGBRPD",I$)GOTO20,37,41,45,76,79,80
  36. 36 BEEP:GOTO34
  37. 37 PRINT"COST IS 1000 GOLD."
  38. 38 PRINT"[C]OMBAT [W]ISDOM [A]GILITY [L]UCK"
  39. 39 I$=INPUT$(1):IFC(7)<1000THENBEEP:GOTO34ELSET=INSTR("CWAL",I$)
  40. 40 C(7)=C(7)-1000:C(T)=C(T)+1:GOSUB207:GOTO34
  41. 41 PRINT@440,CS$;"AMOUNT WAGERED";
  42. 42 INPUTG:IFG>C(7)THENBEEP:GOTO41
  43. 43 W=0:IFC(4)/10>RND(1)THENW=G*2*RND(1):ELSEC(7)=C(7)-G
  44. 44 PRINT"WINNINGS:";W:C(7)=C(7)+W:GOSUB207:GOSUB219:GOTO34
  45. 45 PRINT@440,CS$;C$;" [A]RMOR [W]EAPON [S]CROLL"," [T]ORCH [R]ATION [P]OINTS"
  46. 46 I$=INPUT$(1):PRINT@440,CS$;:ONINSTR("AWSTRP",I$)GOTO48,53,59,66,69,72
  47. 47 BEEP:GOTO34
  48. 48 FORI=1TO4:CT(I)=(I+3)^(3+RND(1)):PRINTI;A$(I);TAB(15);"GOLD:";CT(I),:NEXT
  49. 49 PRINT" SELECT ARMOR ";:I$=INPUT$(1):IN=VAL(I$)
  50. 50 IFC(7)<CT(IN)THENBEEP:GOTO34
  51. 51 IFIN<1ORIN>4THENBEEP:GOTO75
  52. 52 C(7)=C(7)-CT(IN):C(9)=IN:GOTO75
  53. 53 FORI=1TO4:CT(I)=(I+3)^(3+RND(1))
  54. 54 PRINTI;W$(I);TAB(15);"GOLD:";CT(I),:NEXT
  55. 55 PRINT" SELECT WEAPON ";:I$=INPUT$(1):IN=VAL(I$)
  56. 56 IFC(7)<CT(IN)THENBEEP:GOTO34
  57. 57 IFIN<1ORIN>4THENBEEP:GOTO75
  58. 58 C(7)=C(7)-CT(IN):C(10)=IN:GOTO75
  59. 59 PRINT"COST IS 250 GOLD PER SCROLL Y/N?"
  60. 60 I$=INPUT$(1):IFI$<>"Y"THEN34
  61. 61 IFC(7)<250THENBEEP:GOTO34
  62. 62 C(7)=C(7)-250:S=RND(1)*20+1:S$=S$(S)
  63. 63 FORI=1TOLEN(S$)
  64. 64 IFC(2)/8>RND(1)THENX$=CHR$(ASC(MID$(S$,I,1))-5)ELSEX$=MID$(S$,I,1)
  65. 65 PRINTX$;:NEXT:GOSUB219:GOTO75
  66. 66 PRINT"COST IS 50 GOLD PER TORCH"
  67. 67 PRINT"HOW MANY (1-9)";:I$=INPUT$(1):IN=VAL(I$):IF50*IN>C(7)THENBEEP:GOTO34
  68. 68 C(7)=C(7)-50*IN:C(11)=C(11)+IN:GOTO75
  69. 69 PRINT"COST IS 60 GOLD PER RATION"
  70. 70 PRINT"HOW MANY (1-9)";:I$=INPUT$(1):IN=VAL(I$):IF60*IN>C(7)THENBEEP:GOTO34
  71. 71 C(7)=C(7)-60*IN:C(12)=C(12)+IN:GOTO75
  72. 72 PRINT"COST IS 500 GOLD PER POINT"
  73. 73 PRINT"HOW MANY (1-9)";:I$=INPUT$(1):IN=VAL(I$):IF500*IN>C(7)THENBEEP:GOTO34
  74. 74 C(7)=C(7)-500*IN:C(8)=C(8)+IN
  75. 75 GOSUB207:GOTO34
  76. 76 PRINT@440,CS$;"COST IS 50 GOLD PER DAY"
  77. 77 PRINT"DAYS? (1-9)";:I$=INPUT$(1):D=VAL(I$):IF50*D>C(7)THENBEEP:GOTO34
  78. 78 FORI=1TOD:C(7)=C(7)-50:C(6)=C(6)+1:GOSUB207:NEXTI:GOTO34
  79. 79 GOSUB212:GOTO34
  80. 80 R=1:PRINT@65,"MAZE  ":IFFLTHEN83
  81. 81 PRINT@560,CS$;"Loading Maze...":FL=1
  82. 82 FORI=1TO606:READA(I):PRINT@580,I:NEXT:CLOSE#1
  83. 83 IFC(11)THENTR=20
  84. 84 IFC(12)THENRA=30
  85. 85 GOTO96
  86. 86 PRINT@440,"[P]ACK [M]AGIC ";CHR$(155);CHR$(152);CHR$(154);CHR$(153);CS$
  87. 87 I$=INKEY$:IFI$=""THEN87ELSEIN=ASC(I$)
  88. 88 IFIN=80THENGOSUB212:GOTO86
  89. 89 IFIN=77THENGOSUB222:GOTO86
  90. 90 IFIN=28THENR=A(A+2)
  91. 91 IFIN=29THENR=A(A+4)
  92. 92 IFIN=30THENR=A(A+1)
  93. 93 IFIN=31THENR=A(A+3)
  94. 94 IFIN=27THENMENU
  95. 95 IFR=0THENBEEP:GOTO86
  96. 96 LINE(150,20)-(200,70),1,B:A=R*6-5
  97. 97 IFTR<1THEN103
  98. 98 IFA(A+1)THENLINE(170,20)-(180,20),0
  99. 99 IFA(A+2)THENLINE(200,40)-(200,50),0
  100. 100 IFA(A+3)THENLINE(170,70)-(180,70),0
  101. 101 IFA(A+4)THENLINE(150,40)-(150,50),0
  102. 102 TR=TR-1:IFTR<1THENGOSUB253
  103. 103 RA=RA-1:IFRA<1THENGOSUB255
  104. 105 IFR(R)THENPRINT@560,"THIS ROOM SEEMSFAMILIAR"ELSEPRINT@480,CS$
  105. 106 IFA(R*6)THEN108ELSEIFRND(1)>.7THEN185
  106. 107 R(R)=1:GOTO87
  107. 108 PRINT@440,CS$;:IFA(R*6)>20THEN184
  108. 109 ONA(R*6)GOTO110,113,116,119,122,125,128,140,144,154,157,159,161,165,168,170,175,176,178,182
  109. 110 IFC(16)THEN86
  110. 111 PRINT"IN THE ROOM IS A SILVER CROWN","[T]AKE THE CROWN":I$=INPUT$(1):IFI$="T"THENC(16)=1
  111. 112 GOTO86
  112. 113 IFC(13)THEN86
  113. 114 PRINT"IN THE ROOM IS AN IRON KEY","[T]AKE THE KEY":I$=INPUT$(1):IFI$="T"THENC(13)=1
  114. 115 GOTO86
  115. 116 IFC(14)THEN86
  116. 117 PRINT"IN THE ROOM IS A SILVER KEY","[T]AKE THE KEY":I$=INPUT$(1):IFI$="T"THENC(14)=1
  117. 118 GOTO86
  118. 119 IFC(15)THEN86
  119. 120 PRINT"IN THE ROOM IS A GOLD KEY","[T]AKE THE KEY":I$=INPUT$(1):IFI$="T"THENC(15)=1
  120. 121 GOTO86
  121. 122 PRINT"THERE IS A LOCKED WOODEN DOOR"
  122. 123 PRINT"[U]SE A KEY":I$=INPUT$(1):IFI$<>"U"THENR=46:GOTO258
  123. 124 GOSUB131:IFK=2THEN86ELSE139
  124. 125 PRINT"THERE IS A LOCKED METAL DOOR"
  125. 126 PRINT"[U]SE A KEY":I$=INPUT$(1):IFI$<>"U"THENR=46:GOTO258
  126. 127 GOSUB131:IFK=3THEN86ELSE139
  127. 128 PRINT"THERE IS A LOCKED SILVER DOOR"
  128. 129 PRINT"[U]SE A KEY":I$=INPUT$(1):IFI$<>"U"THENR=46:GOTO258
  129. 130 GOSUB131:IFK=1THEN86ELSE139
  130. 131 PRINT@440,"USE:";CS$
  131. 133 IFC(13)THENPRINT"[I]RON KEY"
  132. 134 IFC(14)THENPRINT"[S]ILVER KEY"
  133. 135 IFC(15)THENPRINT"[G]OLD KEY"
  134. 136 U$=INPUT$(1):IFINSTR("ISG",U$)THEN137ELSE138
  135. 137 K=INSTR("ISG",U$):IFC(K+12)THENRETURN
  136. 138 SOUND4000,5:PRINT@440,CS$;"YOU DON'THAVE THAT KEY!":GOSUB219:R=46:GOTO96
  137. 139 SOUND2000,10:PRINT@440,CS$;"OOPS...":GOSUB219:C(6)=1:R=46:GOSUB207:GOTO96
  138. 140 CT=0:NA$="":PRINT"IN THE ROOM IS A KNIGHT","He asks: What is my name?"
  139. 141 INPUTNA$:IFNA$=K$THENPRINT"Pass Friend.":GOTO218
  140. 142 FORI=1TOLEN(NA$):IFINSTR(K$,MID$(NA$,I,1))THENCT=CT+1
  141. 143 NEXT:CT=CT/9*100:PRINT"Well,"CT"percent correct...";CL$:GOSUB219:R=53:GOTO96
  142. 144 IFC(25)THEN86
  143. 145 PRINT"IN THE ROOM IS A VERY LARGE DRAGON"
  144. 146 PRINT@480,"He asks: what will you give me?"
  145. 147 PRINT"GIVE [R]ATION [G]OLD [N]OTHING";CS$;
  146. 148 I$=INPUT$(1):ONINSTR("RGN",I$)GOTO149,152,151
  147. 149 IFC(12)=0THEN151ELSEC(12)=C(12)-1
  148. 150 IFC(4)/10>RND(1)THENPRINT@560,"I'M STILL HUNGRY!":GOSUB219:GOTO146
  149. 151 ML=30:MR=20:MW=9999:CR=C(1)+C(9):GOSUB244:C(25)=1:GOTO86
  150. 152 C=C(7):C(7)=0:IFC>1000THEN218
  151. 153 PRINT@560,"NOT ENOUGH FOOLISH HUMAN!"::GOSUB219:GOTO151
  152. 154 IFC(26)THEN86
  153. 155 PRINT"IN THE ROOM IS THE GOBLIN KING"
  154. 156 ML=20:GOSUB238:C(26)=1:GOTO86
  155. 157 PRINT"IN THE ROOM IS A POOL OF WINE","[D]RINK FROM THE POOL":I$=INPUT$(1):IFI$<>"D"THEN86
  156. 158 C(6)=C(6)/2:PRINT"OUCH...":GOTO218
  157. 159 PRINT"IN THE ROOM IS A POOL OF WATER","[D]RINK FROM THE POOL":I$=INPUT$(1):IFI$<>"D"THEN86
  158. 160 C(6)=C(5):GOTO218
  159. 161 PRINT"IN THE ROOM ARE THREE BUTTONS","PUSH: [R]ED BUTTON [G]REEN BUTTON","      [Y]ELLOW BUTTON"
  160. 162 I$=INPUT$(1):ONINSTR("RGY",I$)GOTO160,158,164
  161. 163 BEEP:GOTO86
  162. 164 SOUND2000,5:R=82:GOTO96
  163. 165 PRINT"IN THE ROOM ARE TWO LEVERS"
  164. 166 PRINT"PULL [R]ED LEVER [G]REEN LEVER":I$=INPUT$(1):ONINSTR("RG",I$)GOTO158,160
  165. 167 BEEP:GOTO86
  166. 168 PRINT"IN THE ROOM IS A GOLDEN CROWN"
  167. 169 PRINT"[T]AKE THE CROWN":I$=INPUT$(1):IFI$="T"THEN158ELSE86
  168. 170 PRINT"IN THE ROOM IS A WOODEN CHEST"
  169. 171 PRINT"[O]PEN THE CHEST":I$=INPUT$(1):IFI$<>"O"THEN86
  170. 172 IFC(4)/10<RND(1)THEN158
  171. 173 IFC(27)THENPRINT"EMPTY...":GOTO218
  172. 174 PRINT"YOU FIND 5000 GOLD PIECES!":C(7)=C(7)+5000:C(27)=1:GOTO218
  173. 175 PRINT"YOU FALL INTO A BOTTOMLESS PIT!":GOSUB219:GOTO211
  174. 176 PRINT"IN THE ROOM IS A DIAMOND KEY"
  175. 177 PRINT"[T]AKE THE KEY":I$=INPUT$(1):IFI$="T"THEN158ELSE86
  176. 178 PRINT"IN THE ROOM IS A MAGE'S STATUE","HE SAYS: BEWARE FOOLISH HUMAN!":S$=S$(RND(1)*20)180 FORI=1TOLEN(S$):PRINTCHR$(ASC(MID$(S$,I,1))-5);:NEXT:PRINT:GOTO158
  177. 182 PRINT"YOU STAND AT THE ENTRANCE OF THE MAZE","[L]EAVE THE MAZE
  178. 183 I$=INPUT$(1):IFI$="L"THEN32ELSE86
  179. 184 PRINT"You are in ";R$(A(R*6)-20):GOTO218
  180. 185 PRINT@440,CS$;:IFR(R)THEN206
  181. 186 E=RND(1)*9+1:ONEGOSUB188,189,190,190,196,199,202,204,206
  182. 187 RETURN
  183. 188 O=RND(1)*9+1:PRINT"You find ";O$(O):PRINT"of no value.":GOTO218
  184. 189 G=RND(1)*100+1:PRINT"You find a bag o' gold","worth";G;"gold pieces.":C(7)=C(7)+G:GOTO218
  185. 190 PRINT"You find a scroll!","[R]EAD":I$=INPUT$(1):IFI$<>"R"THEN86ELSEPRINT@440,CS$
  186. 191 IFC(4)/10<RND(1)THENPRINT"You are Cursed!":GOTO158
  187. 192 S=RND(1)*20+1:S$=S$(S):PRINTS;
  188. 193 FORI=1TOLEN(S$)
  189. 194 IFC(2)/8>RND(1)THENX$=CHR$(ASC(MID$(S$,I,1))-5)ELSEX$=MID$(S$,I,1)
  190. 195 PRINTX$;:NEXT:GOTO218
  191. 196 PRINT"You find a potion!","[D]RINK":I$=INPUT$(1):IFI$<>"D"THEN86
  192. 197 IFC(4)/10<RND(1)THENPRINT"Poison!":C(6)=C(6)-RND(1)*4+1:GOTO158
  193. 198 P=RND(1)*5+1:PRINT"A potion of ";CR$(P):C(P)=C(P)+1:GOTO218
  194. 199 PRINT"You find a Book of Magic!","[R]EAD":I$=INPUT$(1):IFI$<>"R"THEN86
  195. 200 IFC(4)/10<RND(1)THENR=RND(1)*50+10:PRINT"You feel dizzy...":FORI=1TO1000:NEXT:SOUND2000,5:GOTO96
  196. 201 S=RND(1)*6+1:PRINT"You gain";S;"Spell Points!":C(8)=C(8)+S:GOTO218
  197. 202 WP=RND(1)*9+1:PRINT"You find a ";W$(WP),"[T]AKE":I$=INPUT$(1):IFI$="T"THENC(10)=WP
  198. 203 GOTO86
  199. 204 AR=RND(1)*9+1:PRINT"You find ";A$(AR),"[T]AKE":I$=INPUT$(1):IFI$="T"THENC(9)=AR
  200. 205 GOTO86
  201. 206 M=RND(1)*9+1:PRINT"You encounter a ";M$(M):GOSUB237:GOTO86
  202. 207 IFC(6)>C(5)THENC(6)=C(5)ELSEIFC(7)>9999THENC(7)=9999
  203. 208 PRINT@40,N$:FORII=1TO5:PRINT@II*40+40,CR$(II);TAB(7);C(II):NEXT
  204. 209 PRINTCR$(6);TAB(7);C(7);"   ":PRINTCR$(7);TAB(7);C(8):PRINT@250,"/";C(6):IFC(6)<1THEN211
  205. 210 RETURN
  206. 211 PRINT@440,CS$;"You are dead!","Sorryabout that..."," Better luck next time!";:END
  207. 212 PRINT@440,CS$;"ARMOR: ";A$(C(9));"  WEAPON: ";W$(C(10)):PRINT"TORCHES:";C(11);" RATIONS: ";C(12)
  208. 213 IFC(13)THENPRINT"IRON KEY ";
  209. 214 IFC(14)THENPRINT"SILVER KEY ";
  210. 215 IFC(15)THENPRINT"GOLD KEY ";
  211. 216 IFC(16)THENPRINTVP$;" CROWN ";VQ$
  212. 217 GOSUB219:RETURN
  213. 218 GOSUB207:GOSUB219:GOTO86
  214. 219 FORII=1TO5:PRINT@229,CHR$(255)
  215. 220 FORJJ=1TO200:NEXT:PRINT@229,CHR$(148)
  216. 221 FORJJ=1TO200:NEXT:NEXT:RETURN
  217. 222 PRINT@440,CS$;"SELECT SPELL:"
  218. 223 PRINT"[R]OOM: 1 PT  [T]RCH: 2 PTS"
  219. 224 PRINT"[F]OOD: 3 PTS [H]EAL: 4 PTS"
  220. 225 PRINT"[P]ORT: 5 PTS [K]ILL: 6 PTS";
  221. 226 I$=INPUT$(1):SV=INSTR("RTFHPK",I$):IFC(8)<SVTHENBEEP:RETURN
  222. 227 C(8)=C(8)-SV::PRINT@440,CS$:ONINSTR("RTFHPK",I$)GOTO229,230,231,234,232,235
  223. 228 BEEP:RETURN
  224. 229 PRINT"You are in room";R:GOTO236
  225. 230 C(11)=C(11)+1:TR=35:PRINT"Let there be light!":GOTO236
  226. 231 C(12)=C(12)+1:RA=25:PRINT"Let there be food!":GOTO236
  227. 232 INPUT"ROOM NUMBER";RN:IFRN>101ORRN<1THENRN=R
  228. 233 R=RN:SOUND2000,5:GOTO96
  229. 234 C(6)=C(5):PRINT"The pause that refreshes!":GOTO236
  230. 235 ML=ML/3:PRINT"Prepare to die monsterscum!"
  231. 236 GOSUB207:GOSUB219:RETURN
  232. 237 ML=2*M+RND(1)*3
  233. 238 MR=ML-C(10):CR=C(1)+C(9):G=RND(1)*100*ML+RND(1)*100:IFMR<1THENMR=1
  234. 239 PRINT@480,"[F]IGHT [E]VADE [M]AGIC";CL$;
  235. 240 I$=INPUT$(1):ONINSTR("FEM",I$)GOTO244,252,243
  236. 242 BEEP:GOTO239
  237. 243 GOSUB222
  238. 244 FORI=1TO10:SOUND1000,2
  239. 245 PRINT@520,CHR$(148);":";STRING$(C(6),255);CL$
  240. 246 PRINT@560,CHR$(145);":";STRING$(ML,239);CL$
  241. 247 IFCR*RND(1)>MR*RND(1)THENML=ML-1
  242. 248 IFMR*RND(1)>CR*RND(1)THENC(6)=C(6)-1:GOSUB207
  243. 249 IFML<1THEN251
  244. 250 NEXTI:GOTO239
  245. 251 PRINT@440,CS$:PRINT"You find";G;"Gold Pieces!":C(7)=C(7)+G:GOSUB207:GOSUB219:RETURN
  246. 252 IFC(3)/10>RND(1)THEN218ELSE244
  247. 253 PRINT@560,"You use a torch.";CL$:GOSUB219:C(11)=C(11)-1:IFC(11)<1THENC(11)=0:RETURN
  248. 254 TR=20:GOSUB219:RETURN
  249. 255 IFC(12)=0THENPRINT@560,"You are starving.";CL$:C(6)=C(6)-1:GOTO218
  250. 256 C(12)=C(12)-1:RA=30:PRINT@560,"You use a ration.";CL$:GOTO218
  251. 257 PRINT@440,CS$;"CONGRATULATIONS!","You have completed the Quest.":END
  252. 258 PRINT@440,CS$:GOTO96
  253. 300 DATA 1,0,0,2,0,20,2,1,3,12,0,0,3,0,4,0,2,0,4,0,5,0,3,0,5,0,6,15,4,0
  254. 301 DATA 6,0,7,0,0,0,7,0,8,0,6,0,8,0,9,18,7,0,9,0,10,0,8,0,10,0,11,0,9,0
  255. 302 DATA 11,0,7,0,10,0,12,2,0,22,0,0,13,0,14,0,0,21,14,0,15,0,13,0,15,5,16,25,14,0
  256. 303 DATA 16,0,17,0,15,0,17,0,18,27,16,0,18,8,19,0,17,0,19,0,20,0,18,24,20,0,21,0,19,0
  257. 304 DATA 21,0,0,31,20,10,22,0,23,32,0,0,23,0,24,0,22,0,24,0,25,34,23,0,25,15,26,0,24,0
  258. 305 DATA 26,0,0,36,25,0,27,17,0,37,0,0,28,0,0,38,0,13,29,0,30,39,0,0,30,0,0,40,29,0
  259. 306 DATA 31,21,0,0,0,2,32,22,0,0,0,0,33,0,0,43,0,4,34,24,0,44,0,0,35,0,36,0,0,16
  260. 307 DATA 36,26,0,0,35,0,37,27,0,0,0,25,38,28,0,48,0,0,39,29,0,0,0,18,40,30,0,50,0,0
  261. 308 DATA 41,0,92,0,0,22,42,32,0,52,51,0,43,33,0,53,0,8,44,34,0,54,0,0,45,0,46,55,0,0
  262. 309 DATA 46,0,47,56,45,0,47,0,48,0,46,26,48,38,49,0,47,0,49,0,50,0,48,0,50,40,51,0,49,0
  263. 310 DATA 51,0,42,0,50,0,52,42,53,0,0,27,53,43,0,0,52,0,54,44,0,64,0,0,55,45,0,65,0,0
  264. 311 DATA 56,46,0,66,0,5,57,0,0,67,0,11,58,48,59,0,0,0,59,0,60,0,58,0,60,0,61,0,59,23
  265. 312 DATA 61,0,59,71,60,0,62,0,63,72,91,0,63,0,64,0,62,0,64,54,0,0,63,0,65,55,0,75,0,0
  266. 313 DATA 66,56,0,76,0,6,67,57,0,77,0,0,68,0,69,78,0,0,69,0,70,79,68,9,70,0,0,0,69,3
  267. 314 DATA 71,61,0,81,0,0,72,62,0,82,0,0,73,0,0,83,0,17,74,0,75,0,0,29,75,65,0,85,74,0
  268. 315 DATA 76,66,0,86,0,7,77,67,0,87,0,30,78,68,0,88,0,0,79,69,0,0,0,15,80,0,81,90,0,0
  269. 316 DATA 81,71,0,0,80,0,82,72,0,0,0,0,83,73,84,0,0,19,84,0,85,0,83,0,85,75,0,95,84,0
  270. 317 DATA 86,76,0,96,0,0,87,77,88,97,0,0,88,78,89,0,87,0,89,0,90,99,88,0,90,80,91,0,89,0
  271. 318 DATA 91,0,62,0,90,0,92,0,93,0,41,0,93,0,94,0,92,28,94,0,95,0,93,0,95,85,0,0,94,0
  272. 319 DATA 96,86,0,0,0,1,97,87,98,0,0,0,98,0,0,0,97,12,99,89,100,0,0,0
  273. 320 DATA 100,0,101,0,99,0,101,0,0,0,100,14
  274.  
  275.