home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol2 / basic / stub.asc < prev    next >
Text File  |  1996-06-30  |  4KB  |  106 lines
  1. 1 CLS
  2. 2 PRINT "   ***************************************************************"
  3. 3 PRINT "   *                      STUB MATCH                             *"
  4. 4 PRINT "   *             REFERENCE- KING, MIMN0, WING                    *"
  5. 5 PRINT "   *       TRANSMISSION LINES, ANTENNAS AND WAVE-GUIDES          *"
  6. 6 PRINT "   *            PROGRAM BY R.P. HAVILAND, W4MB                   *"
  7. 7 PRINT "   *                    COPYRGHT 1990                            *"
  8. 8 PRINT "   *       MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086           *"
  9. 9 PRINT "   ***************************************************************"
  10. 10 DEF FNP(X)=INT(10*180*X/PI+.5)/10
  11. 20 DEF FNQ(X)=INT(100*X+.5)/100
  12. 30 PI=3.141593
  13. 40 PRINT 
  14. 50 PRINT"   ENTER IMPEDANCE IN OHMS, SUSCEPTANCE IN MILLIMHOS"
  15. 60 PRINT"         ANGLES IN DEGREES"
  16. 70 PRINT 
  17. 80 PRINT"  ENTER LINE TYPE:NULL= RG-8A/U FAMILY"
  18. 90 PRINT"    OR ENTER TYPE, (RG-58/U, ETC), OR 300-TWIN/300-OPEN":INPUT TY$
  19. 100 PRINT:IF TY$="" THEN TY$="RG-8A/U"
  20. 110 IF TY$="RG-8A/U" THEN ZO=52:ML=.21:XP=.57:PF=29.5:VF=.66:GOTO 500
  21. 120 IF TY$="RG-8F/U" THEN ZO=50:ML=.15:XP=.53:PF=25.4:VF=.8:GOTO 500
  22. 130 IF TY$="RG-11A/U" THEN ZO=75:ML=.15:XP=.53:PF=20.6:VF=.66:GOTO 500
  23. 140 IF TY$="RG-58A/U" THEN ZO=53.5:ML=.33:XP=.58:PF=28.5:VF=.66:GOTO 500
  24. 150 IF TY$="RG-58F/U" THEN ZO=53.5:ML=.31:XP=.51:PF=28.5:VF=.79:GOTO 500
  25. 160 IF TY$="RG-59A/U" THEN ZO=73:ML=.31:XP=.51:PF=21:VF=.66:GOTO 500
  26. 170 IF TY$="RG-213/U" THEN ZO=50:ML=.15:XP=.56:PF=30.8:VF=.66:GOTO 500
  27. 180 IF TY$="RG-246/U" THEN ZO=75:ML=.048:XP=.48:PF=16.7:VF=.81:GOTO 500
  28. 190 IF TY$="RG-360/U" THEN ZO=50:ML=.06:XP=.55:PF=25:VF=.81:GOTO 500
  29. 200 IF TY$="30O-OPEN" THEN ZO=300:ML=8.999999E-03:XP=1.12:PF= 5:VF=.95:GOTO 500
  30. 210 IF TY$="30O-TWIN" THEN ZO=300:ML=.08:XP=.56:PF=4.6:VF=.95:GOTO 500
  31. 300 PRINT" TYPE  IS NOT IN FILE. ENTER, IN ORDER"
  32. 310 PRINT" ZO,LOSS MULTIPLIIER, LOSS EXPONENT"
  33. 320 INPUT ZO,ML,XP
  34. 330 PRINT" ENTER IN ORDER"
  35. 340 PRINT" CAPACITY PER FOOT, VELOCITY FACTOR"            
  36. 350 INPUT PF,VF
  37. 500 INPUT "ENTER DESIGN FREQUENCY, MHZ";FREQ
  38. 510 LAMBDA=299.8/FREQ
  39. 520 LAMLINE=LAMBDA*VF
  40. 530 DTORAD=1/57.3
  41. 600 PRINT 
  42. 610 PRINT " LINE CHARACTERISTICS ARE"
  43. 620 PRINT "    CHARACTERISTIC IMPEDANCE=";ZO;" OHMS"
  44. 630 PRINT "             VELOCITY FACTOR=";VF
  45. 640 PRINT "           LOSS PER 100 FEET=";ML* FREQ^XP
  46. 650 PRINT " WAVELENTH IN AIR=;"LAMBDA;"METERS OR ";LAMBDA*3.28;"FEET"
  47. 660 PRINT "   WAVELENTH IN LINE=";LAMLINE;"METERS OR ";LAMLINE*3.28;"FEET"
  48. 670 PRINT  
  49. 2500 PRINT "SELECT STUB MATCH CONDITIONS"
  50. 2510 PRINT "   ENTER 1=SWR ONLY KNOWN"
  51. 2520 PRINT "         2=IMPEDANCE KNOWN"
  52. 2530 PRINT "         3=ADMITANCE KNOWN"
  53. 2540 PRINT "         4=QUIT"
  54. 2550 INPUT TE
  55. 2560 PRINT 
  56. 2570 ON TE GOTO 2600,2700,2800,30000,2510
  57. 2600 INPUT "ENTER SWR";SM
  58. 2610 PRINT 
  59. 2620 PRINT"MEASURE STUB POSITIONS FROM CURRENT MAXIMUM NEAREST LOAD"
  60. 2630 SM=1/SM:SA=0
  61. 2640 GOTO 3000
  62. 2700 INPUT "ENTER IMPEDANCE (OHMS),ANGLE (DEG)";SM,SA:SM=SM/ZO:SA=SA*DTORAD
  63. 2720 SM=1/SM:SA=-SA
  64. 2730 GOTO 3000
  65. 2800 INPUT "ENTER ADMITANCE (MILLIMHOS),ANGLE (DEG)";SM,SA:SM=SM*ZO/1000:SA=SA*DTORAD
  66. 2900 PRINT 
  67. 2910 PRINT" MEASURE STUB POSITIONS FROM LOAD"
  68. 3000 TP=SM:TQ=SA
  69. 3010 SM=TP*COS(TQ):SA=TP*SIN(TQ)
  70. 3020 TV=SQR(((SM-1)*(SM-1)+SA*SA)/SM)
  71. 3030 LO=ATN(TV)
  72. 3040 IF MO<0 THEN MO=PI+MO
  73. 3050 MO=ATN((SM-1)/(SM*TV-SA))
  74. 3060 IF MO<0 THEN MO=PI+MO
  75. 3070 TV=SQR(((1-SM)*(1-SM)+SA*SA)/SM)
  76. 3080 IF MS<0 THEN MS=PI+MS
  77. 3090 LS=ATN(1/TV)
  78. 3100 MS=ATN((1-SM)/(SM*TV+SA))
  79. 3110 IF MS<0 THEN MS=PI+MS
  80. 5000 PRINT 
  81. 5010 PRINT"   OPEN STUB POSITION=";FNP(MO);"DEG"
  82. 5020 PRINT"               LENGTH=";FNP(LO);"DEG"
  83. 5030 PRINT
  84. 5040 PRINT"SHORTED STUB POSITION=";FNP(MS);"DEG"
  85. 5050 PRINT"               LENGTH=";FNP(LS);"DEG"
  86. 6000 PRINT 
  87. 6010 PRINT "FOR LINE TYPE ";TY$
  88. 6020 POSO=MO*LAMLINE/2/PI
  89. 6030 PRINT "      OPEN STUB POSITION=";FNQ(POSO);"METERS"
  90. 6040 PRINT "                        =";FNQ(POSO*3.28);"FEET"
  91. 6050 LENO=LO*LAMLINE/2/PI
  92. 6060 PRINT "                  LENGTH=";FNQ(LENO);"METERS"
  93. 6070 PRINT "                        =";FNQ(LENO*3.28);"FEET"
  94. 6080 PRINT
  95. 7000 POSS=MS*LAMLINE/2/PI
  96. 7010 PRINT "   SHORTED STUB POSITION=";FNQ(POSS);"METERS"
  97. 7020 PRINT "                        =";FNQ(POSS*3.28);"FEET"
  98. 7030 LENS=LS*LAMLINE/2/PI
  99. 7040 PRINT "                  LENGTH=";FNQ(LENS);"METERS"
  100. 7050 PRINT "                        =";FNQ(LENS*3.28);"FEET"
  101. 7060 PRINT 
  102. 8000 PRINT :INPUT "PRESS RETURN FOR MORE";T$
  103. 8010 PRINT 
  104. 10000 GOTO 2500
  105. 30000 END
  106.