home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
DOS/V Power Report 1998 January (DVD)
/
VPR980100.ISO
/
OLS
/
WIN32
/
KAKIMAC
/
KAKIMACG.LZH
/
K_GREP3.MAC
next >
Wrap
Text File
|
1995-12-21
|
21KB
|
629 lines
// k_GREP3.mac
// ★変更可能な変数★ //
#maxHidemaru=10; //一度に開ける秀丸の数。(通常は10ですが、各自の環境により、10以上開いても安定である場合はもっと大きくしてください)
// [3.タイプイン方式]限定版
$sBuffer=searchbuffer;#sFlug=searchoption;
#hwndOrg=hidemaruhandle(0);
disablebreak;
top_grep:
while(1){
$outExtensionOrg="COM;EXE;DIC;DLL;FON;DRV;VBX;TTF;HLP;";
$f0=hidemarudir+"\\kakimac\\k_grep00.kdf";
#outExtensionYN=getininum($f0,"IT0","outExtensionYN");
#showWide=getininum($f0,"IT0","HMSIZE");
#historyFileYN=getininum($f0,"IT0","historyFileYN");
if(#outExtensionYN){
$outExtension=getinistr($f0,"IT0","outExtension");
if($outExtension=="")$outExtension=$outExtensionOrg;
}
setGrepCondition1:
$TitleS="[タイプイン方式]";
$startDirIni=getinistr($f0,"IT0","startDirctory");
call checkOfRootDirOfINI $startDirIni;
$startDirInI=$$return;
$fileWildCardIni=getinistr($f0,"IT0","fileWildCard");
#subdirYN=getininum($f0,"IT0","subdirYN");
#regularYN=getininum($f0,"IT0","regularYN");
$sT0Ini=getinistr($f0,"IT0","sTarget0");
$sT1Ini=getinistr($f0,"IT0","sTarget1");
$sT2Ini=getinistr($f0,"IT0","sTarget2");
if(!#subdirYN)$mL1=" ◎ &D. grepを開始するディレクトリ= "+$startDirIni;
else $mL1=" ◎ &D. grepを開始するディレクトリ= "+$startDirIni+" ...<<subdir>>";
if(!#regularYN){
$mL3=" ◎ &1. 第1(最稀少)検索文字列= "+$sT0Ini;
$mL4=" ◎ &2. 第2(最必須)検索文字列= "+$sT1Ini;
$mL5=" ○ &3. 第3(次限定)検索文字列= "+$sT2Ini;
}else{
$mL3=" ◎ &1. 第1(最稀少)検索文字列= "+$sT0Ini+" ...<<regular>>";
$mL4=" ◎ &2. 第2(最必須)検索文字列= "+$sT1Ini+" ...<<regular>>";
$mL5=" ○ &3. 第3(次限定)検索文字列= "+$sT2Ini+" ...<<regular>>";
}
menu
"●ファイル検索の条件設定 "+$TitleS+" k_GREP Ver0.90 水銀水",
$mL1,
" ◎ &F. 検索ファイルワイルドカード指定= "+$fileWildCardIni,
$mL3,$mL4,$mL5,
"━━━━━━━━━━━━━━━━━━━━━━━━━━━",
"───[ k_GREP実行 &G ]───────────────",
"━━━━━━━━━━━━━━━━━━━━━━[停止 &e ]━",
"───────────[拡張設定 &s]──────────";
if(result==0){endmacroall;goto setGrepCondition1;//whle-result のバグ(Ver.1.41?)回避
}else if(result==1){
call dispMSG 1;
message "●k_GREP Ver.1 ファイル検索の秘訣\n"+
"────────────────────────\n"+
"[高速検索の秘訣]..."+
"k_GREPの実効速度を決定するのは、\n(1)の最稀少文字列の選定です。"+
"\n 検索する文字列の中でできるかぎり「検出したいファ\nイル以外のファイルには、もっとも出現しないであろう\nと思われる文字列」(最稀少文字列)を(1)で指定する事\nが、スピードアップの秘訣です!!!\n"+
"────────────────────────\n"+
" Special Thanks to masasan in Seattle, U.S.A.\n"+
"(C)94,95 水銀水(Suigwinsui)/小田明夫(HGD01603)";
goto setGrepCondition1;
}else if(result==2){call getStartDir;goto setGrepCondition1;
}else if(result==3){call getFileWildcard;goto setGrepCondition1;
}else if(result==4){call set1stStrings;goto setGrepCondition1;
}else if(result==5){call set2ndStrings;goto setGrepCondition1;
}else if(result==6){call set3rdStrings;goto setGrepCondition1;
}else if(result==7){goto setGrepCondition1;
}else if(result==8){
call setNew101;
call wordCheck;
if(##return)break;
else goto setGrepCondition1;
}else if(result==9){
goto ending;
}else if(result==10){
execmacro "k_GREPst.mac";
}call setNew101;
if($startDir==""||$fileWildCard==""||$sT0==""||$sT1==""){
call dispMSG 2;
}
}
call ckeckFirstGrepOKFiles;//1回目のgrep結果からファイル名取得
checkStrings2://ファイルに含まれる文字列をチェック
call checkFileByString2;//第二文字列、第三文字列での再検索(全ファイルオープンによる)
call firstInformation;
if(##return)goto top_grep;
#fsn=#fsn0;//現在までに開かれているファイルの数
call dispResultOfFilesList;
goto ending;
setNew101:
$startDir=$startDirIni;
$fileWildCard=$fileWildCardIni;
$sT0=$sT0Ini;
$sT1=$sT1Ini;
$sT2=$sT2Ini;
return;
wordCheck:// .Doc .DOc .DoC .DO? .d* などには未対応(^^;
##p1=strstr($fileWildCard,".doc");
##p2=strstr($fileWildCard,".DOC");
##p=##p1*##p2;
if(##p<0){
question "●注意...検索ファイルの拡張子が\"DOC\"になっています。\n"+
"●説明...MS-WORDのファイルも検索対象に含んでしまいます。秀丸grepは、掟破り(推奨仕様外)であり(^^;、私の知る限りにおいて、あまり知られてもいないマイナーな使い方なんですけど、事実上、MS-WORDのファイルも検索できてしまいます。しかも、表題や著作名に記載されている文字列まで検索対象にしよりまんねん。ごっつい検索やりよりまぁ。\n"+
"●確認...まあ、検索スピードはえろお遅なりますけど。で、危ないのを承知でgrepしてもぉて、ほんま、よろしゅおまんねんな? ";
if(result)return 1;
else return 0;
}else return 1;
ending:
if(#changeFileName){
#hwndNow=hidemaruhandle(0);
if(#hwndOrg!=#hwndNow)setactivehidemaru #hwndOrg;
changename "";
insertfix "a";// (無題)(変更)の表示の(変更)を消すための操作(^^;ゞ
undo;
if(#hwndOrg!=#hwndNow)setactivehidemaru #hwndNow;
}
setsearch $sBuffer,#sFlug;
title " ";
title 1;
endmacroall;
checkFileByString2:
title "●第二検索文字列などで検索を開始...[Esc]中断";
#MaxfNum=#fNum;
#fsn0=0;
#i=1;
while(#i<=#MaxfNum){
disablebreak;
#gk=keypressed;
if(#gk==0x1B||#breakON==1){#breakON=1;break;}
if(findhidemaru($ffName[#i])==-1){
if($CurentFileON==$ffName[#i]){
#existedFile=1;
call check_ffNameOK_CaseOfOpenedFile;
}else{
#existedFile=0;
openfile "/h "+$ffName[#i];
if(!result){
call dispMSG 3;
setsearch $sBuffer,#sFlug;
endmacroall;
}
call check_ffNameOK_CaseOfOpenedFile;
}
}else{
#existedFile=1;
setactivehidemaru findhidemaru($ffName[#i]);
call check_ffNameOK_CaseOfOpenedFile;
}
if(#ffNameOK==1){
#MaxffNumY=#MaxffNumY+1;
if(#existedFile){
#fsn0=#fsn0+1;
if($CurentFileON==$ffName[#i]){
$Mcheck[#MaxffNumY]="◎";
#nijuu=#MaxffNumY;
}else{
$Mcheck[#MaxffNumY]="○";
}
#openFileYN[#MaxffNumY]=1;
#openFileNumSN[#fsn0]=#MaxffNumY;
}else{
#openFileYN[#MaxffNumY]=0;
$Mcheck[#MaxffNumY]="□";
}
$ffNameMenu[#MaxffNumY]=$Mcheck[#MaxffNumY]+$ffName[#i];
$ffNameBody[#MaxffNumY]=$ffName[#i];
}
if($CurentFileON!=$ffName[#i]){
setactivehidemaru 1;
if(!#existedFile){closehidemaruforced #hwndGrepOK1;disablebreak;}
}
#gk=keypressed;
if(#gk==0x1B||#breakON==1){#breakON=1;break;}
title "● k_GREP 検索完遂度 [ "+str((100*#i)/#MaxfNum)+"%完了 ] (検出="+str(#MaxffNumY)+") [Esc:中断]";
#i=#i+1;
}
return;
ckeckFirstGrepOKFiles://1回目のgrep結果からファイル名取得
disabledraw;
$CurentFileON=filename;
title "●第一検索文字列のgrepの実行中...[Esc]中断";
#hwndNOW=hidemaruhandle(0);
if(filename!=""){
openfile "/(1500,1500,100,100)";
}else{// 無題秀丸の場合は、無題を(ダミー)に換えて、k_GREP終了時に無題に戻す
changename "k_GREP.tmp";
#changeFileName=1;
openfile "/(1500,1500,1600,1600)";
}
#n1=1;
#n0=0;
#hwndGREPc=hidemaruhandle(0);
$$gBuffer=searchbuffer;##gFlug=searchoption;
if(#subdirYN){//★注意!『grepのパラメタは、いわゆるマクロ展開ができないので、文字型変数では設定出来ない。また、findup/downのようにsetsearchも当然効かない。』
if(!#regularYN)grep $sT0,$fileWildCard,$startDir,subdir,filelist;//この場合は([0-9]+)
else grep $sT0,$fileWildCard,$startDir,regular,subdir,filelist;//この場合は([0-9]+)
}else{
if(!#regularYN) grep $sT0,$fileWildCard,$startDir,filelist;//
else grep $sT0,$fileWildCard,$startDir,regular,filelist;//
}
setsearch $$gBuffer,##gFlug;
if(result==-1){
message "●報告...k_GREPは、第一段階のgrep実行中に途中停止されました。\n"+
"●対応...はじめの条件設定の画面に戻ります。";
setactivehidemaru #hwndNOW;
closehidemaruforced #hwndGREPc;
setsearch $sBuffer,#sFlug;
title " ";
title 1;
goto top_grep;
}else if(!result){
if(#subdirYN==1)$sD="および以下のディレクトリからは";else $sD="では";
message "●検索結果\n第一指定の検索文字列『"+$sT0+"』を含むファイル("+$fileWildCard+")は、検索を開始したディレクトリ『"+$startDir+"』"+$sD+"見つかりませんでした ... ";
setactivehidemaru #hwndNOW;
closehidemaruforced #hwndGREPc;
setsearch $sBuffer,#sFlug;
title " ";
title 1;
goto top_grep;
}
#hwndGrep=hidemaruhandle(0);
setactivehidemaru #hwndNOW;
title "●結果を整理しています...[Esc]中断";
setactivehidemaru #hwndGrep;
disablebreak;
gofiletop;
while(1){
#gk=keypressed;
if(#gk==0x1B||#breakON==1){#breakON=1;break;}
searchdown "\\([0-9]+\\)",regular;
if(!result)break;
#tex=x;#tey=y;
$ffName=gettext(0,#tey,x,#tey);
if(#outExtensionYN){
if(strstr($outExtension,midstr($ffName,strstr($ffName,".")+1,3))>=0)continue;
}
#fNum=#fNum+1;
if(!#rootDir)$ffName[#fNum]=directory+"\\"+$ffName;
else $ffName[#fNum]=directory+$ffName;
}
setactivehidemaru 1;
closehidemaruforced #hwndGrep;
return;
check_ffNameOK_CaseOfOpenedFile://既に開いているファイルの場合の調査
disablebreak;
#gk=keypressed;
if(#gk==0x1B){#breakON=1;return;}
##xO=x;##yO=y;
disableinvert;
gofiletop;
if(!#regularYN)searchdown $sT1;else searchdown $sT1,regular;
if(result){
#gk=keypressed;
if(#gk==0x1B||#breakON==1){#breakON=1;return;}
if($sT2!=""){
gofiletop;
if(!#regularYN)searchdown $sT2;else searchdown $sT2,regular;
if(result) #ffNameOK=1;
else #ffNameOK=0;
#gk=keypressed;
if(#gk==0x1B||#breakON==1){#breakON=1;return;}
}else #ffNameOK=1;
}else #ffNameOK=0;
escape;
#hwndGrepOK1=hidemaruhandle(0);
moveto ##xO,##yO;
return;
firstInformation:
if(#breakON){
message "●報告...k_GREPは、最終段階のファイル調査中に途中停止されました(;_;)\n"+
"●対応...はじめの条件設定の画面に戻ります(^^)。";
setsearch $sBuffer,#sFlug;
title " ";
title 1;
##a=1;
#breakON=0;
}
if(#MaxffNumY==0){
call dispMSG 4;
##a=1;
}
return ##a;
dispResultOfFilesList:
disablebreak;
$ffNameMenu[0]="● k_GREP 結果リスト (検出="+str(#MaxffNumY)+") (C) 水銀水";
$ffNameMenu[#MaxffNumY+1]="──────────────────────";
if(!#mop){
$ffNameMenu[#MaxffNumY+2]="━━━━━[結果の拡張処理 &option ]━━━━━━";
$ffNameMenu[#MaxffNumY+3]="━━━━━━━[k_GREP停止 &e]━━━━━━━━━";
}else{//if(#mop)
$ffNameMenu[#MaxffNumY+2]="━━[リストをk_GREP履歴ファイルへ追加 &log]━━";
$ffNameMenu[#MaxffNumY+3]="━━━[リストをクリップボードへ転送 &clip]━━━";
// $ffNameMenu[#MaxffNumY+4]="━━━━━[全検索状態の個別保存 &keep]━━━━";
// $ffNameMenu[#MaxffNumY+5]="━━━━━━[絞り込み検索 &squeeze]━━━━━━";
// $ffNameMenu[#MaxffNumY+6]="━━━━━━━━[拡張処理停止 &e]━━━━━━━";
$ffNameMenu[#MaxffNumY+4]="━━━━━━━[拡張処理停止 &e]━━━━━━━━";
}
if(!#mop)menuarray $ffNameMenu,#MaxffNumY+4;
else menuarray $ffNameMenu,#MaxffNumY+5;
if(result==0){//esc(なぜかAlt,F-10もresult==0になる)じゃ、メニュー外をクリックした場合。カレントファイルなら閲覧。それ以外はメニューループ。
//call checkFSN;
//showvars;
title " ";
title 1;
call checkCurFileNIJUU;
##checkCurFileNIJUUYN=##return;
if(##checkCurFileNIJUUYN){
if(#showWide)showwindow 3;
execmacro "k_grepLK.mac";
if(#showWide)showwindow 1;
title " ";
title 1;// k_LOOK のサブセット版
}else call dispMSG 9;
goto dispResultOfFilesList;//##result==0か、##result==1でk_greSR6を終了したか。でループ。
}else if(result==1){
title " ";
title 1;
call dispMSG 5;
goto dispResultOfFilesList;
}else if(result==#MaxffNumY+2){
title " ";
title 1;
goto dispResultOfFilesList;
}else if(result==#MaxffNumY+3){
title " ";
title 1;
if(!#mop){
#mop=1;
goto dispResultOfFilesList;
}else{
if(!#historyFileYN)call k_GREPhistory;
else call dispMSG 14;
goto dispResultOfFilesList;
}
}else if(result==#MaxffNumY+5){
title " ";
title 1;
#mop=0;goto dispResultOfFilesList;
}else if(result==#MaxffNumY+4){
title " ";
title 1;
if(!#mop){//休止
question "●確認...k_GREPを休止して本当によろしいですね";
if(result)return;//endmacroall;
else goto dispResultOfFilesList;
}else{//[リストをクリップボードへ転送 &clip]
call copyListToClip;goto dispResultOfFilesList;
}
//}else if(result==#MaxffNumY+5){
// message "■結果メニュー個別保存\n(名前を付けて、結果表示メニュー状態を保存/復元)"+
// "";
//// call setStringSaveFullSet;
//// goto dispResultOfFilesList;
// execmacro "k_grepRT";
//// endmacroall;
//}else if(result==#MaxffNumY+6){
// message "■追加(論理積/排他積)の絞り込み実行\n";
//// call setStringSqueeze;
//// goto dispResultOfFilesList;
// execmacro "k_grepSQ";
//// endmacroall;
}//else goto dispResultOfFilesList;
title " ";
title 1;
title 0;
#openFileNum=result-1;
#fsn=#fsn+1;//fsn(FilesSilialNumber)は、ここで設定すべきだろう!!!
#openFileNumSN[#fsn]=#openFileNum;
if($Mcheck[#openFileNum]=="□"){//指定ファイルが開いていない場合
if(hidemarucount>#maxHidemaru){
call dispMSG 15;
goto dispResultOfFilesList;
}
if(!#checkOfMcON)call setMarkOfOldFile;
openfile $ffNameBody[#openFileNum];
call setMarkOfCurentFile;
}else if($Mcheck[#openFileNum]=="○"){
if(!#checkOfMcON)call setMarkOfOldFile;
setactivehidemaru findhidemaru($ffNameBody[#openFileNum]);
call setMarkOfCurentFile;
}else if($Mcheck[#openFileNum]=="◎"){
call setMarkOfClosedFile;
call setNextActiveHM;
}else message "enable take for ... anything ...";
goto dispResultOfFilesList;
return;
checkCurFileNIJUU://現在のhidemaruorder==0のファイル名が◎と同じか?、yes=1,no=0.
if(#nijuu!=0){
if(filename==$ffNameBody[#nijuu])return 1;
else return 0;
}else return 0;
setMarkOfClosedFile:
#openFileYN[#openFileNum]=0;
$Mcheck[#openFileNum]="□";
$ffNameMenu[#openFileNum]=$Mcheck[#openFileNum]+$ffNameBody[#openFileNum];
return;
setMarkOfClosedFileReverse:
#openFileYN[#openFileNum]=1;
$Mcheck[#openFileNum]="◎";
#nijuu=#openFileNum;
$ffNameMenu[#openFileNum]=$Mcheck[#openFileNum]+$ffNameBody[#openFileNum];
return;
setNextActiveHM://#openFileSNの最大のファイルまで移動し、アクティブにする
while(1){
#fsn=#fsn-1;
if(#MaxffNumY==1||#fsn==0){
if(hidemarucount>1){
setactivehidemaru 1;
closehidemaru 1;
#openFileNum=#openFIleSN[#fsn];
}else{
call dispMSG 6;
call setMarkOfClosedFileReverse;
#fsn=1;
#openFileNumSN[#fsn]=#openFileNum;
}
call setMarkOfCurentFile;
break;
}else if(!#openFileYN[#openFileNumSN[#fsn]]){
continue;
}else if(#openFileNumSN[#fsn]==#openFileNumSN[#fsn+1]){
continue;
}else if(#openFileYN[#openFileNumSN[#fsn]]){
#closeFileHWND=hidemaruhandle(0);
#openFileNum=#openFileNumSN[#fsn];
#openFileYN[#openFileNum]=0;
setactivehidemaru findhidemaru($ffNameBody[#openFileNumSN[#fsn]]);
call setMarkOfCurentFile;
closehidemaru #closeFileHWND;
break;
}else{message "致命的なバグかも(^^)";setsearch $sBuffer,#sFlug;endmacroall;}
}
return;
setMarkOfCurentFile:
#openFileYN[#openFileNum]=1;
$Mcheck[#openFileNum]="◎";
#nijuu=#openFileNum;
$ffNameMenu[#openFileNum]=$Mcheck[#openFileNum]+$ffNameBody[#openFileNum];
return;
setMarkOfPastFile:
$Mcheck[#openFileNumSN[#fsn-1]]="□";
#openFileYN[#openFileNum]=0;
$ffNameMenu[#openFileNumSN[#fsn-1]]=$Mcheck[#openFileNumSN[#fsn-1]]+$ffNameBody[#openFileNumSN[#fsn-1]];
return;
setMarkOfOldFile:
$Mcheck[#openFileNumSN[#fsn-1]]="○";
$ffNameMenu[#openFileNumSN[#fsn-1]]=$Mcheck[#openFileNumSN[#fsn-1]]+$ffNameBody[#openFileNumSN[#fsn-1]];
return;
getStartDir:
if(imestate)imeswitch;
$startDir=input("●GREP開始のディレクトリ(フルパスでの)指定\n (ドライブ名から「フルパス」でディレクトリを指定)\n (ルートディレクトリを除き末尾の「¥」は不要)",$startDirIni);
if(!result){return;message "実行がキャンセルされました";}
if($startDir==""||strstr($startDir,":")<0){
call dispMSG 13;
goto getStartDir;endmacro;}
call checkOfRootDirOfINI $startDir;
$startDir=$$return;
writeinistr $f0,"IT0","startDirctory",$startDir;
if(imestate)imeswitch;
return;
checkOfRootDirOfINI://ルートディレクトリか否かでの¥の扱い(結果を$$startDirIniYNで返す)
$$startDirIniYN=$$1;
if(midstr($$startDirIniYN,strlen($$startDirIniYN)-1,1)=="\\"){
if(midstr($$startDirIniYN,strlen($$startDirIniYN)-2,1)!=":"){
$$startDirIniYN=midstr($$startDirIniYN,0,strlen($$startDirIniYN)-1);
#rootDir=0;
}else{
$$startDirIniYN=$$startDirIniYN;
#rootDir=1;
}
}else{
if(midstr($$startDirIniYN,strlen($$startDirIniYN)-1,1)!=":"){
$$startDirIniYN=midstr($$startDirIniYN,0,strlen($$startDirIniYN));
#rootDir=0;
}else{
$$startDirIniYN=$$startDirIniYN+"\\";
#rootDir=1;
}
}
return $$startDirIniYN;
getFileWildcard://ファイルワイルドカード指定
if(imestate)imeswitch;
$fileWildCard=input("●検索対象となるファイル名のワイルドカード指定\n 複数ワイルドカード指定は「;」で区切る\n <注意>拡張子は必ず指定して下さい!!!",$fileWildCardIni);
if(!result){return;message "実行がキャンセルされました";endmacro;}
if($fileWildCard==""){
call dispMSG 10;
$fileWildCard="*.txt";
}
writeinistr $f0,"IT0","fileWildCard",$fileWildCard;
if(imestate)imeswitch;
return;
checkRegularStr:
$$cS=$$1;
if(!#regularYN){//正規表現が設定されていない場合
if(strstr($$cS,"|")!=-1){//文字列「|」が発見された場合
question "●注意...「|」が検索文字列に含まれています。\n"+
"●理由...正規表現を使用した検索において、パターンの論理和を示すメタキャラクタ「|」が、検索文字列の中に含まれていますが、正規表現による検索は設定されていません。"+
"したがって「|」は「または」の意味では作動せず、単なる文字「|」として扱われます。\n"+
"●選択...「はい」そうです、「|」は文字列でよろしい\n 「いいえ」あぅ、忘れてた。再入力やッ"+"\n\n(なお、正規表現によるk_GREP検索は,「拡張設定」で変更できます)";
if(!result)return 0;else return 1;
}else return 1;
}else return 1;
set1stStrings://第1検索文字列指定
if(!imestate)imeswitch;
$sT0=input("●第1検索文字列指定(必須)\n検出したいファイル『以外には存在し無い』だろうと思われるできるだけ特別な文字列を入力",$sT0Ini);
if(!result){return;endmacro;message "実行がキャンセルされました";}
if($sT0==""){
call dispMSG 11;
goto set1stStrings;
}
call checkRegularStr $sT0;
if(!##return)goto set1stStrings;
writeinistr $f0,"IT0","sTarget0",$sT0;
if(imestate)imeswitch;
return;
set2ndStrings://第2検索文字列指定
if(!imestate)imeswitch;
$sT1=input("●第2検索文字列指定(必須)\n検出したい文字列で、『どうしても必要』な文字列を指定してネッ!!!",$sT1Ini);
if(!result){return;endmacro;message "実行がキャンセルされました";}
if($sT1==""){
call dispMSG 12;
goto set2ndStrings;
}
call checkRegularStr $sT1;
if(!##return)goto set2ndStrings;
writeinistr $f0,"IT0","sTarget1",$sT1;
if(imestate)imeswitch;
return;
set3rdStrings://第3検索文字列指定
if(!imestate)imeswitch;
if($sT1Ini=="")goto set2ndStrings;
$sT2=input("●第3検索文字列指定(任意)\n不必要なにに初期候補がある場合は、BackSpaceキーで消去してOKを選択",$sT2Ini);
if(!result){return;endmacro;message "実行がキャンセルされました";}
call checkRegularStr $sT2;
if(!##return)goto set3rdStrings;
writeinistr $f0,"IT0","sTarget2",$sT2;
if(imestate)imeswitch;
return;
dispMSG:
writeininum $f0,"IT0","msg",##1;
execmacro "k_grep3m.mac";
return;
outputStr02:
if(!#subdirYN)$cL1="1 grep・開始のディレクトリ= "+$startDirIni;
else $cL1="1 grep・開始のディレクトリ= "+$startDirIni+" ...<<subdir>>";
if(!#regularYN){
$cL3="3 第1(最稀少)文字列= ";
$cL4="4 第2(最必須)文字列= ";
$cL5="5 第3(次限定)文字列= ";
}else{
$cL3="3 第1(最稀少)文字列= ";$cL3L=" ...<<regular>>";
$cL4="4 第2(最必須)文字列= ";$cL4L=" ...<<regular>>";
$cL5="5 第3(次限定)文字列= ";$cL5L=" ...<<regular>>";
}
return;
copyListToClip://結果リストをクリップボードへ転送(オプションの記述は添付しない)
call outputStr02;
$$toClip="----- k_GREP Report 19"+date+time+"-----"+"\x0D\x0A"+
$cL1+"\x0D\x0A"+
"2 ファイル・ワイルドカード指定= "+$fileWildCardIni+"\x0D\x0A"+
$cL3+$sT0Ini+$cL3L+"\x0D\x0A"+
$cL4+$sT1Ini+$cL4L+"\x0D\x0A"+
$cL5+$sT2Ini+$cL5L+"\x0D\x0A";
setclipboard $$toClip;
addclipboard " 検出ファイル総数="+str(#MaxffNumY)+"個"+"\x0D\x0A";
while(##ii<#MaxffNumY){
addclipboard $ffNameBody[##ii+1]+"\x0D\x0A";
##ii=##ii+1;
}
call dispMSG 8;
return;
k_GREPhistory://履歴
#historyFileYN=getininum($f0,"IT0","historyFileYN");
if(#historyFileYN){
$historyFile=getinistr($f0,"IT0","historyFile");
}else{
$historyFile=hidemarudir+"\\k_GREP01.LOG";
}
if(!existfile($historyFile)){message "●注意k_GREPの履歴ファイル指定がないので、ログを取れません<m(_._)m>\n"+
"●対応...履歴ファイルを使用するにして、『設定』をクリックして下さい。";}
call outputStr02;
$$toHistory="----- k_GREP履歴 19"+date+time+"-----"+"\x0D\x0A"+
$cL1+"\x0D\x0A"+
"2 ファイル・ワイルドカード指定= "+$fileWildCardIni+"\x0D\x0A"+
$cL3+$sT0Ini+"\x0D\x0A"+
$cL4+$sT1Ini+"\x0D\x0A"+
$cL5+$sT2Ini+"\x0D\x0A";
openfile "/h "+$historyFile;
gofileend;
insert $$toHistory;
insert " 検出ファイル総数="+str(#MaxffNumY)+"個"+"\x0D\x0A";
while(##ii<#MaxffNumY){
insert $ffNameBody[##ii+1]+"\x0D\x0A";
##ii=##ii+1;
}
insert "\x0D\x0A";
save;
setactivehidemaru 1;
closehidemaruforced 1;
call dispMSG 7;
return;