home *** CD-ROM | disk | FTP | other *** search
/ NetNews Usenet Archive 1992 #26 / NN_1992_26.iso / spool / comp / os / vms / 17955 < prev    next >
Encoding:
Internet Message Format  |  1992-11-14  |  10.3 KB
  1. Path: sparky!uunet!charon.amdahl.com!pacbell.com!ames!saimiri.primate.wisc.edu!zaphod.mps.ohio-state.edu!cs.utexas.edu!asuvax!ncar!noao!arizona!sunquest!spades.aces.com!gavron
  2. From: gavron@spades.aces.com (Ehud Gavron 602-570-2000 x. 2546)
  3. Newsgroups: comp.os.vms
  4. Subject: Re: VMSMAIL: %MAIL-E-NOTISAM (file organization changed)
  5. Message-ID: <13NOV199210441541@spades.aces.com>
  6. Date: 13 Nov 92 17:44:00 GMT
  7. References: <1992Nov3.110813.17227@dxcern.cern.ch> <1d9islINNsqf@gap.caltech.edu> <1992Nov12.200152.11582@dxcern.cern.ch>
  8. Sender: news@cs.arizona.edu
  9. Reply-To: gavron@ACES.COM
  10. Organization: ACES Consulting Inc.
  11. Lines: 329
  12. News-Software: VAX/VMS VNEWS 1.4-b1
  13.  
  14. In article <1992Nov12.200152.11582@dxcern.cern.ch>, aimar@dxbt00.cern.ch 
  15. (Alberto Aimar SL/BT tel 2564) babbles...
  16.  
  17. #But I also got a very unpolite answer (the only one) who was posted by
  18. #carl@SOL1.GPS.CALTECH.EDU (Carl J Lydick) to whom I explain how he
  19. #could have used his spare time in better ways then posting useless insults.
  20.  
  21. Is that right?  Can you believe it?  Carl sent out USELESS insults?  I
  22. am sorry!  Really!  The thought that he would send out USELESS insults
  23. is horrifying.  Carl, did you really do this?
  24.  
  25. Listen you no good moron mail-stomping whining laut of a yoyo - Carl
  26. knows his stuff.  If he (quite correctly) took the time to point out
  27. WHERE your head is up your ASS then perhaps you should take his
  28. advice and PULL IT OUT instead of whining about Carl being a bad boy.
  29.  
  30. #As most of you will not care about Carl's problems,
  31.  
  32. Carl isn't the one who posted the stupid problem - you were.  Next time
  33. don't scrozzle your mail file and try and blame Carl for your inadequacies.
  34. When he points out to you that you include no information, bow respectfully
  35. and say "thank you", don't be a smart ass, because since you aren't smart,
  36. you just end up as an ass.
  37.  
  38.  
  39. #Sincerely Alberto Aimar.
  40. # 
  41. #        ``Carl, my dear, why dont you go to see a good doctor ?''
  42.  
  43. Alberto.  My dear.  Why don't you pick on someone your own size.  Pee Wee.
  44.  
  45. #Alberto Aimar.                "Who Wills, Can
  46. #aimar@vxcrna.cern.ch           Who Tries, Does
  47. #CERN Geneva (CH)               Who Loves, Lives" (Anne McCaffery)
  48.  
  49. It's sad when the rifraff come out and play.  Still it happens every
  50. September. 
  51.  
  52. Ehud
  53.  
  54. --
  55. Ehud Gavron        (EG76)     
  56. gavron@aces.com
  57. I liked it so much I bought the company.
  58.  
  59. Obligatory technical info:
  60.  
  61.     .TITLE    CHECK_EXE$GRANT_LICENSE    List all license checks on a node
  62.     .IDENT    /V1.0.0-13Nov92/
  63. ;++
  64. ;
  65. ; CHECK_EXE$GRANT_LICENSE    13-Nov-1992            Ehud Gavron
  66. ;
  67. ; For those times you want to know what licenses are seeking validation,
  68. ; this image patches the executive to notify you about license checks.
  69. ;
  70. ; Although no merchantability is expressed or implied, this
  71. ; code was developed for and will work under V5.4-2.
  72. ;
  73. ;       Ehud Gavron             gavron@Spades.ACES.COM
  74. ;
  75. ;--
  76. ; V1.0.0        Created because I'm not getting enough interesting
  77. ;               kernel-coding to do in my regular job.
  78. ;
  79. ;
  80. ; Linking modifications:
  81. ;
  82.             .link    "sys$system:sys.stb"/selective_search
  83. ;
  84. ; Definitions:
  85. ;
  86. iif ndf $opdef,    .library "sys$library:lib.mlb"
  87. iif ndf op$_jmp,    $opdef
  88. iif ndf prt$c_urkw,    $prtdef
  89. iif ndf pte$v_prot,    $ptedef
  90. iif ndf ss$_normal,    $ssdef
  91.  
  92. ;
  93. ; Offsets I stole from the VAX Architecture manual which indicate the
  94. ; location in the SCB of the pointers to the change mode handlers:
  95. ;
  96. SCB_L_CMKRNL    =    ^X40
  97. SCB_L_CMEXEC    =    ^X44
  98.  
  99. ;
  100. ; Location of vector symbol and addresses:
  101. ;
  102. fv_symbol:    .blkl    1    ; The global symbol to find the code for
  103. fv_vector:    .blkl    1    ; The address of the code
  104. ;
  105. ; Argument list to pass it to FIND_VECTOR:
  106. ;
  107. fv_arglst:    .long    2
  108.         .address fv_symbol
  109.         .address fv_vector
  110. ;
  111. ; Macros:
  112. ;
  113.     .macro    cmd_store    cmd,cmdargs    ; Store a command as a string
  114. 'cmd'_inst: 'cmd' 'cmdargs'            ; Descriptor.  Eventually this
  115. 'cmd'_len = . - 'cmd'_inst            ; will lead to a generic patch-
  116. 'cmd'_desc:    .long    'cmd'_len        ; in-memory routine.
  117.         .address 'cmd'_inst
  118.     .endm
  119.  
  120.     .macro    FIND_AND_DESTROY symb        ; A temporary macro to avoid
  121.     movl    #symb,fv_symbol            ; Having repetitious-looking
  122.     $cmkrnl_s    routin=find_vector,-    ; source-code.  This one will
  123.             arglst=fv_arglst    ; find a symbol, and call the
  124.     $cmkrnl_s    routin=fixup_k,-    ; fixup routine.
  125.             arglst=fv_arglst
  126.     .endm
  127.  
  128. ;
  129. ; Start of user-mode code:
  130. ;
  131.     .Entry    Fixup,^m<>            
  132.     find_and_destroy    exe$grant_license    ; Go patch it!
  133.     ret
  134. ;
  135. ; Start of kernel-mode code:
  136. ;
  137.     .entry    FIND_VECTOR,^m<r2,r3,r4,r5,r6,r7,r8,r9,r10,r11>
  138. ;
  139. ; Find out which system service or jump vector it is today...
  140. ;
  141.     movl    @4(ap),r7        ; Address of vector requested
  142.     cmpw    (r7),#op$_jmp!<^x9f00>    ; Check for JMP @#
  143.     beql    10$            ; It is, go use it
  144.     addl    #2,r7            ; Move past the entry mask
  145.     cmpw    (r7),#op$_jmp!<^x9f00>    ; Is it a JMP @#
  146.     beql    10$            ; Yup, go deal with it
  147.     movl    #SCB_l_cmkrnl,r10    ; Prepare for it being a CHMK
  148.     cmpb    (r7),#op$_chmk        ; Is it a CHMK #n
  149.     beql    20$            ; Yup, go deal with it
  150.     movl    #SCB_l_cmexec,r10    ; Prepare for it being a CHME
  151.     cmpb    (r7),#op$_chme        ; Is it a CHME #n
  152.     beql    20$            ; Yup, go deal with it
  153.     movl    #ss$_unsupported,-    ; Eeek, don't know what it is...
  154.         r0            ; So tell user it's unsupported
  155.     ret                ; and go back to user mode!
  156.  
  157. ;
  158. ; So now we extract the address from the JMP instruction:
  159. ;
  160. 10$:
  161.     addl2    #2,r7            ; Get nn from JMP @#nn
  162.     movl    (r7),@8(ap)
  163.     movl    r7,@4(ap)
  164.     movl    #ss$_normal,r0
  165.     ret
  166. ;
  167. ; So now we get the number of the exception...
  168. ;
  169. 20$:
  170.     addl2    #2,r7            ; Get address of #nn from CHMx #nn
  171.     movzbl    (r7),r8            ; Get nn into R8
  172. ;
  173. ; So now we find the dispatcher address
  174. ;
  175.     movl    @#exe$gl_scb,r1        ; Get address of System Control Block
  176.     addl2    r10,r1            ; Get address of correct dispatcher
  177.     movl    (r1),r1            ; Get address of exe$cmodxxxx where
  178.                     ; xxxx is either krnl or exec
  179. ;
  180. ; We look in its code for the dispatch vector table
  181. ;
  182.     movab    movaq_inst,r2        ; Address of our MOVAQ instruction    
  183.     movzwl    (r2),r5
  184.     addl3    #^xff,r1,r3        ; Address past MOVAQ fer shure
  185. 30$:
  186.     movzwl    (r1),r6
  187.     cmpw    r6,r5            ; Have we found a MOVAQ?
  188.     beql    40$            ; Yup!
  189.     aobleq    r3,r1,30$
  190.     movl    #ss$_nodata,r0        ; Whoops, couldn't find it...
  191.     ret                ; So go back to user mode... sigh
  192.  
  193. ;
  194. ; Ok, here R1 points to the start of a MOVAQ instruction that looks like:
  195. ;     MOVAQ CMOD$AR_mode_DISPATCH_VECTOR[R1],R1
  196. ; which translates to bytes:    51hhllCF417E with hhll being the offset
  197. ; from the last byte (51).  We first save this current R1
  198. ;
  199. 40$:
  200.     movl    r1,r9            ; Address of MOVAQ
  201.     movl    r1,r7            ; Saved
  202. ;
  203. ; Then we find the offset
  204. ;
  205.     addl2    #3,r9            ; Address of hhll (word)
  206.     movzwl    (r9),r3            ; R3 = offset
  207. ;
  208. ; Then we add get the address of the end of the instruction
  209. ;
  210.     addl2    #5,r7            ; Address of last byte of instruction
  211. ;
  212. ; Then we add the offset
  213. ;
  214.     addl2    r3,r7            ; R7 = CMOD$AR_mode_DISPATCH_VECTOR
  215. ;
  216. ; Then we take our CHMn code and multiply by 8 (quadword vectors) and add
  217. ;
  218.     ashl    #3,r8,r6        ; Vector offset
  219.     addl2    r6,r7            ; Our vector
  220.     addl2    #4,r7            ; The address [2nd longword of vector]
  221.     movl    (r7),@8(ap)        ; Return this address
  222.     movl    r7,@4(ap)        ; Return address of address
  223.     movl    #ss$_normal,r0
  224.     ret
  225.  
  226.  
  227.     .entry FIXUP_K,^m<r2,r3,r4,r5,r6,r7,r8,r9,r10,r11>
  228. ;++
  229. ; Make EXE$SETPRV ignore a particular username
  230. ;--
  231. ;
  232. ; Allocate a buffer in system space (nonpaged pool) to hold
  233. ; all the code to do this stuff...
  234. ;
  235.     movl    #code_len,r1
  236.     jsb    g^exe$alononpaged
  237.     blbs    r0,10$
  238.     ret
  239. ;
  240. ; Copy the code into the pool.
  241. ;
  242. 10$:    movl    r2,r6            ; Save pointer to new npagedyn
  243.     movc3    #code_len,-        ; Copy code into npagedyn
  244.         w^code,(r6)
  245. ;
  246. ; First we prepare the JMP instruction to stick in the front of the old
  247. ; EXE$GRANT_LICENSE.  We do this because it can be JSB'd to from Kernel
  248. ; mode.  If that occurs then just revectoring the CHMK vector doesn't
  249. ; help...
  250. ;
  251. ; Take the second jump at the end of the code and make it point to here...
  252. ;
  253.     addl3    #<jump2-code+2>,r6,r2
  254.     movl    r6,(r2)
  255. ;
  256. ; Now we change the jump instruction at the end to point to the real
  257. ; exe$setprv plus a couple of instructions.  Then we'll overwrite the
  258. ; first few instructions with the jump2 we prepared.  Finally at the
  259. ; end of our code segment are the instructions (from the listing) that
  260. ; we overwrote...
  261. ;
  262.     movl    @4(ap),r2        ; Address of entry point to exe$setprv
  263.     addl3    #<jump-code+2>,r6,r7    ; Address of jump data
  264.     addl3    (r2),#^x07,r3        ; R3 --> exe$grant_license+9(-2)
  265.     movl    r3,(r7)            ; Make jump go to exe$grant_license+9
  266.     movl    r2,r7            ; Save pointer
  267.     movl    (r2),r8            ; R8 --> exe$setprv
  268.     movl    #prt$c_urkw,r9            ; Set for URKW
  269.     lock    lockname=MMG,-        ; Raise IPL, acquire spinlock
  270.         lockipl=#IPL$_MMG,-
  271.         preserve=NO
  272.     jsb    g^mmg$svaptechk        ; Get SVAPTE in R3
  273.     extzv    #pte$v_prot,#pte$s_prot,(r3),r10
  274.     insv     r9,#pte$v_prot,#pte$s_prot,(r3)
  275.     invalidate_tb
  276.     movl    r8,r2
  277.     jsb    g^mmg$svaptechk
  278.     extzv    #pte$v_prot,#pte$s_prot,(r3),r10
  279.     insv     r9,#pte$v_prot,#pte$s_prot,(r3)
  280.     invalidate_tb             ; Translation Buffer Invalidate All
  281.     movl    r6,(r7)            ; Update vector
  282.     movc3    #jump_len,-
  283.         <jump2-code>(r6),(r8)    ; Put the second jump in...
  284.  
  285.     unlock    lockname=MMG,-        ; Release lock
  286.         newipl=#0
  287.     
  288.     movl    #ss$_normal,r0
  289.     ret
  290.  
  291.  
  292. ;
  293. ; The following code will be run each time EXE$GRANT_LICENSE is invoked.  It
  294. ; will spit out the name of the license on the console.
  295. ;
  296. ;
  297. code:
  298.     pushr    #^m<r0,r1,r2,r3,r4,r5,r6,r7,r8,r9>
  299. IIF DF XDELTA, JSB G^INI$BRK
  300.     movab    flag,r2        ; Are we being quiet
  301.     tstl    (r2)
  302.     beql    out        ; Yup, don't do anything
  303.     movab    stringlen,r7    ; r7 --> string length byte
  304.     movl    04(ap),r0    ; r0 --> string descriptor
  305.     movzbl    (r0),(r7)    ; string length byte set
  306.     movzbl    (r0),r8        ; r8 = length
  307.     movl    04(r0),r9    ; r9 --> string address
  308.     movab    stringbuf,r7    ; r7 --> string itself
  309.     movc3    r8,(r9),(r7)    ; copy string
  310.     find_cpu_data r6    ; r6 --> cpu database
  311.     movab    stringlen,r1    ; primary
  312.     movab    string2,r2    ; secondary
  313.     jsb    g^smp$write_opa0
  314. out:
  315.     popr    #^m<r0,r1,r2,r3,r4,r5,r6,r7,r8,r9>
  316.  
  317. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  318. ;EXE$GRANT_LICENSE+00002:  MOVAL   @#CTL$GL_KRPFL,R0
  319. ;EXE$GRANT_LICENSE+00009:  REMQUE  @04(R0),R7
  320. ;EXE$GRANT_LICENSE+0000D:  BVS     SYSLICENSE+00028
  321. ;EXE$GRANT_LICENSE+0000F:  MOVC5   #00,(R7),#00,#0200,(R7)
  322. ;
  323.     moval    @#ctl$gl_krpfl,r0
  324. ;;    remque    @04(r0),r7
  325. ;
  326. ; End of Digital code
  327. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  328.  
  329. jump:                        ; This code will jump back in
  330.     jmp    @#00000000
  331. jump_len = . - jump
  332. jump2:                        ; This jump will point to the
  333.     jmp    @#00000000            ; start of our code...
  334. Data_area:
  335. flag:    .long 1                    ; Quiet flag, 1 = noisy
  336. stringlen:    .blkb    1            ; Length of string
  337. stringbuf:    .blkb    256            ; String
  338. string2:    .ascic <013><010>
  339. code_len = . - code
  340.         cmd_store       movaq   <w^10[r1],r1>
  341.     .end     fixup
  342.  
  343.