home *** CD-ROM | disk | FTP | other *** search
/ Crawly Crypt Collection 2 / crawlyvol2.bin / apps / dtp / pgsmodst / atariprt / oki84.s < prev    next >
Text File  |  1991-05-23  |  6KB  |  340 lines
  1.  include "prtequ.h"
  2.  
  3. *
  4. * Okidate Microline 182 print driver
  5. *
  6. CR    equ    $d
  7. LF    equ    $a
  8. FF    equ    $c
  9. ESC    equ    $1b
  10. FS    equ    $1c
  11.  
  12.  SECTION printer,CODE,PUBLIC
  13. ***************************************************************
  14. ***************************************************************
  15. ***************************************************************
  16. dumbentry:
  17.     clr.l    d0
  18.     rts
  19.  
  20.     dc.l    "PRNT"
  21.     dc.w    200
  22.  
  23. *
  24. * distribute the calls to the appropriate routines
  25. *
  26. oki182:    move.l    a0,table
  27.     lsl.w    #2,d0
  28.     lea    prntbl,a1
  29.     move.l    0(a1,d0.w),a1
  30.     jmp    (a1)
  31.  
  32. *
  33. * identify who I am, and set up who I like to speak to.
  34. *
  35. p_ident:
  36.     move.l    #driver,pdrvrnm(a0)    ;pointer to string for driver name
  37.     move.w    #PARALLEL+ASCENDING,device(a0)
  38. prtok:    moveq    #1,d0
  39.     rts
  40.  
  41. *
  42. * initialize the table of printer specific routines
  43. *
  44. p_init:    clr.b    pdl(a0)            ;no page description language
  45.     clr.b    pmult(a0)        ;automatically print mulitiple copies?
  46.     clr.b    pman(a0)        ;handle manual feed?
  47.     move.b    #PRT_BW,ptype(a0)    ;printer type?
  48.     move.l    sendout(a0),send+2    ;self-modifing code, tisk, tisk!
  49.  
  50. *
  51. * pminlft and pmaxw must be evenly divisible by 16
  52. * this is the part that should be worked out
  53. *
  54.  
  55.     move.w    pdensity(a0),d0
  56.     cmp.w    #7,d0
  57.     bcs    pint1
  58.     moveq    #6,d0
  59. pint1:    lsl.w    #1,d0
  60.  
  61.     lea    xdpi_tbl,a1
  62.     move.w    0(a1,d0.w),pxdpi(a0)    ;x resolution
  63.     lea    ydpi_tbl,a1
  64.     move.w    0(a1,d0.w),pydpi(a0)    ;y resolution
  65.     lea    minl_tbl,a1
  66.     move.w    0(a1,d0.w),pminlft(a0)    ;pixels from the left
  67.     lea    minr_tbl,a1
  68.     move.w    0(a1,d0.w),pminrht(a0)    ;pixels from the right
  69.     lea    mint_tbl,a1
  70.     move.w    0(a1,d0.w),pmintop(a0)    ;pixels down from top
  71.     lea    minb_tbl,a1
  72.     move.w    0(a1,d0.w),pminbot(a0)    ;pixels up from bottom
  73.     lea    xover_tbl,a1
  74.     move.w    0(a1,d0.w),pxover(a0)    ;percentage of x overlap of dots
  75.     lea    yover_tbl,a1
  76.     move.w    0(a1,d0.w),pyover(a0)    ;percentage of y overlap of dots
  77.     lea    rowht_tbl,a1
  78.     move.w    0(a1,d0.w),prowht(a0)    ;rows height modula
  79.  
  80.     move.w    0(a1,d0.w),rowht
  81.     lea    rows_tbl,a1
  82.     move.w    0(a1,d0.w),rows
  83.     lea    grmode_tbl,a1
  84.     move.w    0(a1,d0.w),grmode
  85.  
  86.     lsl.w    #1,d0
  87.     lea    maxw_tbl,a1
  88.     move.w    0(a1,d0.w),pmaxw(a0)    ;maximum # pixels across
  89.     lea    maxh_tbl,a1
  90.     move.w    0(a1,d0.w),pmaxh(a0)    ;maximum # pixels down
  91.  
  92.     bra    prtok
  93.  
  94. *
  95. * going to begin printing a document
  96. *
  97. p_bgndoc:
  98.     move.b    #ESC,d0
  99.     bsr    send
  100.     move.b    #"-",d0
  101.     bsr    send
  102.     move.b    #FS,d0
  103.     bra    send
  104.  
  105. *
  106. * about to start printing of a page
  107. *
  108. p_bgnpage:
  109.     bra    prtok
  110.  
  111. *
  112. * about to print a new tile for the page
  113. *
  114. p_bgntile:
  115.     bra    prtok
  116.  
  117. *
  118. * print a block to the printer
  119. *
  120. p_block:
  121.     move.l    table,a0
  122.     move.l    pblockw(a0),d0
  123.     move.w    d0,width
  124.     move.l    pblockptr(a0),a1
  125.     move.l    (a1),a1
  126.     add.l    pblockoff(a0),a1
  127.     move.l    a1,v_base
  128. *
  129. *
  130.     move.w    rows,count
  131. pblck2:    move.l    v_base,lineptr
  132.     bsr    putline
  133.     moveq    #0,d0
  134.     move.w    width,d0
  135.     add.l    d0,v_base
  136.     subq.w    #1,count
  137.     bne    pblck2
  138. *
  139.     move.b    #ESC,d0
  140.     bsr    send
  141.     move.b    #"%",d0
  142.     bsr    send
  143.     move.b    #"9",d0
  144.     bsr    send
  145.     move.w    #14,d0
  146.     sub.w    rows,d0
  147.     bsr    send
  148.     move.b    #CR,d0
  149.     bsr    send
  150.     move.b    #LF,d0
  151.     bra    send
  152.  
  153. **************************************
  154.  
  155. putline:
  156.     move.l    lineptr,a0
  157.     move.w    #0,twidth
  158.     move.w    #6,d1
  159. print0:    move.w    width,d0
  160. print1:    tst.b    -1(a0,d0.w)
  161.     bne    print2
  162.     subq.w    #1,d0
  163.     bne    print1
  164. print2:    cmp.w    twidth,d0
  165.     blt    print3
  166.     move.w    d0,twidth
  167. print3:    move.w    rows,d3
  168. pri1:    add.w    width,a0
  169.     sub.w    #1,d3
  170.     bgt    pri1
  171.     dbf    d1,print0
  172. *
  173.     tst.w    twidth
  174.     beq    endline
  175.  
  176.     move.w    grmode,d0
  177.     bsr    send
  178.     move.b    #3,d0
  179.     bsr    send
  180.  
  181.     move.w    twidth,d2                 ;length of the data in byte
  182. print4:    move.w    d2,-(sp)
  183.     moveq    #7,d4
  184. print6:    move.w    d4,pixel
  185.     moveq    #0,d1
  186.     moveq    #0,d0
  187.     move.l    lineptr,a0
  188. s1:    btst    d4,(a0)
  189.     beq     s2
  190.     bset    d1,d0
  191. s2:
  192.     move.w    rows,d3
  193. pri2:    add.w    width,a0
  194.     sub.w    #1,d3
  195.     bgt    pri2
  196.  
  197.     addq.w    #1,d1
  198.     cmp.w    #7,d1
  199.     bcs    s1
  200.  
  201.     cmp.b    #3,d0
  202.     bne    .1
  203.     bsr    send
  204.     move.b    #3,d0
  205. .1:    bsr    send
  206. *
  207.     move.w    pixel,d4
  208.     dbf    d4,print6
  209.  
  210.     add.l    #1,lineptr
  211.     move.w    (sp)+,d2
  212.     subq.w    #1,d2
  213.     bgt    print4
  214.  
  215.     move.b    #3,d0
  216.     bsr    send
  217.     move.b    #2,d0
  218.     bsr    send
  219.  
  220. endline:
  221.     move.b    #ESC,d0
  222.     bsr    send
  223.     move.b    #"%",d0
  224.     bsr    send
  225.     move.b    #"9",d0
  226.     bsr    send
  227.     move.b    #1,d0
  228.     bsr    send
  229.     move.b    #CR,d0
  230.     bsr    send
  231.     move.b    #LF,d0
  232.     bra    send
  233.  
  234. ************************************
  235. *
  236. * just finished describing current tile
  237. *
  238. p_endtile:
  239.     move.l    table,a0
  240.     move.l    pblockh(a0),d0
  241.     mulu    #144,d0
  242.     divu    pydpi(a0),d0
  243.     move.w    d0,scroll
  244. pend1:    tst.b    scroll
  245.     beq    pend2
  246.     move.b    #ESC,d0
  247.     bsr    send
  248.     move.b    #"%",d0
  249.     bsr    send
  250.     move.b    #"9",d0
  251.     bsr    send
  252.     move.b    #255,d0
  253.     bsr    send
  254.     sub.w    #255,scroll
  255.     bra    pend1
  256. pend2:    tst.w    scroll
  257.     beq    prtok
  258.     move.b    #ESC,d0
  259.     bsr    send
  260.     move.b    #"%",d0
  261.     bsr    send
  262.     move.b    #"9",d0
  263.     bsr    send
  264.     move.w    scroll,d0
  265.     bra    send
  266.     
  267. *
  268. * just finished describing all tiles for this page
  269. *
  270. p_endpage:
  271.     bra    prtok
  272.  
  273. *
  274. * finished printing the document
  275. *
  276. p_enddoc:
  277.     bra    prtok
  278.  
  279. *
  280. * user requested stop
  281. *
  282. p_break:
  283.     bra    p_endtile
  284.  
  285. ***************************************************
  286. ***    these are the send routines for the    ***
  287. ***    dot matrix driver.            ***
  288. ***************************************************
  289. sendline:
  290.     move.b    (a0)+,d0
  291.     beq    prtok
  292.     move.l    a0,-(sp)
  293.     bsr    send
  294.     move.l    (sp)+,a0
  295.     bra    sendline
  296.  
  297. send:    jmp    $ffffff
  298.  
  299. ***********************************
  300. ***                ***
  301. ***********************************
  302.  SECTION printer,DATA,PUBLIC
  303.  
  304. prntbl:    dc.l    prtok,prtok,prtok,prtok,p_init
  305.     dc.l    p_bgndoc,p_bgnpage,p_bgntile
  306.     dc.l    p_block
  307.     dc.l    p_endtile,p_endpage,p_enddoc
  308.     dc.l    p_break,p_ident
  309.  
  310.  
  311. xdpi_tbl:    dc.w    60,60,72,72,103,103,103
  312. ydpi_tbl:    dc.w    72,144,72,144,72,144,144
  313. minl_tbl:    dc.w    15,15,18,18,25,25,25
  314. minr_tbl:    dc.w    15,15,18,18,25,25,25
  315. mint_tbl:    dc.w    0,0,0,0,0,0,0
  316. minb_tbl:    dc.w    0,0,0,0,0,0,0
  317. maxw_tbl:    dc.l    480,480,576,576,824,824,824
  318. maxh_tbl:    dc.l    0,0,0,0,0,0,0
  319. xover_tbl:    dc.w    0,0,20,20,40,40,40
  320. yover_tbl:    dc.w    0,50,0,50,0,50,50
  321. rowht_tbl:    dc.w    7,14,7,14,7,14,14
  322. rows_tbl:    dc.w    1,2,1,2,1,2,2
  323. grmode_tbl:    dc.w    $1e,$1e,$1c,$1c,$1d,$1d,$1d
  324.  
  325.  
  326. driver:        dc.b    "Okidate ML-84 v2.0 beta",0
  327.  
  328.  SECTION printer,BSS,PUBLIC
  329. table:        ds.l    1
  330. twidth:        ds.w    1
  331. pixel:        ds.w    1
  332. v_base:        ds.l    1
  333. lineptr:    ds.l    1
  334. width:        ds.w    1
  335. count:        ds.w    1
  336. grmode:        ds.w    1
  337. rows:        ds.w    1
  338. rowht:        ds.w    1
  339. scroll:        ds.w    1
  340.