10 REM *****************************
20 REM *    MAGNETISMUS-MODELL     *
30 REM * 1987 BY STEFAN VILSMEIER  *
40 REM *****************************
50 :
60 IFA=0 THEN A=1:LOAD"FRACTAL.OBJ",8,1
70 POKE53280,0:POKE53281,0:SYS50194
80 OPEN 1,8,15,"U9":CLOSE1:REM DIESE ZEILE KANN BEI PROBLEMEN MIT DEM
90 REM FLOPPYSPEEDER WEGGELASSEN WERDEN!
100 INPUT"[147]ANFANG REALTEIL         ";X1
110 INPUT"ENDE REALTEIL           ";X2
120 INPUT"ANFANG IMAGINAERTEIL    ";Y1
130 INPUT"ENDE IMAGINAERTEIL      ";Y2
140 INPUT"REALTEIL VON C          ";CR
150 INPUT"IMAGINAERTEIL VON C     ";CI
160 INPUT"MAXIMUM                 ";Z
170 :
180 :
190 REM *****************************
200 REM *     HAUPTSCHLEIFE         *
210 REM *****************************
220 :
230 DX=(X2-X1)/320:DY=(Y1-Y2)/200
240 SYS50176,14,0:SYS50179,1
250 FORYY=0TO199
260 :FORXX=0TO319
270 : X=X1+XX*DX
280 : Y=Y1+YY+DX
290 : ZZ=0
300 : GOSUB 440:REM 'ITERATION'
310 : IFRA<120ANDZZ<ZGOTO300
320 : IFINT(ZZ/2)=ZZ/2 OR ZZ=Z THEN SYS 50182,XX,YY,1
330 :NEXTXX
340 NEXTYY
350 GET A$:IF A$="" GOTO 350
360 SYS50179,0:IFA$="S" THEN GOSUB 600:REM 'GRAFIK SPEICHERN'
370 GOTO 80:REM NEUSTART
380 :
390 :
400 REM *****************************
410 REM *        'ITERATION'        *
420 REM *****************************
430 :
440 A1=X*X-Y*Y+CR-1:B1=2*X*Y+CI
450 A2=A1*A1-B1*B1:B2=2*A1*B1
460 A3=2*X+CR-2:B3=2*Y+CI
470 A4=A3*A3-B3*B3:B4=2*A3*B3
480 AG=(A4*A4+B4*B4):IFAG=0THENAG=.0001
490 X=(A2*A4+B2*B4)/AG
500 Y=(A4*B2-A2*B4)/AG
510 ZZ=ZZ+1
520 RA=X*X+Y*Y
530 RETURN
540 :
550 :
560 REM *****************************
570 REM *    'GRAFIK SPEICHERN'     *
580 REM *****************************
590 :
600 INPUT "GRAFIK-NAME ";N$
610 OPEN 2,8,2,"PI."+N$+",P,W":SYS 50191:CLOSE 2
620 RETURN