home *** CD-ROM | disk | FTP | other *** search
/ NetNews Usenet Archive 1992 #18 / NN_1992_18.iso / spool / comp / sys / atari / 8bit / 4199 < prev    next >
Encoding:
Internet Message Format  |  1992-08-13  |  5.7 KB
  1. Path: sparky!uunet!dtix!darwin.sura.net!mips!sdd.hp.com!hpscdc!hplextra!hpl-opus!hpnmdla!frankh
  2. From: frankh@hpnmdla.sr.hp.com (Frank Hamlin)
  3. Newsgroups: comp.sys.atari.8bit
  4. Subject: Re: Math Progs for the 8-bit
  5. Message-ID: <800016@hpnmdla.sr.hp.com>
  6. Date: 13 Aug 92 15:21:24 GMT
  7. References: <9208120111.AA20305@nettlerash.berkeley.edu>
  8. Organization: Hewlett-Packard, Santa Rosa, CA
  9. Lines: 162
  10.  
  11. > In comp.sys.atari.8bit, bp112@cleveland.Freenet.Edu (Steven C. Lin) writes:
  12. > 
  13. > 
  14. > >In a previous article, frankh@hpnmdla.sr.hp.com (Frank Hamlin) says:
  15. > 
  16. > >Or you could let BASIC do it for you, and the program becomes trivial.
  17. > >About 5 years ago my son was learning to graph, so I wrote such a program
  18. > >that finds mins, max, differentiates, finds mins & max of the
  19. > >differential, and plots the equation.  I haven't done anything with the
  20. > >Atari in over 3 years, so I do not know if I still have this.  If I find
  21. > >it, I will post the program.
  22. > >
  23. > I too have written programs that find the DEFINITE integral and/or NUMERIC
  24. > derivative of a function at a certain point.  But, from what I have seen
  25. > of Derive/Mathematica type programs (which the original post refered to),
  26. > they are able to find the INDEFINITE integral and/or the indefinite (is
  27. > that the right term?) derivitive, that is, the function that expresses the
  28. > int. or der., not just the answer... But if all you want is the numeric
  29. > answers, or a function grapher, yes, Atari BASIC will do the job with not
  30. > very much problem at all!
  31. > 
  32. > Steve Lin
  33. > bp112@cleveland.freenet.edu
  34. > -- 
  35.  
  36. This program will not give you a function that expresses the int. or
  37. der.,  but it plots the function, gives the roots, and gives the mins
  38. and maxs.  DEFINITE integral and/or NUMERIC derivative of a function at
  39. a certain point would be easy to add.  I just put this together so my
  40. son would have fun with plotting.  The program was written in TURBO
  41. BASIC.  I stole the plotting section from another program.  The equation
  42. being solved in in line 30
  43.  
  44.  
  45.  
  46. 10 GO# BEGIN
  47. 20 PROC F_X:REM FUNCTION in 21-49
  48. 30   FUNCTION=4*X^5-13*X^4+18*X^2-3
  49. 50 ENDPROC 
  50. 60 GRAPHICS 0
  51. 70 REM *** GRAPHING PROGRAM ***
  52. 80 REM *** INITIAL CONSTANTS ***
  53. 90 X1=-20:X2=20:Y1=-10:Y2=10:XIN=1:YIN=1
  54. 100 LIST 20,50
  55. 110 PRINT "WINDOW (X1,X2,Y1,Y2)";
  56. 120 TRAP 150
  57. 130 INPUT X1,X2,Y1,Y2
  58. 140 IF X2-X1=0 OR Y2-Y1=0 THEN 110
  59. 150 PRINT CHR$(125);"INTERVAL (X AXIS,YAXIS)";
  60. 160 TRAP 190
  61. 170 INPUT XIN,YIN
  62. 180 IF XIN<=0 OR YIN<=0 THEN 150
  63. 190 GRAPHICS 8:SETCOLOR 2,8,4:SETCOLOR 1,0,14:COLOR 1:POKE 752,1
  64. 200 REM *** DRAW AXES ***
  65. 210 XTOP=Y2/(Y2-Y1)*159
  66. 220 IF Y2<0 THEN XTOP=0
  67. 230 IF Y1>0 THEN XTOP=159
  68. 240 YSIDE=ABS(X1)/(X2-X1)*319
  69. 250 IF X1>0 THEN YSIDE=0
  70. 260 IF X2<0 THEN YSIDE=319
  71. 270 PLOT 0,XTOP:DRAWTO 319,XTOP:PLOT YSIDE,0:DRAWTO YSIDE,159
  72. 280 REM *** DRAW TIC MARKS ***
  73. 290 TIC1=XTOP-1*(XTOP>0):TIC2=XTOP+1*(XTOP<159)
  74. 300 FX=INT(X2/XIN)*XIN
  75. 310 XV=(FX-X1)/(X2-X1)*319:IF XV<0 THEN 340
  76. 320 PLOT XV,TIC1:DRAWTO XV,TIC2
  77. 330 FX=FX-XIN:GOTO 310
  78. 340 TIC1=YSIDE-1*(YSIDE>0):TIC2=YSIDE+1*(YSIDE<319)
  79. 350 FY=INT(Y2/YIN)*YIN
  80. 360 YV=(Y2-FY)/(Y2-Y1)*159:IF YV>159 THEN 400
  81. 370 PLOT TIC1,YV:DRAWTO TIC2,YV
  82. 380 FY=FY-YIN:GOTO 360
  83. 390 REM *** GRAPH FUNCTION ***
  84. 400 PRINT CHR$(125):LIST 20,40
  85. 410 TRAP 510
  86. 420 C=0:FLAG=1
  87. 430 FOR X=X1 TO X2 STEP (X2-X1)/319
  88. 440   EXEC F_X
  89. 450   IF FLAG THEN PLOT C,(Y2-FUNCTION)/(Y2-Y1)*159:FLAG=0:GOTO 470
  90. 460   DRAWTO C,(Y2-FUNCTION)/(Y2-Y1)*159
  91. 470   C=C+1
  92. 480 NEXT X
  93. 490 POKE 752,0:GOTO 110
  94. 500 REM *** ERROR HANDLER ***
  95. 510 TRAP 510:FLAG=1
  96. 520 GOTO 470
  97. 530 PROC F_X2
  98. 540   X=X-CHANGE:EXEC F_X:YTEMP=FUNCTION
  99. 550   X=X+2*CHANGE:EXEC F_X
  100. 560   FUNCTION=(FUNCTION-YTEMP)
  101. 570 ENDPROC 
  102. 580 # BEGIN
  103. 590 GRAPHICS 0
  104. 600 ? "CLS":LIST 20,50
  105. 610 CHANGE=1E-06
  106. 620 ? :? "Input a (1) for F(x)=0 you give (x)"
  107. 630 ? "Input a (2) for F(x)=0 you give range"
  108. 640 ? "Input a (3) for F'(x)=0 "
  109. 650 ? "Input a (4) to plot the function"
  110. 660 GET TEMP:TRAP 600:TEMP=VAL(CHR$(TEMP))
  111. 670 TRAP 40000:IF TEMP<1 OR TEMP>4 THEN 600
  112. 680 ON TEMP EXEC FUNCT_0,RANGE1,FUNCT_1
  113. 690 IF TEMP=4 THEN 60
  114. 700 END 
  115. 710 PROC FUNCT_0
  116. 720   INPUT "What is your starting X";X1:X0=999999
  117. 730   ? "CLS":? :? :LIST 20,50
  118. 740   EXEC FUNCT
  119. 750   ? :? " FUNCTION=0 @ X = ";X0
  120. 760 ENDPROC 
  121. 770 PROC FUNCT_1
  122. 780   ? "CLS":? :? :LIST 20,50
  123. 790   INPUT "Input the range of (X) to search.     Xmin, Xmax";XMIN,XMAX
  124. 791   X=XMIN:EXEC F_X2:Y2=FUNCTION
  125. 792   X=XMAX:EXEC F_X2
  126. 793   IF Y2>0 AND FUNCTION>0 THEN GO# BAD_INPUT
  127. 794   IF Y2<0 AND FUNCTION<0 THEN GO# BAD_INPUT
  128. 795   IF XMAX<=XMIN THEN GO# BAD_INPUT
  129. 796   YMAX=FUNCTION
  130. 797   IF YMAX=0 THEN X=XMAX:FUNCTION=0:GOTO 810
  131. 800   EXEC FUNCT2
  132. 810   ? :? " SLOPE= 0  @ X = ";X
  133. 820 ENDPROC 
  134. 821 # BAD_INPUT
  135. 822 ? "Xmax is not greater than Xmin, or the slope is in the same direction at     both points"
  136. 823 PAUSE 200:GOTO 780
  137. 830 PROC FUNCT
  138. 840   REPEAT 
  139. 850     X0=X1
  140. 860     X=X1:EXEC F_X:Y=FUNCTION
  141. 870     X=X1+CHANGE:X2=X:EXEC F_X:Y2=FUNCTION
  142. 880     X=X1-CHANGE:X3=X:EXEC F_X:Y3=FUNCTION
  143. 890     X1=X1-(Y/((Y2-Y3)/(X2-X3)))
  144. 900   UNTIL ABS(X1-X0)<CHANGE
  145. 910 ENDPROC 
  146. 920 PROC NONE
  147. 930   ? "NOT YET IMPLEMENTED"
  148. 940 ENDPROC 
  149. 950 PROC RANGE1
  150. 960   ? "CLS":? :LIST 20,30
  151. 970   INPUT "Input the range to search for roots     Xmin, Xmax";XMIN,XMAX
  152. 980   XCHANGE=(XMAX-XMIN)/100
  153. 990   XTEMP=XMIN
  154. 1000   WHILE XTEMP<=XMAX
  155. 1010     XMIN=XTEMP:XTEMP=XTEMP+XCHANGE
  156. 1020     X=XMIN:EXEC F_X:Y=FUNCTION
  157. 1030     X=XTEMP:EXEC F_X
  158. 1040     IF Y>=0 AND FUNCTION>=0 THEN 1080
  159. 1050     IF Y<=0 AND FUNCTION<=0 THEN 1080
  160. 1060     X1=(XMIN+XTEMP)/2:EXEC FUNCT
  161. 1070     ? :? " FUNCTION=0 @ X = ";X
  162. 1080   WEND 
  163. 1090 ENDPROC 
  164. 1100 PROC FUNCT2
  165. 1110   CHANGE2=(XMAX-XMIN)/2
  166. 1120   WHILE CHANGE2>1E-08
  167. 1130     X=XMIN+CHANGE2:EXEC F_X2:CHANGE2=CHANGE2/2
  168. 1140     IF FUNCTION<0 AND YMAX>0 THEN XMIN=XMIN+2*CHANGE2
  169. 1150     IF FUNCTION>0 AND YMAX<0 THEN XMIN=XMIN+2*CHANGE2
  170. 1160     IF FUNCTION=0 THEN CHANGE2=0
  171. 1170   WEND 
  172. 1180 ENDPROC 
  173.