home *** CD-ROM | disk | FTP | other *** search
/ Club Amiga de Montreal - CAM / CAM_CD_1.iso / files / 550b.lha / newser_v2.10 / iopatch.asm < prev    next >
Assembly Source File  |  1991-09-08  |  23KB  |  975 lines
  1. *****************************************************************************
  2. * Program:  IOpatch.asm - ©1990,91 by Dan Babcock
  3. * Function: This program patches the exec OpenDevice call, and allows the
  4. *           user to select a serial or parallel unit.
  5. *
  6. * Author:   Dan Babcock
  7. * History:  02/07/90 DB V0.50 Created
  8. *           09/22/90 DB V0.51 Added code to prevent redundant requesters
  9. *                             in certain cases.
  10. *           12/10/90 JL V0.52 Added code to parse the command line, and
  11. *                             allow various arguments (outlined below).
  12. *           01/12/91 DB V1.10 Misc. enhancements
  13. *           06/19/91 DB V1.20 Added CacheClearU call, changed gadget text
  14. *****************************************************************************
  15. * Program:  SelectWindow - ©1990 by The Puzzle Factory
  16. * Function: Get the users preference for which unit to open.
  17. *
  18. * Author:   Jeff Lavin
  19. * History:  01/29/90 JL V0.50 Created
  20. *           02/07/90 DB V0.51 Modified to include an "Internal" gadget.
  21. *           08/22/90 JL V0.52 Added borders to the gadgets.
  22. *                             Converted to Macro68 & new syntax.
  23. *           09/12/90 JL V0.53 Dynamically size everything now.
  24. *           09/26/90 JL V0.54 Fixed lores display problem.
  25. *           11/16/90 JL V0.55 Rearrainged gadgets; Gadget 0 is now full width.
  26. *
  27. * [To all: Please don't forget to bump the revision numbers if you do *any*
  28. *          modifications at all.  -Jeff]
  29. *****************************************************************************
  30.  
  31.  
  32. *****************************************************************************
  33. * NAME
  34. *     IOpatch - This program patches the exec OpenDevice call. The user
  35. *     puts this program in his startup-sequence or whereever before he runs
  36. *     his terminal progs, BBS's and whatnot - if these do not permit the
  37. *     user to change the device/unit info. If they do, this utility is not
  38. *     needed, obviously.
  39. *
  40. * INPUTS
  41. *
  42. *     1> IOpatch       ;Check OpenDevice() calls for serial & parallel device
  43. *     1> IOpatch -a    ;Check OpenDevice() calls for serial & parallel device
  44. *     1> IOpatch -s    ;Check OpenDevice() calls for serial device only
  45. *     1> IOpatch -p    ;Check OpenDevice() calls for parallel device only
  46. *     1> IOpatch -q    ;Replaces previous vector for OpenDevice() calls.
  47. *     1> IOpatch ?     ;Prints these instructions
  48. *
  49. * RESULTS
  50. *     OpenDevice() will use the either:
  51. *
  52. *          the serial.device or the newser.device
  53. *          the parallel.device or the eightbit.device
  54. *
  55. *     with the proper unit number depending on which device was to have been
  56. *     opened, and what the user selected from the requester.
  57. *
  58. * NOTES
  59. *     There is one complication: I noticed during testing that most term
  60. *     programs open and close the serial.device several times during their
  61. *     startup routines. This is rather stupid of them, of course, and it
  62. *     unfortunately results in many redundant requesters.
  63. *     This version tries its best to avoid this problem by keeping track of
  64. *     tasks that have opened the serial/parallel device and re-using
  65. *     previously specified (by the user via the requester) unit number.
  66. * 
  67. *     One last note: this program copies itself into dynamically allocated
  68. *     memory, so the user does not have to "run" it.
  69. *     It does a CacheClearU if running under 2.0.
  70. ******************************* tear here ***********************************
  71.  
  72. ;Set Tabs           |       |                 |       |
  73.  
  74.     ifnd    __m68
  75.     fail    'Wrong assembler!'
  76.     endc
  77.     exeobj
  78.     macfile    'IOexp.i'    ;The One & Only include file
  79.     objfile    'IOpatch'
  80.  
  81. TASKTABLESIZE    equ    32
  82.  
  83. Dispatcher    moveq    #-1,d2    ;serflag default
  84.     moveq    #-1,d3    ;parflag default
  85.     moveq    #0,d6    ;quit flag default
  86.     moveq    #0,d5    ;Clear WBenchMsg
  87.  
  88.     movea.l    (SysBase).w,a6
  89.     movea.l    (ThisTask,a6),a2
  90.     tst.l    (pr_CLI,a2)    ;Are we a child of WBench?
  91.     bne.b    FromCLI    ;Branch if no
  92.  
  93.     lea    (pr_MsgPort,a2),a0
  94.     SYS    WaitPort
  95.     lea    (pr_MsgPort,a2),a0
  96.     SYS    GetMsg
  97.     move.l    d0,d5    ;WBenchMsg
  98.     bra.w    SetPatch    ;No args from WBench
  99.  
  100. FromCLI    lea    (a0,d0.w),a1
  101. ..    cmpi.b    #' ',-(a1)    ;Eat trailing garbage
  102.     dbhi    d0,..
  103.     blt.b    SetPatch    ;If no arguments, don't parse
  104.     clr.b    (1,a1)    ;Null terminate the string
  105.  
  106. Parse    moveq    #0,d0
  107.     move.b    (a0)+,d0
  108.     beq.b    SetPatch    ;Null ends
  109.     cmpi.b    #' ',d0    ;Skip spaces
  110.     beq.b    Parse
  111.     cmpi.b    #'?',d0    ;Instruct?
  112.     beq.b    4$    ;"Usage:..."
  113.     cmpi.b    #'-',d0    ;Look for "-" char
  114.     bne.b    Parse    ;Skip til we find one
  115.     move.b    (a0)+,d0    ;Get next char
  116.     beq.b    SetPatch    ;Null ends
  117.     cmpi.b    #'a',d0    ;Convert to U/C
  118.     blo.s    1$
  119.     cmpi.b    #'z',d0
  120.     bhi.s    1$
  121.     subi.b    #$20,d0
  122.  
  123. 1$    cmpi.b    #'A',d0    ;[A]ll
  124.     bne.b    2$
  125.     seq    d2    ;serflag
  126.     seq    d3    ;parflag
  127.     bra.b    SetPatch
  128.  
  129. 2$    cmpi.b    #'S',d0    ;[S]erial only
  130.     bne.b    3$
  131.     seq    d2    ;serflag
  132.     sne    d3    ;parflag
  133.     bra.b    SetPatch
  134.  
  135. 3$    cmpi.b    #'P',d0    ;[P]arallel only
  136.     bne.b    4$
  137.     sne    d2    ;serflag
  138.     seq    d3    ;parflag
  139.     bra.b    SetPatch
  140.  
  141. 4$    cmpi.b    #'Q',d0    ;[Q]uit
  142.     bne.w    Instruct
  143.     seq    d6    ;quit flag
  144.  
  145. ;Note that multitasking is disabled (via Forbid) throughout the install
  146. ;code for 100% safety.
  147. ;First, check to see whether this program has been run before.
  148.  
  149. SetPatch    lea    (serflag,pc),a0
  150.     move.b    d2,(a0)
  151.     lea    (parflag,pc),a0
  152.     move.b    d3,(a0)
  153.  
  154.     movea.l    (SysBase).w,a6
  155.     SYS    Forbid
  156.  
  157.     lea    (portname,pc),a1
  158.     SYS    FindPort
  159.     move.l    d0,d2
  160.     tst.l    d2
  161.     bne.b    installed    ;Go if already installed
  162.  
  163. ;Not installed, so allocate memory and copy
  164.  
  165.     move.l    #enddispatchcode-startdispatchcode,d7
  166.     move.l    d7,d0
  167.     moveq    #0,d1    ;No special attributes
  168.     SYS    AllocMem
  169.     tst.l    d0
  170.     bne.b    allocok
  171.  
  172. panic    tst.l    d5    ;WBenchMsg
  173.     beq.b    1$
  174.     movea.l    d5,a1    ;We're already forbidden
  175.     SYS    ReplyMsg    ;Return msg
  176.     bra.b    2$
  177.  
  178. 1$    SYS    Permit
  179. 2$    moveq    #-1,d0
  180.     rts
  181.  
  182. allocok    movea.l    d0,a5
  183.     movea.l    d0,a1
  184.     lea    (startdispatchcode,pc),a0
  185.     move.l    d7,d0
  186.     SYS    CopyMem
  187.     cmpi.w    #37,(LIB_VERSION,a6)    ;version 2.0?
  188.     blo.b    .SkipCache
  189.     moveq    #-1,d0
  190.     SYS    CacheClearU
  191. .SkipCache:
  192.     lea    (panic,pc),a4
  193.     jmp    (a5)    ;Go to startdispatchcode
  194.  
  195. installed    tst.b    d6    ;Go if already installed
  196.     beq.b    quitdispatch    ;& quit flag set
  197.  
  198. ;Remove the patch (port addr in d2)
  199.  
  200.     movea.l    d2,a2
  201.     movea.l    (MP_SIZE,a2),a3    ;Get start addr of res code
  202.     lea    (newopendevice-startdispatchcode,a3),a4 ;Get addr of replacement
  203.     cmpa.l    (_LVOOpenDevice+2,a6),a4 ;Still there?
  204.     bne.b    panic    ;No, so can't deinstall
  205.     lea    (newremtask-startdispatchcode,a3),a4 ;Get addr of replacement
  206.     cmpa.l    (_LVORemTask+2,a6),a4 ;Still there?
  207.     bne.b    panic    ;No, so can't deinstall
  208.  
  209.     move.l    (oldopenvec-startdispatchcode,a3),d0
  210.     movea.w    #_LVOOpenDevice,a0
  211.     movea.l    a6,a1
  212.     SYS    SetFunction
  213.  
  214.     move.l    (oldremtask-startdispatchcode,a3),d0
  215.     movea.w    #_LVORemTask,a0
  216.     movea.l    a6,a1
  217.     SYS    SetFunction
  218.  
  219.     movea.l    a2,a1    ;Deallocate memory etc.
  220.     SYS    RemPort
  221.  
  222.     moveq    #MP_SIZE+4,d0
  223.     movea.l    a2,a1
  224.     SYS    FreeMem    ;Free message port
  225.  
  226.     move.l    #enddispatchcode-startdispatchcode,d0
  227.     movea.l    a3,a1
  228.     SYS    FreeMem    ;Free the code
  229.  
  230. quitdispatch    tst.l    d5    ;WBenchMsg
  231.     beq.b    1$
  232.     movea.l    d5,a1    ;We're already forbidden
  233.     SYS    ReplyMsg    ;Return msg
  234.     bra.b    2$
  235.  
  236. 1$    SYS    Permit
  237. 2$    moveq    #0,d0
  238.     rts
  239.  
  240. Instruct    tst.l    d5    ;WBenchMsg
  241.     beq.b    .OpenDos
  242.     addq.b    #1,(TDNestCnt,a6)    ;Forbid so WBench won't
  243.     movea.l    d5,a1    ; UnloadSeg() us
  244.     SYS    ReplyMsg    ;Return msg
  245.     bra.b    .Exit
  246.  
  247. .OpenDos    lea    (DosName,pc),a1
  248.     moveq    #0,d0
  249.     SYS    OpenLibrary    ;Open dos.library
  250.     tst.l    d0
  251.     beq.b    .Exit    ;Failed!
  252.  
  253.     move.l    a6,-(sp)
  254.     movea.l    d0,a6
  255.     SYS    Output    ;Get output filehandle
  256.     move.l    d0,d1    ;Filehandle
  257.     beq.b    .CloseDos
  258.     lea    (Help.msg,pc),a0
  259.     move.l    a0,d2    ;Buffer
  260.     move.l    #Help_Len,d3    ;Length
  261.     SYS    Write    ;Help the user
  262.  
  263. .CloseDos    movea.l    a6,a1
  264.     movea.l    (sp)+,a6
  265.     SYS    CloseLibrary    ;Close the dos.library
  266. .Exit    moveq    #0,d0
  267.     rts
  268.  
  269.  
  270. ;***** All the following code is copied into dynamically allocated mem
  271.  
  272. ;Add a port to indicate that we're installed
  273. ;Allocate memory for the port
  274.  
  275. startdispatchcode    moveq    #MP_SIZE+4,d0    ;MsgPort+4 bytes of private info
  276.     moveq    #1,d1
  277.     swap    d1    ;CLEAR parm
  278.     SYS    AllocMem
  279.     tst.l    d0
  280.     bne.b    somememleft
  281.  
  282.     move.l    d7,d0    ;Uh oh. The poor user is out of memory.
  283.     move.l    a4,-(sp)    ;Return addr
  284.     movea.l    a5,a1
  285.     jmp    (_LVOFreeMem,a6)    ;RTS takes us back to 'panic'
  286.  
  287. somememleft    movea.l    d0,a1
  288.     lea    (portname,pc),a0
  289.     move.l    a0,(LN_NAME,a1) 
  290.     move.l    a5,(MP_SIZE,a1)    ;Private info - addr of res code 
  291.     SYS    AddPort
  292.  
  293.     movea.w    #_LVOOpenDevice,a0 ;Patch into OpenDevice
  294.     movea.l    a6,a1
  295.     lea    (newopendevice,pc),a2
  296.     move.l    a2,d0
  297.     SYS    SetFunction
  298.  
  299.     lea    (oldopenvec,pc),a0
  300.     move.l    d0,(a0)
  301.  
  302.     movea.w    #_LVORemTask,a0 ;Patch into RemTask
  303.     movea.l    a6,a1
  304.     lea    (newremtask,pc),a2
  305.     move.l    a2,d0
  306.     SYS    SetFunction
  307.     lea    (oldremtask,pc),a0
  308.     move.l    d0,(a0)
  309.  
  310.     tst.l    d5    ;WBenchMsg
  311.     beq.b    1$
  312.     movea.l    d5,a1    ;We're already forbidden
  313.     SYS    ReplyMsg    ;Return msg
  314.     bra.b    2$
  315.  
  316. 1$    SYS    Permit 
  317. 2$    moveq    #0,d0
  318.     rts
  319.  
  320.  
  321. ;*** NOTE: A zero TCB (in A1) indicates self removal !!!!
  322. ;(this little fact nearly drove me nuts during debugging!)
  323.  
  324. newremtask:
  325.     move.l    a1,d0
  326.     bne.b    .L2
  327.     move.l    a1,-(sp)
  328.     SYS    FindTask
  329.     movea.l    (sp)+,a1
  330. .L2    move.l    a1,-(sp)
  331.     SYS    Forbid
  332.     movea.l    (sp)+,a1
  333.  
  334.     moveq    #TASKTABLESIZE-1,d1
  335.     lea    (sertasklist,pc),a0
  336. ..    cmp.l    (a0)+,d0
  337.     addq.l    #2,a0
  338.     dbeq    d1,..
  339.     bne.b    .L1
  340.     clr.l    (-6,a0)
  341. .L1
  342.  
  343.     moveq    #TASKTABLESIZE-1,d1
  344.     lea    (partasklist,pc),a0
  345. ..    cmp.l    (a0)+,d0
  346.     addq.l    #2,a0
  347.     dbeq    d1,..
  348.     bne.b    .L3
  349.     clr.l    (-6,a0)
  350. .L3
  351.  
  352.     move.l    a1,-(sp)
  353.     SYS    Permit
  354.     movea.l    (sp)+,a1
  355.     movea.l    (oldremtask,pc),a0
  356.     jmp    (a0)
  357.  
  358. newopendevice    movem.l d6-d7/a2-a5,-(sp)
  359.     suba.l    a5,a5    ;Sanity check
  360.     tst.l    d0    ;Check unit number
  361.     bne    oldopenjump    ;If nonzero, skip menu
  362.     lea    (serunitexists,pc),a4
  363.     lea    (serflag,pc),a2
  364.     tst.b    (a2)+    ;Want to check serial device?
  365.     beq.b    1$    ;Branch if no
  366.     movea.l    a0,a3
  367. ..    cmpm.b    (a2)+,(a3)+
  368.     bne.b    1$
  369.     tst.b    (-1,a2)
  370.     bne.b    ..
  371.     lea    (newserialname,pc),a5
  372.     moveq    #0,d5
  373.     bra.b    2$
  374.  
  375. 1$    lea    (parflag,pc),a2
  376.     tst.b    (a2)+    ;Want to check parallel device?
  377.     beq.b    2$    ;Branch if no
  378.     movea.l    a0,a3
  379. ..    cmpm.b    (a2)+,(a3)+
  380.     bne.w    nogood
  381.     tst.b    (-1,a2)
  382.     bne.b    ..
  383.     lea    (newparallelname,pc),a5
  384.     moveq    #1,d5
  385.     addq.w    #4,a4    ;Point to parunitexists
  386.  
  387. ;One last check: if this task has previously opened either the serial.device
  388. ;or the parallel.device, use the same unit number (stored in tasklist) rather
  389. ;than bothering the user.
  390.  
  391. 2$    cmpa.l    #0,a5    ;Sanity check
  392.     beq    nogood    ;User has disabled both flags!
  393.  
  394.     movem.l    d0/d1/a0/a1,-(sp)
  395.     move.l    (ThisTask,a6),d6
  396.     SYS    Forbid
  397.     moveq    #15,d7
  398.     lea    (sertasklist,pc),a2
  399.     tst.l    d5
  400.     beq.b    .skippar
  401.     lea    (partasklist,pc),a2
  402. .skippar:
  403. ..    cmp.l    (a2)+,d6    
  404.     addq.l    #2,a2
  405.     dbeq    d7,..
  406.     bne.b    popup
  407.     SYS    Permit
  408.     movem.l    (sp)+,d0/d1/a0/a1
  409.     moveq    #0,d0
  410.     move.w    (-2,a2),d0
  411.     bra.b    skipmenu
  412.  
  413. popup    SYS    Permit
  414.     movem.l    (sp)+,d0/d1/a0/a1
  415.  
  416. ;pop up a menu
  417.  
  418.     move.l    (a4),d0    ;serunitexists/parunitexists
  419.     movem.l    d1-d7/a0-a6,-(sp)
  420.     bsr    SelWin    ;Get input from the user
  421.     movem.l    (sp)+,d1-d7/a0-a6
  422.     tst.l    d0    ;Ok?
  423.     bpl.b    contdisp
  424.  
  425. ;The user is out of memory; signal an error
  426.  
  427.     moveq    #-1,d0 
  428.     move.b    d0,(IO_ERROR,a1)    ;Set error in the IO Request
  429.     bra.b    endnewopen
  430.  
  431. contdisp:
  432.  
  433. ;store the TCB ptr and the unit# in tasklist for future use
  434.  
  435. ;search for an empty slot
  436.     movem.l    d0/d1/a0/a1,-(sp)
  437.     SYS    Forbid
  438.     lea    (sertasklist,pc),a2
  439.     tst.l    d5
  440.     beq.b    .skippar
  441.     lea    (partasklist,pc),a2
  442. .skippar:
  443.     moveq    #TASKTABLESIZE-1,d7
  444. ..    tst.l    (a2)+
  445.     addq.w    #2,a2
  446.     dbeq    d7,..
  447.     bne.b    oldtask    ;Full! (not likely to happen)
  448.     SYS    Permit
  449.     movem.l    (sp)+,d0/d1/a0/a1
  450.     move.l    d6,(-6,a2)
  451.     move.w    d0,(-2,a2)    
  452.     bra.b    skipmenu
  453. oldtask:
  454.     SYS    Permit
  455.     movem.l    (sp)+,d0/d1/a0/a1
  456.  
  457. skipmenu:
  458.     tst.l    d0
  459.     beq.b    oldopenjump    ;If zero, use std device
  460.     subq.l    #1,d0
  461.  
  462. oldtask1    movea.l    a5,a0    ;newserialname/newparallelname
  463. nogood 
  464. oldopenjump    movea.l    (oldopenvec,pc),a3
  465.     jsr    (a3)
  466. endnewopen    movem.l    (sp)+,d6-d7/a2-a5
  467.     rts
  468.  
  469. oldopenvec    dl    0 
  470. oldremtask    dl    0
  471.  
  472. ;These variables might be set by code that checks for the presence
  473. ;of units 3 and 4.  Right now, they're hard-coded to say that they exist.
  474. ;No harm is done if you select a non-existant unit, so it doesn't matter
  475. ;much.
  476.  
  477. serunitexists    dl    1
  478. parunitexists    dl    1
  479.  
  480. ;Note: TASKTABLESIZE entries, arranged like so:
  481. ;Ptr to TCB (longword)
  482. ;Unit number (word)
  483.  
  484. sertasklist:
  485.     dcb.l    TASKTABLESIZE,0
  486.     dcb.w    TASKTABLESIZE,0
  487. partasklist:
  488.     dcb.l    TASKTABLESIZE,0
  489.     dcb.w    TASKTABLESIZE,0
  490.  
  491. portname    cstr    'IOExp dispatcher V1.20 ©1990,91 by Dan Babcock *INSTALLED*'
  492. serflag    db    $FF    ;Default = ON
  493. oldserialname    cstr    'serial.device'
  494. newserialname    MYDEVNAME
  495. parflag    db    $FF    ;Default = ON
  496. oldparallelname    cstr    'parallel.device'
  497. newparallelname    PARDEVNAME
  498. DosName    cstr    'dos.library'
  499.  
  500. Help.msg    db    'I/O Expansion Dispatcher V1.20 ©1990,91 by Dan Babcock',10
  501.     db    'Usage:',10,10
  502.     db    ' IOpatch     ;Check OpenDevice() calls for serial & parallel device',10
  503.     db    ' IOpatch -a  ;Check OpenDevice() calls for serial & parallel device',10
  504.     db    ' IOpatch -s  ;Check OpenDevice() calls for serial device only',10
  505.     db    ' IOpatch -p  ;Check OpenDevice() calls for parallel device only',10
  506.     db    ' IOpatch -q  ;Replaces previous vector for OpenDevice() calls.',10
  507.     db    ' IOpatch ?   ;Prints these instructions',10,0
  508. Help_Len    equ    *-Help.msg
  509.     quad
  510.  
  511. *****************************************************************************
  512. * NAME
  513. *     SelectWindow - Get the users preference for which unit to open.
  514. *
  515. * SYNOPSIS
  516. *     SelectWindow (UnitExits)
  517. *          D0          D0
  518. *
  519. *     LONG  UnitExists;
  520. *
  521. * INPUTS
  522. *     UnitExists - Non-zero if units 2 and 3 exist, else 0.
  523. *
  524. * RESULTS
  525. *     A value of 0 if the user didn't select a unit and simply hit the close
  526. *     gadget (unit number then defaults to 0).
  527. *
  528. * -> A value of zero is also returned if the user selects the "Internal"
  529. * -> gadget, indicating that he wants to use "serial.device" rather than
  530. * -> "newser.device", or "parallel.device" rather than "eightbit.device".
  531. *
  532. *     A value of 1-4 is returned if the user has selected a unit.
  533. *     A return value of -1 indicates that an error has occured.
  534. *
  535. * NOTES
  536. *     SelectWindow is both relocatable, and reentrant.
  537. *     SelectWindow is Copyright ©1990 by The Puzzle Factory
  538. *
  539. ******************************* tear here ***********************************
  540.  
  541. MyFeatures    equ    SMART_REFRESH!NOCAREREFRESH!ACTIVATE
  542. MyGadgets    equ    WINDOWDRAG!WINDOWDEPTH!WINDOWCLOSE
  543.  
  544. MyBase    clrso        ;BSS structure
  545. Gfx_Base    so.l    1
  546. Int_Base    so.l    1
  547. FontPtr    so.l    1
  548. ScreenPtr    so.l    1
  549. HiresFlag    so.b    1
  550. LaceFlag    so.b    1
  551. MyWindow    so.b    nw_SIZE
  552. Gadget0    so.b    gg_SIZEOF
  553. Gadget1    so.b    gg_SIZEOF
  554. Gadget2    so.b    gg_SIZEOF
  555. Gadget3    so.b    gg_SIZEOF
  556. Gadget4    so.b    gg_SIZEOF
  557.  
  558. Gad0.ITxt    so.b    it_SIZEOF
  559. Gad1.ITxt    so.b    it_SIZEOF
  560. Gad2.ITxt    so.b    it_SIZEOF
  561. Gad3.ITxt    so.b    it_SIZEOF
  562. Gad4.ITxt    so.b    it_SIZEOF
  563. MyBorder    so.b    bd_SIZEOF
  564. MyCoords    so.w    10
  565. Border0    so.b    bd_SIZEOF
  566. Coords0    so.w    10
  567. Text_Attr    so.b    ta_SIZEOF
  568. MB_Sizeof    soval
  569.  
  570. SelWin    move.l    d0,d3    ;UnitExists
  571.     moveq    #0,d7    ;Default = Nothing
  572.     move.l    #MEMF_PUBLIC!MEMF_CLEAR,d1
  573.     move.l    #MB_Sizeof,d0
  574.     movea.l    (SysBase).w,a6
  575.     SYS    AllocMem
  576.     tst.l    d0
  577.     bne.b    1$
  578.     subq.l    #1,d0    ;Return -1 for error
  579.     rts
  580.  
  581. 1$    movea.l    d0,a5    ;Our relative base
  582.     lea    (GfxName,pc),a1    ;Open graphics.library
  583.     moveq    #33,d0
  584.  
  585.     SYS    OpenLibrary
  586.     move.l    d0,(Gfx_Base,a5)
  587.     beq    Error
  588.  
  589.     lea    (IntName,pc),a1    ;Open intuition.library
  590.     moveq    #33,d0
  591.     SYS    OpenLibrary
  592.     move.l    d0,(Int_Base,a5)
  593.     beq    Error
  594.     movea.l    d0,a6
  595.  
  596.     lea    (Text_Attr,a5),a1
  597.     lea    (FontName,pc),a0
  598.     move.l    a0,(ta_Name,a1)
  599.     move.w    #8,(ta_YSize,a1)
  600.     move.b    #FS_NORMAL,(ta_Style,a1)
  601.     move.b    #FPF_ROMFONT,(ta_Flags,a1)
  602.  
  603.     movea.l    (ib_ActiveScreen,a6),a0 ;Get active screen
  604.     move.l    a0,(ScreenPtr,a5)
  605.     move.w    (sc_Width,a0),d0
  606.     cmpi.w    #352,d0    ;Check horz resolution
  607.     sge    (HiresFlag,a5)
  608.     btst    #2,(sc_ViewPort+vp_Modes+1,a0)
  609.     sne    (LaceFlag,a5)
  610.  
  611.     lea    (MyBorder,a5),a1    ;Setup default border
  612.     lea    (Border0,a5),a2
  613.     clr.l    (a1)+    ;bd_LeftEdge,bd_TopEdge
  614.     clr.l    (a2)+    ;bd_LeftEdge,bd_TopEdge
  615.  
  616.     move.l    #$01000005,d0    ;bd_FrontPen,bd_BackPen,bd_DrawMode,bd_Count
  617.     move.l    d0,(a1)+
  618.     move.l    d0,(a2)+
  619.     lea    (MyCoords,a5),a0
  620.     move.l    a0,(a1)+    ;bd_XY
  621.     lea    (Coords0,a5),a0
  622.     move.l    a0,(a2)+    ;bd_XY
  623.  
  624.     lea    (Gadget0,a5),a4
  625.     lea    (Gad0.ITxt,a5),a3
  626.     lea    (GadText.tbl,pc),a2
  627.     tst.b    (HiresFlag,a5)
  628.     bne.b    3$
  629.     lea    (LoresText.tbl,pc),a2
  630. 3$    moveq    #0,d2
  631.  
  632. 4$    lea    (gg_SIZEOF,a4),a0
  633.     move.l    a0,(a4)+    ;gg_NextGadget
  634.  
  635.     moveq    #7,d0    ;0,1,3: LeftEdge=7
  636.     tst.w    d2    ;0
  637.     beq.b    5$
  638.     btst    #0,d2    ;Even or Odd?
  639.     bne.b    5$
  640.     moveq    #55,d0    ;2,4: LeftEdge=55
  641. 5$    tst.b    (HiresFlag,a5)
  642.     beq.b    6$
  643.     add.w    d0,d0
  644. 6$    move.w    d0,(a4)+    ;gg_LeftEdge
  645.  
  646.     moveq    #18,d0    ;0: TopEdge=18
  647.     tst.w    d2
  648.     beq.b    7$
  649.     addi.w    #22,d0    ;1,2: TopEdge=40
  650.     cmpi.w    #3,d2
  651.     blt.b    7$
  652.     addi.w    #22,d0    ;3,4: TopEdge=62
  653. 7$    tst.b    (LaceFlag,a5)
  654.     beq.b    8$
  655.     add.w    d0,d0
  656. 8$    move.w    d0,(a4)+    ;gg_TopEdge
  657.  
  658.     moveq    #40,d0    ;LORES
  659.     tst.w    d2    ;Gadget 0 only
  660.     bne.b    18$
  661.     addq.w    #4,d0
  662.     add.w    d0,d0
  663. 18$    tst.b    (HiresFlag,a5)
  664.     beq.b    9$
  665.     add.w    d0,d0    ;HIRES
  666. 9$    move.w    d0,(a4)+    ;gg_Width
  667.     lea    (MyCoords,a5),a0
  668.     tst.w    d2
  669.     bne.b    19$
  670.     lea    (Coords0,a5),a0    ;Gadget 0 only
  671. 19$    move.w    d0,(4,a0)    ;X border coords
  672.     move.w    d0,(8,a0)
  673.  
  674.     move.w    #18,d0    ;NORMAL
  675.     tst.b    (LaceFlag,a5)
  676.     beq.b    10$
  677.     add.w    d0,d0    ;LACE
  678. 10$    move.w    d0,(a4)+    ;gg_Height
  679.     lea    (MyCoords,a5),a0
  680.     tst.w    d2
  681.     bne.b    20$
  682.     lea    (Coords0,a5),a0    ;Gadget 0 only
  683. 20$    move.w    d0,(10,a0)    ;Y border coords
  684.     move.w    d0,(14,a0)
  685.  
  686.     move.w    #GADGHCOMP,(a4)+    ;gg_Flags
  687.     move.w    #GADGIMMEDIATE,(a4)+ ;gg_Activation
  688.     move.w    #BOOLGADGET,(a4)+    ;gg_GadgetType
  689.     lea    (MyBorder,a5),a0
  690.     tst.w    d2
  691.     bne.b    21$
  692.     lea    (Border0,a5),a0    ;Gadget 0 only
  693. 21$    move.l    a0,(a4)+    ;gg_GadgetRender
  694.     addq.w    #4,a4    ;gg_SelectRender
  695.     move.l    a3,(a4)+    ;gg_GadgetText
  696.     addq.w    #8,a4    ;gg_MutualExclude,gg_SpecialInfo
  697.     move.w    d2,(a4)+    ;gg_GadgetID
  698.     addq.w    #4,a4    ;gg_UserData
  699.  
  700.     move.l    #$01000000,(a3)+    ;it_FrontPen,it_BackPen,it_DrawMode
  701.  
  702.     moveq    #16,d0    ;Gad1-4/HIRES=16
  703.     tst.w    d2
  704.     bne.b    23$
  705.     tst.b    (HiresFlag,a5)    ;Gadget 0 only
  706.     beq.b    22$
  707.     moveq    #56,d0    ;Gad0/HIRES=56
  708.     bra.b    11$
  709.  
  710. 22$    moveq    #20,d0    ;Gad0/LORES=20
  711.     bra.b    11$
  712.  
  713. 23$    tst.b    (HiresFlag,a5)    ;Gadgets 1-4
  714.     bne.b    11$
  715.     subq.w    #4,d0    ;Gad1-4/LORES=12
  716. 11$    move.w    d0,(a3)+    ;it_LeftEdge
  717.  
  718.     moveq    #14,d0
  719.     tst.b    (LaceFlag,a5)
  720.     bne.b    12$
  721.     subq.w    #8,d0
  722. 12$    move.w    d0,(a3)+    ;it_TopEdge
  723.  
  724.     lea    (Text_Attr,a5),a0
  725.     move.l    a0,(a3)+    ;it_TextFont
  726.  
  727.     moveq    #0,d0
  728.     move.b    (a2)+,d0
  729.     move.l    a2,(a3)+    ;it_Text
  730.     add.l    d0,a2    ;Next text
  731.  
  732.     addq.w    #4,a3    ;it_NextText
  733.     addq.w    #1,d2    ;Next gadget
  734.     cmpi.w    #4,d2    ;All the gadgets done?
  735.     ble.w    4$
  736.  
  737.     clr.l    (Gadget4,a5)    ;gg_NextGadget
  738.  
  739.     lea    (Gadget0,a5),a0
  740.     ori.w    #SELECTED,(gg_Flags,a0)
  741.  
  742.     tst.l    d3    ;Units 2 & 3 exist?
  743.     bne.b    13$    ;Branch if yes
  744.     move.w    #GADGDISABLED,d0    ;Else, disable gadgets
  745.     lea    (Gadget3,a5),a0
  746.     or.w    d0,(gg_Flags,a0)
  747.  
  748.     lea    (Gadget4,a5),a0
  749.     or.w    d0,(gg_Flags,a0)
  750.  
  751. 13$    lea    (MyWindow,a5),a0
  752.     movea.l    (ScreenPtr,a5),a2 ;Get active screen
  753.     move.l    a2,(nw_Screen,a0)    ;
  754.  
  755.     move.w    #103,d0    ;LORES = 103
  756.     tst.b    (HiresFlag,a5)
  757.     beq.b    14$
  758.     add.w    d0,d0    ;HIRES = 206
  759. 14$    move.w    d0,(nw_Width,a0)
  760.     move.w    (sc_Width,a2),d1
  761.     lsr.w    #1,d1    ;Screen width / 2
  762.     lsr.w    #1,d0    ;Window width / 2
  763.     sub.w    d0,d1
  764.     move.w    d1,(a0)    ;nw_LeftEdge
  765.  
  766.     move.w    #88,d0    ;NORMAL = 88
  767.     tst.b    (LaceFlag,a5)
  768.     beq.b    15$
  769.     add.w    d0,d0    ;LACE = 176
  770. 15$    move.w    d0,(nw_Height,a0)
  771.     move.w    (sc_Height,a2),d1
  772.     lsr.w    #1,d1    ;Screen height / 2
  773.     lsr.w    #1,d0    ;Window height / 2
  774.     sub.w    d0,d1
  775.     move.w    d1,(nw_TopEdge,a0)
  776.  
  777.     move.b    #-1,(nw_DetailPen,a0)
  778.     move.b    #-1,(nw_BlockPen,a0)
  779.     move.l    #GADGETDOWN!CLOSEWINDOW,(nw_IDCMPFlags,a0)
  780.     move.l    #MyFeatures!MyGadgets,(nw_Flags,a0)
  781.     lea    (Gadget0,a5),a1
  782.     move.l    a1,(nw_FirstGadget,a0)
  783.     lea    (WindowTitle,pc),a1
  784.     tst.b    (HiresFlag,a5)
  785.     bne.b    16$
  786.     lea    (LoresTitle,pc),a1
  787. 16$    move.l    a1,(nw_Title,a0)
  788.     move.w    (sc_Flags,a2),d0
  789.     andi.w    #%00001111,d0
  790.     move.w    d0,(nw_Type,a0)
  791.     SYS    OpenWindow    ;Open window
  792.     movea.l    d0,a3    ;Save window pointer
  793.     tst.l    d0
  794.     beq.b    Error
  795.  
  796.     movea.l    (Gfx_Base,a5),a6
  797.     lea    (Text_Attr,pc),a0
  798.     SYS    OpenFont
  799.     move.l    d0,(FontPtr,a5)
  800.     beq.b    17$
  801.  
  802.     movea.l    d0,a0
  803.     movea.l    (wd_RPort,a3),a1
  804.     SYS    SetFont
  805.  
  806. 17$    moveq    #0,d6    ;Close flag
  807.     bsr.b    MainLoop
  808.     bra.b    Cleanup
  809.  
  810. ************************************************
  811. *             Termination section              *
  812. ************************************************
  813.  
  814. Error    subq.l    #1,d7
  815. Cleanup    move.l    (Gfx_Base,a5),d2
  816.     beq.b    2$
  817.     move.l    (FontPtr,a5),d0
  818.     beq.b    1$
  819.     movea.l    d0,a1
  820.     movea.l    d2,a6
  821.     SYS    CloseFont
  822.  
  823. 1$    movea.l    d2,a1
  824.     movea.l    (SysBase).w,a6
  825.     SYS    CloseLibrary
  826.  
  827. 2$    move.l    (Int_Base,a5),d2
  828.     beq.b    4$
  829.     move.l    a3,d0
  830.     beq.b    3$
  831.     movea.l d0,a0
  832.     movea.l    d2,a6
  833.     SYS    CloseWindow
  834.  
  835. 3$    movea.l    d2,a1
  836.     movea.l    (SysBase).w,a6
  837.     SYS    CloseLibrary
  838.  
  839. 4$    movea.l    a5,a1
  840.     move.l    #MB_Sizeof,d0
  841.     movea.l    (SysBase).w,a6
  842.     SYS    FreeMem
  843.     move.l    d7,d0    ;0-4, or -1 if error.
  844.     rts
  845.  
  846. ************************************************
  847. *             Main Execution Loop              *
  848. ************************************************
  849.  
  850. MainLoop    tst.w    d6    ;Flag set?
  851.     beq.b    1$
  852.     rts        ;Exit
  853.  
  854. 1$    movea.l (wd_UserPort,a3),a0
  855.     moveq    #0,d0
  856.     moveq    #0,d1
  857.     move.b    (MP_SIGBIT,a0),d1
  858.     bset    d1,d0
  859.     movea.l    (SysBase).w,a6
  860.     SYS    Wait    ;Now wait for a message
  861.  
  862. GetIMsg    movea.l (wd_UserPort,a3),a0
  863.     SYS    GetMsg
  864.     tst.l    d0
  865.     beq.b    MainLoop
  866.     movea.l d0,a1
  867.     move.l    (im_Class,a1),d2
  868.     movea.l    (im_IAddress,a1),a2
  869.     SYS    ReplyMsg
  870.  
  871.     cmpi.l    #CLOSEWINDOW,d2
  872.     bne.b    CheckGads
  873.     moveq    #-1,d6
  874.     bra.b    GetIMsg
  875.  
  876. CheckGads    cmpi.w    #GADGETDOWN,d2    ;Someone clicked on a gadget
  877.     bne.b    1$    ;Unknown class
  878.     moveq    #0,d7
  879.     move.w    (gg_GadgetID,a2),d7 ;ID = Unit number
  880.     lea    (Gadget0,a5),a1    ;1st gadget in group
  881.  
  882.     moveq    #5,d0    ;# of gadgets in group
  883.     bsr.b    MutualExclude
  884. 1$    bra.b    GetIMsg
  885.  
  886. *************************************************************************
  887. * NAME:     MutualExclude()
  888. * FUNCTION: Performs a MutualExclude function for Boolean gadgets.
  889. * INPUTS:   A3 = Window
  890. *           A2 = Currently selected gadget
  891. *           A1 = 1st gadget in group
  892. *           D0 = NumGads
  893. * RETURN:   None
  894. * SCRATCH:  D0-D1/A0-A1
  895. *************************************************************************
  896.  
  897. MutualExclude    move.l    a6,-(sp)
  898.     movea.l    (Int_Base,a5),a6
  899.     movem.l    d0/a1,-(sp)
  900.     movea.l    a3,a0    ;Window
  901.     SYS    RemoveGList
  902.     move.l    d0,d4    ;Position
  903.     movem.l    (sp),d1/a1
  904.     bra.b    3$
  905.  
  906. 1$    cmp.w    (gg_GadgetID,a1),d7 ;Is this the current gadget?
  907.     seq    d2    ;D2 = 1 if TRUE
  908.     btst    #7,(gg_Flags+1,a1)    ;Currently selected?
  909.     sne    d3    ;D3 = 1 if TRUE
  910.     eor.b    d2,d3
  911.     beq.b    2$
  912.     bchg    #7,(gg_Flags+1,a1)    ;Toggle the select flag
  913. 2$    movea.l    (a1),a1    ;gg_NextGadget
  914. 3$    dbra    d1,1$
  915.  
  916.     bsr.b    ClearScreen
  917.  
  918.     movea.l    a3,a0    ;Window
  919.     move.l    d4,d0    ;Position
  920.     movem.l    (sp),d1/a1    ;NumGads/Gadget
  921.     SYS    AddGList
  922.  
  923.     movea.l    a3,a1    ;Window
  924.     movem.l    (sp)+,d0/a0    ;NumGads/Gadget
  925.     SYS    RefreshGList
  926.     movea.l    (sp)+,a6
  927.     rts
  928.  
  929. ClearScreen    movem.l    a2/a6,-(sp)
  930.     movea.l    (Gfx_Base,a5),a6
  931.     movea.l    (wd_RPort,a3),a2
  932.     moveq    #0,d0
  933.     movea.l    a2,a1
  934.     SYS    SetAPen
  935.  
  936.     moveq    #4,d0    ;Xmin
  937.     moveq    #14,d1    ;Ymin
  938.     moveq    #0,d2
  939.     move.w    (wd_Width,a3),d2
  940.     subq.w    #4,d2    ;Xmax
  941.     moveq    #0,d3
  942.     move.w    (wd_Height,a3),d3
  943.     subq.w    #4,d3    ;Ymax
  944.     movea.l    a2,a1
  945.     SYS    RectFill
  946.  
  947.     moveq    #1,d0
  948.     movea.l    a2,a1
  949.     SYS    SetAPen
  950.     movem.l    (sp)+,a2/a6
  951.     rts
  952.  
  953. Notice    cstr    'SelectWindow ©1990 by The Puzzle Factory',10
  954. GfxName    cstr    'graphics.library'
  955. IntName    cstr    'intuition.library'
  956. FontName    cstr    'topaz.font'
  957. WindowTitle    cstr    'Select Unit:'
  958. LoresTitle    cstr    'Sel Unit:'
  959.  
  960. GadText.tbl:
  961.     cstr    9,'Internal'
  962.     cstr    7,'Unit 0'
  963.     cstr    7,'Unit 1'
  964.     cstr    7,'Unit 2'
  965.     cstr    7,'Unit 3'
  966.  
  967. LoresText.tbl:
  968.     cstr    9,'Internal'
  969.     cstr    3,'U0'
  970.     cstr    3,'U1'
  971.     cstr    3,'U2'
  972.     cstr    3,'U3'
  973.  
  974. enddispatchcode    end
  975.