home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Antennas
/
Antennas_CD-ROM_Walnut_Creek_September_1996.iso
/
w4mb
/
vol2
/
basic
/
sxtl.asc
< prev
next >
Wrap
Text File
|
1996-06-30
|
4KB
|
86 lines
3 CLS
10 PRINT " ***************************************************************"
20 PRINT " * SMALL TRANSMITTING LOOP ANTENNAS *"
30 PRINT " * R.P. HAVILAND, W4MB *"
40 PRINT " * PROGRAM COPYRGHT 1990 *"
50 PRINT " * MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086 *"
70 PRINT " ***************************************************************"
80 PRINT
90 DEF FNP(X)=INT(1000*X+.5)/1000
100 MTF=3.281
110 PI=3.141593
200 INPUT "ENTER DESIGN FREQUENCY, MHZ";FREQ:IF FREQ=<0 THEN 200
210 LAM=299.8/FREQ
220 MIN=LAM*.125
230 PRINT
240 PRINT " MINIMUM RECOMMENDED LOOP PERIMETER=";FNP(MIN);"METERS";
250 PRINT " OR ";FNP(MIN*MTF);"FEET"
260 PRINT " EQUIVALENT TO A SQUARE";FNP(MIN/4*MTF);" FEET ON THE SIDE"
270 PRINT " SMALLER LOOPS WILL HAVE HIGH LOSS"
280 PRINT " MAXIMUM RECOMMENDED LOOP PERIMETER=";FNP(2.4*MIN);"METERS";
290 PRINT " OR ";FNP(2.4*MIN*MTF);"FEET"
300 PRINT " EQUIVALENT TO A SQUARE";FNP(MIN/2*MTF);" FEET ON THE SIDE"
500 PRINT " LARGER LOOPS ARE USEABLE IF SPACE AND HEIGHT PERMITS"
510 INPUT " ENTER DESIGN PERIMETER, FEET";PER:IF PER<=0 THEN 510
520 PRINT " ENTER LOOP SHAPE INDICATOR"
530 PRINT " C= CIRCLE"
540 PRINT " O= OCTAGON"
550 PRINT " S=SQUARE"
560 INPUT TY$
570 ARE=0
580 INPUT " ENTER CONDUCTOR DIAMETER, INCHES";CD:IF CD<=0 THEN 700
600 IF TY$="C" THEN ARE=PER*PER/4/PI
610 IF TY$="O" THEN ARE=PER*PER/64*4.8284
620 IF TY$="S" THEN ARE=PER*PER/16
630 IF ARE=0 THEN 510
700 PRINT
710 RR=3.38E-08*(FREQ*FREQ*ARE)^2
720 RL=.000996*PER/CD*SQR(FREQ)
730 EFF=RR/(RR+RL)
740 IND=1.9E-08*PER*(7.353*LOG(96*PER/PI/CD)/2.3-6.386) 'HENRY
750 XL=2*PI*FREQ*IND*1000000!
760 TC=1/(2*PI*FREQ*XL*1000000!)*1E+12 'PF
770 Q=XL/2/(RR+RL) 'ASSUMPTION ON CAPACITOR LOSS
780 BW=FREQ*1000000!/Q
790 CDIS=.82*PER
800 FERL=6*RL
810 FEEFF=RR/(RR+FERL)
820 FEQ=XL/2/(RR+FERL)
830 FEBW=FREQ*1000000!/FEQ
1000 PRINT " LOOP AREA=";FNP(ARE);" SQ FT, OR ";FNP(ARE/MTF);"SQ METERS"
1010 PRINT " RADIATION RESISTANCE=";FNP(RR);"OHMS"
1020 PRINT " FOR COPPER CONDUCTOR"
1030 PRINT " LOSS RESISTANCE=";FNP(RL);"OHMS"
1040 PRINT " LOOP EFFICIENCY=";EFF
1050 PRINT " OR A SIZE LOSS OF ";FNP(10*LOG(EFF)/2.3);" DB"
1060 PRINT " GIVING A BANDWIDTH OF";FNP(BW);"HERTZ, OR ";FNP(BW/1000);"KHZ"
1070 PRINT " FOR IRON CONDUCTOR"
1100 PRINT " LOSS RESISTANCE=";FNP(FERL);"OHMS, FOR IRON CONDUCTOR"
1110 PRINT " LOOP EFFICIENCY=";FEEFF
1120 PRINT " OR A SIZE LOSS OF ";FNP(10*LOG(FEEFF)/2.3);" DB"
1130 PRINT " LOOP Q=";FNP(FEQ)
1140 PRINT " GIVING A BANDWIDTH OF";FNP(FEBW);"HERTZ, OR ";FNP(FEBW/1000);"KHZ"
1150 PRINT
1160 PRINT " REQUIRED TUNING CAPACITY=";FNP(TC-10);"PF, 10 PF STRAY ASSUMED"
1200 PRINT
1210 INPUT " INPUT PEAK POWER TO BE RADIATED, WATTS";PP
1220 VC=SQR(PP*XL*Q)
1230 PRINT " CAPACITOR VOLTAGE RATING, MINIMUM=";FNP(VC);"VOLTS"
1240 PRINT " WITH A MINIMUM SPACING OF ";FNP(VC*1.414/75000!);" INCHES"
1250 PRINT " DOUBLE CAPACITY AND HALVE SPACING FOR SPLIT STATOR CAPACITOR"
1300 PRINT
1310 INPUT " ENTER MAXIMUM TUNING CAPACITY, PF";CMAX
1500 MINFREQ=FREQ*SQR(TC/(CMAX+10))
1510 MAXFREQ=FREQ*SQR(TC/15)
1600 PRINT
1610 PRINT " TUNING RANGE IS";FNP(MINFREQ);" TO ";FNP(MAXFREQ);" MHZ"
1800 PRINT
1810 PRINT " *** CAUTION ***
1820 PRINT " CAREFUL CONSTRUCTION IS NEEDED TO OBTAIN CALCULATED PERFORMANCE."
1830 PRINT " SEE REFERENCE"
2000 PRINT
2010 INPUT " ENTER F= NEW FREQUENCY, S= NEW SIZE, OTHER= QUIT";T$
2020 IF T$="F" THEN 200
2030 IF T$="S" THEN 230
3000 END