home *** CD-ROM | disk | FTP | other *** search
/ Crawly Crypt Collection 2 / crawlyvol2.bin / apps / dtp / pgsmodst / atariprt / gemin10x.s < prev    next >
Text File  |  1991-05-23  |  6KB  |  324 lines
  1.  include "prtequ.h"
  2.  
  3. *
  4. * Star Gemini print driver
  5. *
  6. CR    equ    $d
  7. LF    equ    $a
  8. FF    equ    $c
  9. ESC    equ    $1b
  10.  
  11.  SECTION printer,CODE,PUBLIC
  12. ***************************************************************
  13. ***************************************************************
  14. ***************************************************************
  15. dumbentry:
  16.     clr.l    d0
  17.     rts
  18.  
  19.     dc.l    "PRNT"
  20.     dc.w    200
  21.  
  22. *
  23. * distribute the calls to the appropriate routines
  24. *
  25. gemini:    move.l    a0,table
  26.     lsl.w    #2,d0
  27.     lea    prntbl,a1
  28.     move.l    0(a1,d0.w),a1
  29.     jmp    (a1)
  30.  
  31. *
  32. * identify who I am, and set up who I like to speak to.
  33. *
  34. p_ident:
  35.     move.l    #driver,pdrvrnm(a0)    ;pointer to string for driver name
  36.     move.w    #PARALLEL+ASCENDING,device(a0)
  37. prtok:    moveq    #1,d0
  38.     rts
  39.  
  40. *
  41. * initialize the table of printer specific routines
  42. *
  43. p_init:    clr.b    pdl(a0)            ;no page description language
  44.     clr.b    pmult(a0)        ;automatically print mulitiple copies?
  45.     clr.b    pman(a0)        ;handle manual feed?
  46.     move.b    #PRT_BW,ptype(a0)    ;printer type?
  47.     move.l    sendout(a0),send+2    ;self-modifing code, tisk, tisk!
  48.  
  49. *
  50. * pminlft and pmaxw must be evenly divisible by 16
  51. * this is the part that should be worked out
  52. *
  53.  
  54.     move.w    pdensity(a0),d0
  55.     cmp.w    #7,d0
  56.     bcs    pint1
  57.     moveq    #6,d0
  58. pint1:    lsl.w    #1,d0
  59.  
  60.     lea    xdpi_tbl,a1
  61.     move.w    0(a1,d0.w),pxdpi(a0)    ;x resolution
  62.     lea    ydpi_tbl,a1
  63.     move.w    0(a1,d0.w),pydpi(a0)    ;y resolution
  64.     lea    minl_tbl,a1
  65.     move.w    0(a1,d0.w),pminlft(a0)    ;pixels from the left
  66.     lea    minr_tbl,a1
  67.     move.w    0(a1,d0.w),pminrht(a0)    ;pixels from the right
  68.     lea    mint_tbl,a1
  69.     move.w    0(a1,d0.w),pmintop(a0)    ;pixels down from top
  70.     lea    minb_tbl,a1
  71.     move.w    0(a1,d0.w),pminbot(a0)    ;pixels up from bottom
  72.     lea    xover_tbl,a1
  73.     move.w    0(a1,d0.w),pxover(a0)    ;percentage of x overlap of dots
  74.     lea    yover_tbl,a1
  75.     move.w    0(a1,d0.w),pyover(a0)    ;percentage of y overlap of dots
  76.     lea    rowht_tbl,a1
  77.     move.w    0(a1,d0.w),prowht(a0)    ;rows height modula
  78.  
  79.     move.w    0(a1,d0.w),rowht
  80.     lea    rows_tbl,a1
  81.     move.w    0(a1,d0.w),rows
  82.     lea    grmode_tbl,a1
  83.     move.w    0(a1,d0.w),grmode
  84.  
  85.     lsl.w    #1,d0
  86.     lea    maxw_tbl,a1
  87.     move.l    0(a1,d0.w),pmaxw(a0)    ;maximum # pixels across
  88.     lea    maxh_tbl,a1
  89.     move.l    0(a1,d0.w),pmaxh(a0)    ;maximum # pixels down
  90.  
  91.     bra    prtok
  92.  
  93. *
  94. * going to begin printing a document
  95. *
  96. p_bgndoc:
  97.     move.b    #ESC,d0
  98.     bsr    send
  99.     move.b    #"U",d0
  100.     bsr    send
  101.     move.b    #1,d0
  102.     bra    send
  103.  
  104. *
  105. * about to start printing of a page
  106. *
  107. p_bgnpage:
  108.     bra    prtok
  109. *
  110. * about to print a new tile for the page
  111. *
  112. p_bgntile:
  113.     bra    prtok
  114. *
  115. * print a block to the printer
  116. *
  117. p_block:
  118.     move.l    table,a0
  119.     move.l    pblockw(a0),d0
  120.     move.w    d0,width
  121.     move.l    pblockptr(a0),a1
  122.     move.l    (a1),a1
  123.     add.l    pblockoff(a0),a1
  124.     move.l    a1,v_base
  125. *
  126. *
  127.     move.w    rows,count
  128. pblck2:    move.l    v_base,lineptr
  129.     bsr    putline
  130.     moveq    #0,d0
  131.     move.w    width,d0
  132.     add.l    d0,v_base
  133.     subq.w    #1,count
  134.     bne    pblck2
  135. *
  136.     move.b    #ESC,d0            ;already moved 1/144" down
  137.     bsr    send
  138.     move.b    #"J",d0
  139.     bsr    send
  140.     move.w    #16,d0
  141.     sub.w    rows,d0
  142.     bra    send
  143.  
  144. **************************************
  145.  
  146. putline:
  147.     move.l    lineptr,a0
  148.     move.w    #0,twidth
  149.     move.w    #7,d1
  150. print0:    move.w    width,d0
  151. print1:    tst.b    -1(a0,d0.w)
  152.     bne    print2
  153.     subq.w    #1,d0
  154.     bne    print1
  155. print2:    cmp.w    twidth,d0
  156.     blt    print3
  157.     move.w    d0,twidth
  158. print3:    move.w    rows,d3
  159. pri1:    add.w    width,a0
  160.     sub.w    #1,d3
  161.     bgt    pri1
  162.     dbf    d1,print0
  163. *
  164.     tst.w    twidth
  165.     beq    endline
  166.  
  167.     move.b    #ESC,d0
  168.     bsr    send
  169.     move.w    grmode,d0
  170.     bsr    send
  171.  
  172.     move.w    twidth,d0        ;send number of graphic bytes to follow
  173.     lsl.w    #3,d0
  174.     bsr    send
  175.     move.w    twidth,d0    
  176.     lsr.w    #5,d0
  177.     bsr    send
  178.  
  179.     move.w    twidth,d2                 ;length of the data in byte
  180. print4:    move.w    d2,-(sp)
  181.     moveq    #7,d4
  182. print6:    move.w    d4,pixel
  183.     moveq    #7,d1
  184.     moveq    #0,d0
  185.     move.l    lineptr,a0
  186. s1:    btst    d4,(a0)
  187.     beq     s2
  188.     bset    d1,d0
  189. s2:
  190.     move.w    rows,d3
  191. pri2:
  192.     add.w    width,a0
  193.     sub.w    #1,d3
  194.     bgt    pri2
  195.  
  196.     dbf    d1,s1
  197.  
  198.     bsr    send
  199. *
  200.     move.w    pixel,d4
  201.     dbf    d4,print6
  202.  
  203.     add.l    #1,lineptr
  204.     move.w    (sp)+,d2
  205.     subq.w    #1,d2
  206.     bgt    print4
  207.  
  208. endline:
  209.     move.b    #ESC,d0            ;one-time paper feed of 1/144"
  210.     bsr    send
  211.     move.b    #"J",d0
  212.     bsr    send
  213.     move.b    #1,d0
  214.     bsr    send
  215.  
  216.     move.w    #CR,d0
  217.     bra    send
  218.  
  219. ************************************
  220. *
  221. * just finished describing current tile
  222. *
  223. p_endtile:
  224.     move.l    table,a0
  225.     move.l    pblockh(a0),d0
  226.     mulu    #144,d0
  227.     divu    pydpi(a0),d0
  228.     move.w    d0,scroll
  229. pend1:    tst.b    scroll
  230.     beq    pend2
  231.     move.b    #ESC,d0
  232.     bsr    send
  233.     move.b    #"J",d0
  234.     bsr    send
  235.     move.b    #255,d0
  236.     bsr    send
  237.     sub.w    #255,scroll
  238.     bra    pend1
  239. pend2:    tst.w    scroll
  240.     beq    prtok
  241.     move.b    #ESC,d0
  242.     bsr    send
  243.     move.b    #"J",d0
  244.     bsr    send
  245.     move.w    scroll,d0
  246.     bra    send
  247.     
  248. *
  249. * just finished describing all tiles for this page
  250. *
  251. p_endpage:
  252.     bra    prtok
  253.  
  254. *
  255. * finished printing the document
  256. *
  257. p_enddoc:
  258.     bra    prtok
  259.  
  260. *
  261. * user requested stop
  262. *
  263. p_break:
  264.     bra    p_endtile
  265.  
  266. ***************************************************
  267. ***    these are the send routines for the    ***
  268. ***    dot matrix driver.            ***
  269. ***************************************************
  270. *
  271. *
  272. sendline:
  273.     move.b    (a0)+,d0
  274.     beq    prtok
  275.     move.l    a0,-(sp)
  276.     bsr    send
  277.     move.l    (sp)+,a0
  278.     bra    sendline
  279. *
  280. *
  281. send:    jmp    $ffffff
  282. *
  283. *
  284. ***********************************
  285. ***                ***
  286. ***********************************
  287.  SECTION printer,DATA,PUBLIC
  288.  
  289. prntbl:    dc.l    prtok,prtok,prtok,prtok,p_init
  290.     dc.l    p_bgndoc,p_bgnpage,p_bgntile
  291.     dc.l    p_block
  292.     dc.l    p_endtile,p_endpage,p_enddoc
  293.     dc.l    p_break,p_ident
  294.  
  295.  
  296. xdpi_tbl:    dc.w    60,60,120,120,240,240,240
  297. ydpi_tbl:    dc.w    72,144,72,144,72,144,144
  298. minl_tbl:    dc.w    15,15,30,30,60,60,60
  299. minr_tbl:    dc.w    15,15,30,30,60,60,60
  300. mint_tbl:    dc.w    0,0,0,0,0,0,0
  301. minb_tbl:    dc.w    0,0,0,0,0,0,0
  302. maxw_tbl:    dc.l    480,480,960,960,1920,1920,1920
  303. maxh_tbl:    dc.l    0,0,0,0,0,0,0
  304. xover_tbl:    dc.w    0,0,30,30,60,60,60
  305. yover_tbl:    dc.w    0,50,0,50,0,50,50
  306. rowht_tbl:    dc.w    8,16,8,16,8,16,16
  307. rows_tbl:    dc.w    1,2,1,2,1,2,2
  308. grmode_tbl:    dc.w    "K","K","L","L","z","z","z"
  309.  
  310. driver:    dc.b    "Star Gemini 10x v2.0.1",0
  311.  
  312.  SECTION printer,BSS,PUBLIC
  313. table:        ds.l    1
  314. twidth:        ds.w    1
  315. pixel:        ds.w    1
  316. v_base:        ds.l    1
  317. lineptr:    ds.l    1
  318. width:        ds.w    1
  319. count:        ds.w    1
  320. grmode:        ds.w    1
  321. rows:        ds.w    1
  322. rowht:        ds.w    1
  323. scroll:        ds.w    1
  324.