home *** CD-ROM | disk | FTP | other *** search
/ 64'er 1988 April / 64er_Magazin_88-04_1988_Markt__Technik_de_Side_A.d64 / listing.2 (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  2KB  |  63 lines
  1. 10 rem *****************************
  2. 20 rem *    magnetismus-modell     *
  3. 30 rem * 1987 by stefan vilsmeier  *
  4. 40 rem *****************************
  5. 50 :
  6. 60 ifa=0 then a=1:load"fractal.obj",8,1
  7. 70 poke53280,0:poke53281,0:sys50194
  8. 80 open 1,8,15,"u9":close1:rem diese zeile kann bei problemen mit dem
  9. 90 rem floppyspeeder weggelassen werden!
  10. 100 input"[147]anfang realteil         ";x1
  11. 110 input"ende realteil           ";x2
  12. 120 input"anfang imaginaerteil    ";y1
  13. 130 input"ende imaginaerteil      ";y2
  14. 140 input"realteil von c          ";cr
  15. 150 input"imaginaerteil von c     ";ci
  16. 160 input"maximum                 ";z
  17. 170 :
  18. 180 :
  19. 190 rem *****************************
  20. 200 rem *     hauptschleife         *
  21. 210 rem *****************************
  22. 220 :
  23. 230 dx=(x2-x1)/320:dy=(y1-y2)/200
  24. 240 sys50176,14,0:sys50179,1
  25. 250 foryy=0to199
  26. 260 :forxx=0to319
  27. 270 : x=x1+xx*dx
  28. 280 : y=y1+yy+dx
  29. 290 : zz=0
  30. 300 : gosub 440:rem 'iteration'
  31. 310 : ifra<120andzz<zgoto300
  32. 320 : ifint(zz/2)=zz/2 or zz=z then sys 50182,xx,yy,1
  33. 330 :nextxx
  34. 340 nextyy
  35. 350 get a$:if a$="" goto 350
  36. 360 sys50179,0:ifa$="s" then gosub 600:rem 'grafik speichern'
  37. 370 goto 80:rem neustart
  38. 380 :
  39. 390 :
  40. 400 rem *****************************
  41. 410 rem *        'iteration'        *
  42. 420 rem *****************************
  43. 430 :
  44. 440 a1=x*x-y*y+cr-1:b1=2*x*y+ci
  45. 450 a2=a1*a1-b1*b1:b2=2*a1*b1
  46. 460 a3=2*x+cr-2:b3=2*y+ci
  47. 470 a4=a3*a3-b3*b3:b4=2*a3*b3
  48. 480 ag=(a4*a4+b4*b4):ifag=0thenag=.0001
  49. 490 x=(a2*a4+b2*b4)/ag
  50. 500 y=(a4*b2-a2*b4)/ag
  51. 510 zz=zz+1
  52. 520 ra=x*x+y*y
  53. 530 return
  54. 540 :
  55. 550 :
  56. 560 rem *****************************
  57. 570 rem *    'grafik speichern'     *
  58. 580 rem *****************************
  59. 590 :
  60. 600 input "grafik-name ";n$
  61. 610 open 2,8,2,"pi."+n$+",p,w":sys 50191:close 2
  62. 620 return
  63.