home *** CD-ROM | disk | FTP | other *** search
/ Club Amiga de Montreal - CAM / CAM_CD_1.iso / files / 550b.lha / newser_v2.10 / newser.asm < prev    next >
Assembly Source File  |  1991-09-08  |  69KB  |  2,839 lines
  1. *****************************************************************************
  2. * Program:  newser.asm - Copyright © 1990, 1991 by Dan Babcock
  3. *
  4. * Permission is given for PERSONAL use of this code. Commercial
  5. * use is of course forbidden. (Without prior permission etc.)
  6. *
  7. * Function: A "serial.device" compatible driver for the Rockwell 65C52
  8. *
  9. * Author:   Dan Babcock
  10. * History:  08/12/90 V0.50 Created
  11. *           09/06/90 V0.51 Cleaned up "eofdump" code.
  12. *           11/04/90 V0.52 Misc. minor changes
  13. *                          [release 1]
  14. *           03/03/91 V1.10 Fixed some bugs, speeded up, & added prefs hook
  15. *           03/08/91 V1.11 Bug fixes
  16. *                          [release 2]
  17. *           04/18/91 V1.12 Small changes (very small)
  18. *           06/20/91 V2.00 Bug fixes, code clean-up, faster
  19. *                          [release 3]
  20. *           06/27/91 V2.10 Added ASDG-style DTR/RTS control extension
  21. *                          (See "SetControlLines" for documentaion)
  22. *                          Added special time-out to write routine to
  23. *                          avoid theoretical (and possibly real) problem
  24. *                          Fixed bug in Break routine
  25. *                          [release 4]
  26. *
  27. * Feel free to contact me:
  28. *
  29. * [School address]               [Permanent address]      People/Link:
  30. *  Subject to                     Dan Babcock              DANBABCOCK
  31. *  change so not                  P.O. Box 1532              Bix:
  32. *  given here                     Southgate, MI  48195     danbabcock
  33. *                                 U.S.A.
  34. * 
  35. * I am also reachable via internet. I read comp.sys.amiga.programming.
  36. *
  37. * General notes
  38. * =============
  39. * The macro "PUTDEBUG" is used to output debugging information via the
  40. * internal serial port at a low level. It may be used anywhere, including
  41. * critical sections, supervisor mode, and interrupt code. If debugging is
  42. * not desired, set the INFO_LEVEL equate to zero. Conversely, if debugging
  43. * is desired, set it to a high value (e.g. 100000)
  44. *
  45. * A consistent (for the most part) usage of registers was employed:
  46. *  A1 - pointer to an IORequest structure
  47. *  A3 - pointer to a unit structure (defined below)
  48. *  A4 - pointer to a serprefs structure (defined below)
  49. *  A5 - pointer to the hardware (one channel, that is)
  50. *  A6 - pointer to the device structure (defined below)
  51. *
  52. * Known differences between this and serial.device are:
  53. *  1. Start/Stop do not send XON/XOFF characters to the outside world
  54. *     as implied in the autodoc. (I doubt anyone uses Start and Stop...)
  55. *  2. Newser does not currently send an XOFF or otherwise tell the outside
  56. *     world to "shut up" when the driver's input buffer fills.
  57. *     Since the buffer is 64K, it is very unlikely to ever fill.
  58. *  Both of those capabilities can be added external to the driver if you
  59. *  have a custom application that requires them.
  60. *****************************************************************************
  61.  
  62.     MC68010
  63.     super    ;suppress warnings about supervisor mode
  64.     exeobj
  65.     objfile    'devs:newser.device'
  66.     macfile    'newser.i'
  67.  
  68. ;Set INFO_LEVEL to a high number (e.g. 100000) for full debugging output
  69. ;over the internal serial port.
  70. INFO_LEVEL    equ    000000
  71.  
  72. EXEC    macro
  73.     move.l    a1,-(sp)
  74.     move.l    a6,-(sp)
  75.     movea.l    (4).w,a6
  76.     jsr    (_LVO\1,a6)
  77.     movea.l    (sp)+,a6
  78.     movea.l    (sp)+,a1
  79.     endm
  80.  
  81. ;*************************** Structures *************************
  82.  
  83. serprefs    clrso
  84. prefs_CTLCHAR    so.l    1    ;Control char's (order = xON,xOFF,rsvd,rsvd)
  85. prefs_RBUFLEN    so.l    1    ;Length in bytes of serial port's read buffer
  86. prefs_EXTFLAGS    so.l    1    ;Additional serial flags
  87. prefs_BAUD    so.l    1    ;Baud rate requested (true baud)
  88. prefs_BRKTIME    so.l    1    ;Duration of break signal in MICROseconds
  89. prefs_TERMARRAY    so.b    TERMARRAY_SIZE    ;Termination character array
  90. prefs_READLEN    so.b    1    ;Bits per read char (bit count)
  91. prefs_WRITELEN    so.b    1    ;Bits per write char (bit count)
  92. prefs_STOPBITS    so.b    1    ;Stopbits for read (count)
  93. prefs_SERFLAGS    so.b    1    ;See SERFLAGS bit definitions
  94. serprefs_sizeof    soval
  95.  
  96. MyDev    setso    LIB_SIZE
  97. md_Flags    so.b    1
  98. md_Pad1    so.b    1
  99. md_SysLib    so.l    1
  100. md_SegList    so.l    1
  101. md_Units    so.b    MD_NUMUNITS*4
  102. VectorBase    so.l    1
  103. MyPreviousAutoVec:    so.l    1
  104. ScoreBoard    so.w    1
  105. Chip1present    so.w    1
  106. Chip2present    so.w    1
  107. prefs_unit0    so.b    serprefs_sizeof    ;The reason why prefs are in this
  108. prefs_unit1    so.b    serprefs_sizeof    ;structure instead of the unit structure
  109. prefs_unit2    so.b    serprefs_sizeof    ;is that the pref settings should be saved
  110. prefs_unit3    so.b    serprefs_sizeof    ;across CloseDevice calls (which usually
  111. MyDev_Sizeof    soval            ;causes the unit to be dumped).
  112.  
  113. MyDevUnit    setso    UNIT_SIZE    ;Odd # longwords
  114. mdu_wport    so.b    MP_SIZE    ;MsgPort for write task
  115. MDU_FLAGS    so.b    1
  116. IERstate    so.b    1    ;Current state of IER used as a mask
  117. mdu_UnitNum    so.b    1
  118. frstate    so.b    1    ;This var mirrors a write-only register
  119. mdu_SysLib    so.l    1    ;Copy of location 4
  120. mdu_Device    so.l    1    ;Ptr to main device struct
  121. mdu_rstack    so.b    MYPROCSTACKSIZE    ;For read task
  122. mdu_wstack    so.b    MYPROCSTACKSIZE    ;For write task
  123. mdu_rtcb    so.b    TC_SIZE    ;Task Control Block (TCB) for read task
  124. mdu_wtcb    so.b    TC_SIZE    ;Task Control Block (TCB) for write task
  125. timerport    so.b    MP_SIZE
  126. timeriorequest    so.b    IOTV_SIZE
  127.  
  128. ;The -sig longwords must be contiguous!!!
  129. readsig    so.l    1    ;Read task signals
  130. readabortsig    so.l    1
  131.  
  132. tdresig    so.l    1    ;Write block finished
  133. writeabortsig    so.l    1
  134. xonsig    so.l    1    ;Comes from read task, and indicates xon received
  135.  
  136. HeadLong    so.w    1    ;Ptr to start of circular buffer (logical)
  137. Head    so.w    1
  138. TailLong    so.w    1    ;Ptr to end of circular buffer (logical)
  139. Tail    so.w    1
  140. StartBuf    so.l    1    ;Ptr to physical start of input buffer
  141. ReadRequestPtr    so.l    1
  142. WriteRequestPtr    so.l    1
  143. xstate    so.b    1    ;Zero if 'x-off' received, else $FF
  144. ISRcopy    so.b    1    ;Used for read error diagnosis
  145. CSRcopy    so.b    1    ;Used for read error diagnosis
  146. Exclusive    so.b    1    ;True if someone has exclusive access to this unit
  147. daciabase    so.l    1
  148. mdu_prefs    so.l    1    ;Ptr to prefs for this unit (in MyDev)
  149. WriteCount    so.l    1
  150. WriteBufferPtr    so.l    1
  151. MyDevUnit_Sizeof    soval
  152.  
  153. ;Note that we have a single unit structure used by both the read and write
  154. ;tasks (and the interrupt routine).
  155.  
  156. * UNIT_FLAG definitions:
  157.  
  158.     BITDEF    UNIT,BREAKSENT,2    ;break sent flag for Query
  159.     BITDEF    UNIT,READIMMEDIATE,3
  160.     BITDEF    UNIT,NEEDCHAR,4
  161.  
  162. * Bit definitions for MDU_FLAGS
  163.  
  164.     BITDEF    MDU,STOPPED,2    ;State bit for unit stopped
  165.     BITDEF    MDU,V,3    ;Buffer overflow flag - set in int routine if an overflow occurs
  166.     BITDEF    MDU,WaitingForChar,4
  167.     BITDEF    MDU,CharAvailable,5
  168.  
  169. * Bit definitions for ioflags
  170.  
  171.     BITDEF    ioflags,Ignore,4    ;Ignore this IO request
  172.  
  173. * Equates & bit defs for IERstate
  174.  
  175. READINT    equ    $87
  176. READINTMASK    equ    $7
  177.  
  178. WRITEINT    equ    $C0
  179. WRITEINTMASK    equ    $40
  180.  
  181. MYIDENT    macro
  182.     cstr    'newser.device V2.10 (June 27, 1991)',13,10
  183.     even
  184.     endm
  185.  
  186. ;The first executable location.  This should return an error in case someone
  187. ;tried to run us as a program (instead of loading us as a device).
  188.  
  189. FirstAddress:
  190.     moveq    #-1,d0
  191.     rts
  192.  
  193. ;A romtag structure.  After your driver is brought in from disk, the
  194. ;disk image will be scanned for this structure to discover magic constants
  195. ;about you (such as where to start running you from...).
  196.  
  197. initDDescrip:
  198.     dw    RTC_MATCHWORD    ;UWORD    RT_MATCHWORD (Magic cookie)
  199.     dl    initDDescrip    ;APTR    RT_MATCHTAG  (Back pointer)
  200.     dl    EndCode    ;APTR    RT_ENDSKIP   (To end of this hunk)
  201.     db    RTF_AUTOINIT    ;UBYTE    RT_FLAGS     (magic-see "Init")
  202.     db    VERSION    ;UBYTE    RT_VERSION
  203.     db    NT_DEVICE    ;UBYTE    RT_TYPE      (must be correct)
  204.     db    MYPRI    ;BYTE    RT_PRI
  205.     dl    myName    ;APTR    RT_NAME      (exec name)
  206.     dl    idString    ;APTR    RT_IDSTRING  (text string)
  207.     dl    Init    ;APTR    RT_INIT
  208.  
  209.     db    'newser.device - Copyright (c) 1990, 1991 by Dan Babcock. '
  210.     db    'Contact me on People/Link, Bix, or Usenet!'
  211.     even
  212.  
  213. ;nasty data area (makes this version non-ROMable)
  214.  
  215. OldVec:    dc.l    0
  216. Unit0:    dc.l    0
  217. Unit1:    dc.l    0
  218. _Unit2:    dc.l    0    ;_ used because of conflict with chip reg addr sym
  219. Unit3:    dc.l    0
  220.  
  221.  
  222. ;*********************** Tables (constant) **********************
  223.  
  224. ;Note!! Some of these values are depended on in the InitRoutine prefs
  225. ;code...i.e. they may not be changed arbitrarily!
  226.  
  227. defaultprefs:
  228.     dl    SER_DEFAULT_CTLCHAR ;prefs_CTLCHAR
  229.     dl    64*1024    ;prefs_RBUFLEN
  230.     dl    0    ;prefs_EXTFLAGS
  231.     dl    9600    ;prefs_BAUD
  232.     dl    250000    ;prefs_BRKTIME
  233.     dl    0    ;prefs_TERMARRAY
  234.     dl    0    ;prefs_TERMARRAY
  235.     db    8    ;prefs_READLEN
  236.     db    8    ;prefs_WRITELEN
  237.     db    1    ;prefs_STOPBITS
  238. ;Note: RAD_BOOGIE must NOT be set here
  239.     db    $88    ;prefs_SERFLAGS
  240.  
  241. ;Table of DACIA base addresses for the 4 units
  242.  
  243. basetable:
  244.     dl    ACIA_Base
  245.     dl    ACIA_Base+UNIT2
  246.     dl    ACIA_Base+ACIA1
  247.     dl    ACIA_Base+ACIA1+UNIT2
  248.  
  249. ;List of supported baud rates 
  250.  
  251. baudtable:
  252.     dw    50
  253.     dw    110
  254.     dw    135
  255.     dw    150
  256.     dw    300
  257.     dw    600
  258.     dw    1200
  259.     dw    1800
  260.     dw    2400
  261.     dw    3600
  262.     dw    4800
  263.     dw    7200
  264.     dw    9600
  265.     dw    19200
  266.     dw    38400
  267.     dw    31250    ;MIDI (external clock)
  268.  
  269. timername:
  270.     cstr    'timer.device'
  271.  
  272.     ifne    INFO_LEVEL    ;If any debugging enabled at all
  273. subSysName:
  274.     cstr    'newser'    ;This name for debugging use
  275.     endc
  276.  
  277. myName:    MYDEVNAME    ;This is the name that the device will have
  278.  
  279. ;This is an identifier tag to help in supporting the device
  280. ;format is 'name version.revision (dd MON yyyy)',<cr>,<lf>,<null>
  281.  
  282. idString:    MYIDENT
  283.  
  284. ;The romtag specified that we were "RTF_AUTOINIT".  This means that the
  285. ;RT_INIT structure member points to one of these tables below.  If the
  286. ;AUTOINIT bit was not set then RT_INIT would point to a routine to run.
  287.  
  288. Init:    dl    MyDev_Sizeof    ;data space size
  289.     dl    FuncTable    ;pointer to function initializers
  290.     dl    DataTable    ;pointer to data initializers
  291.     dl    InitRoutine    ;routine to run
  292.  
  293. FuncTable:
  294.     dw    -1    ;this indicates that the following are offsets,
  295.             ;rather than absolute addresses
  296.     dw    Open-FuncTable    ;standard system routines
  297.     dw    _Close-FuncTable
  298.     dw    Expunge-FuncTable
  299.     dw    Null-FuncTable    ;Reserved for future use!
  300.     dw    BeginIO-FuncTable    ;my device definitions
  301.     dw    AbortIO-FuncTable
  302.     dw    -1    ;function table end marker
  303.  
  304. ;The data table initializes static data structures. The format is
  305. ;specified in exec/InitStruct routine's manual pages.  The
  306. ;INITBYTE/INITWORD/INITLONG macros are in the file "exec/initializers.i".
  307. ;The first argument is the offset from the device base for this
  308. ;byte/word/long. The second argument is the value to put in that cell.
  309. ;The table is null terminated
  310.  
  311. DataTable:
  312.     INITBYTE    LN_TYPE,NT_DEVICE    ;Must be LN_TYPE!
  313.     INITLONG    LN_NAME,myName
  314.     INITBYTE    LIB_FLAGS,LIBF_SUMUSED+LIBF_CHANGED
  315.     INITWORD    LIB_VERSION,VERSION
  316.     INITWORD    LIB_REVISION,REVISION
  317.     INITLONG    LIB_IDSTRING,idString
  318.     dw     0    ;terminate list
  319.  
  320. ;This routine gets called after the device has been allocated.  The device
  321. ;pointer is in D0.  The AmigaDOS segment list is in a0.  If it returns the
  322. ;device pointer, then the device will be linked into the device list.  If it
  323. ;returns NULL, then the device will be unloaded.
  324. ;
  325. ;This call is single-threaded by exec; please read the description for
  326. ;"Open" below.
  327. ;
  328. ; Register Usage
  329. ; ==============
  330. ; a3 -- Points to temporary RAM
  331. ; a4 -- Expansion library base
  332. ; a5 -- device pointer
  333. ; a6 -- Exec base
  334.  
  335. InitRoutine:
  336.     PUTDEBUG    5,<'%s/Init: called'>
  337.     movem.l    d1-d7/a0-a6,-(sp)    ;Preserve ALL modified registers
  338.  
  339.     movea.l    d0,a5
  340.     move.l    a6,(md_SysLib,a5)    ;Save a pointer to exec
  341.     move.l    a0,(md_SegList,a5) ;Save pointer to our loaded code
  342.  
  343. ;Check for presence/absence of the 2 serial chips
  344.     moveq    #0,d0
  345.     moveq    #0,d1
  346.     move.l    #ACIA_Base,a4
  347.     move.b    #$83,(FMR,a4)
  348.     move.b    (CSR,a4),d2
  349.     and.b    #3,d2
  350.     cmp.b    #3,d2
  351.     bne.b    .Chip2
  352.     move.b    #$80,(FMR,a4)
  353.     move.b    (CSR,a4),d2
  354.     and.b    #3,d2
  355.     bne.b    .Chip2
  356.     moveq    #-1,d0
  357. .Chip2:
  358.     move.l    #ACIA_Base+ACIA1,a4
  359.     move.b    #$83,(FMR,a4)
  360.     move.b    (CSR,a4),d2
  361.     and.b    #3,d2
  362.     cmp.b    #3,d2
  363.     bne.b    .Done
  364.     move.b    #$80,(FMR,a4)
  365.     move.b    (CSR,a4),d2
  366.     and.b    #3,d2
  367.     bne.b    .Done
  368.     moveq    #-1,d1
  369.  
  370. .Done:
  371.     move.w    d0,(Chip1present,a5)
  372.     move.w    d1,(Chip2present,a5)
  373.  
  374. ;Take over level 6 autovector (nasty, but justified)
  375.     clr.l    (VectorBase,a5)
  376.     tst.w    (AttnFlags,a6)
  377.     beq.b    .skipvbr
  378.  
  379.     SYS    SuperState
  380.     movec    vbr,a2
  381.     bsr    MyUserState
  382.  
  383.     move.l    a2,(VectorBase,a5)
  384. .skipvbr:
  385.     move.l    (VectorBase,a5),a0
  386.     move.l    ($78,a0),(OldVec)
  387.     move.l    #Int0000,($78,a0)
  388.     move.l    #Int0000,(MyPreviousAutoVec,a5)
  389.     move.l    a5,a6
  390.     bsr    SetDefaultPrefs
  391.     move.l    (4).w,a6
  392.  
  393. ;Try to find the prefs in memory
  394.     lea    (MagicPortName,pc),a1
  395.     SYS    FindPort
  396.     tst.l    d0
  397.     beq    .EndInit    ;use hard-coded defaults
  398.     move.l    d0,a0
  399.     lea    (MP_SIZE,a0),a3
  400.     move.l    a5,a6
  401.     lea    (prefs_unit0,a6),a2
  402.  
  403.     moveq    #3,d7    ;4 units
  404.     moveq    #0,d5
  405.  
  406. .OuterLoop:
  407.     move.l    d5,d6
  408.     lsl.w    #3,d6    ;Convert unit # to index
  409.     move.l    a3,a1
  410.     lea    (a1,d6.w),a1    ;UnitPrefs for this unit
  411. .PrefsLoop:
  412.     moveq    #0,d0
  413.     move.w    #512,d0
  414.     moveq    #0,d1
  415.     move.w    (up_BufSize,a1),d1 ;0-7
  416.     lsl.l    d1,d0
  417.     move.l    d0,(prefs_RBUFLEN,a2)
  418.  
  419.     lea    (baudtable,pc),a0
  420.     move.w    (up_BaudRate,a1),d0 ;0-15
  421.     add.w    d0,d0
  422.     moveq    #0,d1
  423.     move.w    (a0,d0.w),d1
  424.     move.l    d1,(prefs_BAUD,a2)
  425.  
  426.     moveq    #5,d1    ;5 bit word
  427.     move.b    (up_WordLen,a1),d0
  428.     beq.b    .WordLen    ;up_WordLen=0
  429.     addq.b    #1,d1    ;6 bit word
  430.     subq.b    #1,d0
  431.     beq.b    .WordLen    ;up_WordLen=1
  432.     addq.b    #1,d1    ;7 bit word
  433.     subq.b    #1,d0
  434.     beq.b    .WordLen    ;up_WordLen=2
  435.     addq.b    #1,d1    ;8 bit word
  436. .WordLen:
  437.     move.b    d1,(prefs_READLEN,a2)
  438.     move.b    d1,(prefs_WRITELEN,a2)
  439.  
  440.     move.b    (up_StopBits,a1),d0 ;0-1
  441.     addq.b    #1,d0
  442.     move.b    d0,(prefs_STOPBITS,a2)
  443.  
  444.     move.b    (up_Parity,a1),d0
  445.     cmp.b    #4,d0    ;none?
  446.     beq.b    .SkipParity
  447.     bset    #SERB_PARTY_ON,(prefs_SERFLAGS,a2)
  448.     cmp.b    #2,d0
  449.     bcc.b    .MarkSpace
  450.     bclr    #SERB_PARTY_ODD,(prefs_SERFLAGS,a2)    ;set to even
  451.     tst.b    d0
  452.     bne.b    .SkipParity
  453.     bset    #SERB_PARTY_ODD,(prefs_SERFLAGS,a2)    ;set to odd
  454.     bra.b    .SkipParity
  455. .MarkSpace:
  456.     bset    #SEXTB_MSPON,(3+prefs_EXTFLAGS,a2)
  457.     bclr    #SEXTB_MARK,(3+prefs_EXTFLAGS,a2)    ;set to space
  458.     cmp.b    #3,d0
  459.     beq.b    .SkipParity
  460.     bset    #SEXTB_MARK,(3+prefs_EXTFLAGS,a2)
  461.  
  462. .SkipParity:
  463.     move.b    (up_Shake,a1),d0
  464.     cmp.b    #2,d0
  465.     beq.b    .SkipShake
  466.     cmp.b    #1,d0
  467.     bne.b    .SkipXon
  468.     bclr    #SERB_XDISABLED,(prefs_SERFLAGS,a2)
  469.     bra.b    .SkipShake
  470. .SkipXon:
  471.     bset    #SERB_7WIRE,(prefs_SERFLAGS,a2)
  472. .SkipShake:
  473.     addq.l    #1,d5
  474.     add.w    #serprefs_sizeof,a2
  475.     dbra    d7,.OuterLoop
  476.  
  477. .EndInit:
  478.     move.l    a5,d0    ;no error (zero indicates error)
  479.             ;MUST return device ptr
  480.     PUTDEBUG    5,<'%s/Init: finished'>
  481.     movem.l    (sp)+,d1-d7/a0-a6
  482.     rts
  483.  
  484. MagicPortName:    dc.b    'newser_prefs',0
  485.     even
  486.  
  487. MyUserState:
  488. ;(The one in 1.2/1.3 ROM is buggy)
  489. ;Enter with ExecBase in A6 and SSP in D0
  490.     move.l    (sp)+,d1
  491.     move.l    sp,usp
  492.     movea.l    d0,sp
  493.     movea.l    a5,a0
  494.     lea    (.L1,pc),a5
  495.     jmp    (_LVOSupervisor,a6)
  496. .L1:    movea.l    a0,a5
  497.     move.l    d1,(2,sp)    ;store return address in stack frame
  498.     andi.w    #$DFFF,(sp)    ;clear supervisor bit
  499.     rte
  500.  
  501. ;Enter with device ptr in a6.
  502.  
  503. SetDefaultPrefs:
  504.     movem.l    d0/d1/a0/a1,-(sp)
  505.     lea    (prefs_unit0,a6),a1
  506.     moveq    #MD_NUMUNITS-1,d1
  507. 1$    move.w    #serprefs_sizeof-1,d0
  508.     lea    (defaultprefs,pc),a0
  509. 2$    move.b    (a0)+,(a1)+
  510.     dbra    d0,2$
  511.     dbra    d1,1$
  512.     movem.l    (sp)+,d0/d1/a0/a1
  513.     rts
  514.  
  515. NewVector:
  516. ;Enter with device ptr in a6
  517. ;exit with d0=0 if OK, else error!
  518.  
  519. ;uses d0,a0,a1
  520.  
  521.     movem.l    a0/a1,-(sp)
  522.     move.l    (VectorBase,a6),a1
  523.     move.l    (MyPreviousAutoVec,a6),d0
  524.     cmp.l    ($78,a1),d0
  525.     bne.b    .Error
  526.  
  527.     moveq    #0,d0
  528.     move.b    (ScoreBoard,a6),d0
  529.     lsl.l    #2,d0
  530.     lea    (IntRoutines,pc),a0
  531.     move.l    (a0,d0.w),(MyPreviousAutoVec,a6)
  532.     move.l    (a0,d0.w),($78,a1)
  533.     moveq    #0,d0
  534. .End:
  535.     movem.l    (sp)+,a0/a1
  536.     rts
  537. .Error:
  538.     moveq    #1,d0
  539.     bra.b    .End
  540.  
  541. ;Here begins the system interface commands.  When the user calls OpenDevice/
  542. ;CloseDevice/RemDevice, this eventually gets translated into a call to the
  543. ;following routines (Open/Close/Expunge).  Exec has already put our device
  544. ;pointer in a6 for us.
  545. ;
  546. ;Open sets the IO_ERROR field on an error. If it was successful, we should
  547. ;also set up the IO_UNIT and LN_TYPE fields.  exec takes care of setting up
  548. ;IO_DEVICE.
  549. ;
  550. ;NOTE: We must also copy the current prefs for this unit into the user's
  551. ;extended iorequest fields.
  552. ;
  553. ; Register Usage
  554. ; ==============
  555. ; d0 -- unitnum
  556. ; d1 -- flags
  557. ; a1 -- iob
  558. ; a6 -- Device ptr
  559.  
  560. Open:
  561.     addq.w    #1,(LIB_OPENCNT,a6) ;Fake an opener for duration of call
  562.     PUTDEBUG    20,<'%s/Open: called'>
  563.     movem.l    d2/a2-a4,-(sp)
  564.     movea.l    a1,a2    ;Save the iob
  565.     cmp.l    #MD_NUMUNITS,d0    ;See if the unit number is in range
  566.     bcc    Open_Range_Error    ;Unit number out of range (BHS)
  567.  
  568. ;Check to see if the corresponding chip is installed
  569.     lea    (Chip1present,a6),a4
  570.     tst.b    (a4,d0.w)
  571.     beq    Open_Range_Error
  572.  
  573.     move.l    d0,d2    ;Save unit number
  574.     lsl.l    #2,d0    ;See if the unit is already initialized
  575.     lea    (md_Units,a6,d0.l),a4
  576.     move.l    (a4),d0
  577.     bne.b    Open_UnitOK
  578.                 ;Try to conjure up a unit
  579.     bsr    InitUnit    ;scratch:a3 unitnum:d2 devpoint:a6
  580.     move.l    (a4),d0    ;See if it initialized OK
  581.     beq.w    Open_Error
  582.     movea.l    d0,a3
  583.     bra.b    Open_UnitOK1
  584.  
  585. Open_UnitOK:
  586.     movea.l    d0,a3    ;Unit pointer in a3
  587.     tst.b    (Exclusive,a3)    ;Check for an exclusive access violation
  588.     beq    Open_Error
  589. Open_UnitOK1:
  590.     btst    #SERB_SHARED,(IO_FLAGS,a2)
  591.     seq    (Exclusive,a3)
  592.     movea.l    (mdu_prefs,a3),a4    ;Set the "7WIRE" flag
  593.  
  594.     bclr    #SERB_7WIRE,(prefs_SERFLAGS,a4)
  595.     btst    #SERB_7WIRE,(IO_SERFLAGS,a2)
  596.     beq.b    2$
  597.     bset    #SERB_7WIRE,(prefs_SERFLAGS,a4)
  598.  
  599. 2$:    movea.l    a2,a1    ;Copy the current internal prefs into the iorequest.
  600.     bsr    CopyPrefs
  601.     move.l    d0,(IO_UNIT,a2)
  602.     addq.w    #1,(LIB_OPENCNT,a6)  ;Mark us as having another opener
  603.     addq.w    #1,(UNIT_OPENCNT,a3) ;Internal bookkeeping
  604.     bclr    #LIBB_DELEXP,(md_Flags,a6) ;Prevent delayed expunges
  605.     clr.b    (IO_ERROR,a2)    ;no error
  606.     move.b    #NT_REPLYMSG,(LN_TYPE,a2) ;Mark IORequest as "complete"
  607. Open_End:
  608.     subq.w    #1,(LIB_OPENCNT,a6) ;End of expunge protection
  609.     movem.l    (sp)+,d2/a2-a4
  610.     PUTDEBUG 30,<'%s/Open: Finished!'>
  611.     rts
  612.  
  613. Open_Range_Error:
  614. Open_Error:
  615.     moveq    #IOERR_OPENFAIL,d0
  616.     move.b    d0,(IO_ERROR,a2)
  617.     move.l    d0,(IO_DEVICE,a2)    ;Trash IO_DEVICE on open failure
  618.     PUTDEBUG    2,<'%s/Open: failed'>
  619.     bra.b    Open_End
  620.  
  621. ;Copy prefs from our device struct to an IOrequest.  Enter with IORequest
  622. ;in a1 and unit pointer in a3.  All registers are preserved.
  623.  
  624. CopyPrefs:
  625.     movem.l    d0/a1/a4,-(sp)
  626.     movea.l    (mdu_prefs,a3),a4
  627.     lea    (IO_CTLCHAR,a1),a1
  628.     move.w    #serprefs_sizeof-1,d0
  629. 1$:    move.b    (a4)+,(a1)+
  630.     dbra    d0,1$
  631.     movem.l    (sp)+,d0/a1/a4
  632.     rts 
  633.  
  634. ;Copy prefs from an IOrequest to our device struct Enter with IORequest
  635. ;in a1 and unit pointer in a3.  All registers are preserved.
  636.  
  637. SetPrefs:
  638.     movem.l    d0/a1/a4,-(sp)
  639.     movea.l    (mdu_prefs,a3),a4
  640.     lea    (IO_CTLCHAR,a1),a1
  641.     move.w    #serprefs_sizeof-1,d0
  642. 1$:    move.b    (a1)+,(a4)+
  643.     dbra    d0,1$
  644.     movem.l    (sp)+,d0/a1/a4
  645.     rts 
  646.  
  647. ;There are two different things that might be returned from the Close
  648. ;routine.  If the device wishes to be unloaded, then Close must return
  649. ;the segment list (as given to Init).  Otherwise close MUST return NULL.
  650. ; ( device:a6, iob:a1 )
  651.  
  652. _Close:
  653.     movem.l    a2-a3,-(sp)
  654.     PUTDEBUG    20,<'%s/Close: called'>
  655.     movea.l    a1,a2
  656.     movea.l    (IO_UNIT,a2),a3
  657.     moveq    #-1,d0
  658.     move.l    d0,(IO_UNIT,a2)      ;We're closed...
  659.     move.l    d0,(IO_DEVICE,a2)    ;Customers not welcome at this IORequest!
  660.     subq.w    #1,(UNIT_OPENCNT,a3) ;See if the unit is still in use
  661.     bne.b    Close_Device
  662.     bsr    ExpungeUnit
  663.  
  664. Close_Device:
  665.     moveq    #0,d0
  666.     subq.w    #1,(LIB_OPENCNT,a6) ;Mark us as having one fewer openers
  667.     bne.b    Close_End     ;See if there is anyone left with us open
  668.     btst    #LIBB_DELEXP,(md_Flags,a6) ;See if we have a delayed expunge pending
  669.     beq.b    Close_End
  670.     bsr    Expunge    ;Do the expunge
  671. Close_End:
  672.     movem.l    (sp)+,a2-a3
  673.     PUTDEBUG    20,<'%s/Close: Finished!'>
  674.     rts        ;MUST return either zero or the SegList!
  675.  
  676. ;Expunge is called by the memory allocator when the system is low on
  677. ;memory.
  678. ;
  679. ;There are two different things that might be returned from the Expunge
  680. ;routine.  If the device is no longer open then Expunge may return the
  681. ;segment list (as given to Init).  Otherwise Expunge may set the
  682. ;delayed expunge flag and return NULL.
  683. ;
  684. ;One other important note: because Expunge is called from the memory
  685. ;allocator, it may NEVER Wait() or otherwise take long time to complete.
  686. ;
  687. ; A6          - library base (scratch)
  688. ; D0-D1/A0-A1 - scratch
  689.  
  690. Expunge:
  691.     PUTDEBUG    10,<'%s/Expunge: called'>
  692.     movem.l    d1/d2/a5/a6,-(sp)    ;Save ALL modified registers
  693.     movea.l    a6,a5
  694.     movea.l    (md_SysLib,a5),a6
  695.     tst.w    (LIB_OPENCNT,a5)    ;See if anyone has us open
  696.     beq.b    1$
  697.     bset    #LIBB_DELEXP,(md_Flags,a5)    ;Set the delayed expunge flag
  698.     moveq    #0,d0
  699.     bra.b    Expunge_End
  700. 1$:
  701.  
  702. ;Important: If it's not possible to restore the old autovector, then don't
  703. ;expunge!!
  704. ;Restore old autovector if possible
  705.     move.l    (MyPreviousAutoVec,a5),a0
  706.     move.l    (VectorBase,a5),a1
  707.     cmp.l    ($78,a1),a0
  708.     beq.b    .ok
  709.     moveq    #0,d0
  710.     bra.b    Expunge_End
  711. .ok:
  712.     move.l    (OldVec,pc),($78,a1)
  713.  
  714.     move.l    (md_SegList,a5),d2 ;Store our seglist in d2
  715.     movea.l    a5,a1     ;Unlink from device list
  716.     SYS    Remove     ;Remove first (before FreeMem)
  717.  
  718.     movea.l    a5,a1     ;Devicebase
  719.     moveq    #0,d0
  720.     move.w    (LIB_NEGSIZE,a5),d0
  721.     suba.l    d0,a1    ;Calculate base of functions
  722.     add.w    (LIB_POSSIZE,a5),d0 ;Calculate size of functions + data area
  723.     SYS    FreeMem
  724.     move.l    d2,d0    ;Set up our return value
  725. Expunge_End:
  726.     movem.l    (sp)+,d1/d2/a5/a6
  727.     rts
  728.  
  729. Null:    moveq    #0,d0    ;The "Null" function MUST return zero.
  730.     rts
  731.  
  732. ;This is the main unit initialization routine. It allocates memory for
  733. ;the device structure, calls SetUpUnit, then calls InitTask.
  734.  
  735. ; ( d2:unit number, a3:scratch, a6:devptr )
  736.  
  737. InitUnit:
  738.     PUTDEBUG    30,<'%s/InitUnit: called'>
  739.     movem.l    d0/d1/a4/a2,-(sp)
  740.     move.l    d2,d1
  741.     mulu.w    #serprefs_sizeof,d1
  742.     lea    (prefs_unit0,a6),a4
  743.     adda.l    d1,a4
  744.  
  745. ;Now A4 is a ptr to the prefs for this unit
  746.  
  747.     move.l    #MyDevUnit_Sizeof,d0 ;Allocate unit memory
  748.     move.l    #MEMF_PUBLIC!MEMF_CLEAR,d1
  749.     move.l    a6,-(sp)
  750.     movea.l    (md_SysLib,a6),a6
  751.     SYS    AllocMem
  752.     movea.l    (sp)+,a6
  753.     movea.l    d0,a3
  754.     tst.l    d0
  755.     bne    continitunit1
  756.  
  757. ;Couldn't init the unit (out of memory).
  758.  
  759. ReturnVoid:
  760.     move.l    d2,d0    ;Unit number
  761.     lsl.l    #2,d0
  762.     clr.l    (md_Units,a6,d0.l) ;Set unit table
  763.     movem.l    (sp)+,d0/d1/a4/a2
  764.     rts
  765.  
  766. BadSetup:
  767.     bsr    KillTask
  768.     bra.b    ReturnVoid
  769.  
  770. continitunit1:
  771.     moveq    #0,d0    ;Don't need to re-zero it
  772.     movea.l    a3,a2
  773.     lea    (mdu_Init,pc),a1
  774.     move.l    a6,-(sp)
  775.     movea.l    (md_SysLib,a6),a6
  776.     SYS    InitStruct
  777.     movea.l    (sp)+,a6
  778.  
  779.     move.l    a5,-(sp)    ;Look up DACIA base address
  780.     lea    (basetable,pc),a0
  781.     moveq    #0,d0
  782.     move.b    d2,d0
  783.     lsl.l    #2,d0
  784.     movea.l    (0,a0,d0.w),a5 
  785.     move.l    a5,(daciabase,a3)
  786.  
  787.     move.b    #$7f,(IER,a5)     ;Disable DACIA interrupts
  788.  
  789.     bset    d2,(ScoreBoard,a6)
  790.     bsr    SetUpUnit
  791.     movea.l    (sp)+,a5
  792.     tst.l    d0
  793.     bne.b    BadSetup
  794.  
  795.     bsr    InitTask    ;Set up the two tasks for this unit
  796.     tst.l    d0
  797.     beq.b    BadSetup
  798.  
  799. ;Done with InitUnit - fill in the proper md_Unit field in the device struct
  800. ;and return.
  801.     move.l    d2,d0    ;Unit number
  802.     lsl.l    #2,d0
  803.     move.l    a3,(md_Units,a6,d0.l) ;Set unit table
  804.     lea    (Unit0,pc),a2
  805.     move.l    a3,(a2,d0.l)
  806.     movem.l    (sp)+,d0/d1/a4/a2
  807.     PUTDEBUG    30,<'%s/InitUnit: finished! End of silence.'>
  808.     rts
  809.  
  810. ;This routine does the following:
  811. ;
  812. ;1. Allocate read buffer memory
  813. ;2. Initialize all the special MyDevUnit fields (but NOT the signals -
  814. ;   they must be allocated in the task's context)
  815. ;3. Call InitDACIA [Initialize/set-up DACIA registers (for this unit).]
  816. ;4. Install an interrupt server.
  817. ;
  818. ;Returns failure code in d0 - zero if OK, -1 if out of memory, 1 if
  819. ;unable to open timer.device, 2 if invalid parm
  820. ;
  821. ;SetUpUnit(d2:unit number, a3:unit, a6:devptr)
  822. ;AND...ptr to prefs in A4
  823. ;uses d1,a0,a1,a2,a6
  824.  
  825. SetUpUnit:
  826.     PUTDEBUG    30,<'%s/SetUpUnit: called'>
  827.     movem.l    d1/a0/a1/a2,-(sp)
  828.  
  829.     move.l    #65536,d0    ;buffer size
  830.     move.l    d0,(prefs_RBUFLEN,a4)
  831.  
  832.     move.l    #MEMF_PUBLIC,d1
  833.     EXEC    AllocMem
  834.     tst.l    d0
  835.     bne.b    continitunit
  836.     moveq    #-1,d0    ;Failed to allocate input buffer memory - exit.
  837.     movem.l    (sp)+,d1/a0/a1/a2
  838.     rts
  839.  
  840. ;Initialize all the special MyDevUnit fields (but NOT the signals -
  841. ;they must be allocated in the task's context)
  842.  
  843. continitunit:
  844.     move.l    d0,(StartBuf,a3)
  845.     clr.l    (HeadLong,a3)
  846.     clr.l    (TailLong,a3)
  847.  
  848.     move.l    a4,(mdu_prefs,a3)
  849.     move.l    (SysBase).w,(mdu_SysLib,a3) 
  850.     lea    (timerport+MP_MSGLIST,a3),a0
  851.     NEWLIST    a0         ;Init the unit's timer MsgPort's list
  852.     move.b    d2,(mdu_UnitNum,a3)    ;Initialize unit number
  853.     move.l    a6,(mdu_Device,a3)     ;Initialize device pointer
  854.     move.b    #$FF,(xstate,a3)
  855.     move.b    #$80,(frstate,a3)
  856.     bset    #UNITB_NEEDCHAR,(UNIT_FLAGS,a3)
  857.  
  858.     lea    (timername,pc),a0    ;Open the timer device.
  859.     moveq    #UNIT_MICROHZ,d0
  860.     lea    (timeriorequest,a3),a1
  861.     moveq    #0,d1 ;no special flags
  862.     move.l    a6,-(sp)
  863.     movea.l    (md_SysLib,a6),a6
  864.     SYS    OpenDevice
  865.     movea.l    (sp)+,a6
  866.     tst.l    d0
  867.     bne    OpenTimerFailed
  868.  
  869. ;Initialize/set-up DACIA registers (for this unit).
  870. ;(according to the prefs pointed to by a4) 
  871.  
  872.     bsr    InitDACIA
  873.     tst.l    d0
  874.     bne    InitDACIAfailed 
  875.  
  876. ;Install an interrupt server.
  877.  
  878.     bsr    NewVector
  879.     tst.l    d0
  880.     bne.b    EndSetUpUnit
  881.  
  882.     moveq    #0,d0 ;situation under control
  883.     movem.l    (sp)+,d1/a0/a1/a2
  884.     PUTDEBUG    30,<'%s/SetUpUnit: Finished!'>
  885.     rts
  886.  
  887. InitDACIAfailed:
  888.     moveq    #2,d0
  889.     bra.b    EndSetUpUnit
  890.  
  891. OpenTimerFailed:
  892.     moveq    #1,d0
  893. EndSetUpUnit:
  894.     move.l    d0,-(sp)
  895.     move.l    (prefs_RBUFLEN,a4),d0
  896.     movea.l    (StartBuf,a3),a1
  897.     EXEC    FreeMem
  898.     move.l    (sp)+,d0
  899.     movem.l    (sp)+,d1/a0/a1/a2
  900.     rts
  901.  
  902. ;****** end of SetUpUnit ******
  903.  
  904. ;Initialize/set-up DACIA registers (for this unit).
  905. ;(according to the prefs pointed to by a4) 
  906. ;d0.b will mirror CTR, d1.b will mirror FMR
  907. ;Returns error code in d0 - zero if successful.
  908. ;uses d1,d3,d5,a0
  909.  
  910. InitDACIA:
  911.     PUTDEBUG    30,<'%s/InitDACIA: Called.'>
  912.     movem.l    d1/d3/d5/a0,-(sp)
  913.  
  914. ;"During power-on initialization, all readable registers should be read to
  915. ; assure that the status registers are initialized."
  916.  
  917.     move.b    (ISR,a5),d0
  918.     move.b    (CSR,a5),d0
  919.     move.b    (RDR,a5),d0
  920.  
  921.     move.b    (frstate,a3),d0    ;Set DTR* and RTS* low (assert)
  922.     and.b    #$FC,d0    ;Clear bits zero and one
  923.     move.b    d0,(frstate,a3)
  924.     move.b    d0,(FMR,a5)
  925.  
  926.     moveq    #0,d0
  927.     bset    #6,d0    ;Always access ACR, never CDR
  928.     move.b    (frstate,a3),d1
  929.   
  930.     move.l    (prefs_BAUD,a4),d3 ;First, set proper baud rate.
  931.  
  932.     ifne    INFO_LEVEL    ;If any debugging enabled at all
  933.     move.l    d3,-(sp)
  934.     PUTDEBUG    150,<'%s/InitDACIA: %ldbps requested.'>
  935.     addq.l    #4,sp
  936.     endc
  937.  
  938.     swap    d3
  939.     tst.w    d3
  940.     bne    InvParm
  941.     swap    d3
  942.  
  943. ;Test for (and allow) zero baud -- this makes Handshake happy
  944. ;(Not a bug in Handshake.)  Old RKMs mentioned this behavior, but the
  945. ;latest RKMs do not. Argh!
  946.  
  947.     tst.l    d3
  948.     beq.b    SkipBAUD
  949.  
  950.     lea    (baudtable,pc),a0
  951.     moveq    #15,d5 
  952. baudloop:    cmp.w    (a0)+,d3
  953.     dbeq    d5,baudloop
  954.     bne    InvParm
  955.     not.b    d5
  956.     and.b    #$0F,d5
  957.     or.b    d5,d0    
  958.  
  959.     ifne    INFO_LEVEL
  960.     clr.l    -(sp)
  961.     move.b    d0,(3,sp)
  962.     PUTDEBUG    30,<'%s/InitDACIA: Baud rate = %lx'>
  963.     addq.l    #4,sp
  964.     endc
  965.  
  966. SkipBAUD:
  967.     cmpi.b    #1,(prefs_STOPBITS,a4) ;Next, set number of stop bits per character
  968.     beq.b    onestop
  969.     bset    #5,d0
  970. onestop:
  971.     move.b    d0,(CTR,a5)
  972.  
  973. ;set data bits per character
  974.     move.b    (prefs_READLEN,a4),d3
  975.     cmp.b    (prefs_WRITELEN,a4),d3
  976.     bne    InvParm    ;We don't support different read & write char lengths
  977.     subq.b    #5,d3
  978.     bmi    InvParm
  979.     cmp.b    #3,d3
  980.     bhi    InvParm
  981.     lsl.b    #5,d3
  982.     and.b    #$80,d1    ;bug fix (clear before OR)
  983.     or.b    d3,d1
  984.  
  985.     btst    #SEXTB_MSPON,(prefs_EXTFLAGS+3,a4) ;Set parity
  986.     beq.b    EvenOdd
  987.     bset    #2,d1
  988.     btst    #SEXTB_MARK,(prefs_EXTFLAGS+3,a4)
  989.     bne.b    UseMark
  990.     or.b    #24,d1    ;Use space
  991.     bra.b    NoParity
  992.  
  993. UseMark:    or.b    #16,d1
  994.     bra.b    NoParity
  995.  
  996. EvenOdd:    btst    #SERB_PARTY_ON,(prefs_SERFLAGS,a4)
  997.     beq.b    NoParity
  998.     bset    #2,d1
  999.  
  1000.     btst    #SERB_PARTY_ODD,(prefs_SERFLAGS,a4)
  1001.     bne.b    UseOdd
  1002.     or.b    #8,d1
  1003. UseOdd:
  1004. NoParity:
  1005.  
  1006.     ifne    INFO_LEVEL
  1007.     clr.l    -(sp)
  1008.     move.b    d1,(3,sp)
  1009.     PUTDEBUG    30,<'%s/InitDACIA: FMR = %lx'>
  1010.     addq.l    #4,sp
  1011.     endc
  1012.  
  1013.     move.b    d1,(frstate,a3)
  1014.     move.b    d1,(FMR,a5)
  1015.     moveq    #0,d0
  1016.     movem.l    (sp)+,d1/d3/d5/a0
  1017.     PUTDEBUG    30,<'%s/InitDACIA: Finished!'>
  1018.     rts
  1019.  
  1020. InvParm:    PUTDEBUG    30,<'%s/InitDACIA: Invalid Parm!'>
  1021.     moveq    #-1,d0
  1022.     movem.l    (sp)+,d1/d3/d5/a0
  1023.     rts
  1024.  
  1025. ;****** end of InitDACIA ******
  1026.  
  1027. ;(this is a subroutine for InitUnit)
  1028. ;This routine sets up the two tasks (one for reading, one for writing).
  1029. ;Returns zero in d0.l if an error occured else a ptr to the unit.
  1030. ;
  1031. ;uses d1-d4 and a0-a5
  1032.  
  1033. InitTask:
  1034.     PUTDEBUG    30,<'%s/InitTask: called.'>
  1035.     movem.l    d1-d4/a0-a5,-(sp)
  1036.     lea    (ReadTask_Begin,pc),a5 ;Set up the read task
  1037.     lea    (mdu_rstack,a3),a0
  1038.     lea    (mdu_rtcb,a3),a1
  1039.     movea.l    a3,a2    ;Read message port
  1040.     bsr.b    InitTaskStruct
  1041.  
  1042.     lea    (WriteTask_Begin,pc),a5 ;Set up the write task
  1043.     lea    (mdu_wstack,a3),a0
  1044.     lea    (mdu_wtcb,a3),a1
  1045.     lea    (mdu_wport,a3),a2
  1046.     bsr.b    InitTaskStruct
  1047.  
  1048.     move.l    a3,d0    ;Mark us as ready to go
  1049.     PUTDEBUG    30,<'%s/InitTask: ok'>
  1050.  
  1051. ;Return zero in d0.l if an error occured, else a ptr to the unit
  1052.  
  1053.     movem.l    (sp)+,d1-d4/a0-a5
  1054.     rts
  1055.  
  1056. ;Start up the unit task.  We do a trick here --we set his message port to
  1057. ;PA_IGNORE until the new task has a change to set it up.  We cannot go to
  1058. ;sleep here: it would be very nasty if someone else tried to open the unit
  1059. ;(exec's OpenDevice has done a Forbid() for us --we depend on this to become
  1060. ;single threaded).
  1061. ;
  1062. ;Enter with:
  1063. ;a0 - ptr to low end of stack
  1064. ;a1 - ptr to tcb (task control block)
  1065. ;a3 - unit pointer
  1066. ;a5 - starting address of task
  1067. ;a2 - ptr to a (uninitialized) message port
  1068. ;
  1069. ;uses a0-a3 and d0,d1
  1070.  
  1071. InitTaskStruct:
  1072.     movem.l    d0/d1/a0-a3,-(sp)
  1073.     move.l    a0,(TC_SPLOWER,a1)    ;Initialize the stack information
  1074.     lea    (MYPROCSTACKSIZE,a0),a0 ;High end of stack
  1075.     move.l    a0,(TC_SPUPPER,a1)
  1076.     move.l    a3,-(a0)    ;Argument - unit ptr (send on stack)
  1077.     move.l    a0,(TC_SPREG,a1)
  1078.     move.l    a1,(MP_SIGTASK,a2)
  1079.  
  1080.     ifge    INFO_LEVEL-30
  1081.     move.l    a1,-(sp)
  1082.     move.l    a3,-(sp)
  1083.     PUTDEBUG    30,<'%s/InitUnit, unit= %lx, task=%lx'>
  1084.     addq.l    #8,sp
  1085.     endc
  1086.  
  1087.     lea    (MP_MSGLIST,a2),a0
  1088.     NEWLIST    a0    ;Init the unit's MsgPort's list
  1089.     movea.l    a5,a2    ;Startup the task
  1090.     move.w    #-1,a3    ;generate address error
  1091.             ;if task ever "returns" (we RemTask() it
  1092.             ;to get rid of it...)
  1093.     moveq    #0,d0
  1094.     PUTDEBUG    30,<'%s/About to add task'>
  1095.     move.l    a6,-(sp)
  1096.     movea.l    (md_SysLib,a6),a6
  1097.     SYS    AddTask
  1098.     movea.l    (sp)+,a6
  1099.     movem.l    (sp)+,d0/d1/a0-a3
  1100.     rts
  1101.  
  1102. ;Get rid of the unit's tasks.  We know this is safe because the unit has an
  1103. ;open count of zero, so it is 'guaranteed' not in use.
  1104. ;
  1105. ;Kill the two tasks
  1106. ; ( a3:unitptr, a6:deviceptr )
  1107. ;
  1108. ;uses a0,a1 and d0-d2
  1109.  
  1110. KillTask:
  1111.     movem.l    a0/a1/d0-d2,-(sp)
  1112.     lea    (mdu_rtcb,a3),a1
  1113.     move.l    a6,-(sp)
  1114.     movea.l    (md_SysLib,a6),a6
  1115.     SYS    RemTask
  1116.     movea.l    (sp)+,a6
  1117.  
  1118.     lea    (mdu_wtcb,a3),a1
  1119.     move.l    a6,-(sp)
  1120.     movea.l    (md_SysLib,a6),a6
  1121.     SYS    RemTask
  1122.     movea.l    (sp)+,a6
  1123.  
  1124.     moveq    #0,d2
  1125.     move.b    (mdu_UnitNum,a3),d2 ;Save the unit number
  1126.     bsr    FreeUnit    ;Free the unit structure
  1127.     lsl.l    #2,d2
  1128.     clr.l    (md_Units,a6,d2.l)    ;Clear out the unit vector in the device
  1129.     movem.l    (sp)+,a0/a1/d0-d2
  1130.     rts
  1131.  
  1132. ; ( a3:unitptr, a6:deviceptr )
  1133. ;uses a0,a1,d0,d1
  1134.  
  1135. FreeUnit:
  1136.     movem.l    a0/a1/d0/d1,-(sp)
  1137.     movea.l    a3,a1
  1138.     move.l    #MyDevUnit_Sizeof,d0
  1139.     move.l    a6,-(sp)
  1140.     movea.l    (md_SysLib,a6),a6
  1141.     SYS    FreeMem
  1142.     movea.l    (sp)+,a6
  1143.     movem.l    (sp)+,a0/a1/d0/d1
  1144.     rts
  1145.  
  1146. ; ( a3:unitptr, a6:deviceptr )
  1147. ;
  1148. ;uses a0,a1,a5,d0-d2
  1149.  
  1150. ExpungeUnit:
  1151.     movem.l    a0/a1/a5/d0-d2,-(sp)
  1152.     PUTDEBUG    10,<'%s/ExpungeUnit: called'>
  1153.  
  1154.     movea.l    (daciabase,a3),a5
  1155.     move.b    #$7f,(IER,a5)    ;shut off all interrupts
  1156.     move.b    #$83,(FMR,a5)    ;Deassert DTR* and RTS*
  1157.  
  1158.     bsr    FreeResources
  1159.  
  1160.     lea    (mdu_rtcb,a3),a1
  1161.     move.l    a6,-(sp)
  1162.     movea.l    (md_SysLib,a6),a6
  1163.     SYS    RemTask
  1164.     movea.l    (sp)+,a6
  1165.  
  1166.     lea    (mdu_wtcb,a3),a1
  1167.     move.l    a6,-(sp)
  1168.     movea.l    (md_SysLib,a6),a6
  1169.     SYS    RemTask
  1170.     movea.l    (sp)+,a6
  1171.  
  1172.     moveq    #0,d2
  1173.     move.b    (mdu_UnitNum,a3),d2 ;Save the unit number
  1174.     bsr    FreeUnit    ;Free the unit structure.
  1175.  
  1176.     bclr    d2,(ScoreBoard,a6)
  1177.     bsr    NewVector
  1178.     lsl.l    #2,d2
  1179.     clr.l    (md_Units,a6,d2.l) ;Clear out the unit pointer in the device
  1180.  
  1181.     movem.l    (sp)+,a0/a1/a5/d0-d2
  1182.     rts
  1183.  
  1184. ;This routines frees up resources specific to this driver (the other
  1185. ;resources are taken care of by the skeleton).
  1186. ;Be careful with this routine, so as not to pull the rug out from
  1187. ;underneath the driver...
  1188. ;
  1189. ;Enter with unit ptr in a3 and device ptr in a6
  1190. ;
  1191. ;uses a0,a1,a4,d0,d1
  1192.  
  1193. FreeResources:
  1194.     PUTDEBUG    10,<'%s/FreeResources: called'>
  1195.     movem.l    a0/a1/a4/d0/d1,-(sp)
  1196.     movea.l    (StartBuf,a3),a1    ;Free input buffer memory
  1197.     movea.l    (mdu_prefs,a3),a4
  1198.     move.l    (prefs_RBUFLEN,a4),d0
  1199.     move.l    a6,-(sp)
  1200.     movea.l    (md_SysLib,a6),a6
  1201.     SYS    FreeMem
  1202.     movea.l    (sp)+,a6
  1203.  
  1204.     lea    (timeriorequest,a3),a1 ;Close timer device
  1205.     move.l    a6,-(sp)
  1206.     movea.l    (md_SysLib,a6),a6
  1207.     SYS    CloseDevice
  1208.     movea.l    (sp)+,a6
  1209.     movem.l    (sp)+,a0/a1/a4/d0/d1
  1210.     PUTDEBUG    10,<'%s/FreeResources: finished!'>
  1211.     rts
  1212.  
  1213. ;Here begins the device functions
  1214. ;
  1215. ;Cmdtable is used to look up the address of a routine that will
  1216. ;implement the device command.
  1217.  
  1218. cmdtable:
  1219.     dc.w    Invalid-cmdtable    ;0    CMD_INVALID
  1220.     dc.w    MyReset-cmdtable    ;1    CMD_RESET
  1221.     dc.w    Read-cmdtable    ;2    CMD_READ
  1222.     dc.w    Write-cmdtable    ;3    CMD_WRITE
  1223.     dc.w    Invalid-cmdtable    ;4    CMD_UPDATE (update has no meaning here)
  1224.     dc.w    MyClear-cmdtable    ;5    CMD_CLEAR
  1225.     dc.w    MyStop-cmdtable    ;6    CMD_STOP
  1226.     dc.w    Start-cmdtable    ;7    CMD_START
  1227.     dc.w    Flush-cmdtable    ;8    CMD_FLUSH
  1228.     dc.w    Query-cmdtable    ;9    SDCMD_QUERY
  1229.     dc.w    Break-cmdtable    ;10    SDCMD_BREAK
  1230.     dc.w    SetParams-cmdtable    ;11    SDCMD_SETPARAMS
  1231.     dc.w    Invalid-cmdtable    ;12    not used
  1232.     dc.w    Invalid-cmdtable    ;13    not used
  1233.     dc.w    Invalid-cmdtable    ;14    not used
  1234.     dc.w    Invalid-cmdtable    ;15    not used
  1235.     dc.w    SetControlLines-cmdtable    ;16 - ASDG extension
  1236.  
  1237. ;BeginIO starts all incoming io.  The IO is either queued up for the
  1238. ;unit task or processed immediately.
  1239. ;
  1240. ;BeginIO often is given the responsibility of making devices single
  1241. ;threaded... so two tasks sending commands at the same time don't cause
  1242. ;a problem.  Once this has been done, the command is dispatched.
  1243. ;
  1244. ;Some IO requests do not need single threading. These can be performed
  1245. ;immediatley.
  1246. ;The immediate commands are Invalid, Reset, Stop, Start, Flush, Clear,
  1247. ;Query, SetParams, and SetControlLines.
  1248. ;
  1249. ;IMPORTANT:
  1250. ; The exec WaitIO() function uses the IORequest node type (LN_TYPE)
  1251. ; as a flag.  If set to NT_MESSAGE, it assumes the request is
  1252. ; still pending and will wait.  If set to NT_REPLYMSG, it assumes the
  1253. ; request is finished.  It's the responsibility of the device driver
  1254. ; to set the node type to NT_MESSAGE before returning to the user.
  1255. ;
  1256. ;Notes: This routine looks at IO_COMMAND to determine which task
  1257. ;to use. Break and Write requests go to the write
  1258. ;task. Read requests (only) go to the read task. 
  1259. ;All other requests are performed immediately, i.e. within the caller's
  1260. ;context.
  1261. ;
  1262. ;This routine uses a3,a4,a5 (and a0/a1/d0/d1, but those do not need to be
  1263. ;preserved).
  1264. ; ( iob: a1, device:a6 )
  1265.  
  1266. ;************************** Start of BeginIO ***************************
  1267.  
  1268. BeginIO:
  1269.  
  1270.     movem.l    a3-a5,-(sp)
  1271.  
  1272.     ifge    INFO_LEVEL-1
  1273.     bchg.b    #1,($bfe001).l    ;Blink the power LED
  1274.     endc
  1275.  
  1276.     ifge    INFO_LEVEL-3
  1277.     clr.l    -(sp)
  1278.     move.w    (IO_COMMAND,a1),(2,sp) ;Get entire word
  1279.     PUTDEBUG    3,<'%s/BeginIO  --  %ld'>
  1280.     addq.l    #4,sp
  1281.     endc
  1282.  
  1283.     move.w    (IO_COMMAND,a1),d0
  1284.     cmp.w    #16,d0    ;command in range?
  1285.     bhi    .NoCmd    ;no, reject it.
  1286.  
  1287. ;Do some initial set-up work
  1288.     andi.b    #$f,(IO_FLAGS,a1)    ;clear upper nibble
  1289.     move.b    #NT_MESSAGE,(LN_TYPE,a1) ;So WaitIO() is guaranteed to work
  1290.     movea.l    (IO_UNIT,a1),a3    ;Bookkeeping -> what unit to play with
  1291.     movea.l    (mdu_prefs,a3),a4
  1292.     movea.l    (daciabase,a3),a5
  1293.     clr.b    (IO_ERROR,a1)    ;No error so far
  1294.  
  1295.     cmp.w    #CMD_READ,d0
  1296.     bne    .NotRead
  1297.  
  1298. ;If the task is busy reading, don't read in the caller's context!
  1299.     tst.l    (ReadRequestPtr,a3)
  1300.     bne.b    .ForgetIt
  1301.     lea    (MP_MSGLIST,a3),a0    ;Read port - anything there?
  1302.     movea.l    (a0),a0
  1303.     tst.l    (a0)
  1304.     bne.b    .ForgetIt
  1305.  
  1306. ;Check whether there are enough characters in the buffer to do the read
  1307. ;immediately.
  1308.  
  1309.     btst    #SERB_RAD_BOOGIE,(prefs_SERFLAGS,a4)    ;Check for RAD_BOOGIE
  1310.     beq.b    .ForgetIt
  1311.     bsr    GetBytesInReadBuf
  1312.     cmp.l    (IO_LENGTH,a1),d0
  1313.     blo.b    .ForgetIt
  1314.     bset    #UNITB_READIMMEDIATE,(UNIT_FLAGS,a3)
  1315.     bne.b    .ForgetIt
  1316.     bsr    ReadImmediate
  1317.     bclr    #UNITB_READIMMEDIATE,(UNIT_FLAGS,a3)
  1318.     bra    .ReplyEnd
  1319. .ForgetIt:
  1320.  
  1321. ;Send message to read task
  1322.  
  1323.     move.l    a3,a0
  1324.     bra    .SendMessage
  1325.  
  1326. .NotRead:
  1327.     cmp.w    #CMD_WRITE,d0
  1328.     bne    .NotWrite
  1329.  
  1330.     moveq    #1,d0
  1331.     cmp.l    (IO_LENGTH,a1),d0
  1332.     bne    .QueueForWriteTask
  1333.  
  1334. ;If the write task is busy writing, don't write in the caller's context!
  1335.     tst.l    (WriteRequestPtr,a3)
  1336.     bne    .QueueForWriteTask
  1337.     lea    (mdu_wport+MP_MSGLIST,a3),a0    ;Write port - anything there?
  1338.     movea.l    (a0),a0
  1339.     tst.l    (a0)
  1340.     bne    .QueueForWriteTask
  1341.  
  1342.     btst    #SERB_7WIRE,(prefs_SERFLAGS,a4)
  1343.     bne.b    .Handshake
  1344.     btst    #CSRB_CTSL,(CSR,a5)
  1345.     bne    .QueueForWriteTask
  1346. .Handshake:
  1347.     tst.b    (xstate,a3)
  1348.     beq    .QueueForWriteTask
  1349.  
  1350.     Disable
  1351.     btst    #UNITB_NEEDCHAR,(UNIT_FLAGS,a3)
  1352.     beq.b    .NeedInt    ;Enable, then QueueForWriteTask
  1353.     move.l    (IO_DATA,a1),a0
  1354.     move.b    (a0),(TDR,a5)
  1355.     bclr    #UNITB_NEEDCHAR,(UNIT_FLAGS,a3)
  1356.     Enable
  1357.     bclr    #UNITB_BREAKSENT,(UNIT_FLAGS,a3)    ;for Query
  1358.     move.l    d0,(IO_ACTUAL,a1)
  1359.     bra.b    .ReplyEnd
  1360.  
  1361. .NotWrite:
  1362.     cmp.w    #SDCMD_BREAK,d0
  1363.     beq.b    .QueueForWriteTask    ;Handle just like a write request
  1364.  
  1365. ;execute immediately
  1366.     lea    (cmdtable,pc),a0
  1367.     add.w    d0,d0
  1368.     add.w    (a0,d0.w),a0
  1369.     jsr    (a0)
  1370.  
  1371. ;If the quick bit is set then we don't need to reply
  1372.  
  1373. .ReplyEnd:
  1374.     btst    #IOB_QUICK,(IO_FLAGS,a1)
  1375.     bne.b    .End
  1376.     push    a6
  1377.     move.l    (4).w,a6
  1378.     SYS    ReplyMsg
  1379.     pop    a6
  1380. .End:    movem.l    (sp)+,a3-a5
  1381.     rts
  1382.  
  1383. .NeedInt:
  1384.     Enable
  1385.  
  1386. .QueueForWriteTask:
  1387. ;Send message to write task
  1388.  
  1389.     lea    (mdu_wport,a3),a0
  1390.  
  1391. .SendMessage:
  1392. ;Send the IO request as a "message" to either the read or write task
  1393. ;Enter with port address in A0 and IORequest in A1
  1394.  
  1395.     bclr    #IOB_QUICK,(IO_FLAGS,a1)    ;We did NOT complete this quickly
  1396.  
  1397.     ifge    INFO_LEVEL-250
  1398.     move.l    a1,-(sp)
  1399.     move.l    a0,-(sp)
  1400.     PUTDEBUG    250,<'%s/PutMsg: Port=%lx Message=%lx'>
  1401.     addq.l    #8,sp
  1402.     endc
  1403.  
  1404.     push    a6
  1405.     movea.l    (md_SysLib,a6),a6
  1406.     SYS    PutMsg    ;Port=a0, Message=a1
  1407.     pop    a6
  1408.     bra    .End
  1409.  
  1410. .NoCmd:
  1411.     PUTDEBUG 200,<'%s/BeginIO_NoCmd!'>
  1412.     move.b    #IOERR_NOCMD,(IO_ERROR,a1)
  1413.     bra    .ReplyEnd
  1414.  
  1415. ;************************* End of BeginIO ****************************
  1416.  
  1417. ;Here begins the functions that implement the device commands
  1418. ;all functions are called with:
  1419. ;  a1 -- a pointer to the io request block
  1420. ;  a3 -- a pointer to the unit
  1421. ;  a4 -- a pointer to prefs
  1422. ;  a5 -- a pointer to the unit hardware
  1423. ;  a6 -- a pointer to the device
  1424. ;
  1425. ;Commands that conflict with 68000 instructions have a "My" prepended to them.
  1426.  
  1427. ;****************************** Read *****************************
  1428.  
  1429. Read:
  1430.     movem.l    d0-d6/a0/a2,-(sp)
  1431.  
  1432. ;Try to do a quick read
  1433.     btst    #SERB_RAD_BOOGIE,(prefs_SERFLAGS,a4)    ;Check for RAD_BOOGIE
  1434.     beq.b    .NoBoogie
  1435.  
  1436.     bsr    GetBytesInReadBuf
  1437.     cmp.l    (IO_LENGTH,a1),d0
  1438.     blo.b    .NotEnoughDataInBuf
  1439.     bsr    ReadImmediate
  1440.     bra    .FinalEndRead
  1441.  
  1442. .NoBoogie:
  1443. .NotEnoughDataInBuf:
  1444.  
  1445.     moveq    #0,d5    ;IO_ACTUAL
  1446.     move.l    (IO_LENGTH,a1),d6
  1447.     movea.l    (IO_DATA,a1),a2
  1448.  
  1449.     ifne    INFO_LEVEL    ;If any debugging enabled at all
  1450.     move.l    d6,-(sp)
  1451.     PUTDEBUG    150,<'%s/Read entered -- %ld bytes requested.'>
  1452.     addq.l    #4,sp
  1453.     endc
  1454.  
  1455.     bra    .ReadEntry
  1456.  
  1457. .ReadLoop:
  1458.     PUTDEBUG    150,<'%s/Read: Waiting for signal from interrupt code.'>
  1459.     move.l    (readsig,a3),d0
  1460.     add.l    (readabortsig,a3),d0
  1461.     bset    #MDUB_WaitingForChar,(MDU_FLAGS,a3)
  1462.     EXEC    Wait    ;Wait for one or more bytes to come in
  1463.     and.l    (readabortsig,a3),d0
  1464.     bne    .ReadAbort
  1465. .NoErrorAtAll:
  1466.     PUTDEBUG    150,<'%s/Read: One or more bytes came in.'>
  1467.  
  1468. .ReadEntry:
  1469.     bsr    GetBytesInReadBuf
  1470.  
  1471.     ifne    INFO_LEVEL    ;If any debugging enabled at all
  1472.     move.l    d0,-(sp)
  1473.     PUTDEBUG    150,<'%s/Read: There are %ld bytes in the buffer.'>
  1474.     addq.l    #4,sp
  1475.     endc
  1476.  
  1477.     tst.l    d0
  1478.     beq    .ReadLoop
  1479.     cmp.l    d0,d6
  1480.     bls.b    .AllDone    ;Branch if d6 <= d0
  1481.     sub.l    d0,d6
  1482.     bsr    DumpReadBuf    ;Dump d0 bytes of the read buffer into the user's buffer
  1483.     tst.l    d0
  1484.     beq    .ReadLoop  
  1485.     bra.b    .EndRead    ;Go if TermArray caused early exit
  1486.  
  1487. ;The number of bytes in the read buffer equals or exceeds the number of
  1488. ;bytes the user wants.
  1489.  
  1490. .AllDone:
  1491.     PUTDEBUG    150,<'%s/Read: All done.'>
  1492.     move.l    d6,d0
  1493.     bsr    DumpReadBuf    ;Dump d0 bytes of the read buffer into the user's buffer
  1494. .EndRead:    PUTDEBUG    150,<'%s/Read: Finished!'>
  1495.  
  1496. ;    bclr    #MDUB_V,(MDU_FLAGS,a3)
  1497. ;    beq.b    NoOverflow
  1498. ;    move.b    #SerErr_BufOverflow,(IO_ERROR,a1)
  1499. ;NoOverflow:
  1500.  
  1501.     move.l    d5,(IO_ACTUAL,a1)
  1502. .FinalEndRead:
  1503.     movem.l    (sp)+,d0-d6/a0/a2
  1504.     rts        ;Done with read
  1505.  
  1506. ;Something exceptional happened.  An informative error code should be
  1507. ;returned.  first, check for error conditions...  Note that the serial.device
  1508. ;standard does not provide a way to inform the caller of simultaneous error
  1509. ;conditions.
  1510.  
  1511. .ReadAbort:
  1512.     PUTDEBUG    150,<'%s/readabort: Something exceptional happened.'>
  1513.     Disable
  1514.     move.b    (ISRcopy,a3),d2
  1515.     move.b    (CSRcopy,a3),d3
  1516.     clr.b    (ISRcopy,a3)
  1517.     clr.b    (CSRcopy,a3)
  1518.     Enable
  1519.     btst    #ISRB_PAR,d2
  1520.     beq.b    .notpar
  1521.  
  1522.     move.b    #SerErr_ParityErr,(IO_ERROR,a1)    ;parity error
  1523.     bra    .EndRead
  1524.  
  1525. .notpar:    btst    #1,d2    ;Check for frame err, overrun, & break
  1526.     beq    .EndRead    ;We infer that an abort has been issued
  1527.  
  1528. ;This is a check for framing error....it might cause problems for
  1529. ;some auto-baud algorithms, so it's commented out for this release.
  1530.  
  1531. ;    btst    #CSRB_FE,d3    ;Probe further...
  1532. ;    beq.b    noframe
  1533.  
  1534. ;    move.b    #SerErr_LineErr,(IO_ERROR,a1)    ;Framing Error
  1535. ;    bra    endread
  1536.  
  1537. .noframe:    btst    #CSRB_RBRK,d3
  1538.     beq    .NoErrorAtAll
  1539.  
  1540. ;Note that we ignore receive overrun errors. Since there is no error
  1541. ;code for it, I assume this is what serial.device does too.
  1542.  
  1543.     move.b    #SerErr_DetectedBreak,(IO_ERROR,a1)    ;Break
  1544.     bra    .EndRead 
  1545.  
  1546. ;****** Subroutines for the read routine ******
  1547.  
  1548. GetBytesInReadBuf:
  1549.  
  1550. ;Return with the number of bytes in the read buffer in d0
  1551.  
  1552.     move.l    d1,-(sp)
  1553.  
  1554.     movem.l    (HeadLong,a3),d0/d1    ;load HeadLong/TailLong
  1555.  
  1556.     ifne    INFO_LEVEL    ;If any debugging enabled at all
  1557.     move.l    d0,-(sp)
  1558.     PUTDEBUG    150,<'%s/GetBytesInReadBuf: HeadLong=%ld'>
  1559.     addq.l    #4,sp
  1560.     endc
  1561.  
  1562.     ifne    INFO_LEVEL    ;If any debugging enabled at all
  1563.     move.l    d1,-(sp)
  1564.     PUTDEBUG    150,<'%s/GetBytesInReadBuf: TailLong=%ld'>
  1565.     addq.l    #4,sp
  1566.     endc
  1567.  
  1568.     sub.l    d0,d1
  1569.     bpl.b    .skipadd
  1570.     add.l    #65536,d1
  1571. .skipadd:
  1572.     move.l    d1,d0
  1573.  
  1574.     move.l    (sp)+,d1
  1575.     rts
  1576.  
  1577. ;Enter with number of bytes to read in d0
  1578. ;Enter with a pointer to a dump buffer in a2
  1579. ;the pointer in a2 is updated to reflect the current position
  1580. ;
  1581. ;This routine uses as scratch: d0,d5,d6,a2
  1582. ;and updates the following: d5,a2
  1583. ;Returns with D0=0 if all is OK, else a TermArray match was found.
  1584.  
  1585. ;This is a subroutine used only by Read
  1586.  
  1587. DumpReadBuf:
  1588.     movem.l    d1/d6/d7/a0/a6,-(sp)
  1589.     move.l    (HeadLong,a3),d1
  1590.     add.w    d0,(Head,a3)
  1591.     move.l    (StartBuf,a3),a0
  1592.  
  1593.     btst    #SERB_RAD_BOOGIE,(prefs_SERFLAGS,a4)
  1594.     bne.b    .Loop
  1595.  
  1596.     btst    #SERB_EOFMODE,(IO_SERFLAGS,a1)
  1597.     beq.b    .XLoop 
  1598.  
  1599. .EOFDump:
  1600.     moveq    #7,d7
  1601.     lea    (prefs_TERMARRAY,a4),a6
  1602.     move.b    (a0,d1.l),d6    ;index MUST be long (sign extended)!
  1603.     btst    #SERB_XDISABLED,(prefs_SERFLAGS,a4)
  1604.     bne.b    .Skip
  1605.     bsr    xcode
  1606. .Skip:    cmp.b    (a6)+,d6
  1607.     dbcc    d7,.Skip
  1608.     beq.b    .TermRead    
  1609.     move.b    d6,(a2)+
  1610.     addq.l    #1,d5
  1611.     addq.w    #1,d1
  1612.     subq.l    #1,d0
  1613.     bne.b    .EOFDump
  1614.     bra.b    .End
  1615.  
  1616. .Loop:
  1617.     move.b    (a0,d1.l),(a2)+    ;index MUST be long (sign extended)!
  1618.     addq.l    #1,d5    ;add to IO_ACTUAL
  1619.     addq.w    #1,d1    ;increment 16-bit head ptr
  1620.     subq.l    #1,d0
  1621.     bne.b    .Loop 
  1622.     bra.b    .End
  1623.  
  1624. .XLoop:
  1625.     move.b    (a0,d1.l),d6    ;index MUST be long (sign extended)!
  1626.     bsr.b    xcode
  1627.     move.b    d6,(a2)+
  1628.     addq.l    #1,d5    ;add to IO_ACTUAL
  1629.     addq.w    #1,d1    ;increment 16-bit head ptr
  1630.     subq.l    #1,d0
  1631.     bne.b    .XLoop 
  1632.     bra.b    .End
  1633.  
  1634. .TermRead:
  1635.     moveq    #-1,d0
  1636.     bra.b    .End1
  1637. .End:
  1638.     moveq    #0,d0
  1639. .End1:
  1640.     movem.l    (sp)+,d1/d6/d7/a0/a6
  1641.     rts
  1642.  
  1643. xcode:
  1644.  
  1645. ;Check for xon/xoff
  1646. ;Enter with current read character in d6.b
  1647.  
  1648.     ifne    INFO_LEVEL
  1649.     move.l    (prefs_CTLCHAR,a4),-(sp)
  1650.     PUTDEBUG    5,<'%s/XCODE: prefs_CTLCHAR = %lx'>
  1651.     addq.l    #4,sp
  1652.     endc
  1653.  
  1654.     ifne    INFO_LEVEL
  1655.     clr.l    -(sp)
  1656.     move.b    d6,(3,sp)
  1657.     PUTDEBUG    5,<'%s/XCODE: Current char = %lx'>
  1658.     addq.l    #4,sp
  1659.     endc
  1660.  
  1661.     cmp.b    (prefs_CTLCHAR,a4),d6    ;Xon check
  1662.     beq.b    .XON
  1663.     cmp.b    (prefs_CTLCHAR+1,a4),d6    ;Xoff check
  1664.     beq.b    .XOFF
  1665.     rts
  1666.  
  1667. .XON:    PUTDEBUG    5,<'%s/XCODE: XON!'>
  1668.     tst.b    (xstate,a3)
  1669.     bne.b    .End    ;If already on, don't signal!
  1670.     st    (xstate,a3)
  1671.     movem.l    d0/d1/a0/a1/a6,-(sp)
  1672.     move.l    (xonsig,a3),d0
  1673.     lea    (mdu_wtcb,a3),a1
  1674.     movea.l    (mdu_SysLib,a3),a6
  1675.     SYS    Signal
  1676.     movem.l    (sp)+,d0/d1/a0/a1/a6
  1677. .End:    rts
  1678.  
  1679. .XOFF:    PUTDEBUG    5,<'%s/XCODE: XOFF!'>
  1680.     clr.b    (xstate,a3)
  1681.     rts
  1682.  
  1683. ReadImmediate:
  1684.  
  1685. ;Fast read routine
  1686. ;Requires boogie mode to be set and for there to be a sufficient number
  1687. ;of bytes in the buffer to completely satisfy the request.
  1688.  
  1689. ;Uses d0,d1,d2,d4,a0,a1,a2,a4,a6
  1690.  
  1691.     movem.l    d0-d2/d4/a0-a2/a4/a6,-(sp)
  1692.     push    a1
  1693.     move.l    (HeadLong,a3),d2
  1694.     move.l    (IO_LENGTH,a1),d4
  1695.     add.w    d4,(Head,a3)
  1696.     move.l    (IO_DATA,a1),a4
  1697.     move.l    (StartBuf,a3),a2
  1698.     move.l    (mdu_SysLib,a3),a6
  1699.  
  1700.     move.l    #65536,d0
  1701.     sub.l    d2,d0
  1702.     cmp.l    d0,d4
  1703.     bls.b    .UseIOLength
  1704.  
  1705. ;Need 2 copy operations
  1706.     sub.l    d0,d4
  1707.     move.l    a4,a1
  1708.     add.l    d0,a4
  1709.     lea    (a2,d2.l),a0
  1710.     SYS    CopyMem
  1711.     move.l    d4,d0
  1712.     move.l    a4,a1
  1713.     move.l    a2,a0
  1714.     SYS    CopyMem
  1715.     bra.b    .ReadQuickEnd
  1716.  
  1717. .UseIOLength:
  1718.     move.l    d4,d0
  1719.     move.l    a4,a1
  1720.     lea    (a2,d2.l),a0
  1721.     SYS    CopyMem
  1722. .ReadQuickEnd:
  1723.     pop    a1
  1724.     move.l    (IO_LENGTH,a1),(IO_ACTUAL,a1)
  1725.     movem.l    (sp)+,d0-d2/d4/a0-a2/a4/a6
  1726.     rts
  1727.  
  1728. ;*************************** Write ******************************
  1729.  
  1730. Write:
  1731.     comment |
  1732. Potential problem: If a TDRE interrupt happens, and just at that instant
  1733. (before the interrupt routine has time to kick into action) CTS is
  1734. deasserted, the interrupt routine will miss the TDRE condition and the
  1735. write routine will hang. This is unlikely, but possible. V2.10 adds
  1736. a time-out feature to avoid this if it ever happens in real life.
  1737. Testing the effectiveness of this solution is difficult, because I am
  1738. solving a problem that has, to my knowledge, never occured. (hehe)
  1739. |
  1740.  
  1741.     movem.l    d0-d5/a0-a2,-(sp)
  1742.     push    a1
  1743.     bclr    #UNITB_BREAKSENT,(UNIT_FLAGS,a3)    ;for Query
  1744.     btst    #SERB_7WIRE,(prefs_SERFLAGS,a4)
  1745.     bne.b    .Handshake
  1746.     btst    #CSRB_CTSL,(CSR,a5)
  1747.     bne    .NotConnected
  1748.  
  1749. .Handshake:
  1750.     movea.l    (IO_DATA,a1),a2
  1751.     move.l    (IO_LENGTH,a1),d2
  1752.     beq    .End
  1753.     bpl.b    .CheckX
  1754.     move.l    a2,a0    ;handle zero-terminated writes
  1755. .L1:    tst.b    (a0)+
  1756.     bne.b    .L1
  1757.     sub.l    a2,a0
  1758.     move.l    a0,d2
  1759. .CheckX:
  1760.     tst.b    (xstate,a3)
  1761.     bne    .DoIt    ;go if no XOFF
  1762.  
  1763.     PUTDEBUG    5,<'%s/Transmit: Waiting for XON!'>
  1764.     move.l    (xonsig,a3),d0
  1765.     add.l    (writeabortsig,a3),d0
  1766.     EXEC    Wait    ;Wait for an x-on signal before sending
  1767.     and.l    (writeabortsig,a3),d0
  1768.     bne    .Abort
  1769.     PUTDEBUG    5,<'%s/Transmit: Received XON!'>
  1770.     bra    .CheckX
  1771.  
  1772. .DoIt:
  1773.     move.l    d2,d4
  1774.     Disable    ;quite neccessary!
  1775.     btst    #UNITB_NEEDCHAR,(UNIT_FLAGS,a3)
  1776.     beq.b    .NeedInt
  1777.     bclr    #UNITB_NEEDCHAR,(UNIT_FLAGS,a3)
  1778.     move.b    (a2)+,(TDR,a5)    ;If set, we can load up the transmit reg immediately
  1779.     subq.l    #1,d4
  1780.     beq    .DoneWriting    ;does an Enable
  1781.  
  1782. .NeedInt:
  1783.     move.l    a2,(WriteBufferPtr,a3)
  1784.     move.l    d4,(WriteCount,a3)    ;GO!!!
  1785.     Enable
  1786.  
  1787.     lea    (timeriorequest,a3),a1
  1788.     movea.l    (MN_REPLYPORT,a1),a0
  1789.     moveq    #0,d0
  1790.     move.b    (MP_SIGBIT,a0),d0
  1791.     moveq    #0,d3
  1792.     bset    d0,d3
  1793.  
  1794. .TopWaitBlock:
  1795.     moveq    #0,d5    ;clear danger flag
  1796. .WaitBlock:
  1797.     move.w    #TR_ADDREQUEST,(IO_COMMAND,a1)
  1798.     clr.l    (TV_SECS+IO_SIZE,a1)
  1799.     move.l    #100000,(TV_MICRO+IO_SIZE,a1)    ;100ms
  1800.     EXEC    SendIO
  1801.  
  1802.     move.l    d3,d0    ;timer signal
  1803.     add.l    (writeabortsig,a3),d0
  1804.     add.l    (tdresig,a3),d0
  1805.  
  1806. ;Wait for the block write to finish
  1807.     EXEC    Wait    ;Wait for write to finish
  1808.     move.l    d0,d1
  1809.     and.l    (tdresig,a3),d1
  1810.     beq.b    .NotTDRE
  1811.     EXEC    AbortIO    ;kill timer request
  1812.     EXEC    WaitIO
  1813.  
  1814. ;    PUTDEBUG    150,<'%s/Transmit: Write block finished.'>
  1815. .End:
  1816.     moveq    #0,d0    ;value
  1817.     move.l    d3,d1    ;mask
  1818.     EXEC    SetSignal    ;clear timer signal just in case
  1819.     pop    a1
  1820.     move.l    d2,(IO_ACTUAL,a1)
  1821.     movem.l    (sp)+,d0-d5/a0-a2
  1822.     rts
  1823. .NotTDRE:
  1824.     move.l    d0,d1
  1825.     and.l    (writeabortsig,a3),d1
  1826.     beq.b    .CheckOut
  1827.  
  1828. ;Abort signal
  1829.     EXEC    AbortIO    ;kill timer request
  1830.     EXEC    WaitIO
  1831.     bra    .Abort
  1832.  
  1833. .CheckOut:
  1834. ;If we end up here then a 100ms timeout has occured - so check a few
  1835. ;things...
  1836.     EXEC    WaitIO    ;remove the message from the replyport
  1837.     move.l    (WriteCount,a3),d0
  1838.     cmp.l    d4,d0    ;compare with previous WriteCount value
  1839.     beq.b    .Equal
  1840.     move.l    d0,d4
  1841.     bra    .TopWaitBlock
  1842. .Equal:
  1843.     btst    #CSRB_CTSL,(CSR,a5)
  1844.     bne    .TopWaitBlock    ;go if not asserted
  1845.     tst.l    d5
  1846.     bne.b    .Danger
  1847.     moveq    #1,d5    ;set danger flag
  1848.     bra    .WaitBlock
  1849. .Danger:
  1850.  
  1851. ;If we get here we know:
  1852. ;1. Nothing has been outputted (no TDRE) in the last 100-200+ ms, and
  1853. ;2. CTS is asserted (presumably at least 100ms -- we assume this)
  1854. ;So, we assume that we got unlucky and missed a TDRE, and force a byte out:
  1855.  
  1856.     Disable
  1857.     bclr    #UNITB_NEEDCHAR,(UNIT_FLAGS,a3)
  1858.     move.l    (WriteBufferPtr,a3),a0
  1859.     move.b    (a0)+,(TDR,a5)
  1860.     move.l    a0,(WriteBufferPtr,a3)
  1861.     subq.l    #1,(WriteCount,a3)
  1862.     beq.b    .DoneWriting
  1863.     Enable
  1864.     bra    .TopWaitBlock
  1865.  
  1866. .DoneWriting:
  1867.     Enable
  1868.     bra    .End
  1869. .NotConnected:
  1870.     move.b    #SerErr_LineErr,(IO_ERROR,a1)
  1871.     bra    .End
  1872. .Abort:
  1873.     sub.l    (WriteCount,a3),d2
  1874.     clr.l    (WriteCount,a3)
  1875.     bra    .End
  1876.  
  1877. ;******* end of write routine *******
  1878.  
  1879. Break:
  1880.     movem.l    d0-d2/a0/a1,-(sp)
  1881.     PUTDEBUG    5,<'%s/Break: called'>
  1882.     move.b    #2,(ACR,a5) ;start break
  1883.     bset    #UNITB_BREAKSENT,(UNIT_FLAGS,a3)
  1884.     lea    (timeriorequest,a3),a1
  1885.     move.w    #TR_ADDREQUEST,(IO_COMMAND,a1)
  1886.     clr.l    (TV_SECS+IO_SIZE,a1)
  1887.     move.l    (prefs_BRKTIME,a4),d0
  1888.     ori.b    #$FF,d0    ;To avoid the V33/V34 timer bug
  1889.  
  1890.     ifne    INFO_LEVEL    ;If any debugging enabled at all
  1891.     move.l    d0,-(sp)
  1892.     PUTDEBUG    5,<'%s/Break: TV_MICRO=%ld'>
  1893.     addq.l    #4,sp
  1894.     endc
  1895.  
  1896.     move.l    d0,(TV_MICRO+IO_SIZE,a1)
  1897.     movea.l    (MN_REPLYPORT,a1),a0
  1898.     moveq    #0,d2
  1899.     move.b    (MP_SIGBIT,a0),d2
  1900.     EXEC    SendIO
  1901.     moveq    #0,d0
  1902.     bset    d2,d0
  1903.     add.l    (writeabortsig,a3),d0
  1904.  
  1905.     PUTDEBUG    5,<'%s/Break: Waiting...'>
  1906.  
  1907.     EXEC    Wait
  1908.     and.l    (writeabortsig,a3),d0
  1909.     beq.b    .BreakOK
  1910.  
  1911.     PUTDEBUG    5,<'%s/Break: Aborted!'>
  1912.  
  1913.     EXEC    AbortIO    ;The break was aborted. Clean up.
  1914. .BreakOK:
  1915.     EXEC    WaitIO 
  1916.     moveq    #0,d0    ;value
  1917.     moveq    #0,d1
  1918.     bset    d2,d1    ;mask
  1919.     EXEC    SetSignal    ;clear timer signal bit just in case
  1920.     move.b    #0,(ACR,a5) ;stop the break
  1921.  
  1922.     PUTDEBUG    5,<'%s/Break: Finished!'>
  1923.     movem.l    (sp)+,d0-d2/a0/a1
  1924.     rts
  1925.  
  1926. ;AbortIO() is a REQUEST to "hurry up" processing of an IORequest.
  1927. ;If the IORequest was already complete, nothing happens (if an IORequest
  1928. ;is quick or LN_TYPE=NT_REPLYMSG, the IORequest is complete).
  1929. ;The message must be replied with ReplyMsg(), as normal.
  1930. ;
  1931. ;Note that AbortIO is called directly, not via BeginIO.
  1932. ;
  1933. ;If sucessful, AbortIO returns IOERR_ABORTED in IO_ERROR and zero in D0
  1934.  
  1935. AbortIO:
  1936.     PUTDEBUG    5,<'%s/AbortIO: called'>
  1937.     Forbid
  1938.     movem.l    d1/a0/a1/a3,-(sp)
  1939.     movea.l    (IO_UNIT,a1),a3
  1940.     move.b    #IOERR_ABORTED,(IO_ERROR,a1)    ;We always say we succeed(ed)
  1941.     cmpi.b    #NT_REPLYMSG,(LN_TYPE,a1)    ;Already complete?
  1942.     beq.b    .End
  1943.     btst    #IOB_QUICK,(IO_FLAGS,a1)
  1944.     bne.b    .End
  1945.  
  1946. ;Check to see whether or not the IORequest is being processed 
  1947.  
  1948.     cmpi.w    #CMD_READ,(IO_COMMAND,a1)
  1949.     bne.b    .NotRead
  1950.     cmp.l    (ReadRequestPtr,a3),a1
  1951.     bne.b    .NotActive
  1952.     move.l    (readabortsig,a3),d0
  1953.     lea    (mdu_rtcb,a3),a1
  1954. .Signal:    EXEC    Signal
  1955.     bra.b    .End
  1956. .NotRead:
  1957.     cmpi.w    #CMD_WRITE,(IO_COMMAND,a1)
  1958.     bne.b    .NotWrite
  1959. .Write:    cmp.l    (WriteRequestPtr,a3),a1
  1960.     bne.b    .NotActive
  1961.     move.l    (writeabortsig,a3),d0
  1962.     lea    (mdu_wtcb,a3),a1
  1963.     bra.b    .Signal
  1964. .NotWrite:
  1965.     cmpi.w    #SDCMD_BREAK,(IO_COMMAND,a1)
  1966.     beq.b    .Write
  1967.     bra.b    .End
  1968.  
  1969. .NotActive:
  1970. ;Set ignore bit in the IORequest
  1971.     bset    #ioflagsB_Ignore,(IO_FLAGS,a1)
  1972.  
  1973. .End:    Permit
  1974.     movem.l    (sp)+,d1/a0/a1/a3
  1975.     moveq    #0,d0    ;error code (always successful)
  1976.     PUTDEBUG    5,<'%s/AbortIO: Finished!'>
  1977.     rts
  1978.  
  1979. ;**************** End of AbortIO *****************
  1980.  
  1981. Invalid:
  1982.     move.b    #IOERR_NOCMD,(IO_ERROR,a1)
  1983.     rts
  1984.  
  1985. ;Clear invalidates all internal buffers.
  1986. ;
  1987. ; a1 -- a pointer to the io request block
  1988. ; a3 -- a pointer to the unit
  1989. ; a4 -- a pointer to prefs
  1990. ; a5 -- a pointer to the unit hardware
  1991. ; a6 -- a pointer to the device
  1992.  
  1993. MyClear:
  1994.     movem.l    d0/d1,-(sp)
  1995.     moveq    #0,d0
  1996.     moveq    #0,d1
  1997.     movem.l    d0/d1,(HeadLong,a3)
  1998.     movem.l    (sp)+,d0/d1
  1999.     rts
  2000.  
  2001. ; a1 -- a pointer to the io request block
  2002. ; a3 -- a pointer to the unit
  2003. ; a4 -- a pointer to prefs
  2004. ; a5 -- a pointer to the unit hardware
  2005. ; a6 -- a pointer to the device
  2006.  
  2007. MyReset:
  2008.     movem.l    d0/d7/a1,-(sp)
  2009.  
  2010.     PUTDEBUG    30,<'%s/MyReset: called'>
  2011.     Forbid
  2012.     move.b    (IERstate,a3),d7
  2013.     clr.b    (IERstate,a3)
  2014.     move.b    #$7f,(IER,a5)    ;Disable ACIA interrupts
  2015.     bsr    Flush    ;Flush pending requests
  2016.  
  2017. ;Abort current IO, if any IO is indeed occuring
  2018.  
  2019.     move.l    a1,-(sp)
  2020.  
  2021.     movea.l    (WriteRequestPtr,a3),a1
  2022.     move.l    a1,d0
  2023.     beq.b    .WriteNotActive
  2024.     bsr    AbortIO
  2025.  
  2026. .WriteNotActive:
  2027.     movea.l    (ReadRequestPtr,a3),a1
  2028.     move.l    a1,d0
  2029.     beq.b    .NothingActive
  2030.     bsr    AbortIO
  2031.  
  2032. .NothingActive:
  2033.     movea.l    (sp)+,a1 
  2034.     bsr    SetDefaultPrefs
  2035.     bsr    CopyPrefs  
  2036.     bsr    FreeResources
  2037.     bsr    SetUpUnit
  2038.  
  2039.     tst.l    d0    ;Check for a possible error condition
  2040.     bmi.b    .OutOfMem
  2041.     subq.l    #1,d0
  2042.     beq.b    .TimerError
  2043.     subq.l    #1,d0
  2044.     beq.b    .ParamError
  2045.  
  2046.     move.b    d7,(IERstate,a3)    ;Enable DACIA interrupts again
  2047.     bset    #7,d7
  2048.     move.b    d7,(IER,a5)
  2049.     Permit
  2050.     clr.l    (IO_ACTUAL,a1)
  2051.     PUTDEBUG    30,<'%s/MyReset: Finished!'>
  2052. .ResetEnd:
  2053.     movem.l    (sp)+,d0/d7/a1
  2054.     rts
  2055.  
  2056. .ParamError:
  2057.     move.b    #SerErr_InvParam,(IO_ERROR,a1)
  2058.     bra.b    .MyResetFailed
  2059.  
  2060. .TimerError:
  2061.     move.b    #SerErr_TimerErr,(IO_ERROR,a1)
  2062.     bra.b    .MyResetFailed
  2063.  
  2064. .OutOfMem:
  2065.     move.b    #SerErr_BufErr,(IO_ERROR,a1)
  2066. .MyResetFailed:
  2067.     Permit
  2068.     clr.l    (IO_ACTUAL,a1)
  2069.     PUTDEBUG    30,<'%s/MyReset: Error!'>
  2070.     bra.b    .ResetEnd
  2071.  
  2072. ; a1 -- a pointer to the io request block
  2073. ; a3 -- a pointer to the unit
  2074. ; a4 -- a pointer to prefs
  2075. ; a5 -- a pointer to the unit hardware
  2076. ; a6 -- a pointer to the device
  2077. ;
  2078. ;Return number of chars in buffer in IO_ACTUAL
  2079. ;Fill in IO_STATUS
  2080.  
  2081. Query:
  2082.     movem.l    d0-d1,-(sp)
  2083. ;    PUTDEBUG    30,<'%s/Query: called.'>
  2084.  
  2085.     bsr    GetBytesInReadBuf
  2086.     move.l    d0,(IO_ACTUAL,a1)
  2087.  
  2088.     ifne    INFO_LEVEL  ;If any debugging enabled at all
  2089.     move.l    d0,-(sp)
  2090. ;    PUTDEBUG    30,<'%s/Query: %ld bytes in buf.'>
  2091.     move.l    (sp)+,d0
  2092.     endc
  2093.  
  2094.     moveq    #0,d0 ;d0 will mirror IO_STATUS
  2095.     move.b    (CSR,a5),d1
  2096.     btst    #0,d1
  2097.     beq.b    Q1
  2098.     bset    #6,d0
  2099. Q1:    btst    #1,d0
  2100.     beq.b    Q2
  2101.     bset    #7,d0
  2102. Q2:    btst    #3,d1
  2103.     beq.b    Q3
  2104.     bset    #3,d0
  2105. Q3:    btst    #4,d1
  2106.     beq.b    Q4
  2107.     bset    #5,d0    ;carrier detect
  2108. Q4:    btst    #5,d1
  2109.     beq.b    Q5
  2110.     bset    #4,d0
  2111. Q5:    btst    #UNITB_BREAKSENT,(UNIT_FLAGS,a3)
  2112.     beq.b    NB
  2113.     bset    #9,d0
  2114. NB:    btst    #2,d1
  2115.     beq.b    NRB
  2116.     bset    #10,d0
  2117. NRB:    tst.b    (xstate,a3)
  2118.     bne.b    xIsOn
  2119.     bset    #11,d0
  2120. xIsOn:    move.w    d0,(IO_STATUS,a1)
  2121.     movem.l    (sp)+,d0-d1
  2122.     rts
  2123.  
  2124. ; a1 -- a pointer to the io request block
  2125. ; a3 -- a pointer to the unit
  2126. ; a4 -- a pointer to prefs
  2127. ; a5 -- a pointer to the unit hardware
  2128. ; a6 -- a pointer to the device
  2129.  
  2130. SetParams:
  2131.     movem.l    d0/a0/a2,-(sp)
  2132.     bclr    #SERB_XDISABLED,(prefs_SERFLAGS,a4)    ;enable
  2133.     btst    #SERB_XDISABLED,(IO_SERFLAGS,a1)
  2134.     beq.b    .NotDisabled
  2135.     bset    #SERB_XDISABLED,(prefs_SERFLAGS,a4)
  2136.     st    (xstate,a3)    ;set to X-ON state
  2137. .NotDisabled:
  2138.  
  2139. ;Now check to see whether the device is busy, i.e. any current or pending requests.
  2140.  
  2141.     Forbid
  2142.     tst.l    (ReadRequestPtr,a3)
  2143.     bne    .DevBusy
  2144.     tst.l    (WriteRequestPtr,a3)
  2145.     bne    .DevBusy
  2146.     lea    (MP_MSGLIST,a3),a0    ;Read port - anything there?
  2147.     movea.l    (a0),a2
  2148.     tst.l    (a2)
  2149.     bne.b    .DevBusy
  2150.     lea    (mdu_wport+MP_MSGLIST,a3),a0    ;Write port - anything there?
  2151.     movea.l    (a0),a2
  2152.     tst.l    (a2)
  2153.     bne.b    .DevBusy
  2154.  
  2155. ;Ok, the device is not busy. Set all params.
  2156.  
  2157.     bsr    SetPrefs    ;First copy the data
  2158.     move.l    #65536,(prefs_RBUFLEN,a4)
  2159.  
  2160. ;---> This section of code was supposed to increase compatibility, but
  2161. ;---> it actually decreases it!! The autodocs fail me again....
  2162. ;If boogie is set, it implies a few other things...(NOT!!!!)
  2163. ;    btst    #SERB_RAD_BOOGIE,(IO_SERFLAGS,a1) ;Check for RAD_BOOGIE
  2164. ;    beq.b    .SkipBoogie
  2165. ;    bclr    #SEXTB_MSPON,(prefs_EXTFLAGS+3,a4)
  2166. ;    bclr    #SERB_PARTY_ON,(prefs_SERFLAGS,a4)
  2167. ;    bset    #SERB_XDISABLED,(prefs_SERFLAGS,a4)
  2168. ;    move.b    #8,(prefs_READLEN,a4)
  2169. ;    move.b    #8,(prefs_WRITELEN,a4)
  2170. ;    bra.b    .SkipNext
  2171. ;.SkipBoogie:
  2172.  
  2173.  
  2174. ;The boogie flag is not set...but maybe it should be...
  2175. ;Note that this logic is depended on in the Read routine
  2176.     btst    #SERB_XDISABLED,(prefs_SERFLAGS,a4)
  2177.     beq.b    .nochance
  2178.     btst    #SERB_EOFMODE,(prefs_SERFLAGS,a4)
  2179.     bne.b    .nochance
  2180.     bset    #SERB_RAD_BOOGIE,(prefs_SERFLAGS,a4) ;Set RAD_BOOGIE !
  2181.  
  2182. .nochance:
  2183. .SkipNext:
  2184.     bsr    InitDACIA    ;Then set up the chip 
  2185.     tst.l    d0
  2186.     bne.b    .Invalid
  2187.  
  2188. .End:    Permit
  2189.     movem.l    (sp)+,d0/a0/a2
  2190.     rts
  2191.  
  2192. .Invalid:    move.b    #SerErr_InvParam,(IO_ERROR,a1)
  2193.     bra.b    .End
  2194.  
  2195. .DevBusy:    move.b    #SerErr_DevBusy,(IO_ERROR,a1)
  2196.     bra.b    .End
  2197.  
  2198. SetControlLines:
  2199.  
  2200.     comment |
  2201.  
  2202. This routine is an extension specified by ASDG for their Dual Serial
  2203. Board. It allows application control of RTS and DTR. It works like this:
  2204.  
  2205. IO_COMMAND = 16
  2206.  
  2207. IO_OFFSET = mask
  2208. IO_LENGTH = value
  2209. Bit 0 = RTS
  2210. Bit 1 = DTR
  2211. |
  2212.  
  2213.     movem.l    d0-d2,-(sp)
  2214.     Forbid
  2215.     move.b    (frstate,a3),d0
  2216.     move.l    (IO_LENGTH,a1),d1    ;state
  2217.     move.l    (IO_OFFSET,a1),d2    ;mask
  2218.     and.b    d2,d1
  2219.     not.b    d2
  2220.     and.b    d2,d0    ;clear
  2221.     or.b    d1,d0    ;set
  2222.     move.b    d0,(frstate,a3)
  2223.     move.b    d0,(FMR,a5)
  2224.     Permit
  2225.     movem.l    (sp)+,d0-d2
  2226.     rts
  2227.  
  2228. ;The Stop command stop all future io requests from being processed until a
  2229. ;Start command is received. The Stop command is NOT stackable: e.g. no matter
  2230. ;how many stops have been issued, it only takes one Start to restart
  2231. ;processing.
  2232.  
  2233. MyStop:
  2234.     PUTDEBUG    30,<'%s/MyStop: called'>
  2235.     bset    #MDUB_STOPPED,(MDU_FLAGS,a3)
  2236.     rts
  2237.  
  2238. Start:
  2239.  
  2240. ;[A3=unit A6=device]
  2241.  
  2242.     movem.l    d0-d1/a0-a2,-(sp)
  2243.     PUTDEBUG    30,<'%s/Start: called'>
  2244.     movea.l    a1,a2
  2245.  
  2246. ;Turn processing back on
  2247.     bclr    #MDUB_STOPPED,(MDU_FLAGS,a3)
  2248.  
  2249. ;Kick the tasks to start them moving
  2250.  
  2251.     move.b    (MP_SIGBIT,a3),d1    ;First the read task...
  2252.     moveq    #0,d0
  2253.     bset    d1,d0    ;Prepared signal mask
  2254.     movea.l    (MP_SIGTASK,a3),a1    ;FIXED: marco-task to signal
  2255.     move.l    a6,-(sp)
  2256.     movea.l    (md_SysLib,a6),a6
  2257.     SYS    Signal    ;FIXED: marco-a6 not a3
  2258.     movea.l    (sp)+,a6
  2259.  
  2260.     movea.l    a2,a1    ;Then the write task
  2261.     lea    (mdu_wport,a3),a0
  2262.     move.b    (MP_SIGBIT,a0),d1
  2263.     moveq    #0,d0
  2264.     bset    d1,d0    ;Prepared signal mask
  2265.     movea.l    (MP_SIGTASK,a0),a1    ;FIXED: marco-task to signal
  2266.     move.l    a6,-(sp)
  2267.     movea.l    (md_SysLib,a6),a6
  2268.     SYS    Signal    ;FIXED: marco-a6 not a3
  2269.     movea.l    (sp)+,a6
  2270.     PUTDEBUG    30,<'%s/Start: Finished!'>
  2271.     movem.l    (sp)+,d0-d1/a0-a2
  2272.     rts
  2273.  
  2274. ;Flush pulls all I/O requests off the queue and sends them back.  We must be
  2275. ;careful not to destroy work in progress, and also that we do not let some io
  2276. ;requests slip by.
  2277.  
  2278. Flush:
  2279.     movem.l    d0-d1/a0/a1/a6,-(sp)
  2280.     PUTDEBUG    30,<'%s/Flush: called'>
  2281.     movea.l    (md_SysLib,a6),a6
  2282.     SYS    Forbid
  2283. ReadFlush_Loop:
  2284.     movea.l    a3,a0
  2285.     SYS    GetMsg    ;Steal messages from task's port
  2286.     tst.l    d0
  2287.     beq.b    WriteFlush_Loop
  2288.  
  2289.     movea.l    d0,a1
  2290.     move.b    #IOERR_ABORTED,(IO_ERROR,a1)
  2291.     SYS    ReplyMsg
  2292.     bra.b    ReadFlush_Loop
  2293.  
  2294. WriteFlush_Loop:
  2295.     lea    (mdu_wport,a3),a0
  2296.     SYS    GetMsg    ;Steal messages from task's port
  2297.     tst.l    d0
  2298.     beq.b    Flush_End
  2299.  
  2300.     movea.l    d0,a1
  2301.     move.b    #IOERR_ABORTED,(IO_ERROR,a1)
  2302.     SYS    ReplyMsg
  2303.     bra.b    WriteFlush_Loop
  2304.  
  2305. Flush_End:
  2306.     SYS    Permit
  2307.     PUTDEBUG    30,<'%s/Flush: Finished!'>
  2308.     movem.l    (sp)+,d0-d1/a0/a1/a6
  2309.     rts
  2310.  
  2311. ;Here begins the task related routines
  2312. ;
  2313. ; Register Usage
  2314. ; ==============
  2315. ; a2 -- device pointer
  2316. ; a3 -- unit pointer
  2317. ; a4 -- prefs pointer
  2318. ; a5 -- hardware pointer
  2319. ; a6 -- syslib pointer
  2320. ;----------------------------------------------------------------------
  2321. ;
  2322. ;Note: Signals must be allocated within this (the task's) context!
  2323. ;The task is responsible for enabling the right DACIA interrupts...AFTER
  2324. ;it has done its setup (like allocating signals).
  2325. ;
  2326. ;NOTE: We actually have two tasks, each with their own separate
  2327. ;      code (but shared data). First comes the read task...:
  2328.  
  2329. ReadTask_Begin:
  2330.     PUTDEBUG    35,<'%s/ReadTask_Begin'>
  2331.     movea.l    (4).w,a6
  2332.  
  2333. ;Grab the arguments passed down from our parent
  2334.  
  2335.     movea.l    (4,sp),a3    ;Unit pointer
  2336.     move.l    (mdu_prefs,a3),a4
  2337.     movea.l    (daciabase,a3),a5
  2338.  
  2339.     lea    (readsig,a3),a2
  2340.     moveq    #1,d6    ;Number of signals to allocate-1
  2341. ReadSigLoop:
  2342.     moveq    #-1,d0    ;-1 is any signal at all
  2343.     SYS    AllocSignal    ;Allocate signals for I/O interrupts
  2344.     moveq    #0,d7    ;Convert bit number signal mask
  2345.     bset    d0,d7
  2346.     move.l    d7,(a2)+    ;Save in unit structure
  2347.     dbra    d6,ReadSigLoop
  2348.  
  2349.     movea.l    (mdu_Device,a3),a2    ;Point to device structure
  2350.  
  2351.     moveq    #-1,d0    ;-1 is any signal at all
  2352.     SYS    AllocSignal    ;Allocate a signal
  2353.     move.b    d0,(MP_SIGBIT,a3)
  2354.     move.b    #PA_SIGNAL,(MP_FLAGS,a3) ;Make message port "live"
  2355.  
  2356.     ifge    INFO_LEVEL-40
  2357.     move.l    ($114,a6),-(sp)
  2358.     move.l    (mdu_Device,a3),-(sp)
  2359.     move.l    a3,-(sp)
  2360.     move.l    d0,-(sp)
  2361.     PUTDEBUG    40,<'%s/ReadTask -- Signal=%ld, Unit=%lx Device=%lx Task=%lx'>
  2362.     adda.l    #4*4,sp
  2363.     endc
  2364.  
  2365. ;Enable read-related ACIA interrupts
  2366.  
  2367.     ori.b    #READINTMASK,(IERstate,a3)
  2368.     move.b    #READINT,(IER,a5)
  2369.     bra    ReadTask_NextMessage
  2370.  
  2371. ;OK, kids, we are done with initialization.  We now can start the main loop
  2372. ;of the driver.  It goes like this.  Because we had the port marked PA_IGNORE
  2373. ;for a while (in InitUnit) we jump to the getmsg code on entry.  (The first
  2374. ;message will probably be posted BEFORE our task gets a chance to run).
  2375. ;  wait for a message
  2376. ;  lock the device
  2377. ;  get a message.  If no message, unlock device and loop
  2378. ;  dispatch the message
  2379. ;  loop back to get a message
  2380.  
  2381. ;Main loop: wait for a new message
  2382.  
  2383. ReadTask_PermitMainLoop:
  2384.     Permit
  2385. ReadTask_MainLoop:
  2386.     PUTDEBUG    75,<'%s/ReadTask ++Sleep'>
  2387.     move.l    a3,a0
  2388.     SYS    WaitPort
  2389.     ifge    INFO_LEVEL-5
  2390.     bchg.b    #1,($bfe001).l  ;Blink the power LED
  2391.     endc
  2392.  
  2393.     PUTDEBUG    75,<'%s/ReadTask ++Wakeup'>
  2394.  
  2395.     btst    #MDUB_STOPPED,(MDU_FLAGS,a3)    ;See if we are stopped
  2396.     bne.b    ReadTask_MainLoop    ;Device is stopped, ignore messages
  2397.  
  2398. ReadTask_NextMessage:
  2399.     movea.l    a3,a0
  2400.     Forbid
  2401.     SYS    GetMsg    ;Get the next request
  2402.     PUTDEBUG    1,<'%s/ReadTask GotMsg'>
  2403.     tst.l    d0
  2404.     beq    ReadTask_PermitMainLoop    ;no message?
  2405.  
  2406.     movea.l    d0,a1    ;Do this request
  2407.     exg    a2,a6    ;Put device ptr in right place
  2408.  
  2409.     btst    #ioflagsB_Ignore,(IO_FLAGS,a1)
  2410.     bne.b    Readignorecmd
  2411.     move.l    a1,(ReadRequestPtr,a3)
  2412.     Permit
  2413.     bsr    Read    ;Do it!
  2414.     clr.l    (ReadRequestPtr,a3)
  2415.     EXEC    ReplyMsg
  2416.  
  2417. ;No longer active - abort has stopped sending signals. Now we can
  2418. ;(and should) clear the abort signal.
  2419.  
  2420.     moveq    #0,d0
  2421.     move.l    (readabortsig,a3),d1
  2422.     EXEC    SetSignal
  2423.     bra.b    Readconttl
  2424.  
  2425. Readignorecmd:
  2426.     Permit
  2427.     clr.l    (IO_ACTUAL,a1)
  2428.     EXEC    ReplyMsg
  2429. Readconttl:
  2430.     exg    a2,a6    ;Get ExecBase back in a6
  2431.     bra    ReadTask_NextMessage
  2432.  
  2433. ;**** End of read task code ****
  2434.  
  2435. ;**** Beginning of write task code ****
  2436.  
  2437. ; Register Usage
  2438. ; ==============
  2439. ; a2 -- device pointer
  2440. ; a3 -- unit pointer
  2441. ; a4 -- prefs pointer
  2442. ; a5 -- hardware pointer
  2443. ; a6 -- syslib pointer
  2444.  
  2445. WriteTask_Begin:
  2446.     PUTDEBUG    35,<'%s/WriteTask_Begin'>
  2447.     movea.l    (SysBase).w,a6
  2448.  
  2449. ;Grab the arguments passed down from our parent
  2450.  
  2451.     movea.l    (4,sp),a3    ;Unit pointer
  2452.     move.l    (mdu_prefs,a3),a4
  2453.     movea.l    (daciabase,a3),a5
  2454.  
  2455.     lea    (tdresig,a3),a2
  2456.     moveq    #2,d6    ;Number of signals to allocate-1
  2457. WriteSigLoop:
  2458.     moveq    #-1,d0    ;-1 is any signal at all
  2459.     SYS    AllocSignal    ;Allocate signals for I/O interrupts
  2460.     moveq    #0,d7    ;Convert bit number signal mask
  2461.     bset    d0,d7
  2462.     move.l    d7,(a2)+    ;Save in unit structure
  2463.     dbra    d6,WriteSigLoop
  2464.  
  2465. ;Allocate a signal for the timer message port
  2466.  
  2467.     moveq    #-1,d0    ;-1 is any signal at all
  2468.     SYS    AllocSignal
  2469.     lea    (timerport,a3),a2
  2470.     move.b    d0,(MP_SIGBIT,a2)
  2471.     move.l    a2,(timeriorequest+MN_REPLYPORT,a3)
  2472.     suba.l    a1,a1
  2473.     SYS    FindTask
  2474.     move.l    d0,(MP_SIGTASK,a2)    
  2475.     move.b    #PA_SIGNAL,(MP_FLAGS,a2) ;Make message port "live"
  2476.  
  2477.     movea.l    (mdu_Device,a3),a2    ;Point to device structure
  2478.  
  2479. ;Allocate a signal for the cmd message port
  2480.  
  2481.     moveq    #-1,d0    ;-1 is any signal at all
  2482.     SYS    AllocSignal
  2483.     move.b    d0,(mdu_wport+MP_SIGBIT,a3)
  2484.     move.b    #PA_SIGNAL,(mdu_wport+MP_FLAGS,a3) ;Make message port "live"
  2485.  
  2486.     ifge    INFO_LEVEL-40
  2487.     move.l    (ThisTask,a6),-(sp)
  2488.     move.l    a5,-(sp)
  2489.     move.l    a3,-(sp)
  2490.     move.l    d0,-(sp)
  2491.     PUTDEBUG    40,<'%s/WriteTask -- Signal=%ld, Unit=%lx Device=%lx Task=%lx'>
  2492.     adda.l    #4*4,sp
  2493.     endc
  2494.  
  2495. ;Enable write-related ACIA interrupts
  2496.  
  2497.     ori.b    #WRITEINTMASK,(IERstate,a3)
  2498.     move.b    #WRITEINT,(IER,a5)
  2499.     bra    WriteTask_NextMessage
  2500.  
  2501. ;Main loop: wait for a new message
  2502.  
  2503. WriteTask_PermitMainLoop:
  2504.     Permit
  2505. WriteTask_MainLoop:
  2506.     PUTDEBUG    75,<'%s/WriteTask ++Sleep'>
  2507.  
  2508.     lea    (mdu_wport,a3),a0
  2509.     SYS    WaitPort
  2510.  
  2511.     ifge    INFO_LEVEL-5
  2512.     bchg.b    #1,($bfe001).l  ;Blink the power LED
  2513.     endc
  2514.     PUTDEBUG    75,<'%s/WriteTask ++Wakeup'>
  2515.  
  2516.     btst    #MDUB_STOPPED,(MDU_FLAGS,a3)    ;See if we are stopped
  2517.     bne    ReadTask_MainLoop    ;Device is stopped, ignore messages
  2518.  
  2519. WriteTask_NextMessage:
  2520.     lea    (mdu_wport,a3),a0
  2521.     Forbid
  2522.     SYS    GetMsg    ;Get the next request
  2523.     PUTDEBUG    1,<'%s/WriteTask GotMsg'>
  2524.     tst.l    d0
  2525.     beq    WriteTask_PermitMainLoop    ;No message?
  2526.  
  2527.     movea.l    d0,a1    ;Do this request
  2528.     exg    a2,a6    ;Put device ptr in right place
  2529.  
  2530.     btst    #ioflagsB_Ignore,(IO_FLAGS,a1)
  2531.     bne.b    Writeignorecmd
  2532.     move.l    a1,(WriteRequestPtr,a3)
  2533.     Permit
  2534.     cmp.w    #CMD_WRITE,(IO_COMMAND,a1)
  2535.     bne.b    .NotWrite
  2536.     bsr    Write
  2537.     bra.b    .Continue
  2538. .NotWrite:
  2539.     bsr    Break
  2540. .Continue:
  2541.     clr.l    (WriteRequestPtr,a3)
  2542.     EXEC    ReplyMsg
  2543.  
  2544. ;No longer active - abort has stopped sending signals. Now we can
  2545. ;(and should) clear the abort signal.
  2546.  
  2547.     moveq    #0,d0
  2548.     move.l    (writeabortsig,a3),d1
  2549.     EXEC    SetSignal
  2550.     bra.b    Writeconttl
  2551.  
  2552. Writeignorecmd:
  2553.     Permit
  2554.     clr.l    (IO_ACTUAL,a1)
  2555.     EXEC    ReplyMsg
  2556. Writeconttl:
  2557.     exg    a2,a6    ; get syslib back in a6
  2558.     bra    WriteTask_NextMessage
  2559.  
  2560. ;********** end of write task code ***********
  2561.  
  2562. ;Initialize the device
  2563.  
  2564. mdu_Init:
  2565. ;Initialize read task message port/tcb
  2566.     INITBYTE    MP_FLAGS,PA_IGNORE    ;Unit starts with read message port
  2567.     INITBYTE    LN_TYPE,NT_MSGPORT
  2568.     INITLONG    LN_NAME,myName
  2569.     INITLONG    mdu_rtcb+LN_NAME,myName
  2570.     INITBYTE    mdu_rtcb+LN_TYPE,NT_TASK
  2571.     INITBYTE    mdu_rtcb+LN_PRI,127
  2572.  
  2573. ;Initialize write task message port/tcb
  2574.  
  2575.     INITBYTE    mdu_wport+MP_FLAGS,PA_IGNORE    ;Write message port
  2576.     INITBYTE    mdu_wport+LN_TYPE,NT_MSGPORT
  2577.     INITLONG    mdu_wport+LN_NAME,myName
  2578.     INITLONG    mdu_wtcb+LN_NAME,myName
  2579.     INITBYTE    mdu_wtcb+LN_TYPE,NT_TASK
  2580.     INITBYTE    mdu_wtcb+LN_PRI,126
  2581.  
  2582. ;Initialize timer message port
  2583.  
  2584.     INITBYTE    timerport+MP_FLAGS,PA_IGNORE    ;Timer message port
  2585.     INITBYTE    timerport+LN_TYPE,NT_MSGPORT
  2586.     INITLONG    timerport+LN_NAME,myName
  2587.  
  2588.     dc.w    0
  2589.  
  2590. ;******************** Interrupt code *********************************
  2591.  
  2592. ;Notes:
  2593.  
  2594. ;In this version of the driver we use a single interrupt routine for all
  2595. ;units, and that routine bypasses the usual Exec conventions. Normally
  2596. ;this would be bad, but the need for speed certainly warrents it in this
  2597. ;case.
  2598.  
  2599. ;This is the interrupt routine. It serves three purposes:
  2600. ;1. Read in a byte if available, store it, and signal the read task
  2601. ;2. Check for TDRE-empty condition and signal write task
  2602. ;3. Check for an exceptional condition and signal read task
  2603.  
  2604. ;uses d0,d7,a0,a3,a5
  2605.  
  2606. DoInt    macro
  2607.     movem.l    d0/d7/a0/a3/a5,-(sp)
  2608.  
  2609.     ifge    \1-1
  2610.     move.l    (Unit3,pc),a3
  2611.     move.l    (daciabase,a3),a5
  2612.     move.b    (ISR,a5),d7
  2613.     and.b    (IERstate,a3),d7    ;Quick check (note that this masking is very
  2614.                 ;important)
  2615.     bne    FastInt    ;Service it
  2616.     endc
  2617.  
  2618.     ifge    \2-1
  2619.     move.l    (_Unit2,pc),a3
  2620.     move.l    (daciabase,a3),a5
  2621.     move.b    (ISR,a5),d7
  2622.     and.b    (IERstate,a3),d7    ;Quick check (note that this masking is very
  2623.                 ;important)
  2624.     bne    FastInt    ;Service it
  2625.     endc
  2626.  
  2627.     ifge    \3-1
  2628.     move.l    (Unit1,pc),a3
  2629.     move.l    (daciabase,a3),a5
  2630.     move.b    (ISR,a5),d7
  2631.     and.b    (IERstate,a3),d7    ;Quick check (note that this masking is very
  2632.                 ;important)
  2633.     bne    FastInt    ;Service it
  2634.     endc
  2635.  
  2636.     ifge    \4-1
  2637.     move.l    (Unit0,pc),a3
  2638.     move.l    (daciabase,a3),a5
  2639.     move.b    (ISR,a5),d7
  2640.     and.b    (IERstate,a3),d7    ;Quick check (note that this masking is very
  2641.                 ;important)
  2642.     bne    FastInt    ;Service it
  2643.     endc
  2644.  
  2645.     movem.l    (sp)+,d0/d7/a0/a3/a5
  2646.     move.l    (OldVec,pc),-(sp)
  2647.     rts
  2648.  
  2649.     endm
  2650.  
  2651. IntRoutines:
  2652.     dc.l    Int0000    ;dummy entry for 0
  2653.     dc.l    Int0001
  2654.     dc.l    Int0010
  2655.     dc.l    Int0011
  2656.     dc.l    Int0100
  2657.     dc.l    Int0101
  2658.     dc.l    Int0110
  2659.     dc.l    Int0111
  2660.     dc.l    Int1000
  2661.     dc.l    Int1001
  2662.     dc.l    Int1010
  2663.     dc.l    Int1011
  2664.     dc.l    Int1100
  2665.     dc.l    Int1101
  2666.     dc.l    Int1110
  2667.     dc.l    Int1111
  2668.  
  2669. ;************* Start of fast interrupt routine **************
  2670.  
  2671. FastInt:
  2672.  
  2673. ;****** NOTE/WARNING:  Reading the ISR will cause the interrupt line
  2674. ;****** to be deasserted, although the bits in the ISR (except for read
  2675. ;****** error bits) will stay set ---- therefore simultaneous
  2676. ;****** conditions MUST!!!! be checked for!!!!!! There is no
  2677. ;****** second chance!
  2678.  
  2679.  
  2680. ;Read error condition?
  2681. ;(Note: Reading the RDR clears the error flags.)
  2682.     move.b    d7,d0
  2683.     and.b    #6,d0
  2684.     bne.b    ReadErr    ;read errors?
  2685.  
  2686.     btst    #ISRB_RDRF,d7    ;Test Receive Data Buffer Full
  2687.     beq.b    DoTDRE
  2688.  
  2689. DoRDRF:
  2690. ;    PUTDEBUG    75,<'%s/Int: Read.'>
  2691.  
  2692. ;Store the byte in the circular buffer.  Note that this code *can't* be
  2693. ;interrupted, so we're safe (that's because CIA B, which we're plugging into,
  2694. ;is connected to INT6*).
  2695.  
  2696.     move.l    (TailLong,a3),d0    ;Read and store
  2697.     move.l    (StartBuf,a3),a0
  2698.     move.b    (RDR,a5),(a0,d0.l)
  2699.     addq.w    #1,(Tail,a3)
  2700.  
  2701. ;Currently waiting for a character?
  2702.     btst    #MDUB_WaitingForChar,(MDU_FLAGS,a3)
  2703.     bne.b    SignalRead    ;yes, signal read task
  2704.     bset    #MDUB_CharAvailable,(MDU_FLAGS,a3)
  2705.  
  2706.     btst    #ISRB_TDRE,d7
  2707.     bne.b    DoTDRE
  2708.  
  2709. ;Return from int routine
  2710.     movem.l    (sp)+,d0/d7/a0/a3/a5
  2711.     move.w    #$2000,(_custom+intreq)
  2712.     rte
  2713.  
  2714. DoTDRE:
  2715. ;Continue with int routine...
  2716.  
  2717. ;We can deduce that the interrupt was caused by TDRE
  2718. ;Therefore we have something to write...
  2719.  
  2720.     tst.l    (WriteCount,a3)
  2721.     beq.b    SetNeedChar
  2722.  
  2723.     bclr    #UNITB_NEEDCHAR,(UNIT_FLAGS,a3)
  2724.     move.l    (WriteBufferPtr,a3),a0
  2725.     move.b    (a0)+,(TDR,a5)
  2726.     move.l    a0,(WriteBufferPtr,a3)
  2727.     subq.l    #1,(WriteCount,a3)
  2728.     beq.b    DoneWriting
  2729. EndInt:    movem.l    (sp)+,d0/d7/a0/a3/a5
  2730.     move.w    #$2000,(_custom+intreq)
  2731.     rte
  2732.  
  2733. SetNeedChar:
  2734.     bset    #UNITB_NEEDCHAR,(UNIT_FLAGS,a3)
  2735.     bra.b    EndInt
  2736.  
  2737. ReadErr:
  2738.     bra.b    RealReadErr
  2739.  
  2740. SignalRead:
  2741.     bclr    #MDUB_WaitingForChar,(MDU_FLAGS,a3)
  2742.     bset    #MDUB_CharAvailable,(MDU_FLAGS,a3)
  2743.     movem.l    d1/a1/a6,-(sp)
  2744.     movea.l    (mdu_SysLib,a3),a6
  2745.     move.l    (readsig,a3),d0
  2746.     lea    (mdu_rtcb,a3),a1
  2747.     SYS    Signal    ;Signal the read task
  2748.     movem.l    (sp)+,d1/a1/a6
  2749.  
  2750.     btst    #ISRB_TDRE,d7
  2751.     bne    DoTDRE
  2752.  
  2753.     movem.l    (sp)+,d0/d7/a0/a3/a5
  2754.     move.l    (OldVec,pc),-(sp)
  2755.     rts
  2756.  
  2757. DoneWriting:
  2758.  
  2759. ;    PUTDEBUG    75,<'%s/Int: Write signal.'>
  2760.  
  2761.     movem.l    d1/a1/a6,-(sp)
  2762.     move.l    (tdresig,a3),d0
  2763.     lea    (mdu_wtcb,a3),a1
  2764.     movea.l    (mdu_SysLib,a3),a6
  2765.     SYS    Signal    ;Signal the write task
  2766.     movem.l    (sp)+,d1/a1/a6
  2767.     movem.l    (sp)+,d0/d7/a0/a3/a5
  2768.     move.l    (OldVec,pc),-(sp)
  2769.     rts
  2770.  
  2771. ;Exceptional conditions handled here....
  2772.  
  2773. RealReadErr:
  2774.  
  2775. ;An exceptional condition occured - signal the read task
  2776.     movem.l    d1/a1/a6,-(sp)
  2777.     move.b    d7,(ISRcopy,a3)    ;Useful info
  2778.     move.b    (CSR,a5),(CSRcopy,a3) ;More useful info
  2779.     move.l    (readabortsig,a3),d0
  2780.     lea    (mdu_rtcb,a3),a1
  2781.     movea.l    (mdu_SysLib,a3),a6
  2782.     SYS    Signal
  2783.     move.b    (RDR,a5),d0    ;This forces a clear of the error bits
  2784.     movem.l    (sp)+,d1/a1/a6
  2785.  
  2786.     btst    #ISRB_RDRF,d7    ;Test Receive Data Buffer Full
  2787.     bne    DoRDRF
  2788.     btst    #ISRB_TDRE,d7
  2789.     bne    DoTDRE
  2790.  
  2791.     movem.l    (sp)+,d0/d7/a0/a3/a5
  2792.     move.l    (OldVec,pc),-(sp)
  2793.     rts
  2794.  
  2795. ;********* End of fast interrupt routine *********
  2796.  
  2797. Int0000:    DoInt    0,0,0,0
  2798. Int0001:    DoInt    0,0,0,1
  2799. Int0010:    DoInt    0,0,1,0
  2800. Int0011:    DoInt    0,0,1,1
  2801. Int0100:    DoInt    0,1,0,0
  2802. Int0101:    DoInt    0,1,0,1
  2803. Int0110:    DoInt    0,1,1,0
  2804. Int0111:    DoInt    0,1,1,1
  2805. Int1000:    DoInt    1,0,0,0
  2806. Int1001:    DoInt    1,0,0,1
  2807. Int1010:    DoInt    1,0,1,0
  2808. Int1011:    DoInt    1,0,1,1
  2809. Int1100:    DoInt    1,1,0,0
  2810. Int1101:    DoInt    1,1,0,1
  2811. Int1110:    DoInt    1,1,1,0
  2812. Int1111:    DoInt    1,1,1,1
  2813.  
  2814.  
  2815.     ifne    INFO_LEVEL    ;If any debugging enabled at all
  2816.  
  2817. KPutFmt:    move.l    a2,-(sp)
  2818.     lea    (KPutChar,pc),a2
  2819.     bsr.b    KDoFmt
  2820.     movea.l    (sp)+,a2
  2821.     rts
  2822.  
  2823. KDoFmt:    move.l    a6,-(sp)
  2824.     movea.l    (SysBase).w,a6
  2825.     SYS    RawDoFmt
  2826.     movea.l    (sp)+,a6
  2827.     rts
  2828.  
  2829. KPutChar:    move.l    a6,-(sp)
  2830.     movea.l    (SysBase).w,a6
  2831.     SYS    RawPutChar
  2832.     movea.l    (sp)+,a6
  2833.     rts
  2834.  
  2835.     endc
  2836.  
  2837. EndCode:
  2838.     end
  2839.