home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol2 / basic / swrz.asc < prev    next >
Text File  |  1996-06-30  |  3KB  |  78 lines
  1. 1 CLS
  2. 2 PRINT "      ***********************************************************"
  3. 3 PRINT "      *           IMPEDANCE FROM SWR MEASUREMENTS               *"
  4. 4 PRINT "      *            PROGRAM BY R.P. HAVILAND, W4MB               *"
  5. 5 PRINT "      *                    COPYRGHT 1990                        *"
  6. 6 PRINT "      *       MINILAB BOOKS, DAYTONA BEACH, FL 32119-1086       *"
  7. 7 PRINT "      ***********************************************************"
  8. 10 DEF FNP(X)=INT(10*X+.5)/10
  9. 20 INPUT "ENTER Y FOR INSTRUCTIONS, ANY ELSE TO SKIP";T$
  10. 30 IF T$<>"Y" THEN 2000
  11. 100 PRINT " TO DETERMINE R,X FROM SWR MEASUREMENTS OF A TRANSMISSION LINE;"
  12. 110 PRINT "  FIRST MEASURE SWR OF LINE TO BEST ACURACY POSSIBLE"
  13. 120 PRINT "   SECONDLY, AN AUXILARY RESISTANCE MUST BE INSERTED INTO LINE"
  14. 130 PRINT "    AND THE SWR RE-MEASURED, AGAIN TO BEST ACCURACY POSSIBLE."
  15. 140 PRINT " THE AUXILARY RESISTOR MAY BE A LINE SHUNT, 100 OHMS BEING GOOD"
  16. 150 PRINT "   OR IT MAY IN SERIES WITH THE CENTER CONDUCTOR,"
  17. 160 PRINT "     27 OHMS BEING A GOOD VALUE."
  18. 170 PRINT "  THIS PROGRAM CALCULATES THE ORIGINAL RESISTANCE AND REACTANCE."
  19. 200 PRINT "   IF THE SIGN OF REACTANCE IS REQUIRED,"
  20. 210 PRINT "    A THIRD MEASUREMENT IS NEEDED, WITH A SMALL SERIES INDUCTANCE"
  21. 220 PRINT "     IN THE LINE, 0.1 MICROHENRIES BEING GOOD IN MOST CASES"
  22. 230 PRINT "      AND R,X RECALCULATED USING THE FIRST AND THIRD SWR VALUES.
  23. 240 PRINT "  IF THE MAGNITUDE OF REACTANCE HAS DECREASED"
  24. 250 PRINT "   THE ORIGINAL REACTANCE SIGN WAS NEGATIVE, OTHERWISE POSITIVE"
  25. 260 PRINT 
  26. 2000 INPUT " ENTER LINE IMPEDANCE, ZO";ZO
  27. 2010 INPUT "  ENTER 1=27 OHM SERIES RESISTOR, 2=100 OHM SHUNT";SS
  28. 2020 IF SS=1 THEN AD=27/ZO:GOTO 2050
  29. 2030 IF SS=2 THEN AD=ZO/100:GOTO 2050
  30. 2040 GOTO 2010
  31. 2050 PRINT:INPUT " ENTER LINE SWR";W1
  32. 2060 IF W1<1 THEN PRINT " NOT POSSIBLE":GOTO 2050
  33. 2070 INPUT "  ENTER SWR WITH ADDED RESISTOR";W2
  34. 2080 IF W1<1 THEN PRINT " NOT POSSIBLE":GOTO 2070
  35. 2090 PRINT 
  36. 2100 R1=(W1-1/W1)/2
  37. 2110 A1=(W1+1/W1)/2
  38. 2120 R2=(W2-1/W2)/2
  39. 2130 A2=(W2+1/W2)/2-AD
  40. 2140 RT=(R1*R1-R2*R2-A1*A1+A2*A2)/(A2-A1)/2
  41. 2150 XT=R1*R1-(RT-A1)^2
  42. 2160 IF RT<0 OR XT<0 THEN GOSUB 3000
  43. 2170 IF XT<0 THEN XT=-XT
  44. 2180 XT=XT^.5
  45. 2190 IF SS=1 THEN 2230
  46. 2200 PRINT " LOAD CONDUCTANCE=";RT*1000/ZO;"MILLIMHOS"
  47. 2210 PRINT "      SUSCEPTANCE=";XT*1000/ZO;"MILLIMHOS"
  48. 2220 GOTO 2250
  49. 2230 PRINT " LOAD RESISTANCE=";RT*ZO;"OHMS"
  50. 2240 PRINT "       REACTANCE=";XT*ZO;"OHMS"
  51. 2250 PRINT 
  52. 2260 PRINT " REPEAT WITH ADDED INDUCTANCE FOR REACTANCE SIGN."
  53. 2300 PRINT
  54. 2310 PRINT "   R=REPEAT ALL"
  55. 2320 PRINT "   S=NEW SWR VALUE"
  56. 2330 PRINT "   Q=QUIT";
  57. 2340 INPUT S$
  58. 2350 IF S$="R" THEN  2000
  59. 2360 IF S$="S" THEN 2050
  60. 2370 IF S$<>"Q" THEN 2300
  61. 2500 STOP
  62. 3000 CLS
  63. 3010 PRINT " MEASUREMENTS APPEAR TO BE IN ERROR."
  64. 3020 PRINT "  THIS IS POSSIBLY DUE TO ANTENNA CURRENTS ON TRANSMISSION LINE."
  65. 3030 PRINT "   CHECK BY REVERSING LINE AND LOAD CONNECTIONS TO SWR BRIDGE."
  66. 3040 PRINT "    IF NEW REFLECTED READING IS NOT SAME AS OLD FORWARD,"
  67. 3050 PRINT "      THIS PROBLEM EXISTS."
  68. 3060 PRINT " CHECK FOR POOR SHIELD CONNECTIONS, LACK OF GROUNDING, ETC."
  69. 3070 PRINT 
  70. 3080 PRINT "CALCULATED VALUES ARE PRINTED FOR INFORMATION,"
  71. 3090 PRINT "  BUT MAY BE SERIOUSLY IN ERROR."
  72. 3100 PRINT 
  73. 3110 IF RT<0 THEN PRINT " THE ERROR AFFECTS RESISTANCE CALCULATION.":PRINT 
  74. 3120 IF XT<0 THEN PRINT " THE ERROR AFFECTS REACTANCE CALCULATION.":PRINT 
  75. 3200 INPUT " PRESS ENTER TO CONTINUE";T$
  76. 3210 RETURN
  77. 4000 END
  78.