home *** CD-ROM | disk | FTP | other *** search
/ PC Online 1996 October / PCO_10.ISO / filesbbs / commo.arj / COMMO.MAC < prev    next >
Encoding:
Text File  |  1996-08-24  |  23.0 KB  |  557 lines
  1.  
  2.   Most of the macros in this file support {COMMO} features, such as file
  3.   transfers and VT102 emulation.  Others are provided as examples and may need
  4.   to be modified to work for you.  More examples are shown in SAMPLES.MAC.
  5.  
  6.   See MACRO.DOC for a complete guide to programming {COMMO} macros.  Press
  7.   PgDn to view the remainder of this file.
  8.  
  9.  
  10.   ASCII Upload macro, press Alt+A
  11.   ────────────────────────────────────────────────────────────────────────────
  12.   {:ala} {ascii %uldir\} {}             ASCII Upload with upload path
  13.  
  14.  
  15.   Macro to review capture file, press Shift+F8                Program required
  16.   ────────────────────────────────────────────────────────────────────────────
  17.   {:sf8} {exec LIST %_cap /e} {}  (aka Scrollback using no RAM)       LIST.COM
  18.  
  19.  
  20.   Simple login macro, press F2
  21.   ────────────────────────────────────────────────────────────────────────────
  22.   {:nf2} {send First|~~Last|~~~~%_pas|} {}           PCBoard, Wildcat, etc.
  23.  
  24.  
  25.   Macro to list download directory, press Alt+F10
  26.   ────────────────────────────────────────────────────────────────────────────
  27.   {:af0} {exec-w dir %dldir /w} {}                 Download directory
  28.  
  29.  
  30.   Macros to load VT102/VT220/PINE keyboard files and set VT emulation
  31.   ────────────────────────────────────────────────────────────────────────────
  32.   {:vt102} {parm ,,,V} {goto ,vt102.mac}   Linked Macro is "vt102"
  33.   {:vt220} {parm ,,,V} {goto ,vt220.mac}   Linked Macro is "vt220"
  34.   {:pine}  {parm ,,,V} {goto ,pine.mac}    Linked Macro is "pine"
  35.  
  36.  
  37.   Macro to login to a PCBoard (put "pcb" in Dialing Directory macro field)
  38.   ────────────────────────────────────────────────────────────────────────────
  39.   {:pcb} {capture y,c:\commo\pcb.cap} {asci ,}
  40.          {setv ss_r,~|}
  41.          {setlook 60,hng}
  42.          {sslook ss_r,change?}
  43.          {lookfor graphics} {send y|}
  44.          {setlook 60,hng,6,n|}
  45.          {lookfor first name?}
  46.          {send First Last|~%_pas|}          <= your name here
  47.          {lookfor Main Board Command?} {}
  48.   {:hng} {hangup y} {stop}
  49.  
  50.  
  51.   CompuServe login macro (put "cis" in Dialing Directory macro field)
  52.   ────────────────────────────────────────────────────────────────────────────
  53.   {:cis} {setlook 45,hng,2,^c} {send ^c}
  54.          {capt y,c:\commo\cis.%_day}
  55.          {lookfor User ID:} {send XXXXX,XXX|}  <= Change to your user ID
  56.          {setl 20,hng} {lookfor Password:} {send %_pas|} {}
  57.  
  58.  
  59.   GEnie login macros
  60.   ────────────────────────────────────────────────────────────────────────────
  61.   {:genie-t}  (using Telnet)
  62.          {setlook 90,hng} {capt y,c:\commo\genie.%_day}
  63.          {asci ,>} {local y} {send ~H~H~H}
  64.          {lookfor u#} {send XXXXXXXX,%_pas|} {}  <= Change to your user #
  65.  
  66.   {:genie-s}  (using Sprintnet)
  67.          {setlook 90,hng} {capt y,c:\commo\genie.%_day}
  68.          {asci ,>} {local y} {lookfor connect} {send @H|}
  69.          {lookfor terminal=} {send d1|} {lookfor @} {send c genie|}
  70.          {lookfor u#} {send XXXXXXXX,%_pas|} {}  <= Change to your user #
  71.  
  72.  
  73.   Doorway Mode macro (key must be defined in COMMO.SET)
  74.   ────────────────────────────────────────────────────────────────────────────
  75.   {:al=} {doorway} {}                   Toggle Doorway Mode
  76.  
  77.  
  78.   Macro to report {COMMO} version number, press Alt+V
  79.   ────────────────────────────────────────────────────────────────────────────
  80.   {:alv} {info-d2s0 Version is %_ver} {}
  81.  
  82.  
  83.   DOWNLOAD (receive) menu macro
  84.   ────────────────────────────────────────────────────────────────────────────
  85.   {:pgd} {:mpd}
  86.    {setv _menu1,  Press "M" to change Zmodem receive mode}
  87.    {setv _menu3, Z = Zmodem batch (mode=%zr_mode)        Internal}
  88.    {setv _menu4, Y = Ymodem batch                 Internal}
  89.    {setv _menu5, G = Ymodem-G batch               Internal}
  90.    {setv _menu6, X = Xmodem-CRC (or old Ymodem)   Internal}
  91.    {setv _menu7, O = Xmodem-G                     Internal}
  92.    {setv _menu8, S = Xmodem csum                  Internal}
  93.    {setv _menu9, B = CompuServe B, B+             Overlay}
  94.   {setv _menu11,   External Protocols (program required)}
  95.   {setv _menu13, H = HS/Link              using HSLINK.EXE}
  96.   {setv _menu14, K = Kermit               using KERMIT.EXE}
  97.    {setv _mhelp,phld}
  98.    {setv _mlabel,,pcbr,,,,,pygr,phbr,,,pckr,,pmzm,,pxgr,,,,px2r,,,,,px1r,pybr,pzbr}
  99.    {setv _mcolor,%menu_clr}
  100.    {menu 18,47,DOWNLOAD Protocol Menu  F1 for Help} {return}
  101.  
  102.   Help        {:phld} {help z} {goto mpd}
  103.   Zmodem      {:pzbr} {setv pr_alarm} {setv pr_down,%dldir} {call z_recv} {}
  104.   Y batch     {:pybr} {setv pr_alarm} {setv pr_down,%dldir} {call yb_recv} {}
  105.   Y-G batch   {:pygr} {setv pr_alarm} {setv pr_down,%dldir} {call yg_recv} {}
  106.   X CRC       {:px1r} {setv pr_alarm} {call gfnd} {call xc_recv} {}
  107.   X-G         {:pxgr} {setv pr_alarm} {call gfnd} {call xg_recv} {}
  108.   X csum      {:px2r} {setv pr_alarm} {call gfnd} {call xs_recv} {}
  109.   HSLink      {:phbr} {setv pr_alarm} {setv pr_down,%dldir} {setv pr_file}
  110.                       {info-q0s0 Any files to upload?}
  111.                       {ifco ,phbr_1} {call gfnu}
  112.               {:phbr_1} {call h_recv} {}
  113.   Kermit      {:pckr} {setv pr_alarm} {setv pr_down,%dldir} {call k_recv} {}
  114.   CIS BPlus   {:pcbr} {setv pr_alarm} {setv pr_down,%dldir} {call b_recv} {}
  115.  
  116.   {:gfnd} {setv pr_file,%dldir\} {input pr_file,Enter a filename to DOWNLOAD}
  117.           {ifex %pr_file,,gf_y} {info-q0 File exists, overwrite?}
  118.           {ifco gf_y} {send ^x^x^x^x^x^x^x^x^h^h^h^h^h^h^h^h^h^h} {}
  119.   {:gf_y} {return}
  120.  
  121.  
  122.   UPLOAD (send) menu macro
  123.   ────────────────────────────────────────────────────────────────────────────
  124.   {:pgu} {:mpu}
  125.    {setv _menu1, Z = Zmodem batch                 Internal}
  126.    {setv _menu2, Y = Ymodem batch                 Internal}
  127.    {setv _menu3, G = Ymodem-G batch               Internal}
  128.    {setv _menu4, X = Xmodem-1K (old Ymodem)       Internal}
  129.    {setv _menu5, O = Xmodem-G                     Internal}
  130.    {setv _menu6, S = Xmodem                       Internal}
  131.    {setv _menu7, A = ASCII Upload                 Internal}
  132.    {setv _menu8, B = CompuServe B, B+             Overlay}
  133.    {setv _menu10,   External Protocols (program required)}
  134.   {setv _menu12, H = HS/Link              using HSLINK.EXE}
  135.   {setv _menu13, K = Kermit               using KERMIT.EXE}
  136.    {setv _mhelp,phlu}
  137.    {setv _mlabel,paus,pcbs,,,,,pybs,phbs,,,pcks,,,,px1s,,,,px2s,,,,,px1s,pybs,pzbs}
  138.    {setv _mcolor,%menu_clr}
  139.    {menu 17,47,UPLOAD Protocol Menu  F1 for Help} {return}
  140.  
  141.   Help        {:phlu} {help z} {goto mpu}
  142.   Y batch     {:pybs} {setv pr_alarm} {call gfnu} {call yb_send} {}
  143.   X-1K        {:px1s} {setv pr_alarm} {call gfnu_x} {call xk_send} {}
  144.   X           {:px2s} {setv pr_alarm} {call gfnu_x} {call x_send} {}
  145.   ASCII       {:paus} {call gfnu_x} {asci %pr_file} {}
  146.   Zmodem      {:pzbs} {setv pr_alarm} {call gfnu} {call z_send} {}
  147.   HS/Link     {:phbs} {setv pr_alarm} {setv pr_down,%dldir} {call gfnu}
  148.                       {call h_send} {}
  149.   Kermit      {:pcks} {setv pr_alarm} {call gfnu_x} {call k_send} {}
  150.   CIS BPlus   {:pcbs} {setv pr_alarm} {call gfnu_x} {call b_send} {}
  151.  
  152.   {:gfnu}   {call sel_delsend}
  153.             {setv pr_file,%uldir\}
  154.             {inst sel_up,y} {comp _pos,1} {ifco gfnu_s}
  155.   {:gfnu_f} {input pr_file,Filename to UPLOAD (end with "\" for picklist)}
  156.             {comp pr_file} {ifco gfnu_s}
  157.             {subs temp,-1,1,%pr_file}
  158.             {comp temp,\} {ifco gfnu_s}
  159.             {ifex %pr_file,,gfnu_n} {return}
  160.   {:gfnu_n} {info-d2 File not found} {goto gfnu_f}
  161.   {:gfnu_s} {inst sel_pns,y} {comp _pos,1} {ifco gfnu_p}
  162.             {call select} {goto gfnu_t}
  163.   {:gfnu_p} {exec-d %protodir\COMMOPNS.EXE %_hom%^(send^).lst -D%pr_file -S%_mod}
  164.             {setv pr_file,@%_hom%^(send^).lst}
  165.   {:gfnu_t} {comp pr_file} {ifco gfnu_c}
  166.             {ifexist %_hom^(send^).lst,,gfnu_c} {return}
  167.   {:gfnu_c} {send ^x^x^x^x^x^x^x^x^h^h^h^h^h^h^h^h^h^h}
  168.             {inform-s0d1 No files to send} {}
  169.  
  170.   {:gfnu_x} {call gfnu} {ifex %_hom^(send^).lst,,gfnu_r}
  171.             {ropen %_hom^(send^).lst,gfnu_c}
  172.   {:gfnu_a} {read pr_file} {comp pr_file} {ifco gfnu_a} {rclose}
  173.   {:gfnu_r} {return}
  174.  
  175.  
  176.   Protocol macros used for DOWNLOADING (receiving)
  177.   ────────────────────────────────────────────────────────────────────────────
  178.    These are the basic download protocol macros and may be CALLed
  179.    from anywhere. The following variables must be set (if applicable):
  180.      pr_down    download directory
  181.      pr_file    filespec (files to download)
  182.      pr_alarm   set to: 0    - alarm off
  183.                         1+   - number of rings
  184.                         null - default rings (from setup)
  185.  
  186.   Internals
  187.    {:z_recv}  {goto zmr_%zr_mode}                              Zmodem batch
  188.     {:zmr_s} {:zmr_} {rzmo %pr_down} {goto zmr_end}   Skip (default)
  189.     {:zmr_r}  {rzmo-r %pr_down} {goto zmr_end}        Resume
  190.     {:zmr_n}  {rzmo-n %pr_down} {goto zmr_end}        Rename
  191.     {:zmr_o}  {rzmo-y %pr_down} {goto zmr_end}        Overwrite
  192.     {:zmr_end} {call ring_alarm} {retu}
  193.    {:yb_recv} {rymo %pr_down} {call ring_alarm} {retu}         Ymodem batch
  194.    {:yg_recv} {rymo-g %pr_down} {call ring_alarm} {retu}       Ymodem-G batch
  195.    {:xc_recv} {rxmo-y %pr_file} {call ring_alarm} {retu}       Xmodem-CRC
  196.    {:xg_recv} {rxmo-gy %pr_file} {call ring_alarm} {retu}      Xmodem-G
  197.    {:xs_recv} {rxmo-c0y %pr_file} {call ring_alarm} {retu}     Xmodem-Csum
  198.  
  199.   HS/Link
  200.    {:h_recv} {exec-d %protodir\HSLINK.EXE -pb0x%_pad -pi%_irq -nv %pr_file -u%pr_down}
  201.              {call ring_alarm} {retu}
  202.  
  203.   Kermit
  204.    {:k_recv} {wopen %_hom%kerm_rcv.ini}
  205.              {write set file type binary}
  206.              {write set receive packet-length 1024}
  207.              {write log transaction %_uselog}
  208.              {write set com%_por \x%_pad %_irq}
  209.              {write set port %_por}
  210.              {write cd %pr_down}
  211.              {write receive}
  212.              {wclose}
  213.              {exec-d %protodir\KERMIT.EXE take %_hom%kerm_rcv.ini}
  214.              {call ring_alarm} {retu}
  215.  
  216.   CIS BPlus
  217.    {:b_recv} {exec-d %_hom%BPLUS1.POV %pr_down}
  218.              {call ring_alarm} {retu}
  219.  
  220.  
  221.   Protocol macros used for UPLOADING (sending)
  222.   ────────────────────────────────────────────────────────────────────────────
  223.    These are the basic upload protocol macros and may be CALLed
  224.    from anywhere. The following variables must be set (if applicable):
  225.      pr_down    download directory (HS/Link only)
  226.      pr_file    filespec (files to upload)
  227.      pr_alarm   set to: 0    - alarm off
  228.                         1+   - number of rings
  229.                         null - default rings (from setup)
  230.  
  231.   Internals
  232.    {:z_send}  {szmo-r %pr_file} {call ring_alarm} {retu}     Zmodem batch
  233.    {:yb_send} {symo-k %pr_file} {call ring_alarm} {retu}     Ymodem batch
  234.    {:xk_send} {sxmo-k %pr_file} {call ring_alarm} {retu}     Xmodem 1k
  235.    {:x_send}  {sxmo %pr_file} {call ring_alarm} {retu}       Xmodem
  236.  
  237.   HS/Link
  238.    {:h_send} {exec-d %protodir\HSLINK.EXE -pb0x%_pad -pi%_irq -nv %pr_file -u%pr_down}
  239.              {call ring_alarm} {retu}
  240.  
  241.   Kermit
  242.    {:k_send} {wopen %_hom%kerm_snd.ini}
  243.              {write set file type binary}
  244.              {write set send packet-length 1024}
  245.              {write log transaction %_uselog}
  246.              {write set com%_por \x%_pad %_irq}
  247.              {write set port %_por}
  248.              {write send %pr_file}
  249.              {wclose}
  250.              {exec-d %protodir\KERMIT.EXE take %_hom%kerm_snd.ini}
  251.              {call ring_alarm} {retu}
  252.  
  253.   CIS BPlus
  254.    {:b_send} {leng %pr_file} {setv temp1,\}
  255.    {:bsnd_1} {setv temp,%_len}
  256.    {:bsnd_2} {subs temp2,%temp,1,%pr_file}
  257.              {comp temp2,%temp1} {ifco bsnd_3}
  258.              {decr temp} {comp temp,0} {ifco ,bsnd_2}
  259.              {comp temp1,\} {ifco ,bsnd_3}
  260.              {setv temp1,:} {goto bsnd_1}
  261.    {:bsnd_3} {subs temp1,1,%temp,%pr_file}
  262.              {incr temp} {subs temp2,%temp,12,%pr_file}
  263.              {send %temp2|} {pause-t 4}
  264.              {exec-d %_hom%BPLUS1.POV %temp1}
  265.              {setv temp} {setv temp1} {setv temp2}
  266.              {call ring_alarm} {retu}
  267.  
  268.    {:ring_alarm} {ifer 1,ring_fail} {alarm %pr_alarm} {return}
  269.    {:ring_fail}  {alarm-f %pr_alarm} {return}
  270.  
  271.  
  272.   Zmodem like-named file menu macro
  273.   ────────────────────────────────────────────────────────────────────────────
  274.   {:pmzm}
  275.    {goto zmm_%zr_mode}
  276.   {:zmm_s} {:zmm_} {setv zmr_disp,Skip} {setv zmr_temp,s} {goto zmr_menu}
  277.   {:zmm_r} {setv zmr_disp,Resume} {setv zmr_temp,r} {goto zmr_menu}
  278.   {:zmm_n} {setv zmr_disp,Rename} {setv zmr_temp,n} {goto zmr_menu}
  279.   {:zmm_o} {setv zmr_disp,Overwrite} {setv zmr_temp,o}
  280.   {:zmr_menu}
  281.    {setv _menu1,    This parameter tells ^(COMMO^) what to}
  282.    {setv _menu2,    do when a file received with Zmodem}
  283.    {setv _menu3,    has the same name as a file that is}
  284.    {setv _menu4,    already in the download directory.}
  285.    {setv _menu6, S = Skip (do not receive the file)}
  286.    {setv _menu7, R = Resume (receive remainder of file)}
  287.    {setv _menu8, N = Rename (change last letter of name)}
  288.    {setv _menu9, O = Overwrite (replace the existing file)}
  289.    {setv _menu11,       Current setting is "%zmr_disp"}
  290.    {setv _menu13,       Press Enter to save setting}
  291.    {setv _mlabel,,,,,,,,,,,,,,zmm_n,zmm_o,,,zmm_r,zmm_s}
  292.    {setv _menter,zmr_done}
  293.    {setv _mcolor,%menu_clr}
  294.    {window-k}
  295.    {menu 17,47,Set Zmodem File Receive Mode} {goto zmr_esc}
  296.   {:zmr_done}
  297.    {setv zr_mode,%zmr_temp}
  298.   {:zmr_esc}
  299.    {setv zmr_disp} {setv zmr_temp} {wind-k0} {goto mpd}
  300.  
  301.  
  302.   File select macro used for uploading files
  303.   ────────────────────────────────────────────────────────────────────────────
  304.   {:select}
  305.         {setv fspec,*.*}    <-- Set default filespec
  306.         {setv dsksav,%_dsk} {setv dirsav,%_dir}
  307.   {:sel_curdir}
  308.         {setv drive,%_dsk} {setv path,%_dir\}
  309.         {comp pr_file} {ifco sel_nodir}
  310.         {setv path,%pr_file} {inst %pr_file,:}
  311.         {comp _pos,2} {ifco ,sel_nodrive}
  312.         {subs drive,1,2,%pr_file} {subs path,3,66,%pr_file}
  313.   {:sel_nodir}
  314.         {call sel_chkpath}
  315.   {:sel_nodrive}
  316.         {file %drive%%path%%fspec}
  317.         {ifco sel_dirok}
  318.         {info-q Directory isn't valid.  Change it?}
  319.         {ifco ,sel_exit}
  320.         {input pr_file,Enter new directory (end with "\")}
  321.         {goto sel_curdir}
  322.   {:sel_dirok}
  323.         {exec-n %drive}
  324.         {leng %path} {setv temp,%_len}
  325.         {comp path,\} {ifco sel_root} {decr temp}
  326.   {:sel_root}
  327.         {subs temp,1,%temp,%path} {exec-n cd %temp}
  328.   {:sel_disp}
  329.         {wind-k} {file-s %drive%%path%%fspec}
  330.         {comp _err,0} {ifco sel_done}
  331.         {comp _err,1} {ifco sel_escape}
  332.         {comp _err,2} {ifco sel_edit}
  333.         {comp _err,3} {ifco sel_drive}
  334.         {comp _err,4} {ifco sel_dirchg}
  335.         {comp _err,5} {ifco sel_fspchg} {goto sel_disp}
  336.   {:sel_fspchg}
  337.         {setv fspec,%_ffn} {goto sel_disp}
  338.   {:sel_dirchg}
  339.         {subs temp,2,13,%_ffn} {exec-n cd %temp} {setv path,%_dir\}
  340.         {call sel_chkpath} {goto sel_disp}
  341.   {:sel_drive}
  342.         {setv drive,%_ffn:}
  343.         {exec-n %drive} {setv path,%_dir\}
  344.         {call sel_chkpath} {goto sel_disp}
  345.   {:sel_edit}
  346.         {edit %_hom^(send^).lst} {goto sel_disp}
  347.   {:sel_escape}
  348.         {call sel_delsend} {goto sel_exit}
  349.   {:sel_done}
  350.         {setv pr_file,@%_hom%^(send^).lst}
  351.   {:sel_exit}
  352.         {exec-n %dsksav} {exec-n cd %dirsav}
  353.         {setv dsksav} {setv dirsav} {setv temp} {setv drive}
  354.         {setv path} {setv fspec}
  355.         {wind-k0} {return}
  356.   {:sel_chkpath}
  357.         {comp path,\\} {ifco ,sel_notroot}
  358.         {setv path,\}
  359.   {:sel_notroot}
  360.         {return}
  361.   {:sel_delsend}
  362.         {ifex %_hom%^(send^).lst,,sel_nolst}
  363.         {exec-n del %_hom%^(send^).lst}
  364.   {:sel_nolst}
  365.         {return}
  366.  
  367.  
  368.   Macros for Utility Menu
  369.   ────────────────────────────────────────────────────────────────────────────
  370.   {:alu}
  371.    {setv _menu1, D = add a new Dialing Directory entry}
  372.    {setv _menu2, 1 = set VT102 emulation}
  373.    {setv _menu3, 2 = set VT220 emulation}
  374.    {setv _menu4, P = set emulation for PINE system}
  375.    {setv _menu5, E = Edit an external file}
  376.    {setv _menu6, R = Run a macro}
  377.    {setv _menu7, L = Load auxiliary Macro File}
  378.    {setv _menu8, U = Unload auxiliary Macro File}
  379.    {setv _menu9, H = run MOSTHOST Host mode}
  380.    {setv _menu10,   (use I to install)}
  381.    {setv _menu11, I = Install/view MOSTHOST}
  382.    {setv _menu12, V = modify a Variable}
  383.    {setv _menu13,   (for this session only)}
  384.    {setv _menu14, S = toggle speech mode}
  385.    {setv _mhelp,uhelp}
  386.    {setv _mlabel,vt102,vt220,,ufon,uext,,,uhost,vhost,,,uload,,,,pine,,urun,uspch,,unload,mvari}
  387.    {setv _mcolor,%menu_clr}
  388.    {menu 18,43,^(COMMO^) Utility Menu} {}
  389.   {:utilbad} {setr} {info-d2 %_met} {goto alu}
  390.   {:uhelp} {help q} {goto alu}
  391.   {:urun}  {setv temp} {input temp,Enter "label" and/or ",filename"}
  392.            {setr utilbad} {goto %temp}
  393.   {:uload}  {setv temp} {input temp,Macro File to load}
  394.             {setr utilbad} {goto-f ,%temp}
  395.   {:unload} {unload} {}
  396.   {:uext}  {setv temp} {input temp,Filename to edit}
  397.            {setr utilbad} {edit %temp} {goto alu}
  398.   {:uhost} {setr utilbad} {goto bbs,mosthost.mac}
  399.   {:vhost} {setv temp,%_hom%mosthost.mac} {ifex %temp,,nohost}
  400.            {edit %temp} {goto alu}
  401.            {:nohost} {info-d2 Unable to open file} {goto alu}
  402.   {:uspch} {sfic} {goto uspch%_sfi}
  403.    {:uspch1} {beep 1,1391,1,1568,1,1760} {}
  404.    {:uspch0} {beep 1,1760,1,1568,1,1391} {}
  405.   {:mvari}
  406.    {setv _menu1, 1 = Download Path}
  407.    {setv _menu3, 2 = Upload Path}
  408.    {setv _menu5, 3 = Modem Init String}
  409.    {setv _menu7, 4 = Dialing Prefix}
  410.    {setv _menu9, 5 = Pacing Character}
  411.    {setv _mhelp,mvari}
  412.    {setv _mlabel,mvar1,mvar2,mvar3,mvar4,mvar5}
  413.    {setv _mcolor,%menu_clr}
  414.    {menu 13,27,Modify a Variable} {}
  415.   {:mvar1} {input dldir,Download Path, no "\" at end} {}
  416.   {:mvar2} {input uldir,Upload Path, no "\" at end} {}
  417.   {:mvar3} {input _modini,Modem Initialization String} {}
  418.   {:mvar4} {input _dialpf,Dialing Prefix, e.g., ATDT} {}
  419.   {:mvar5} {setv temp} {input temp,Pacing Character for ASCII Upload}
  420.            {asci ,%temp} {}
  421.   {:ufon}      Adapted from a macro by Jeff Bishop.
  422.    {setv entry} {inpu entry,The name of the system to be called}
  423.    {setv entry, %entry ^(} {setv emu_type}
  424.    {setv temp} {inpu temp,The system's phone number}
  425.    {setv entry,%entry%%temp^) ^(}
  426.    {setv temp} {inpu temp,Password for this system, Enter for none}
  427.    {setv entry,%entry%%temp^) ^(}
  428.   {:ufon_1}
  429.    {setv _menu1, 1 = Load VT102 keyboard file, set VT emulation}
  430.    {setv _menu2, 2 = Load VT220 keyboard file, set VT emulation}
  431.    {setv _menu3, P = Load PINE keyboard file, set VT emulation}
  432.    {setv _menu4, E = Enter label for your own macro}
  433.    {setv _menu6,           Press Enter for no macro}
  434.    {setv _mhelp,ufon_1}
  435.    {setv _menter,add_parm}
  436.    {setv _mlabel,add_102,add_220,,,add_own,,,,,,,,,,,add_pine}
  437.    {setv _mcolor,%menu_clr}
  438.    {menu 10,52,Choose Macro to Run When Connected} {goto add_end}
  439.   {:add_own}
  440.    {setv temp} {inpu temp,Linked Macro for this system}
  441.    {setv entry,%entry%%temp}
  442.    {goto add_parm}
  443.   {:add_pine}
  444.    {setv entry,%entry%pine} {goto add_vt}
  445.   {:add_102}
  446.    {setv entry,%entry%vt102} {goto add_vt}
  447.   {:add_220}
  448.    {setv entry,%entry%vt220}
  449.   {:add_vt} {setv emu_type,,,V}
  450.   {:add_parm}
  451.    {setv temp}
  452.    {setv _menu1,            7 = 7e1}
  453.    {setv _menu2,            8 = 8n1}
  454.    {setv _menu4,     Press Enter for default}
  455.    {setv _menter,add_p3}
  456.    {setv _mlabel,,,,,,,add_p1,add_p2}
  457.    {setv _mcolor,%menu_clr}
  458.    {menu 8,39,Choose Data Format Parameters} {goto add_end}
  459.   {:add_p1} {setv temp,7e1} {goto add_p3}
  460.   {:add_p2} {setv temp,8n1}
  461.   {:add_p3} {comp emu_type} {ifco ,add_e4}
  462.   {:ufon_2}
  463.    {setv _menu1,        A = ANSI-BBS}
  464.    {setv _menu2,        V = VT102/VT220}
  465.    {setv _menu3,        T = TTY}
  466.    {setv _menu5,   Press Enter for default}
  467.    {setv _menter,add_e4}
  468.    {setv _mhelp,ufon_2}
  469.    {setv _mlabel,add_e1,,,,,,,,,,,,,,,,,,,add_e2,,add_e3}
  470.    {setv _mcolor,%menu_clr}
  471.    {menu 9,35,Choose Terminal Emulation} {goto add_end}
  472.   {:add_e1} {setv emu_type,,,A} {goto add_e4}
  473.   {:add_e2} {setv emu_type,,,T} {goto add_e4}
  474.   {:add_e3} {setv emu_type,,,V}
  475.   {:add_e4} {setv temp,,%temp%%emu_type}
  476.    {comp temp,,} {ifco ,add_e5} {setv temp}
  477.   {:add_e5} {setv entry,%entry%^) ^(%temp^) 00/00/00}
  478.    {fonf %_fon}
  479.    {wope-a %_hom%%_fon} {writ %entry} {wclo}
  480.    {fonf %_fon}
  481.    {info-q1s0 Entry completed, add another?} {ifco ufon}
  482.   {:add_end}
  483.    {setv entry} {setv temp} {setv emu_type}
  484.    {retu}
  485.  
  486.  
  487.  Alternate Capture Options macro, press Alt+L
  488.  ───────────────────────────────────────────────────────────────────────────
  489.   {:all}
  490.   {:capmenu}
  491.     {setv _menu1, G = Get Capture File status}
  492.     {setv _menu2, O = Open/change Capture File}
  493.     {setv _menu3, C = Close Capture File}
  494.     {setv _menu4, S = set Capture Mode to SCREEN}
  495.     {setv _menu5, F = set Capture Mode to FILTER}
  496.     {setv _menu6, R = set Capture Mode to RAW}
  497.     {setv _mlabel,,,clscap,,,fltcap,stscap,,,,,,,,opncap,,,rawcap,scncap}
  498.     {setv _mcolor,%menu_clr}
  499.     {menu 10,36,Capture Options Menu} {}
  500.   {:stscap}
  501.     {goto stscap%_cfs}
  502.   {:stscap0} {setv temp,closed} {goto stscap2}
  503.   {:stscap1} {setv temp,open}
  504.   {:stscap2}
  505.     {info-d1s0 Capture File %_cap is %temp}
  506.     {goto capmenu}
  507.   {:clscap}
  508.     {capt n} {beep 1,1760,1,1568,1,1391} {}
  509.   {:fltcap}
  510.     {capm f} {goto capmenu}
  511.   {:opncap}
  512.     {setv temp,%_cap}
  513.   {:agncap}
  514.     {inpu temp,Edit and press Enter to open Capture File}
  515.     {setr badcap}
  516.     {capt y,%temp} {beep 1,1391,1,1568,1,1760} {}
  517.   {:rawcap}
  518.     {capm r} {goto capmenu}
  519.   {:scncap}
  520.     {capm s} {goto capmenu}
  521.   {:badcap}
  522.     {info-d2 %_met}
  523.     {setr} {goto agncap}
  524.  
  525.                     ──────────────────────────────
  526.                     Full Screen Editor Key Support
  527.                     ──────────────────────────────
  528.  
  529.   The following keys are used by full screen editors such as those in PCBoard,
  530.   Wildcat, RBBS and others.  They may be changed to suit your own needs (all
  531.   keys do not work with all editors -- capture the editor help info on the
  532.   BBS).  See Appendix D in COMMO.DOC for details on character representation.
  533.  
  534.   PgUp and PgDn are normally used for uploading and downloading.  To use them
  535.   for editing, change the key-labels in the menus above.
  536.  
  537.   Macro                   Key             Function
  538.   ────────────────────────────────────────────────────────────────────────────
  539.   {:hom} {send ^W} {}     Home            Start of line
  540.   {:end} {send ^P} {}     End             End of line
  541.   {:pgu} {send ^R} {}     PgUp            Page up
  542.   {:pgd} {send ^C} {}     PgDn            Page down
  543.  
  544.   {:upa} {send ^[[A} {}   Up Arrow        Cursor up
  545.   {:dna} {send ^[[B} {}   Down Arrow      Cursor down
  546.   {:lfa} {send ^[[D} {}   Left Arrow      Cursor left
  547.   {:rta} {send ^[[C} {}   Right Arrow     Cursor right
  548.  
  549.   {:cla} {send ^A} {}     ^Left Arrow     Word left
  550.   {:cra} {send ^F} {}     ^Right Arrow    Word right
  551.  
  552.   {:ins} {send ^V} {}     Insert          Toggle insert mode
  553.   {:del} {send ^G} {}     Delete          Delete character
  554.   {:cnd} {send ^K} {}     ^End            Delete to end of line
  555.  
  556.                                 - end -
  557.