home *** CD-ROM | disk | FTP | other *** search
/ Crawly Crypt Collection 2 / crawlyvol2.bin / apps / dtp / pgsmodst / atariprt / gemin15x.s < prev    next >
Text File  |  1991-05-23  |  6KB  |  326 lines
  1.  include "prtequ.h"
  2.  
  3. *
  4. * Star Gemini 15x (wide) print driver
  5. *
  6. CR    equ    $d
  7. LF    equ    $a
  8. FF    equ    $c
  9. ESC    equ    $1b
  10.  
  11.  SECTION printer,CODE,PUBLIC
  12. ***************************************************************
  13. ***************************************************************
  14. ***************************************************************
  15. dumbentry:
  16.     clr.l    d0
  17.     rts
  18.  
  19.     dc.l    "PRNT"
  20.     dc.w    200
  21.  
  22. *
  23. * distribute the calls to the appropriate routines
  24. *
  25. gemini:    move.l    a0,table
  26.     lsl.w    #2,d0
  27.     lea    prntbl,a1
  28.     move.l    0(a1,d0.w),a1
  29.     jmp    (a1)
  30.  
  31. *
  32. * identify who I am, and set up who I like to speak to.
  33. *
  34. p_ident:
  35.     move.l    #driver,pdrvrnm(a0)    ;pointer to string for driver name
  36.     move.w    #PARALLEL+ASCENDING,device(a0)
  37. prtok:    moveq    #1,d0
  38.     rts
  39.  
  40. *
  41. * initialize the table of printer specific routines
  42. *
  43. p_init:    clr.b    pdl(a0)            ;no page description language
  44.     clr.b    pmult(a0)        ;automatically print mulitiple copies?
  45.     clr.b    pman(a0)        ;handle manual feed?
  46.     move.b    #PRT_BW,ptype(a0)    ;printer type?
  47.     move.l    sendout(a0),send+2    ;self-modifing code, tisk, tisk!
  48.  
  49. *
  50. * pminlft and pmaxw must be evenly divisible by 16
  51. * this is the part that should be worked out
  52. *
  53.  
  54.     move.w    pdensity(a0),d0
  55.     cmp.w    #7,d0
  56.     bcs    pint1
  57.     moveq    #6,d0
  58. pint1:    lsl.w    #1,d0
  59.  
  60.     lea    xdpi_tbl,a1
  61.     move.w    0(a1,d0.w),pxdpi(a0)    ;x resolution
  62.     lea    ydpi_tbl,a1
  63.     move.w    0(a1,d0.w),pydpi(a0)    ;y resolution
  64.     lea    minl_tbl,a1
  65.     move.w    0(a1,d0.w),pminlft(a0)    ;pixels from the left
  66.     lea    minr_tbl,a1
  67.     move.w    0(a1,d0.w),pminrht(a0)    ;pixels from the right
  68.     lea    mint_tbl,a1
  69.     move.w    0(a1,d0.w),pmintop(a0)    ;pixels down from top
  70.     lea    minb_tbl,a1
  71.     move.w    0(a1,d0.w),pminbot(a0)    ;pixels up from bottom
  72.     lea    xover_tbl,a1
  73.     move.w    0(a1,d0.w),pxover(a0)    ;percentage of x overlap of dots
  74.     lea    yover_tbl,a1
  75.     move.w    0(a1,d0.w),pyover(a0)    ;percentage of y overlap of dots
  76.     lea    rowht_tbl,a1
  77.     move.w    0(a1,d0.w),prowht(a0)    ;rows height modula
  78.  
  79.     move.w    0(a1,d0.w),rowht
  80.     lea    rows_tbl,a1
  81.     move.w    0(a1,d0.w),rows
  82.     lea    grmode_tbl,a1
  83.     move.w    0(a1,d0.w),grmode
  84.  
  85.     lsl.w    #1,d0
  86.     lea    maxw_tbl,a1
  87.     move.w    0(a1,d0.w),pmaxw(a0)    ;maximum # pixels across
  88.     lea    maxh_tbl,a1
  89.     move.w    0(a1,d0.w),pmaxh(a0)    ;maximum # pixels down
  90.  
  91.     bra    prtok
  92.  
  93. *
  94. * going to begin printing a document
  95. *
  96. p_bgndoc:
  97.     move.b    #ESC,d0
  98.     bsr    send
  99.     move.b    #"U",d0
  100.     bsr    send
  101.     move.b    #1,d0
  102.     bra    send
  103.  
  104. *
  105. * about to start printing of a page
  106. *
  107. p_bgnpage:
  108.     bra    prtok
  109.  
  110. *
  111. * about to print a new tile for the page
  112. *
  113. p_bgntile:
  114.     bra    prtok
  115.  
  116. *
  117. * print a block to the printer
  118. *
  119. p_block:
  120.     move.l    table,a0
  121.     move.l    pblockw(a0),d0
  122.     move.w    d0,width
  123.     move.l    pblockptr(a0),a1
  124.     move.l    (a1),a1
  125.     add.l    pblockoff(a0),a1
  126.     move.l    a1,v_base
  127. *
  128. *
  129.     move.w    rows,count
  130. pblck2:    move.l    v_base,lineptr
  131.     bsr    putline
  132.     moveq    #0,d0
  133.     move.w    width,d0
  134.     add.l    d0,v_base
  135.     subq.w    #1,count
  136.     bne    pblck2
  137. *
  138.     move.b    #ESC,d0            ;already moved 1/216" down
  139.     bsr    send
  140.     move.b    #"J",d0
  141.     bsr    send
  142.     move.w    #16,d0
  143.     sub.w    rows,d0
  144.     bra    send
  145.  
  146. **************************************
  147.  
  148. putline:
  149.     move.l    lineptr,a0
  150.     move.w    #0,twidth
  151.     move.w    #7,d1
  152. print0:    move.w    width,d0
  153. print1:    tst.b    -1(a0,d0.w)
  154.     bne    print2
  155.     subq.w    #1,d0
  156.     bne    print1
  157. print2:    cmp.w    twidth,d0
  158.     blt    print3
  159.     move.w    d0,twidth
  160. print3:    move.w    rows,d3
  161. pri1:    add.w    width,a0
  162.     sub.w    #1,d3
  163.     bgt    pri1
  164.     dbf    d1,print0
  165. *
  166.     tst.w    twidth
  167.     beq    endline
  168.  
  169.     move.b    #ESC,d0
  170.     bsr    send
  171.     move.w    grmode,d0
  172.     bsr    send
  173.  
  174.     move.w    twidth,d0        ;send number of graphic bytes to follow
  175.     lsl.w    #3,d0
  176.     bsr    send
  177.     move.w    twidth,d0    
  178.     lsr.w    #5,d0
  179.     bsr    send
  180.  
  181.     move.w    twidth,d2                 ;length of the data in byte
  182. print4:    move.w    d2,-(sp)
  183.     moveq    #7,d4
  184. print6:    move.w    d4,pixel
  185.     moveq    #7,d1
  186.     moveq    #0,d0
  187.     move.l    lineptr,a0
  188. s1:    btst    d4,(a0)
  189.     beq     s2
  190.     bset    d1,d0
  191. s2:
  192.     move.w    rows,d3
  193. pri2:
  194.     add.w    width,a0
  195.     sub.w    #1,d3
  196.     bgt    pri2
  197.  
  198.     dbf    d1,s1
  199.  
  200.     bsr    send
  201. *
  202.     move.w    pixel,d4
  203.     dbf    d4,print6
  204.  
  205.     add.l    #1,lineptr
  206.     move.w    (sp)+,d2
  207.     subq.w    #1,d2
  208.     bgt    print4
  209.  
  210. endline:
  211.     move.b    #ESC,d0            ;one-time paper feed of 1/144"
  212.     bsr    send
  213.     move.b    #"J",d0
  214.     bsr    send
  215.     move.b    #1,d0
  216.     bsr    send
  217.  
  218.     move.w    #CR,d0
  219.     bra    send
  220.  
  221. ************************************
  222. *
  223. * just finished describing current tile
  224. *
  225. p_endtile:
  226.     move.l    table,a0
  227.     move.l    pblockh(a0),d0
  228.     mulu    #144,d0
  229.     divu    pydpi(a0),d0
  230.     move.w    d0,scroll
  231. pend1:    tst.b    scroll
  232.     beq    pend2
  233.     move.b    #ESC,d0
  234.     bsr    send
  235.     move.b    #"J",d0
  236.     bsr    send
  237.     move.b    #255,d0
  238.     bsr    send
  239.     sub.w    #255,scroll
  240.     bra    pend1
  241. pend2:    tst.w    scroll
  242.     beq    prtok
  243.     move.b    #ESC,d0
  244.     bsr    send
  245.     move.b    #"J",d0
  246.     bsr    send
  247.     move.w    scroll,d0
  248.     bra    send
  249.  
  250. *
  251. * just finished describing all tiles for this page
  252. *
  253. p_endpage:
  254.     bra    prtok
  255.  
  256. *
  257. * finished printing the document
  258. *
  259. p_enddoc:
  260.     bra    prtok
  261.  
  262. *
  263. * user requested stop
  264. *
  265. p_break:
  266.     bra    p_endtile
  267.  
  268. ***************************************************
  269. ***    these are the send routines for the    ***
  270. ***    dot matrix driver.            ***
  271. ***************************************************
  272. *
  273. *
  274. sendline:
  275.     move.b    (a0)+,d0
  276.     beq    prtok
  277.     move.l    a0,-(sp)
  278.     bsr    send
  279.     move.l    (sp)+,a0
  280.     bra    sendline
  281. *
  282. *
  283. send:    jmp    $ffffff
  284. *
  285. *
  286. ***********************************
  287. ***                ***
  288. ***********************************
  289.  SECTION printer,DATA,PUBLIC
  290.  
  291. prntbl:    dc.l    prtok,prtok,prtok,prtok,p_init
  292.     dc.l    p_bgndoc,p_bgnpage,p_bgntile
  293.     dc.l    p_block
  294.     dc.l    p_endtile,p_endpage,p_enddoc
  295.     dc.l    p_break,p_ident
  296.  
  297.  
  298. xdpi_tbl:    dc.w    60,60,120,120,240,240,240
  299. ydpi_tbl:    dc.w    72,144,72,144,72,144,144
  300. minl_tbl:    dc.w    15,15,30,30,60,60,60
  301. minr_tbl:    dc.w    15,15,30,30,60,60,60
  302. mint_tbl:    dc.w    0,0,0,0,0,0,0
  303. minb_tbl:    dc.w    0,0,0,0,0,0,0
  304. maxw_tbl:    dc.l    816,816,1632,1632,3264,3264,3264
  305. maxh_tbl:    dc.l    0,0,0,0,0,0,0
  306. xover_tbl:    dc.w    0,0,30,30,60,60,60
  307. yover_tbl:    dc.w    0,50,0,50,0,50,50
  308. rowht_tbl:    dc.w    8,16,8,16,8,16,16
  309. rows_tbl:    dc.w    1,2,1,2,1,2,2
  310. grmode_tbl:    dc.w    "K","K","L","L","z","z","z"
  311.  
  312. driver:        dc.b    "Star Gemini 15x v2.0.1",0
  313.  
  314.  SECTION printer,BSS,PUBLIC
  315. table:        ds.l    1
  316. twidth:        ds.w    1
  317. pixel:        ds.w    1
  318. v_base:        ds.l    1
  319. lineptr:    ds.l    1
  320. width:        ds.w    1
  321. count:        ds.w    1
  322. grmode:        ds.w    1
  323. rows:        ds.w    1
  324. rowht:        ds.w    1
  325. scroll:        ds.w    1
  326.